t/db_dependent/Koha/Patron/Messages.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 9;
  23
  24 use C4::Context;
  25 use C4::Log;
  26 use Koha::Patron::Message;
  27 use Koha::Patron::Messages;
  28 use Koha::Database;
  29
  30 use t::lib::TestBuilder;
  31
  32 my $schema = Koha::Database->new->schema;
  33 $schema->storage->txn_begin;
  34
  35 my $builder        = t::lib::TestBuilder->new;
  36 my $library        = $builder->build( { source => 'Branch' } );
  37 my $patron         = $builder->build( { source => 'Borrower', values => { branchcode => $library->{branchcode} } } );
  38 my $nb_of_logaction = get_nb_of_logactions();
  39 my $nb_of_messages = Koha::Patron::Messages->search->count;
  40
  41 C4::Context->set_preference('BorrowersLog', 0);
  42 my $new_message_1  = Koha::Patron::Message->new(
  43     {   borrowernumber => $patron->{borrowernumber},
  44         branchcode     => $library->{branchcode},
  45         message_type   => 'L',
  46         message        => 'my message 1',
  47     }
  48 )->store;
  49 is( get_nb_of_logactions(), $nb_of_logaction, 'With BorrowersLog off, no new log should have been added' );
  50
  51 C4::Context->set_preference('BorrowersLog', 1);
  52 my $new_message_2  = Koha::Patron::Message->new(
  53     {   borrowernumber => $patron->{borrowernumber},
  54         branchcode     => $library->{branchcode},
  55         message_type   => 'B',
  56         message        => 'my message 2',
  57     }
  58 )->store;
  59 is( get_nb_of_logactions(), $nb_of_logaction + 1, 'With BorrowersLog on, 1 new log should have been added when adding a new message' );
  60
  61 like( $new_message_1->message_id, qr|^\d+$|, 'Adding a new message should have set the message_id');
  62 is( Koha::Patron::Messages->search->count, $nb_of_messages + 2, 'The 2 messages should have been added' );
  63
  64 my $retrieved_message_1 = Koha::Patron::Messages->find( $new_message_1->message_id );
  65 is( $retrieved_message_1->message, $new_message_1->message, 'Find a message by id should return the correct message' );
  66
  67 C4::Context->set_preference('BorrowersLog', 0);
  68 $retrieved_message_1->delete;
  69 is( Koha::Patron::Messages->search->count, $nb_of_messages + 1, 'Delete should have deleted the message 1' );
  70 is( get_nb_of_logactions(), $nb_of_logaction + 1, 'With BorrowersLog off, no new log should have been added when deleting a new message' );
  71
  72 C4::Context->set_preference('BorrowersLog', 1);
  73 $new_message_2->delete;
  74 is( Koha::Patron::Messages->search->count, $nb_of_messages, 'Delete should have deleted the message 2' );
  75 is( get_nb_of_logactions(), $nb_of_logaction + 2, 'With BorrowersLog on, 1 new log should have been added when deleting a new message' );
  76
  77 $schema->storage->txn_rollback;
  78
  79 sub get_nb_of_logactions {
  80     return scalar( @{ C4::Log::GetLogs( undef, undef, undef, ['MEMBERS'] ) } );
  81 }
  82
  83 1;