t/db_dependent/Koha/Patron/Categories.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 9;
  23
  24 use C4::Context;
  25 use Koha::Database;
  26 use Koha::DateUtils;
  27 use Koha::Patron::Category;
  28 use Koha::Patron::Categories;
  29 use t::lib::TestBuilder;
  30 use t::lib::Mocks;
  31
  32 my $schema = Koha::Database->new->schema;
  33 $schema->storage->txn_begin;
  34
  35 my $builder = t::lib::TestBuilder->new;
  36 my $branch = $builder->build({ source => 'Branch', });
  37 my $nb_of_categories = Koha::Patron::Categories->search->count;
  38 my $new_category_1 = Koha::Patron::Category->new({
  39     categorycode => 'mycatcodeX',
  40     category_type => 'A',
  41     description  => 'mycatdescX',
  42 })->store;
  43 $new_category_1->add_branch_limitation( $branch->{branchcode} );
  44 my $new_category_2 = Koha::Patron::Category->new({
  45     categorycode => 'mycatcodeY',
  46     category_type => 'S',
  47     description  => 'mycatdescY',
  48     checkprevcheckout => undef,
  49 })->store;
  50
  51 is( Koha::Patron::Categories->search->count, $nb_of_categories + 2, 'The 2 patron categories should have been added' );
  52
  53 my $retrieved_category_1 = Koha::Patron::Categories->find( $new_category_1->categorycode );
  54 is( $retrieved_category_1->categorycode, $new_category_1->categorycode, 'Find a patron category by categorycode should return the correct category' );
  55 is_deeply( $retrieved_category_1->branch_limitations, [ $branch->{branchcode} ], 'The branch limitation should have been stored and retrieved' );
  56 is_deeply( $retrieved_category_1->default_messaging, [], 'By default there is not messaging option' );
  57
  58 my $retrieved_category_2 = Koha::Patron::Categories->find( $new_category_2->categorycode );
  59 is( $retrieved_category_1->checkprevcheckout, 'inherit', 'Koha::Patron::Category->store should default checkprevcheckout to inherit' );
  60 is( $retrieved_category_2->checkprevcheckout, 'inherit', 'Koha::Patron::Category->store should default checkprevcheckout to inherit' );
  61
  62 subtest 'get_expiry_date' => sub {
  63     plan tests => 5;
  64     my $next_month = dt_from_string->add( months => 1 );
  65     my $next_year = dt_from_string->add( months => 12 );
  66     my $yesterday = dt_from_string->add( days => -1 );
  67     my $category = Koha::Patron::Category->new({
  68         categorycode => 'mycat',
  69         category_type => 'A',
  70         description  => 'mycatdesc',
  71         enrolmentperiod => undef,
  72         enrolmentperioddate => $next_month,
  73     })->store;
  74     is( $category->get_expiry_date, $next_month, 'Without enrolmentperiod and parameter, ->get_expiry_date should return enrolmentperioddate' );
  75     is( $category->get_expiry_date( $next_year ), $next_month, 'Without enrolmentperiod, ->get_expiry_date should return enrolmentperiodadate even if a parameter is given' );
  76
  77     $category->enrolmentperiod( 12 )->store;
  78     is( $category->get_expiry_date, $next_year, 'With enrolmentperiod defined and no parameter, ->get_expiry_date should return today + enrolmentperiod' );
  79     is( $category->get_expiry_date( $yesterday ), $next_year->clone->add( days => -1 ), 'With enrolmentperiod defined and a date given in parameter, ->get_expiry_date should take this date + enrolmentperiod' );
  80
  81     my $hardcoded_date = '2000-01-31';
  82     is( $category->get_expiry_date( $hardcoded_date ), dt_from_string( $hardcoded_date )->add( months => 12 ), 'get_expiry_date accepts strings as well'  );
  83
  84     $category->delete;
  85 };
  86
  87 subtest 'BlockExpiredPatronOpacActions' => sub {
  88     plan tests => 2;
  89     t::lib::Mocks::mock_preference('BlockExpiredPatronOpacActions', 42);
  90     my $category = Koha::Patron::Category->new({
  91         categorycode => 'ya_cat',
  92         category_type => 'A',
  93         description  => 'yacatdesc',
  94         enrolmentperiod => undef,
  95         BlockExpiredPatronOpacActions => -1,
  96     })->store;
  97     is( $category->effective_BlockExpiredPatronOpacActions, 42 );
  98     $category->BlockExpiredPatronOpacActions(24)->store;
  99     is( $category->effective_BlockExpiredPatronOpacActions, 24 );
 100     $category->delete;
 101 };
 102
 103 $retrieved_category_1->delete;
 104 is( Koha::Patron::Categories->search->count, $nb_of_categories + 1, 'Delete should have deleted the patron category' );
 105
 106 $schema->storage->txn_rollback;
 107
 108 1;