t/db_dependent/Koha/Pseudonymization.t

   1 #!/usr/bin/perl
   2
   3 # Copyright 2019 Koha Development team
   4 #
   5 # This file is part of Koha
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Test::More tests => 3;
  23 use Try::Tiny;
  24
  25 use C4::Circulation qw( AddIssue AddReturn );
  26 use C4::Stats qw( UpdateStats );
  27
  28 use Koha::Database;
  29 use Koha::DateUtils qw( dt_from_string );
  30 use Koha::Patrons;
  31 use Koha::PseudonymizedTransactions;
  32
  33 use t::lib::TestBuilder;
  34 use t::lib::Mocks;
  35
  36 my $schema  = Koha::Database->new->schema;
  37 my $builder = t::lib::TestBuilder->new;
  38
  39 subtest 'Config does not exist' => sub {
  40
  41     plan tests => 2;
  42
  43     $schema->storage->txn_begin;
  44
  45     t::lib::Mocks::mock_config( 'bcrypt_settings', '' );
  46     t::lib::Mocks::mock_preference( 'Pseudonymization', 1 );
  47     t::lib::Mocks::mock_preference( 'PseudonymizationPatronFields', 'branchcode,categorycode,sort1' );
  48
  49     my $library = $builder->build_object( { class => 'Koha::Libraries' } );
  50     my $item    = $builder->build_sample_item;
  51     my $patron  = $builder->build_object( { class => 'Koha::Patrons' } );
  52
  53     try{
  54         C4::Stats::UpdateStats(
  55             {
  56                 type           => 'issue',
  57                 branch         => $library->branchcode,
  58                 itemnumber     => $item->itemnumber,
  59                 borrowernumber => $patron->borrowernumber,
  60                 itemtype       => $item->effective_itemtype,
  61                 location       => $item->location,
  62                 ccode          => $item->ccode,
  63             }
  64         );
  65
  66     } catch {
  67         ok($_->isa('Koha::Exceptions::Config::MissingEntry'), "Koha::Patron->store should raise a Koha::Exceptions::Config::MissingEntry if 'bcrypt_settings' is not defined in the config");
  68         is( $_->message, "Missing 'bcrypt_settings' entry in config file");
  69     };
  70
  71     $schema->storage->txn_rollback;
  72 };
  73
  74 subtest 'Koha::Anonymized::Transactions tests' => sub {
  75
  76     plan tests => 12;
  77
  78     $schema->storage->txn_begin;
  79
  80     t::lib::Mocks::mock_config( 'bcrypt_settings', '$2a$08$9lmorEKnwQloheaCLFIfje' );
  81
  82     my $patron = $builder->build_object( { class => 'Koha::Patrons' } );
  83
  84     t::lib::Mocks::mock_preference( 'Pseudonymization', 0 );
  85     my $item = $builder->build_sample_item;
  86     t::lib::Mocks::mock_userenv({ branchcode => $item->homebranch });
  87     AddIssue( $patron->unblessed, $item->barcode, dt_from_string );
  88     AddReturn( $item->barcode, $item->homebranch, undef, dt_from_string );
  89     my $pseudonymized= Koha::PseudonymizedTransactions->search(
  90         { itemnumber => $item->itemnumber } )->next;
  91     is( $pseudonymized, undef,
  92         'No pseudonymized transaction if Pseudonymization is off' );
  93
  94     t::lib::Mocks::mock_preference( 'Pseudonymization', 1 );
  95     t::lib::Mocks::mock_preference( 'PseudonymizationTransactionFields', 'datetime,transaction_branchcode,transaction_type,itemnumber,itemtype,holdingbranch,homebranch,location,itemcallnumber,ccode'
  96     );
  97     $item = $builder->build_sample_item;
  98     t::lib::Mocks::mock_userenv({ branchcode => $item->homebranch });
  99     AddIssue( $patron->unblessed, $item->barcode, dt_from_string );
 100     AddReturn( $item->barcode, $item->homebranch, undef, dt_from_string );
 101     my $statistic = Koha::Statistics->search( { itemnumber => $item->itemnumber } )->next;
 102     $pseudonymized = Koha::PseudonymizedTransactions->search( { itemnumber => $item->itemnumber } )->next;
 103     like( $pseudonymized->hashed_borrowernumber,
 104         qr{^\$2a\$08\$}, "The hashed_borrowernumber must be a bcrypt hash" );
 105     is( $pseudonymized->datetime,               $statistic->datetime,      'datetime attribute copied correctly' );
 106     is( $pseudonymized->transaction_branchcode, $statistic->branch,        'transaction_branchcode copied correctly' );
 107     is( $pseudonymized->transaction_type,       $statistic->type,          'transacttion_type copied correctly' );
 108     is( $pseudonymized->itemnumber,             $item->itemnumber,         'itemnumber copied correctly' );
 109     is( $pseudonymized->itemtype,               $item->effective_itemtype, 'itemtype copied correctly' );
 110     is( $pseudonymized->holdingbranch,          $item->holdingbranch,      'holdingbranch copied correctly' );
 111     is( $pseudonymized->homebranch,             $item->homebranch,         'homebranch copied correctly' );
 112     is( $pseudonymized->location,               $item->location,           'location copied correctly' );
 113     is( $pseudonymized->itemcallnumber,         $item->itemcallnumber,     'itemcallnumber copied correctly' );
 114     is( $pseudonymized->ccode,                  $item->ccode,              'ccode copied correctly' );
 115
 116     $schema->storage->txn_rollback;
 117 };
 118
 119 subtest 'PseudonymizedBorrowerAttributes tests' => sub {
 120
 121     plan tests => 3;
 122
 123     $schema->storage->txn_begin;
 124
 125     t::lib::Mocks::mock_config( 'bcrypt_settings', '$2a$08$9lmorEKnwQloheaCLFIfje' );
 126     t::lib::Mocks::mock_preference( 'Pseudonymization', 1 );
 127     t::lib::Mocks::mock_preference( 'PseudonymizationPatronFields',
 128         'branchcode,categorycode,sort1' );
 129
 130     my $patron = $builder->build_object( { class => 'Koha::Patrons' } );
 131     my $patron_info = $patron->unblessed;
 132     delete $patron_info->{borrowernumber};
 133     $patron->delete;
 134
 135     my $attribute_type1 = $builder->build_object(
 136         {
 137             class => 'Koha::Patron::Attribute::Types',
 138             value => {
 139                 repeatable                => 1,
 140                 keep_for_pseudonymization => 1,
 141             }
 142         }
 143     );
 144     my $attribute_type2 = $builder->build_object(
 145         {
 146             class => 'Koha::Patron::Attribute::Types',
 147             value => {
 148                 keep_for_pseudonymization => 0,
 149             }
 150         }
 151     );
 152     my $attribute_type3 = $builder->build_object(
 153         {
 154             class => 'Koha::Patron::Attribute::Types',
 155             value => {
 156                 keep_for_pseudonymization => 1,
 157             }
 158         }
 159     );
 160
 161     $patron = Koha::Patron->new($patron_info)->store->get_from_storage;
 162     my $attribute_values = [
 163         {
 164             attribute => 'attribute for code1',
 165             code      => $attribute_type1->code,
 166         },
 167         {
 168             attribute => 'attribute for code2',
 169             code      => $attribute_type2->code
 170         },
 171         {
 172             attribute => 'attribute for code3',
 173             code      => $attribute_type3->code
 174         },
 175     ];
 176
 177     $patron->extended_attributes($attribute_values);
 178
 179
 180     my $library = $builder->build_object( { class => 'Koha::Libraries' } );
 181     my $item    = $builder->build_sample_item;
 182
 183     C4::Stats::UpdateStats(
 184         {
 185             type           => 'issue',
 186             branch         => $library->branchcode,
 187             itemnumber     => $item->itemnumber,
 188             borrowernumber => $patron->borrowernumber,
 189             itemtype       => $item->effective_itemtype,
 190             location       => $item->location,
 191             ccode          => $item->ccode,
 192         }
 193     );
 194
 195     my $p = Koha::PseudonymizedTransactions->search({itemnumber => $item->itemnumber})->next;
 196     my $attributes =
 197       Koha::Database->new->schema->resultset('PseudonymizedBorrowerAttribute')
 198       ->search( { transaction_id => $p->id }, { order_by => 'attribute' } );
 199     is( $attributes->count, 2,
 200         'Only the 2 attributes that have a type with keep_for_pseudonymization set should be kept'
 201     );
 202     my $attribute_1 = $attributes->next;
 203     is_deeply(
 204         { attribute => $attribute_1->attribute, code => $attribute_1->code->code },
 205         $attribute_values->[0],
 206         'Attribute 1 should be retrieved correctly'
 207     );
 208     my $attribute_2 = $attributes->next;
 209     is_deeply(
 210         { attribute => $attribute_2->attribute, code => $attribute_2->code->code },
 211         $attribute_values->[2],
 212         'Attribute 2 should be retrieved correctly'
 213     );
 214
 215     $schema->storage->txn_rollback;
 216 };