t/db_dependent/Koha/Object.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 21;
  21 use Test::Exception;
  22 use Test::Warn;
  23 use DateTime;
  24
  25 use C4::Context;
  26 use C4::Circulation qw( AddIssue );
  27 use C4::Biblio qw( AddBiblio );
  28
  29 use Koha::Database;
  30
  31 use Koha::Acquisition::Orders;
  32 use Koha::DateUtils qw( dt_from_string );
  33 use Koha::Libraries;
  34 use Koha::Patrons;
  35 use Koha::Library::Groups;
  36
  37 use JSON;
  38 use Scalar::Util qw( isvstring );
  39 use Try::Tiny;
  40
  41 use t::lib::TestBuilder;
  42 use t::lib::Mocks;
  43
  44 BEGIN {
  45     use_ok('Koha::Object');
  46     use_ok('Koha::Patron');
  47 }
  48
  49 my $schema  = Koha::Database->new->schema;
  50 my $builder = t::lib::TestBuilder->new();
  51
  52 subtest 'is_changed / make_column_dirty' => sub {
  53     plan tests => 11;
  54
  55     $schema->storage->txn_begin;
  56
  57     my $categorycode = $builder->build({ source => 'Category' })->{categorycode};
  58     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
  59
  60     my $object = Koha::Patron->new();
  61     $object->categorycode( $categorycode );
  62     $object->branchcode( $branchcode );
  63     $object->surname("Test Surname");
  64     $object->store->discard_changes;
  65     is( $object->is_changed(), 0, "Object is unchanged" );
  66     $object->surname("Test Surname");
  67     is( $object->is_changed(), 0, "Object is still unchanged" );
  68     $object->surname("Test Surname 2");
  69     is( $object->is_changed(), 1, "Object is changed" );
  70
  71     $object->store();
  72     is( $object->is_changed(), 0, "Object no longer marked as changed after being stored" );
  73
  74     $object->set({ firstname => 'Test Firstname' });
  75     is( $object->is_changed(), 1, "Object is changed after Set" );
  76     $object->store();
  77     is( $object->is_changed(), 0, "Object no longer marked as changed after being stored" );
  78
  79     # Test make_column_dirty
  80     is( $object->make_column_dirty('firstname'), '', 'make_column_dirty returns empty string on success' );
  81     is( $object->make_column_dirty('firstname'), 1, 'make_column_dirty returns 1 if already dirty' );
  82     is( $object->is_changed, 1, "Object is changed after make dirty" );
  83     $object->store;
  84     is( $object->is_changed, 0, "Store clears dirty mark" );
  85     $object->make_column_dirty('firstname');
  86     $object->discard_changes;
  87     is( $object->is_changed, 0, "Discard clears dirty mark too" );
  88
  89     $schema->storage->txn_rollback;
  90 };
  91
  92 subtest 'in_storage' => sub {
  93     plan tests => 6;
  94
  95     $schema->storage->txn_begin;
  96
  97     my $categorycode = $builder->build({ source => 'Category' })->{categorycode};
  98     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
  99
 100     my $object = Koha::Patron->new();
 101     is( $object->in_storage, 0, "Object is not in storage" );
 102     $object->categorycode( $categorycode );
 103     $object->branchcode( $branchcode );
 104     $object->surname("Test Surname");
 105     $object->store();
 106     is( $object->in_storage, 1, "Object is now stored" );
 107     $object->surname("another surname");
 108     is( $object->in_storage, 1 );
 109
 110     my $borrowernumber = $object->borrowernumber;
 111     my $patron = $schema->resultset('Borrower')->find( $borrowernumber );
 112     is( $patron->surname(), "Test Surname", "Object found in database" );
 113
 114     $object->delete();
 115     $patron = $schema->resultset('Borrower')->find( $borrowernumber );
 116     ok( ! $patron, "Object no longer found in database" );
 117     is( $object->in_storage, 0, "Object is not in storage" );
 118
 119     $schema->storage->txn_rollback;
 120 };
 121
 122 subtest 'id' => sub {
 123     plan tests => 1;
 124
 125     $schema->storage->txn_begin;
 126
 127     my $categorycode = $builder->build({ source => 'Category' })->{categorycode};
 128     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 129
 130     my $patron = Koha::Patron->new({categorycode => $categorycode, branchcode => $branchcode })->store;
 131     is( $patron->id, $patron->borrowernumber );
 132
 133     $schema->storage->txn_rollback;
 134 };
 135
 136 subtest 'get_column' => sub {
 137     plan tests => 1;
 138
 139     $schema->storage->txn_begin;
 140
 141     my $categorycode = $builder->build({ source => 'Category' })->{categorycode};
 142     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 143
 144     my $patron = Koha::Patron->new({categorycode => $categorycode, branchcode => $branchcode })->store;
 145     is( $patron->get_column('borrowernumber'), $patron->borrowernumber, 'get_column should retrieve the correct value' );
 146
 147     $schema->storage->txn_rollback;
 148 };
 149
 150 subtest 'discard_changes' => sub {
 151     plan tests => 1;
 152
 153     $schema->storage->txn_begin;
 154
 155     my $patron = $builder->build( { source => 'Borrower' } );
 156     $patron = Koha::Patrons->find( $patron->{borrowernumber} );
 157     $patron->dateexpiry(dt_from_string);
 158     $patron->discard_changes;
 159     is(
 160         dt_from_string( $patron->dateexpiry ),
 161         dt_from_string->truncate( to => 'day' ),
 162         'discard_changes should refresh the object'
 163     );
 164
 165     $schema->storage->txn_rollback;
 166 };
 167
 168 subtest 'TO_JSON tests' => sub {
 169
 170     plan tests => 9;
 171
 172     $schema->storage->txn_begin;
 173
 174     my $dt = dt_from_string();
 175     my $borrowernumber = $builder->build(
 176         { source => 'Borrower',
 177           value => { lost => 1,
 178                      sms_provider_id => undef,
 179                      gonenoaddress => 0,
 180                      updated_on => $dt,
 181                      lastseen   => $dt, } })->{borrowernumber};
 182
 183     my $patron = Koha::Patrons->find($borrowernumber);
 184     my $lost = $patron->TO_JSON()->{lost};
 185     my $gonenoaddress = $patron->TO_JSON->{gonenoaddress};
 186     my $updated_on = $patron->TO_JSON->{updated_on};
 187     my $lastseen = $patron->TO_JSON->{lastseen};
 188
 189     ok( $lost->isa('JSON::PP::Boolean'), 'Boolean attribute type is correct' );
 190     is( $lost, 1, 'Boolean attribute value is correct (true)' );
 191
 192     ok( $gonenoaddress->isa('JSON::PP::Boolean'), 'Boolean attribute type is correct' );
 193     is( $gonenoaddress, 0, 'Boolean attribute value is correct (false)' );
 194
 195     is( $patron->TO_JSON->{sms_provider_id}, undef, 'Undef values should not be casted to 0' );
 196
 197     ok( !isvstring($patron->borrowernumber), 'Integer values are not coded as strings' );
 198
 199     my $rfc3999_regex = qr/
 200             (?<year>\d{4})
 201             -
 202             (?<month>\d{2})
 203             -
 204             (?<day>\d{2})
 205             ([Tt\s])
 206             (?<hour>\d{2})
 207             :
 208             (?<minute>\d{2})
 209             :
 210             (?<second>\d{2})
 211             (([Zz])|([\+|\-]([01][0-9]|2[0-3]):[0-5][0-9]))
 212         /xms;
 213     like( $updated_on, $rfc3999_regex, "Date-time $updated_on formatted correctly");
 214     like( $lastseen, $rfc3999_regex, "Date-time $updated_on formatted correctly");
 215
 216     # Test JSON doesn't receive strings
 217     my $order = $builder->build_object({ class => 'Koha::Acquisition::Orders' });
 218     $order = Koha::Acquisition::Orders->find( $order->ordernumber );
 219     is_deeply( $order->TO_JSON, decode_json( encode_json( $order->TO_JSON ) ), 'Orders are similar' );
 220
 221     $schema->storage->txn_rollback;
 222 };
 223
 224 subtest "to_api() tests" => sub {
 225
 226     plan tests => 28;
 227
 228     $schema->storage->txn_begin;
 229
 230     my $city = $builder->build_object({ class => 'Koha::Cities' });
 231
 232     # THE mapping
 233     # cityid       => 'city_id',
 234     # city_country => 'country',
 235     # city_name    => 'name',
 236     # city_state   => 'state',
 237     # city_zipcode => 'postal_code'
 238
 239     my $api_city = $city->to_api;
 240
 241     is( $api_city->{city_id},     $city->cityid,       'Attribute translated correctly' );
 242     is( $api_city->{country},     $city->city_country, 'Attribute translated correctly' );
 243     is( $api_city->{name},        $city->city_name,    'Attribute translated correctly' );
 244     is( $api_city->{state},       $city->city_state,   'Attribute translated correctly' );
 245     is( $api_city->{postal_code}, $city->city_zipcode, 'Attribute translated correctly' );
 246
 247     # Lets emulate an undef
 248     my $city_class = Test::MockModule->new('Koha::City');
 249     $city_class->mock( 'to_api_mapping',
 250         sub {
 251             return {
 252                 cityid       => 'city_id',
 253                 city_country => 'country',
 254                 city_name    => 'name',
 255                 city_state   => 'state',
 256                 city_zipcode => undef
 257             };
 258         }
 259     );
 260
 261     $api_city = $city->to_api;
 262
 263     is( $api_city->{city_id},     $city->cityid,       'Attribute translated correctly' );
 264     is( $api_city->{country},     $city->city_country, 'Attribute translated correctly' );
 265     is( $api_city->{name},        $city->city_name,    'Attribute translated correctly' );
 266     is( $api_city->{state},       $city->city_state,   'Attribute translated correctly' );
 267     ok( !exists $api_city->{postal_code}, 'Attribute removed' );
 268
 269     # Pick a class that won't have a mapping for the API
 270     my $illrequest = $builder->build_object({ class => 'Koha::Illrequests' });
 271     is_deeply( $illrequest->to_api, $illrequest->TO_JSON, 'If no overloaded to_api_mapping method, return TO_JSON' );
 272
 273     my $biblio = $builder->build_sample_biblio();
 274     my $item = $builder->build_sample_item({ biblionumber => $biblio->biblionumber });
 275     my $hold = $builder->build_object({ class => 'Koha::Holds', value => { itemnumber => $item->itemnumber } });
 276
 277     my $embeds = { 'items' => {} };
 278
 279     my $biblio_api = $biblio->to_api({ embed => $embeds });
 280
 281     ok(exists $biblio_api->{items}, 'Items where embedded in biblio results');
 282     is($biblio_api->{items}->[0]->{item_id}, $item->itemnumber, 'Item matches');
 283     ok(!exists $biblio_api->{items}->[0]->{holds}, 'No holds info should be embedded yet');
 284
 285     $embeds = (
 286         {
 287             'items' => {
 288                 'children' => {
 289                     'holds' => {}
 290                 }
 291             },
 292             'biblioitem' => {}
 293         }
 294     );
 295     $biblio_api = $biblio->to_api({ embed => $embeds });
 296
 297     ok(exists $biblio_api->{items}, 'Items where embedded in biblio results');
 298     is($biblio_api->{items}->[0]->{item_id}, $item->itemnumber, 'Item still matches');
 299     ok(exists $biblio_api->{items}->[0]->{holds}, 'Holds info should be embedded');
 300     is($biblio_api->{items}->[0]->{holds}->[0]->{hold_id}, $hold->reserve_id, 'Hold matches');
 301     is_deeply($biblio_api->{biblioitem}, $biblio->biblioitem->to_api, 'More than one root');
 302
 303     my $hold_api = $hold->to_api(
 304         {
 305             embed => { 'item' => {} }
 306         }
 307     );
 308
 309     is( ref($hold_api->{item}), 'HASH', 'Single nested object works correctly' );
 310     is( $hold_api->{item}->{item_id}, $item->itemnumber, 'Object embedded correctly' );
 311
 312     # biblio with no items
 313     my $new_biblio = $builder->build_sample_biblio;
 314     my $new_biblio_api = $new_biblio->to_api({ embed => $embeds });
 315
 316     is_deeply( $new_biblio_api->{items}, [], 'Empty list if no items' );
 317
 318     my $biblio_class = Test::MockModule->new('Koha::Biblio');
 319     $biblio_class->mock( 'undef_result', sub { return; } );
 320
 321     $new_biblio_api = $new_biblio->to_api({ embed => ( { 'undef_result' => {} } ) });
 322     ok( exists $new_biblio_api->{undef_result}, 'If a method returns undef, then the attribute is defined' );
 323     is( $new_biblio_api->{undef_result}, undef, 'If a method returns undef, then the attribute is undef' );
 324
 325     $biblio_class->mock( 'items',
 326         sub { return [ bless { itemnumber => 1 }, 'Somethings' ]; } );
 327
 328     throws_ok {
 329         $new_biblio_api = $new_biblio->to_api(
 330             { embed => { 'items' => { children => { asd => {} } } } } );
 331     }
 332     'Koha::Exceptions::Exception',
 333 "An exception is thrown if a blessed object to embed doesn't implement to_api";
 334
 335     is(
 336         "$@",
 337         "Asked to embed items but its return value doesn't implement to_api",
 338         "Exception message correct"
 339     );
 340
 341
 342     my $patron = $builder->build_object( { class => 'Koha::Patrons' } );
 343     $builder->build_object(
 344         {
 345             class => 'Koha::Holds',
 346             value => {
 347                 biblionumber   => $biblio->biblionumber,
 348                 borrowernumber => $patron->borrowernumber
 349             }
 350         }
 351     );
 352     $builder->build_object(
 353         {
 354             class => 'Koha::Holds',
 355             value => {
 356                 biblionumber   => $biblio->biblionumber,
 357                 borrowernumber => $patron->borrowernumber
 358             }
 359         }
 360     );
 361
 362     my $patron_api = $patron->to_api(
 363         {
 364             embed => { holds_count => { is_count => 1 } }
 365         }
 366     );
 367     is( $patron_api->{holds_count}, $patron->holds->count, 'Count embeds are supported and work as expected' );
 368
 369     throws_ok
 370         {
 371             $patron->to_api({ embed => { holds_count => {} } });
 372         }
 373         'Koha::Exceptions::Object::MethodNotCoveredByTests',
 374         'Unknown method exception thrown if is_count not specified';
 375
 376     $schema->storage->txn_rollback;
 377 };
 378
 379 subtest "to_api_mapping() tests" => sub {
 380
 381     plan tests => 1;
 382
 383     $schema->storage->txn_begin;
 384
 385     my $illrequest = $builder->build_object({ class => 'Koha::Illrequests' });
 386     is_deeply( $illrequest->to_api_mapping, {}, 'If no to_api_mapping present, return empty hashref' );
 387
 388     $schema->storage->txn_rollback;
 389 };
 390
 391 subtest "from_api_mapping() tests" => sub {
 392
 393     plan tests => 5;
 394
 395     $schema->storage->txn_begin;
 396
 397     my $city = $builder->build_object({ class => 'Koha::Cities' });
 398
 399     # Lets emulate an undef
 400     my $city_class = Test::MockModule->new('Koha::City');
 401     $city_class->mock( 'to_api_mapping',
 402         sub {
 403             return {
 404                 cityid       => 'city_id',
 405                 city_country => 'country',
 406                 city_zipcode => undef
 407             };
 408         }
 409     );
 410
 411     is_deeply(
 412         $city->from_api_mapping,
 413         {
 414             city_id => 'cityid',
 415             country => 'city_country'
 416         },
 417         'Mapping returns correctly, undef ommited'
 418     );
 419
 420     $city_class->unmock( 'to_api_mapping');
 421     $city_class->mock( 'to_api_mapping',
 422         sub {
 423             return {
 424                 cityid       => 'city_id',
 425                 city_country => 'country',
 426                 city_zipcode => 'postal_code'
 427             };
 428         }
 429     );
 430
 431     is_deeply(
 432         $city->from_api_mapping,
 433         {
 434             city_id => 'cityid',
 435             country => 'city_country'
 436         },
 437         'Reverse mapping is cached'
 438     );
 439
 440     # Get a fresh object
 441     $city = $builder->build_object({ class => 'Koha::Cities' });
 442     is_deeply(
 443         $city->from_api_mapping,
 444         {
 445             city_id     => 'cityid',
 446             country     => 'city_country',
 447             postal_code => 'city_zipcode'
 448         },
 449         'Fresh mapping loaded'
 450     );
 451
 452     $city_class->unmock( 'to_api_mapping');
 453     $city_class->mock( 'to_api_mapping', undef );
 454
 455     # Get a fresh object
 456     $city = $builder->build_object({ class => 'Koha::Cities' });
 457     is_deeply(
 458         $city->from_api_mapping,
 459         {},
 460         'No to_api_mapping then empty hashref'
 461     );
 462
 463     $city_class->unmock( 'to_api_mapping');
 464     $city_class->mock( 'to_api_mapping', sub { return; } );
 465
 466     # Get a fresh object
 467     $city = $builder->build_object({ class => 'Koha::Cities' });
 468     is_deeply(
 469         $city->from_api_mapping,
 470         {},
 471         'Empty to_api_mapping then empty hashref'
 472     );
 473
 474     $schema->storage->txn_rollback;
 475 };
 476
 477 subtest 'set_from_api() tests' => sub {
 478
 479     plan tests => 4;
 480
 481     $schema->storage->txn_begin;
 482
 483     my $city = $builder->build_object({ class => 'Koha::Cities' });
 484     my $city_unblessed = $city->unblessed;
 485     my $attrs = {
 486         name        => 'Cordoba',
 487         country     => 'Argentina',
 488         postal_code => '5000'
 489     };
 490     $city->set_from_api($attrs);
 491
 492     is( $city->city_state, $city_unblessed->{city_state}, 'Untouched attributes are preserved' );
 493     is( $city->city_name, $attrs->{name}, 'city_name updated correctly' );
 494     is( $city->city_country, $attrs->{country}, 'city_country updated correctly' );
 495     is( $city->city_zipcode, $attrs->{postal_code}, 'city_zipcode updated correctly' );
 496
 497     $schema->storage->txn_rollback;
 498 };
 499
 500 subtest 'new_from_api() tests' => sub {
 501
 502     plan tests => 4;
 503
 504     $schema->storage->txn_begin;
 505
 506     my $attrs = {
 507         name        => 'Cordoba',
 508         country     => 'Argentina',
 509         postal_code => '5000'
 510     };
 511     my $city = Koha::City->new_from_api($attrs);
 512
 513     is( ref($city), 'Koha::City', 'Object type is correct' );
 514     is( $city->city_name,    $attrs->{name}, 'city_name updated correctly' );
 515     is( $city->city_country, $attrs->{country}, 'city_country updated correctly' );
 516     is( $city->city_zipcode, $attrs->{postal_code}, 'city_zipcode updated correctly' );
 517
 518     $schema->storage->txn_rollback;
 519 };
 520
 521 subtest 'attributes_from_api() tests' => sub {
 522
 523     plan tests => 12;
 524
 525     my $patron = Koha::Patron->new();
 526
 527     my $attrs = $patron->attributes_from_api(
 528         {
 529             updated_on => '2019-12-27T14:53:00',
 530         }
 531     );
 532
 533     ok( exists $attrs->{updated_on},
 534         'No translation takes place if no mapping' );
 535     is(
 536         ref( $attrs->{updated_on} ),
 537         'DateTime',
 538         'Given a string, a timestamp field is converted into a DateTime object'
 539     );
 540
 541     $attrs = $patron->attributes_from_api(
 542         {
 543             last_seen  => '2019-12-27T14:53:00'
 544         }
 545     );
 546
 547     ok( exists $attrs->{lastseen},
 548         'Translation takes place because of the defined mapping' );
 549     is(
 550         ref( $attrs->{lastseen} ),
 551         'DateTime',
 552         'Given a string, a datetime field is converted into a DateTime object'
 553     );
 554
 555     $attrs = $patron->attributes_from_api(
 556         {
 557             date_of_birth  => '2019-12-27'
 558         }
 559     );
 560
 561     ok( exists $attrs->{dateofbirth},
 562         'Translation takes place because of the defined mapping' );
 563     is(
 564         ref( $attrs->{dateofbirth} ),
 565         'DateTime',
 566         'Given a string, a date field is converted into a DateTime object'
 567     );
 568
 569     throws_ok
 570         {
 571             $attrs = $patron->attributes_from_api(
 572                 {
 573                     date_of_birth => '20141205',
 574                 }
 575             );
 576         }
 577         'Koha::Exceptions::BadParameter',
 578         'Bad date throws an exception';
 579
 580     is(
 581         $@->parameter,
 582         'date_of_birth',
 583         'Exception parameter is the API field name, not the DB one'
 584     );
 585
 586     # Booleans
 587     $attrs = $patron->attributes_from_api(
 588         {
 589             incorrect_address => Mojo::JSON->true,
 590             patron_card_lost  => Mojo::JSON->false,
 591         }
 592     );
 593
 594     ok( exists $attrs->{gonenoaddress}, 'Attribute gets translated' );
 595     is( $attrs->{gonenoaddress}, 1, 'Boolean correctly translated to integer (true => 1)' );
 596     ok( exists $attrs->{lost}, 'Attribute gets translated' );
 597     is( $attrs->{lost}, 0, 'Boolean correctly translated to integer (false => 0)' );
 598 };
 599
 600 subtest "Test update method" => sub {
 601     plan tests => 6;
 602
 603     $schema->storage->txn_begin;
 604
 605     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 606     my $library = Koha::Libraries->find( $branchcode );
 607     $library->update({ branchname => 'New_Name', branchcity => 'AMS' });
 608     is( $library->branchname, 'New_Name', 'Changed name with update' );
 609     is( $library->branchcity, 'AMS', 'Changed city too' );
 610     is( $library->is_changed, 0, 'Change should be stored already' );
 611     try {
 612         $library->update({
 613             branchcity => 'NYC', not_a_column => 53, branchname => 'Name3',
 614         });
 615         fail( 'It should not be possible to update an unexisting column without an error from Koha::Object/DBIx' );
 616     } catch {
 617         ok( $_->isa('Koha::Exceptions::Object'), 'Caught error when updating wrong column' );
 618         $library->discard_changes; #requery after failing update
 619     };
 620     # Check if the columns are not updated
 621     is( $library->branchcity, 'AMS', 'First column not updated' );
 622     is( $library->branchname, 'New_Name', 'Third column not updated' );
 623
 624     $schema->storage->txn_rollback;
 625 };
 626
 627 subtest 'store() tests' => sub {
 628
 629     plan tests => 16;
 630
 631     # Using Koha::Library::Groups to test Koha::Object>-store
 632     # Simple object with foreign keys and unique key
 633
 634     $schema->storage->txn_begin;
 635
 636     # Create a library to make sure its ID doesn't exist on the DB
 637     my $library = $builder->build_object({ class => 'Koha::Libraries' });
 638     my $branchcode = $library->branchcode;
 639     $library->delete;
 640
 641     my $library_group = Koha::Library::Group->new(
 642         {
 643             branchcode      => $library->branchcode,
 644             title => 'a title',
 645         }
 646     );
 647
 648     my $dbh = $schema->storage->dbh;
 649     {
 650         local *STDERR;
 651         open STDERR, '>', '/dev/null';
 652         throws_ok
 653             { $library_group->store }
 654             'Koha::Exceptions::Object::FKConstraint',
 655             'Exception is thrown correctly';
 656         is(
 657             $@->message,
 658             "Broken FK constraint",
 659             'Exception message is correct'
 660         );
 661         is(
 662             $@->broken_fk,
 663             'branchcode',
 664             'Exception field is correct'
 665         );
 666
 667         $library_group = $builder->build_object({ class => 'Koha::Library::Groups' });
 668
 669         my $new_library_group = Koha::Library::Group->new(
 670             {
 671                 branchcode      => $library_group->branchcode,
 672                 title        => $library_group->title,
 673             }
 674         );
 675
 676         throws_ok
 677             { $new_library_group->store }
 678             'Koha::Exceptions::Object::DuplicateID',
 679             'Exception is thrown correctly';
 680
 681         is(
 682             $@->message,
 683             'Duplicate ID',
 684             'Exception message is correct'
 685         );
 686
 687         like(
 688            $@->duplicate_id,
 689            qr/(library_groups\.)?title/,
 690            'Exception field is correct (note that MySQL 8 is displaying the tablename)'
 691         );
 692         close STDERR;
 693     }
 694
 695     # Successful test
 696     $library_group->set({ title => 'Manuel' });
 697     my $ret = $library_group->store;
 698     is( ref($ret), 'Koha::Library::Group', 'store() returns the object on success' );
 699
 700     $library = $builder->build_object( { class => 'Koha::Libraries' } );
 701     my $patron_category = $builder->build_object(
 702         {
 703             class => 'Koha::Patron::Categories',
 704             value => { category_type => 'P', enrolmentfee => 0 }
 705         }
 706     );
 707
 708     my $patron = eval {
 709         Koha::Patron->new(
 710             {
 711                 categorycode    => $patron_category->categorycode,
 712                 branchcode      => $library->branchcode,
 713                 dateofbirth     => "", # date will be set to NULL
 714                 sms_provider_id => "", # Integer will be set to NULL
 715                 privacy         => "", # privacy cannot be NULL but has a default value
 716             }
 717         )->store;
 718     };
 719     is( $@, '', 'No error should be raised by ->store if empty strings are passed' );
 720     is( $patron->privacy, 1, 'Default value for privacy should be set to 1' );
 721     is( $patron->dateofbirth,     undef, 'dateofbirth must have been set to undef');
 722     is( $patron->sms_provider_id, undef, 'sms_provider_id must have been set to undef');
 723
 724     my $itemtype = eval {
 725         Koha::ItemType->new(
 726             {
 727                 itemtype        => 'IT4test',
 728                 rentalcharge    => "",
 729                 notforloan      => "",
 730                 hideinopac      => "",
 731             }
 732         )->store;
 733     };
 734     is( $@, '', 'No error should be raised by ->store if empty strings are passed' );
 735     is( $itemtype->rentalcharge, undef, 'decimal DEFAULT NULL should default to null');
 736     is( $itemtype->notforloan, undef, 'int DEFAULT NULL should default to null');
 737     is( $itemtype->hideinopac, 0, 'int NOT NULL DEFAULT 0 should default to 0');
 738
 739     subtest 'Bad value tests' => sub {
 740
 741         plan tests => 3;
 742
 743         my $patron = $builder->build_object({ class => 'Koha::Patrons' });
 744
 745
 746         try {
 747             local *STDERR;
 748             open STDERR, '>', '/dev/null';
 749             $patron->lastseen('wrong_value')->store;
 750             close STDERR;
 751         } catch {
 752             ok( $_->isa('Koha::Exceptions::Object::BadValue'), 'Exception thrown correctly' );
 753             like( $_->property, qr/(borrowers\.)?lastseen/, 'Column should be the expected one' ); # The table name is not always displayed, it depends on the DBMS version
 754             is( $_->value, 'wrong_value', 'Value should be the expected one' );
 755         };
 756     };
 757
 758     $schema->storage->txn_rollback;
 759 };
 760
 761 subtest 'unblessed_all_relateds' => sub {
 762     plan tests => 3;
 763
 764     $schema->storage->txn_begin;
 765
 766     # FIXME It's very painful to create an issue in tests!
 767     my $library = $builder->build_object( { class => 'Koha::Libraries' } );
 768     t::lib::Mocks::mock_userenv({ branchcode => $library->branchcode });
 769
 770     my $patron_category = $builder->build(
 771         {
 772             source => 'Category',
 773             value  => {
 774                 category_type                 => 'P',
 775                 enrolmentfee                  => 0,
 776                 BlockExpiredPatronOpacActions => -1, # Pick the pref value
 777             }
 778         }
 779     );
 780     my $patron_data = {
 781         firstname =>  'firstname',
 782         surname => 'surname',
 783         categorycode => $patron_category->{categorycode},
 784         branchcode => $library->branchcode,
 785     };
 786     my $patron = Koha::Patron->new($patron_data)->store;
 787     my ($biblionumber) = AddBiblio( MARC::Record->new, '' );
 788     my $biblio = Koha::Biblios->find( $biblionumber );
 789     my $item = $builder->build_object(
 790         {
 791             class => 'Koha::Items',
 792             value => {
 793                 homebranch    => $library->branchcode,
 794                 holdingbranch => $library->branchcode,
 795                 biblionumber  => $biblio->biblionumber,
 796                 itemlost      => 0,
 797                 withdrawn     => 0,
 798             }
 799         }
 800     );
 801
 802     my $issue = AddIssue( $patron->unblessed, $item->barcode, DateTime->now->subtract( days => 1 ) );
 803     my $overdues = Koha::Patrons->find( $patron->id )->get_overdues; # Koha::Patron->get_overdue prefetches
 804     my $overdue = $overdues->next->unblessed_all_relateds;
 805     is( $overdue->{issue_id}, $issue->issue_id, 'unblessed_all_relateds has field from the original table (issues)' );
 806     is( $overdue->{title}, $biblio->title, 'unblessed_all_relateds has field from other tables (biblio)' );
 807     is( $overdue->{homebranch}, $item->homebranch, 'unblessed_all_relateds has field from other tables (items)' );
 808
 809     $schema->storage->txn_rollback;
 810 };
 811
 812 subtest 'get_from_storage' => sub {
 813     plan tests => 4;
 814
 815     $schema->storage->txn_begin;
 816
 817     my $biblio = $builder->build_sample_biblio;
 818
 819     my $old_title = $biblio->title;
 820     my $new_title = 'new_title';
 821     Koha::Biblios->find( $biblio->biblionumber )->title($new_title)->store;
 822
 823     is( $biblio->title, $old_title, 'current $biblio should not be modified' );
 824     is( $biblio->get_from_storage->title,
 825         $new_title, 'get_from_storage should return an updated object' );
 826
 827     Koha::Biblios->find( $biblio->biblionumber )->delete;
 828     is( ref($biblio), 'Koha::Biblio', 'current $biblio should not be deleted' );
 829     is( $biblio->get_from_storage, undef,
 830         'get_from_storage should return undef if the object has been deleted' );
 831
 832     $schema->storage->txn_rollback;
 833 };
 834
 835 subtest 'prefetch_whitelist() tests' => sub {
 836
 837     plan tests => 3;
 838
 839     $schema->storage->txn_begin;
 840
 841     my $biblio = Koha::Biblio->new;
 842
 843     my $prefetch_whitelist = $biblio->prefetch_whitelist;
 844
 845     ok(
 846         exists $prefetch_whitelist->{orders},
 847         'Relationship matching method name is listed'
 848     );
 849     is(
 850         $prefetch_whitelist->{orders},
 851         'Koha::Acquisition::Order',
 852         'Guessed the non-standard object class correctly'
 853     );
 854
 855     is(
 856         $prefetch_whitelist->{items},
 857         'Koha::Item',
 858         'Guessed the standard object class correctly'
 859     );
 860
 861     $schema->storage->txn_rollback;
 862 };
 863
 864 subtest 'set_or_blank' => sub {
 865
 866     plan tests => 5;
 867
 868     $schema->storage->txn_begin;
 869
 870     my $item = $builder->build_sample_item;
 871     my $item_info = $item->unblessed;
 872     $item = $item->set_or_blank($item_info);
 873     is_deeply($item->unblessed, $item_info, 'set_or_blank assign the correct value if unchanged');
 874
 875     # int not null
 876     delete $item_info->{itemlost};
 877     $item = $item->set_or_blank($item_info);
 878     is($item->itemlost, 0, 'set_or_blank should have set itemlost to 0, default value defined in DB');
 879
 880     # int nullable
 881     delete $item_info->{restricted};
 882     $item = $item->set_or_blank($item_info);
 883     is($item->restricted, undef, 'set_or_blank should have set restristed to null' );
 884
 885     # datetime nullable
 886     delete $item_info->{dateaccessioned};
 887     $item = $item->set_or_blank($item_info);
 888     is($item->dateaccessioned, undef, 'set_or_blank should have set dateaccessioned to null');
 889
 890     # timestamp not null
 891     delete $item_info->{timestamp};
 892     $item = $item->set_or_blank($item_info);
 893     isnt($item->timestamp, undef, 'set_or_blank should have set timestamp to a correct value');
 894
 895     $schema->storage->txn_rollback;
 896 };
 897
 898 subtest 'messages() and add_message() tests' => sub {
 899
 900     plan tests => 7;
 901
 902     $schema->storage->txn_begin;
 903
 904     my $patron = Koha::Patron->new;
 905
 906     my @messages = @{ $patron->messages };
 907     is( scalar @messages, 0, 'No messages' );
 908
 909     $patron->add_message({ message => "message_1" });
 910     $patron->add_message({ message => "message_2" });
 911
 912     @messages = @{ $patron->messages };
 913
 914     is( scalar @messages, 2, 'Messages are returned' );
 915     is( ref($messages[0]), 'Koha::Object::Message', 'Right type returned' );
 916     is( ref($messages[1]), 'Koha::Object::Message', 'Right type returned' );
 917     is( $messages[0]->message, 'message_1', 'Right message recorded' );
 918
 919     my $patron_id = $builder->build_object({ class => 'Koha::Patrons' })->id;
 920     # get a patron from the DB, ->new is not called, ->messages should initialize _messages as an empty arrayref
 921     $patron = Koha::Patrons->find( $patron_id );
 922
 923     isnt( $patron->messages, undef, '->messages initializes the array if required' );
 924     is( scalar @{ $patron->messages }, 0, '->messages returns an empty arrayref' );
 925
 926     $schema->storage->txn_rollback;
 927 };