t/db_dependent/Koha/Objects.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 15;
  23 use Test::Warn;
  24
  25 use Koha::Authority::Types;
  26 use Koha::Cities;
  27 use Koha::IssuingRules;
  28 use Koha::Patron::Category;
  29 use Koha::Patron::Categories;
  30 use Koha::Patrons;
  31 use Koha::Database;
  32
  33 use t::lib::TestBuilder;
  34
  35 use Try::Tiny;
  36
  37 my $schema = Koha::Database->new->schema;
  38 $schema->storage->txn_begin;
  39 my $builder = t::lib::TestBuilder->new;
  40
  41 is( ref(Koha::Authority::Types->find('')), 'Koha::Authority::Type', 'Koha::Objects->find should work if the primary key is an empty string' );
  42
  43 my @columns = Koha::Patrons->columns;
  44 my $borrowernumber_exists = grep { /^borrowernumber$/ } @columns;
  45 is( $borrowernumber_exists, 1, 'Koha::Objects->columns should return the table columns' );
  46
  47 subtest 'find' => sub {
  48     plan tests => 4;
  49     my $patron = $builder->build({source => 'Borrower'});
  50     my $patron_object = Koha::Patrons->find( $patron->{borrowernumber} );
  51     is( $patron_object->borrowernumber, $patron->{borrowernumber}, '->find should return the correct object' );
  52
  53     eval { my @patrons = Koha::Patrons->find( $patron->{borrowernumber} ); };
  54     like( $@, qr|^Cannot use "->find" in list context|, "->find should not be called in list context to avoid side-effects" );
  55
  56     # Test sending undef to find; should not generate a warning
  57     warning_is { $patron = Koha::Patrons->find( undef ); }
  58         "", "Sending undef does not trigger a DBIx warning";
  59     warning_is { $patron = Koha::Patrons->find( undef, undef ); }
  60         "", "Sending two undefs does not trigger a DBIx warning too";
  61 };
  62
  63 subtest 'update' => sub {
  64     plan tests => 2;
  65
  66     $builder->build( { source => 'City', value => { city_country => 'UK' } } );
  67     $builder->build( { source => 'City', value => { city_country => 'UK' } } );
  68     $builder->build( { source => 'City', value => { city_country => 'UK' } } );
  69     $builder->build( { source => 'City', value => { city_country => 'France' } } );
  70     $builder->build( { source => 'City', value => { city_country => 'France' } } );
  71     $builder->build( { source => 'City', value => { city_country => 'Germany' } } );
  72     Koha::Cities->search( { city_country => 'UK' } )->update( { city_country => 'EU' } );
  73     is( Koha::Cities->search( { city_country => 'EU' } )->count, 3, 'Koha::Objects->update should have updated the 3 rows' );
  74     is( Koha::Cities->search( { city_country => 'UK' } )->count, 0, 'Koha::Objects->update should have updated the 3 rows' );
  75 };
  76
  77 subtest 'reset' => sub {
  78     plan tests => 3;
  79
  80     my $patrons = Koha::Patrons->search;
  81     my $first_borrowernumber = $patrons->next->borrowernumber;
  82     my $second_borrowernumber = $patrons->next->borrowernumber;
  83     is( ref( $patrons->reset ), 'Koha::Patrons', 'Koha::Objects->reset should allow chaining' );
  84     is( ref( $patrons->reset->next ), 'Koha::Patron', 'Koha::Objects->reset should allow chaining' );
  85     is( $patrons->reset->next->borrowernumber, $first_borrowernumber, 'Koha::Objects->reset should work as expected');
  86 };
  87
  88 subtest 'delete' => sub {
  89     plan tests => 2;
  90
  91     my $patron_1 = $builder->build({source => 'Borrower'});
  92     my $patron_2 = $builder->build({source => 'Borrower'});
  93     is( Koha::Patrons->search({ -or => { borrowernumber => [ $patron_1->{borrowernumber}, $patron_2->{borrowernumber}]}})->delete, 2, '');
  94     is( Koha::Patrons->search({ -or => { borrowernumber => [ $patron_1->{borrowernumber}, $patron_2->{borrowernumber}]}})->count, 0, '');
  95 };
  96
  97 subtest 'not_covered_yet' => sub {
  98     plan tests => 1;
  99     warning_is { Koha::Patrons->search->not_covered_yet } { carped => 'The method not_covered_yet is not covered by tests' }, "If a method is not covered by tests, the AUTOLOAD method won't execute the method";
 100 };
 101 subtest 'new' => sub {
 102     plan tests => 2;
 103     my $a_cat_code = 'A_CAT_CODE';
 104     my $patron_category = Koha::Patron::Category->new( { categorycode => $a_cat_code } )->store;
 105     is( Koha::Patron::Categories->find($a_cat_code)->category_type, 'A', 'Koha::Object->new should set the default value' );
 106     Koha::Patron::Categories->find($a_cat_code)->delete;
 107     $patron_category = Koha::Patron::Category->new( { categorycode => $a_cat_code, category_type => undef } )->store;
 108     is( Koha::Patron::Categories->find($a_cat_code)->category_type, 'A', 'Koha::Object->new should set the default value even if the argument exists but is not defined' );
 109     Koha::Patron::Categories->find($a_cat_code)->delete;
 110 };
 111
 112 subtest 'find' => sub {
 113     plan tests => 5;
 114
 115     # check find on a single PK
 116     my $patron = $builder->build({ source => 'Borrower' });
 117     is( Koha::Patrons->find($patron->{borrowernumber})->surname,
 118         $patron->{surname}, "Checking an arbitrary patron column after find"
 119     );
 120     # check find with unique column
 121     my $obj = Koha::Patrons->find($patron->{cardnumber}, { key => 'cardnumber' });
 122     is( $obj->borrowernumber, $patron->{borrowernumber},
 123         'Find with unique column and key specified' );
 124     # check find with an additional where clause in the attrs hash
 125     # we do not expect to find something now
 126     is( Koha::Patrons->find(
 127         $patron->{borrowernumber},
 128         { where => { surname => { '!=', $patron->{surname} }}},
 129     ), undef, 'Additional where clause in find call' );
 130
 131     # check find with a composite FK
 132     my $rule = $builder->build({ source => 'Issuingrule' });
 133     my @pk = ( $rule->{branchcode}, $rule->{categorycode}, $rule->{itemtype} );
 134     is( ref(Koha::IssuingRules->find(@pk)), "Koha::IssuingRule",
 135         'Find returned a Koha object for composite primary key' );
 136
 137     is( Koha::Patrons->find(), undef, 'Find returns undef if no params passed' );
 138 };
 139
 140 subtest 'search_related' => sub {
 141     plan tests => 8;
 142     my $builder   = t::lib::TestBuilder->new;
 143     my $patron_1  = $builder->build( { source => 'Borrower' } );
 144     my $patron_2  = $builder->build( { source => 'Borrower' } );
 145     my $libraries = Koha::Patrons->search( { -or => { borrowernumber => [ $patron_1->{borrowernumber}, $patron_2->{borrowernumber} ] } } )->search_related('branchcode');
 146     is( ref( $libraries ), 'Koha::Libraries', 'Koha::Objects->search_related should return an instanciated Koha::Objects-based object' );
 147     is( $libraries->count,            2,                       'Koha::Objects->search_related should work as expected' );
 148     is( $libraries->next->branchcode, $patron_1->{branchcode}, 'Koha::Objects->search_related should work as expected' );
 149     is( $libraries->next->branchcode, $patron_2->{branchcode}, 'Koha::Objects->search_related should work as expected' );
 150
 151     my @libraries = Koha::Patrons->search( { -or => { borrowernumber => [ $patron_1->{borrowernumber}, $patron_2->{borrowernumber} ] } } )->search_related('branchcode');
 152     is( ref( $libraries[0] ),      'Koha::Library',         'Koha::Objects->search_related should return a list of Koha::Object-based objects' );
 153     is( scalar(@libraries),        2,                       'Koha::Objects->search_related should work as expected' );
 154     is( $libraries[0]->branchcode, $patron_1->{branchcode}, 'Koha::Objects->search_related should work as expected' );
 155     is( $libraries[1]->branchcode, $patron_2->{branchcode}, 'Koha::Objects->search_related should work as expected' );
 156 };
 157
 158 subtest 'single' => sub {
 159     plan tests => 2;
 160     my $builder   = t::lib::TestBuilder->new;
 161     my $patron_1  = $builder->build( { source => 'Borrower' } );
 162     my $patron_2  = $builder->build( { source => 'Borrower' } );
 163     my $patron = Koha::Patrons->search({}, { rows => 1 })->single;
 164     is(ref($patron), 'Koha::Patron', 'Koha::Objects->single returns a single Koha::Patron object.');
 165     warning_like { Koha::Patrons->search->single } qr/SQL that returns multiple rows/,
 166     "Warning is presented if single is used for a result with multiple rows.";
 167 };
 168
 169 subtest 'last' => sub {
 170     plan tests => 3;
 171     my $builder = t::lib::TestBuilder->new;
 172     my $patron_1  = $builder->build( { source => 'Borrower' } );
 173     my $patron_2  = $builder->build( { source => 'Borrower' } );
 174     my $last_patron = Koha::Patrons->search->last;
 175     is( $last_patron->borrowernumber, $patron_2->{borrowernumber}, '->last should return the last inserted patron' );
 176     $last_patron = Koha::Patrons->search({ borrowernumber => $patron_1->{borrowernumber} })->last;
 177     is( $last_patron->borrowernumber, $patron_1->{borrowernumber}, '->last should work even if there is only 1 result' );
 178     $last_patron = Koha::Patrons->search({ surname => 'should_not_exist' })->last;
 179     is( $last_patron, undef, '->last should return undef if search does not return any results' );
 180 };
 181
 182 subtest 'get_column' => sub {
 183     plan tests => 1;
 184     my @cities = Koha::Cities->search;
 185     my @city_names = map { $_->city_name } @cities;
 186     is_deeply( [ Koha::Cities->search->get_column('city_name') ], \@city_names, 'Koha::Objects->get_column should be allowed' );
 187 };
 188
 189 subtest 'Exceptions' => sub {
 190     plan tests => 2;
 191
 192     my $patron_borrowernumber = $builder->build({ source => 'Borrower' })->{ borrowernumber };
 193     my $patron = Koha::Patrons->find( $patron_borrowernumber );
 194
 195     try {
 196         $patron->blah('blah');
 197     } catch {
 198         ok( $_->isa('Koha::Exceptions::Object::MethodNotCoveredByTests'),
 199             'Calling a non-covered method should raise a Koha::Exceptions::Object::MethodNotCoveredByTests exception' );
 200     };
 201
 202     try {
 203         $patron->set({ blah => 'blah' });
 204     } catch {
 205         ok( $_->isa('Koha::Exceptions::Object::PropertyNotFound'),
 206             'Setting a non-existent property should raise a Koha::Exceptions::Object::PropertyNotFound exception' );
 207     };
 208 };
 209
 210 $schema->storage->txn_rollback;
 211
 212 subtest '->is_paged and ->pager tests' => sub {
 213
 214     plan tests => 5;
 215
 216     $schema->storage->txn_begin;
 217
 218     # Delete existing patrons
 219     Koha::Checkouts->delete;
 220     Koha::Patrons->delete;
 221     # Create 10 patrons
 222     foreach (1..10) {
 223         $builder->build_object({ class => 'Koha::Patrons' });
 224     }
 225
 226     # Non-paginated search
 227     my $patrons = Koha::Patrons->search();
 228     is( $patrons->count, 10, 'Search returns all patrons' );
 229     ok( !$patrons->is_paged, 'Search is not paged' );
 230
 231     # Paginated search
 232     $patrons = Koha::Patrons->search( undef, { 'page' => 1, 'rows' => 3 } );
 233     is( $patrons->count, 3, 'Search returns only one page, 3 patrons' );
 234     ok( $patrons->is_paged, 'Search is paged' );
 235     my $pager = $patrons->pager;
 236     is( ref($patrons->pager), 'DBIx::Class::ResultSet::Pager',
 237        'Koha::Objects->pager returns a valid DBIx::Class object' );
 238
 239     $schema->storage->txn_rollback;
 240 }