t/db_dependent/Reserves.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 62;
  21 use Test::MockModule;
  22 use Test::Warn;
  23
  24 use t::lib::Mocks;
  25 use t::lib::TestBuilder;
  26
  27 use MARC::Record;
  28 use DateTime::Duration;
  29
  30 use C4::Circulation;
  31 use C4::Items;
  32 use C4::Biblio;
  33 use C4::Members;
  34 use C4::Reserves;
  35 use Koha::Caches;
  36 use Koha::DateUtils;
  37 use Koha::Holds;
  38 use Koha::Items;
  39 use Koha::Libraries;
  40 use Koha::Notice::Templates;
  41 use Koha::Patrons;
  42 use Koha::Patron::Categories;
  43 use Koha::CirculationRules;
  44
  45 BEGIN {
  46     require_ok('C4::Reserves');
  47 }
  48
  49 # Start transaction
  50 my $database = Koha::Database->new();
  51 my $schema = $database->schema();
  52 $schema->storage->txn_begin();
  53 my $dbh = C4::Context->dbh;
  54 $dbh->do('DELETE FROM circulation_rules');
  55
  56 my $builder = t::lib::TestBuilder->new;
  57
  58 my $frameworkcode = q//;
  59
  60
  61 t::lib::Mocks::mock_preference('ReservesNeedReturns', 1);
  62
  63 # Somewhat arbitrary field chosen for age restriction unit tests. Must be added to db before the framework is cached
  64 $dbh->do("update marc_subfield_structure set kohafield='biblioitems.agerestriction' where tagfield='521' and tagsubfield='a' and frameworkcode=?", undef, $frameworkcode);
  65 my $cache = Koha::Caches->get_instance;
  66 $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
  67 $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
  68 $cache->clear_from_cache("default_value_for_mod_marc-");
  69 $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
  70
  71 ## Setup Test
  72 # Add branches
  73 my $branch_1 = $builder->build({ source => 'Branch' })->{ branchcode };
  74 my $branch_2 = $builder->build({ source => 'Branch' })->{ branchcode };
  75 my $branch_3 = $builder->build({ source => 'Branch' })->{ branchcode };
  76 # Add categories
  77 my $category_1 = $builder->build({ source => 'Category' })->{ categorycode };
  78 my $category_2 = $builder->build({ source => 'Category' })->{ categorycode };
  79 # Add an item type
  80 my $itemtype = $builder->build(
  81     { source => 'Itemtype', value => { notforloan => undef } } )->{itemtype};
  82
  83 t::lib::Mocks::mock_userenv({ branchcode => $branch_1 });
  84
  85 my $bibnum = $builder->build_sample_biblio({frameworkcode => $frameworkcode})->biblionumber;
  86
  87 # Create a helper item instance for testing
  88 my ( $item_bibnum, $item_bibitemnum, $itemnumber ) = AddItem(
  89     {   homebranch    => $branch_1,
  90         holdingbranch => $branch_1,
  91         itype         => $itemtype
  92     },
  93     $bibnum
  94 );
  95
  96 my $biblio_with_no_item = $builder->build({
  97     source => 'Biblio'
  98 });
  99
 100
 101 # Modify item; setting barcode.
 102 my $testbarcode = '97531';
 103 ModItem({ barcode => $testbarcode }, $bibnum, $itemnumber);
 104
 105 # Create a borrower
 106 my %data = (
 107     firstname =>  'my firstname',
 108     surname => 'my surname',
 109     categorycode => $category_1,
 110     branchcode => $branch_1,
 111 );
 112 Koha::Patron::Categories->find($category_1)->set({ enrolmentfee => 0})->store;
 113 my $borrowernumber = Koha::Patron->new(\%data)->store->borrowernumber;
 114 my $patron = Koha::Patrons->find( $borrowernumber );
 115 my $borrower = $patron->unblessed;
 116 my $biblionumber   = $bibnum;
 117 my $barcode        = $testbarcode;
 118
 119 my $bibitems       = '';
 120 my $priority       = '1';
 121 my $resdate        = undef;
 122 my $expdate        = undef;
 123 my $notes          = '';
 124 my $checkitem      = undef;
 125 my $found          = undef;
 126
 127 my $branchcode = Koha::Libraries->search->next->branchcode;
 128
 129 AddReserve($branchcode,    $borrowernumber, $biblionumber,
 130         $bibitems,  $priority, $resdate, $expdate, $notes,
 131         'a title',      $checkitem, $found);
 132
 133 my ($status, $reserve, $all_reserves) = CheckReserves($itemnumber, $barcode);
 134
 135 is($status, "Reserved", "CheckReserves Test 1");
 136
 137 ok(exists($reserve->{reserve_id}), 'CheckReserves() include reserve_id in its response');
 138
 139 ($status, $reserve, $all_reserves) = CheckReserves($itemnumber);
 140 is($status, "Reserved", "CheckReserves Test 2");
 141
 142 ($status, $reserve, $all_reserves) = CheckReserves(undef, $barcode);
 143 is($status, "Reserved", "CheckReserves Test 3");
 144
 145 my $ReservesControlBranch = C4::Context->preference('ReservesControlBranch');
 146 t::lib::Mocks::mock_preference( 'ReservesControlBranch', 'ItemHomeLibrary' );
 147 ok(
 148     'ItemHomeLib' eq GetReservesControlBranch(
 149         { homebranch => 'ItemHomeLib' },
 150         { branchcode => 'PatronHomeLib' }
 151     ), "GetReservesControlBranch returns item home branch when set to ItemHomeLibrary"
 152 );
 153 t::lib::Mocks::mock_preference( 'ReservesControlBranch', 'PatronLibrary' );
 154 ok(
 155     'PatronHomeLib' eq GetReservesControlBranch(
 156         { homebranch => 'ItemHomeLib' },
 157         { branchcode => 'PatronHomeLib' }
 158     ), "GetReservesControlBranch returns patron home branch when set to PatronLibrary"
 159 );
 160 t::lib::Mocks::mock_preference( 'ReservesControlBranch', $ReservesControlBranch );
 161
 162 ###
 163 ### Regression test for bug 10272
 164 ###
 165 my %requesters = ();
 166 $requesters{$branch_1} = Koha::Patron->new({
 167     branchcode   => $branch_1,
 168     categorycode => $category_2,
 169     surname      => "borrower from $branch_1",
 170 })->store->borrowernumber;
 171 for my $i ( 2 .. 5 ) {
 172     $requesters{"CPL$i"} = Koha::Patron->new({
 173         branchcode   => $branch_1,
 174         categorycode => $category_2,
 175         surname      => "borrower $i from $branch_1",
 176     })->store->borrowernumber;
 177 }
 178 $requesters{$branch_2} = Koha::Patron->new({
 179     branchcode   => $branch_2,
 180     categorycode => $category_2,
 181     surname      => "borrower from $branch_2",
 182 })->store->borrowernumber;
 183 $requesters{$branch_3} = Koha::Patron->new({
 184     branchcode   => $branch_3,
 185     categorycode => $category_2,
 186     surname      => "borrower from $branch_3",
 187 })->store->borrowernumber;
 188
 189 # Configure rules so that $branch_1 allows only $branch_1 patrons
 190 # to request its items, while $branch_2 will allow its items
 191 # to fill holds from anywhere.
 192
 193 $dbh->do('DELETE FROM issuingrules');
 194 $dbh->do(
 195     q{INSERT INTO issuingrules (categorycode, branchcode, itemtype, reservesallowed)
 196       VALUES (?, ?, ?, ?)},
 197     {},
 198     '*', '*', '*', 25
 199 );
 200
 201 # CPL allows only its own patrons to request its items
 202 Koha::CirculationRules->set_rules(
 203     {
 204         branchcode   => $branch_1,
 205         categorycode => undef,
 206         itemtype     => undef,
 207         rules        => {
 208             holdallowed  => 1,
 209             returnbranch => 'homebranch',
 210         }
 211     }
 212 );
 213
 214 # ... while FPL allows anybody to request its items
 215 Koha::CirculationRules->set_rules(
 216     {
 217         branchcode   => $branch_2,
 218         categorycode => undef,
 219         itemtype     => undef,
 220         rules        => {
 221             holdallowed  => 2,
 222             returnbranch => 'homebranch',
 223         }
 224     }
 225 );
 226
 227 my $bibnum2 = $builder->build_sample_biblio({frameworkcode => $frameworkcode})->biblionumber;
 228
 229 my ($itemnum_cpl, $itemnum_fpl);
 230 ( undef, undef, $itemnum_cpl ) = AddItem(
 231     {   homebranch    => $branch_1,
 232         holdingbranch => $branch_1,
 233         barcode       => 'bug10272_CPL',
 234         itype         => $itemtype
 235     },
 236     $bibnum2
 237 );
 238 ( undef, undef, $itemnum_fpl ) = AddItem(
 239     {   homebranch    => $branch_2,
 240         holdingbranch => $branch_2,
 241         barcode       => 'bug10272_FPL',
 242         itype         => $itemtype
 243     },
 244     $bibnum2
 245 );
 246
 247
 248 # Ensure that priorities are numbered correcly when a hold is moved to waiting
 249 # (bug 11947)
 250 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum2));
 251 AddReserve($branch_3,  $requesters{$branch_3}, $bibnum2,
 252            $bibitems,  1, $resdate, $expdate, $notes,
 253            'a title',      $checkitem, $found);
 254 AddReserve($branch_2,  $requesters{$branch_2}, $bibnum2,
 255            $bibitems,  2, $resdate, $expdate, $notes,
 256            'a title',      $checkitem, $found);
 257 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum2,
 258            $bibitems,  3, $resdate, $expdate, $notes,
 259            'a title',      $checkitem, $found);
 260 ModReserveAffect($itemnum_cpl, $requesters{$branch_3}, 0);
 261
 262 # Now it should have different priorities.
 263 my $biblio = Koha::Biblios->find( $bibnum2 );
 264 my $holds = $biblio->holds({}, { order_by => 'reserve_id' });;
 265 is($holds->next->priority, 0, 'Item is correctly waiting');
 266 is($holds->next->priority, 1, 'Item is correctly priority 1');
 267 is($holds->next->priority, 2, 'Item is correctly priority 2');
 268
 269 my @reserves = Koha::Holds->search({ borrowernumber => $requesters{$branch_3} })->waiting();
 270 is( @reserves, 1, 'GetWaiting got only the waiting reserve' );
 271 is( $reserves[0]->borrowernumber(), $requesters{$branch_3}, 'GetWaiting got the reserve for the correct borrower' );
 272
 273
 274 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum2));
 275 AddReserve($branch_3,  $requesters{$branch_3}, $bibnum2,
 276            $bibitems,  1, $resdate, $expdate, $notes,
 277            'a title',      $checkitem, $found);
 278 AddReserve($branch_2,  $requesters{$branch_2}, $bibnum2,
 279            $bibitems,  2, $resdate, $expdate, $notes,
 280            'a title',      $checkitem, $found);
 281 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum2,
 282            $bibitems,  3, $resdate, $expdate, $notes,
 283            'a title',      $checkitem, $found);
 284
 285 # Ensure that the item's home library controls hold policy lookup
 286 t::lib::Mocks::mock_preference( 'ReservesControlBranch', 'ItemHomeLibrary' );
 287
 288 my $messages;
 289 # Return the CPL item at FPL.  The hold that should be triggered is
 290 # the one placed by the CPL patron, as the other two patron's hold
 291 # requests cannot be filled by that item per policy.
 292 (undef, $messages, undef, undef) = AddReturn('bug10272_CPL', $branch_2);
 293 is( $messages->{ResFound}->{borrowernumber},
 294     $requesters{$branch_1},
 295     'restrictive library\'s items only fill requests by own patrons (bug 10272)');
 296
 297 # Return the FPL item at FPL.  The hold that should be triggered is
 298 # the one placed by the RPL patron, as that patron is first in line
 299 # and RPL imposes no restrictions on whose holds its items can fill.
 300
 301 # Ensure that the preference 'LocalHoldsPriority' is not set (Bug 15244):
 302 t::lib::Mocks::mock_preference( 'LocalHoldsPriority', '' );
 303
 304 (undef, $messages, undef, undef) = AddReturn('bug10272_FPL', $branch_2);
 305 is( $messages->{ResFound}->{borrowernumber},
 306     $requesters{$branch_3},
 307     'for generous library, its items fill first hold request in line (bug 10272)');
 308
 309 $biblio = Koha::Biblios->find( $biblionumber );
 310 $holds = $biblio->holds;
 311 is($holds->count, 1, "Only one reserves for this biblio");
 312 my $reserve_id = $holds->next->reserve_id;
 313
 314 # Tests for bug 9761 (ConfirmFutureHolds): new CheckReserves lookahead parameter, and corresponding change in AddReturn
 315 # Note that CheckReserve uses its lookahead parameter and does not check ConfirmFutureHolds pref (it should be passed if needed like AddReturn does)
 316 # Test 9761a: Add a reserve without date, CheckReserve should return it
 317 $resdate= undef; #defaults to today in AddReserve
 318 $expdate= undef; #no expdate
 319 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum));
 320 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum,
 321            $bibitems,  1, $resdate, $expdate, $notes,
 322            'a title',      $checkitem, $found);
 323 ($status)=CheckReserves($itemnumber,undef,undef);
 324 is( $status, 'Reserved', 'CheckReserves returns reserve without lookahead');
 325 ($status)=CheckReserves($itemnumber,undef,7);
 326 is( $status, 'Reserved', 'CheckReserves also returns reserve with lookahead');
 327
 328 # Test 9761b: Add a reserve with future date, CheckReserve should not return it
 329 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum));
 330 t::lib::Mocks::mock_preference('AllowHoldDateInFuture', 1);
 331 $resdate= dt_from_string();
 332 $resdate->add_duration(DateTime::Duration->new(days => 4));
 333 $resdate=output_pref($resdate);
 334 $expdate= undef; #no expdate
 335 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum,
 336            $bibitems,  1, $resdate, $expdate, $notes,
 337            'a title',      $checkitem, $found);
 338 ($status)=CheckReserves($itemnumber,undef,undef);
 339 is( $status, '', 'CheckReserves returns no future reserve without lookahead');
 340
 341 # Test 9761c: Add a reserve with future date, CheckReserve should return it if lookahead is high enough
 342 ($status)=CheckReserves($itemnumber,undef,3);
 343 is( $status, '', 'CheckReserves returns no future reserve with insufficient lookahead');
 344 ($status)=CheckReserves($itemnumber,undef,4);
 345 is( $status, 'Reserved', 'CheckReserves returns future reserve with sufficient lookahead');
 346
 347 # Test 9761d: Check ResFound message of AddReturn for future hold
 348 # Note that AddReturn is in Circulation.pm, but this test really pertains to reserves; AddReturn uses the ConfirmFutureHolds pref when calling CheckReserves
 349 # In this test we do not need an issued item; it is just a 'checkin'
 350 t::lib::Mocks::mock_preference('ConfirmFutureHolds', 0);
 351 (my $doreturn, $messages)= AddReturn('97531',$branch_1);
 352 is($messages->{ResFound}//'', '', 'AddReturn does not care about future reserve when ConfirmFutureHolds is off');
 353 t::lib::Mocks::mock_preference('ConfirmFutureHolds', 3);
 354 ($doreturn, $messages)= AddReturn('97531',$branch_1);
 355 is(exists $messages->{ResFound}?1:0, 0, 'AddReturn ignores future reserve beyond ConfirmFutureHolds days');
 356 t::lib::Mocks::mock_preference('ConfirmFutureHolds', 7);
 357 ($doreturn, $messages)= AddReturn('97531',$branch_1);
 358 is(exists $messages->{ResFound}?1:0, 1, 'AddReturn considers future reserve within ConfirmFutureHolds days');
 359
 360 # End of tests for bug 9761 (ConfirmFutureHolds)
 361
 362 # test marking a hold as captured
 363 my $hold_notice_count = count_hold_print_messages();
 364 ModReserveAffect($itemnumber, $requesters{$branch_1}, 0);
 365 my $new_count = count_hold_print_messages();
 366 is($new_count, $hold_notice_count + 1, 'patron notified when item set to waiting');
 367
 368 # test that duplicate notices aren't generated
 369 ModReserveAffect($itemnumber, $requesters{$branch_1}, 0);
 370 $new_count = count_hold_print_messages();
 371 is($new_count, $hold_notice_count + 1, 'patron not notified a second time (bug 11445)');
 372
 373 # avoiding the not_same_branch error
 374 t::lib::Mocks::mock_preference('IndependentBranches', 0);
 375 is(
 376     DelItemCheck( $bibnum, $itemnumber),
 377     'book_reserved',
 378     'item that is captured to fill a hold cannot be deleted',
 379 );
 380
 381 my $letter = ReserveSlip( { branchcode => $branch_1, borrowernumber => $requesters{$branch_1}, biblionumber => $bibnum } );
 382 ok(defined($letter), 'can successfully generate hold slip (bug 10949)');
 383
 384 # Tests for bug 9788: Does Koha::Item->current_holds return a future wait?
 385 # 9788a: current_holds does not return future next available hold
 386 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum));
 387 t::lib::Mocks::mock_preference('ConfirmFutureHolds', 2);
 388 t::lib::Mocks::mock_preference('AllowHoldDateInFuture', 1);
 389 $resdate= dt_from_string();
 390 $resdate->add_duration(DateTime::Duration->new(days => 2));
 391 $resdate=output_pref($resdate);
 392 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum,
 393            $bibitems,  1, $resdate, $expdate, $notes,
 394            'a title',      $checkitem, $found);
 395 my $item = Koha::Items->find( $itemnumber );
 396 $holds = $item->current_holds;
 397 my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 398 my $future_holds = $holds->search({ reservedate => { '>' => $dtf->format_date( dt_from_string ) } } );
 399 is( $future_holds->count, 0, 'current_holds does not return a future next available hold');
 400 # 9788b: current_holds does not return future item level hold
 401 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum));
 402 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum,
 403            $bibitems,  1, $resdate, $expdate, $notes,
 404            'a title',      $itemnumber, $found); #item level hold
 405 $future_holds = $holds->search({ reservedate => { '>' => $dtf->format_date( dt_from_string ) } } );
 406 is( $future_holds->count, 0, 'current_holds does not return a future item level hold' );
 407 # 9788c: current_holds returns future wait (confirmed future hold)
 408 ModReserveAffect( $itemnumber,  $requesters{$branch_1} , 0); #confirm hold
 409 $future_holds = $holds->search({ reservedate => { '>' => $dtf->format_date( dt_from_string ) } } );
 410 is( $future_holds->count, 1, 'current_holds returns a future wait (confirmed future hold)' );
 411 # End of tests for bug 9788
 412
 413 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum));
 414 # Tests for CalculatePriority (bug 8918)
 415 my $p = C4::Reserves::CalculatePriority($bibnum2);
 416 is($p, 4, 'CalculatePriority should now return priority 4');
 417 $resdate=undef;
 418 AddReserve($branch_1,  $requesters{'CPL2'}, $bibnum2,
 419            $bibitems,  $p, $resdate, $expdate, $notes,
 420            'a title',      $checkitem, $found);
 421 $p = C4::Reserves::CalculatePriority($bibnum2);
 422 is($p, 5, 'CalculatePriority should now return priority 5');
 423 #some tests on bibnum
 424 $dbh->do("DELETE FROM reserves WHERE biblionumber=?",undef,($bibnum));
 425 $p = C4::Reserves::CalculatePriority($bibnum);
 426 is($p, 1, 'CalculatePriority should now return priority 1');
 427 #add a new reserve and confirm it to waiting
 428 AddReserve($branch_1,  $requesters{$branch_1}, $bibnum,
 429            $bibitems,  $p, $resdate, $expdate, $notes,
 430            'a title',      $itemnumber, $found);
 431 $p = C4::Reserves::CalculatePriority($bibnum);
 432 is($p, 2, 'CalculatePriority should now return priority 2');
 433 ModReserveAffect( $itemnumber,  $requesters{$branch_1} , 0);
 434 $p = C4::Reserves::CalculatePriority($bibnum);
 435 is($p, 1, 'CalculatePriority should now return priority 1');
 436 #add another biblio hold, no resdate
 437 AddReserve($branch_1,  $requesters{'CPL2'}, $bibnum,
 438            $bibitems,  $p, $resdate, $expdate, $notes,
 439            'a title',      $checkitem, $found);
 440 $p = C4::Reserves::CalculatePriority($bibnum);
 441 is($p, 2, 'CalculatePriority should now return priority 2');
 442 #add another future hold
 443 t::lib::Mocks::mock_preference('AllowHoldDateInFuture', 1);
 444 $resdate= dt_from_string();
 445 $resdate->add_duration(DateTime::Duration->new(days => 1));
 446 AddReserve($branch_1,  $requesters{'CPL3'}, $bibnum,
 447            $bibitems,  $p, output_pref($resdate), $expdate, $notes,
 448            'a title',      $checkitem, $found);
 449 $p = C4::Reserves::CalculatePriority($bibnum);
 450 is($p, 2, 'CalculatePriority should now still return priority 2');
 451 #calc priority with future resdate
 452 $p = C4::Reserves::CalculatePriority($bibnum, $resdate);
 453 is($p, 3, 'CalculatePriority should now return priority 3');
 454 # End of tests for bug 8918
 455
 456 # Tests for cancel reserves by users from OPAC.
 457 $dbh->do('DELETE FROM reserves', undef, ($bibnum));
 458 AddReserve($branch_1,  $requesters{$branch_1}, $item_bibnum,
 459            $bibitems,  1, undef, $expdate, $notes,
 460            'a title',      $checkitem, '');
 461 my (undef, $canres, undef) = CheckReserves($itemnumber);
 462
 463 is( CanReserveBeCanceledFromOpac(), undef,
 464     'CanReserveBeCanceledFromOpac should return undef if called without any parameter'
 465 );
 466 is(
 467     CanReserveBeCanceledFromOpac( $canres->{resserve_id} ),
 468     undef,
 469     'CanReserveBeCanceledFromOpac should return undef if called without the reserve_id'
 470 );
 471 is(
 472     CanReserveBeCanceledFromOpac( undef, $requesters{CPL} ),
 473     undef,
 474     'CanReserveBeCanceledFromOpac should return undef if called without borrowernumber'
 475 );
 476
 477 my $cancancel = CanReserveBeCanceledFromOpac($canres->{reserve_id}, $requesters{$branch_1});
 478 is($cancancel, 1, 'Can user cancel its own reserve');
 479
 480 $cancancel = CanReserveBeCanceledFromOpac($canres->{reserve_id}, $requesters{$branch_2});
 481 is($cancancel, 0, 'Other user cant cancel reserve');
 482
 483 ModReserveAffect($itemnumber, $requesters{$branch_1}, 1);
 484 $cancancel = CanReserveBeCanceledFromOpac($canres->{reserve_id}, $requesters{$branch_1});
 485 is($cancancel, 0, 'Reserve in transfer status cant be canceled');
 486
 487 $dbh->do('DELETE FROM reserves', undef, ($bibnum));
 488 AddReserve($branch_1,  $requesters{$branch_1}, $item_bibnum,
 489            $bibitems,  1, undef, $expdate, $notes,
 490            'a title',      $checkitem, '');
 491 (undef, $canres, undef) = CheckReserves($itemnumber);
 492
 493 ModReserveAffect($itemnumber, $requesters{$branch_1}, 0);
 494 $cancancel = CanReserveBeCanceledFromOpac($canres->{reserve_id}, $requesters{$branch_1});
 495 is($cancancel, 0, 'Reserve in waiting status cant be canceled');
 496
 497 # End of tests for bug 12876
 498
 499        ####
 500 ####### Testing Bug 13113 - Prevent juvenile/children from reserving ageRestricted material >>>
 501        ####
 502
 503 t::lib::Mocks::mock_preference( 'AgeRestrictionMarker', 'FSK|PEGI|Age|K' );
 504
 505 #Reserving an not-agerestricted Biblio by a Borrower with no dateofbirth is tested previously.
 506
 507 #Set the ageRestriction for the Biblio
 508 my $record = GetMarcBiblio({ biblionumber =>  $bibnum });
 509 my ( $ageres_tagid, $ageres_subfieldid ) = GetMarcFromKohaField( "biblioitems.agerestriction" );
 510 $record->append_fields(  MARC::Field->new($ageres_tagid, '', '', $ageres_subfieldid => 'PEGI 16')  );
 511 C4::Biblio::ModBiblio( $record, $bibnum, $frameworkcode );
 512
 513 is( C4::Reserves::CanBookBeReserved($borrowernumber, $biblionumber)->{status} , 'OK', "Reserving an ageRestricted Biblio without a borrower dateofbirth succeeds" );
 514
 515 #Set the dateofbirth for the Borrower making them "too young".
 516 $borrower->{dateofbirth} = DateTime->now->add( years => -15 );
 517 Koha::Patrons->find( $borrowernumber )->set({ dateofbirth => $borrower->{dateofbirth} })->store;
 518
 519 is( C4::Reserves::CanBookBeReserved($borrowernumber, $biblionumber)->{status} , 'ageRestricted', "Reserving a 'PEGI 16' Biblio by a 15 year old borrower fails");
 520
 521 #Set the dateofbirth for the Borrower making them "too old".
 522 $borrower->{dateofbirth} = DateTime->now->add( years => -30 );
 523 Koha::Patrons->find( $borrowernumber )->set({ dateofbirth => $borrower->{dateofbirth} })->store;
 524
 525 is( C4::Reserves::CanBookBeReserved($borrowernumber, $biblionumber)->{status} , 'OK', "Reserving a 'PEGI 16' Biblio by a 30 year old borrower succeeds");
 526
 527 is( C4::Reserves::CanBookBeReserved($borrowernumber, $biblio_with_no_item->{biblionumber})->{status} , '', "Biblio with no item. Status is empty");
 528        ####
 529 ####### EO Bug 13113 <<<
 530        ####
 531
 532 $item = Koha::Items->find($itemnumber);
 533
 534 ok( C4::Reserves::IsAvailableForItemLevelRequest($item, $patron), "Reserving a book on item level" );
 535
 536 my $pickup_branch = $builder->build({ source => 'Branch' })->{ branchcode };
 537 t::lib::Mocks::mock_preference( 'UseBranchTransferLimits',  '1' );
 538 t::lib::Mocks::mock_preference( 'BranchTransferLimitsType', 'itemtype' );
 539 my $limit = Koha::Item::Transfer::Limit->new(
 540     {
 541         toBranch   => $pickup_branch,
 542         fromBranch => $item->holdingbranch,
 543         itemtype   => $item->effective_itemtype,
 544     }
 545 )->store();
 546 is( C4::Reserves::IsAvailableForItemLevelRequest($item, $patron, $pickup_branch), 0, "Item level request not available due to transfer limit" );
 547 t::lib::Mocks::mock_preference( 'UseBranchTransferLimits',  '0' );
 548
 549 # tests for MoveReserve in relation to ConfirmFutureHolds (BZ 14526)
 550 #   hold from A pos 1, today, no fut holds: MoveReserve should fill it
 551 $dbh->do('DELETE FROM reserves', undef, ($bibnum));
 552 t::lib::Mocks::mock_preference('ConfirmFutureHolds', 0);
 553 t::lib::Mocks::mock_preference('AllowHoldDateInFuture', 1);
 554 AddReserve($branch_1,  $borrowernumber, $item_bibnum,
 555     $bibitems,  1, undef, $expdate, $notes, 'a title', $checkitem, '');
 556 MoveReserve( $itemnumber, $borrowernumber );
 557 ($status)=CheckReserves( $itemnumber );
 558 is( $status, '', 'MoveReserve filled hold');
 559 #   hold from A waiting, today, no fut holds: MoveReserve should fill it
 560 AddReserve($branch_1,  $borrowernumber, $item_bibnum,
 561    $bibitems,  1, undef, $expdate, $notes, 'a title', $checkitem, 'W');
 562 MoveReserve( $itemnumber, $borrowernumber );
 563 ($status)=CheckReserves( $itemnumber );
 564 is( $status, '', 'MoveReserve filled waiting hold');
 565 #   hold from A pos 1, tomorrow, no fut holds: not filled
 566 $resdate= dt_from_string();
 567 $resdate->add_duration(DateTime::Duration->new(days => 1));
 568 $resdate=output_pref($resdate);
 569 AddReserve($branch_1,  $borrowernumber, $item_bibnum,
 570     $bibitems,  1, $resdate, $expdate, $notes, 'a title', $checkitem, '');
 571 MoveReserve( $itemnumber, $borrowernumber );
 572 ($status)=CheckReserves( $itemnumber, undef, 1 );
 573 is( $status, 'Reserved', 'MoveReserve did not fill future hold');
 574 $dbh->do('DELETE FROM reserves', undef, ($bibnum));
 575 #   hold from A pos 1, tomorrow, fut holds=2: MoveReserve should fill it
 576 t::lib::Mocks::mock_preference('ConfirmFutureHolds', 2);
 577 AddReserve($branch_1,  $borrowernumber, $item_bibnum,
 578     $bibitems,  1, $resdate, $expdate, $notes, 'a title', $checkitem, '');
 579 MoveReserve( $itemnumber, $borrowernumber );
 580 ($status)=CheckReserves( $itemnumber, undef, 2 );
 581 is( $status, '', 'MoveReserve filled future hold now');
 582 #   hold from A waiting, tomorrow, fut holds=2: MoveReserve should fill it
 583 AddReserve($branch_1,  $borrowernumber, $item_bibnum,
 584     $bibitems,  1, $resdate, $expdate, $notes, 'a title', $checkitem, 'W');
 585 MoveReserve( $itemnumber, $borrowernumber );
 586 ($status)=CheckReserves( $itemnumber, undef, 2 );
 587 is( $status, '', 'MoveReserve filled future waiting hold now');
 588 #   hold from A pos 1, today+3, fut holds=2: MoveReserve should not fill it
 589 $resdate= dt_from_string();
 590 $resdate->add_duration(DateTime::Duration->new(days => 3));
 591 $resdate=output_pref($resdate);
 592 AddReserve($branch_1,  $borrowernumber, $item_bibnum,
 593     $bibitems,  1, $resdate, $expdate, $notes, 'a title', $checkitem, '');
 594 MoveReserve( $itemnumber, $borrowernumber );
 595 ($status)=CheckReserves( $itemnumber, undef, 3 );
 596 is( $status, 'Reserved', 'MoveReserve did not fill future hold of 3 days');
 597 $dbh->do('DELETE FROM reserves', undef, ($bibnum));
 598
 599 $cache->clear_from_cache("MarcStructure-0-$frameworkcode");
 600 $cache->clear_from_cache("MarcStructure-1-$frameworkcode");
 601 $cache->clear_from_cache("default_value_for_mod_marc-");
 602 $cache->clear_from_cache("MarcSubfieldStructure-$frameworkcode");
 603
 604 subtest '_koha_notify_reserve() tests' => sub {
 605
 606     plan tests => 2;
 607
 608     my $wants_hold_and_email = {
 609         wants_digest => '0',
 610         transports => {
 611             sms => 'HOLD',
 612             email => 'HOLD',
 613             },
 614         letter_code => 'HOLD'
 615     };
 616
 617     my $mp = Test::MockModule->new( 'C4::Members::Messaging' );
 618
 619     $mp->mock("GetMessagingPreferences",$wants_hold_and_email);
 620
 621     $dbh->do('DELETE FROM letter');
 622
 623     my $email_hold_notice = $builder->build({
 624             source => 'Letter',
 625             value => {
 626                 message_transport_type => 'email',
 627                 branchcode => '',
 628                 code => 'HOLD',
 629                 module => 'reserves',
 630                 lang => 'default',
 631             }
 632         });
 633
 634     my $sms_hold_notice = $builder->build({
 635             source => 'Letter',
 636             value => {
 637                 message_transport_type => 'sms',
 638                 branchcode => '',
 639                 code => 'HOLD',
 640                 module => 'reserves',
 641                 lang=>'default',
 642             }
 643         });
 644
 645     my $hold_borrower = $builder->build({
 646             source => 'Borrower',
 647             value => {
 648                 smsalertnumber=>'5555555555',
 649                 email=>'a@b.com',
 650             }
 651         })->{borrowernumber};
 652
 653     C4::Reserves::AddReserve(
 654         $item->homebranch, $hold_borrower,
 655         $item->biblionumber );
 656
 657     ModReserveAffect($item->itemnumber, $hold_borrower, 0);
 658     my $sms_message_address = $schema->resultset('MessageQueue')->search({
 659             letter_code     => 'HOLD',
 660             message_transport_type => 'sms',
 661             borrowernumber => $hold_borrower,
 662         })->next()->to_address();
 663     is($sms_message_address, undef ,"We should not populate the sms message with the sms number, sending will do so");
 664
 665     my $email_message_address = $schema->resultset('MessageQueue')->search({
 666             letter_code     => 'HOLD',
 667             message_transport_type => 'email',
 668             borrowernumber => $hold_borrower,
 669         })->next()->to_address();
 670     is($email_message_address, undef ,"We should not populate the hold message with the email address, sending will do so");
 671
 672 };
 673
 674 subtest 'ReservesNeedReturns' => sub {
 675     plan tests => 18;
 676
 677     my $library    = $builder->build_object( { class => 'Koha::Libraries' } );
 678     my $item_info  = {
 679         homebranch       => $library->branchcode,
 680         holdingbranch    => $library->branchcode,
 681     };
 682     my $item = $builder->build_sample_item($item_info);
 683     my $patron   = $builder->build_object(
 684         {
 685             class => 'Koha::Patrons',
 686             value => { branchcode => $library->branchcode, }
 687         }
 688     );
 689     my $patron_2   = $builder->build_object(
 690         {
 691             class => 'Koha::Patrons',
 692             value => { branchcode => $library->branchcode, }
 693         }
 694     );
 695
 696     my $priority = 1;
 697
 698     t::lib::Mocks::mock_preference('ReservesNeedReturns', 1); # Test with feature disabled
 699     my $hold = place_item_hold( $patron, $item, $library, $priority );
 700     is( $hold->priority, $priority, 'If ReservesNeedReturns is 1, priority must not have been set to changed' );
 701     is( $hold->found, undef, 'If ReservesNeedReturns is 1, found must not have been set waiting' );
 702     $hold->delete;
 703
 704     t::lib::Mocks::mock_preference('ReservesNeedReturns', 0); # '0' means 'Automatically mark a hold as found and waiting'
 705     $hold = place_item_hold( $patron, $item, $library, $priority );
 706     is( $hold->priority, 0, 'If ReservesNeedReturns is 0 and no other status, priority must have been set to 0' );
 707     is( $hold->found, 'W', 'If ReservesNeedReturns is 0 and no other status, found must have been set waiting' );
 708     $hold->delete;
 709
 710     $item->onloan('2010-01-01')->store;
 711     $hold = place_item_hold( $patron, $item, $library, $priority );
 712     is( $hold->priority, 1, 'If ReservesNeedReturns is 0 but item onloan priority must be set to 1' );
 713     $hold->delete;
 714
 715     t::lib::Mocks::mock_preference('AllowHoldsOnDamagedItems', 0); # '0' means damaged holds not allowed
 716     $item->onloan(undef)->damaged(1)->store;
 717     $hold = place_item_hold( $patron, $item, $library, $priority );
 718     is( $hold->priority, 1, 'If ReservesNeedReturns is 0 but item damaged and not allowed holds on damaged items priority must be set to 1' );
 719     $hold->delete;
 720     t::lib::Mocks::mock_preference('AllowHoldsOnDamagedItems', 1); # '0' means damaged holds not allowed
 721     $hold = place_item_hold( $patron, $item, $library, $priority );
 722     is( $hold->priority, 0, 'If ReservesNeedReturns is 0 and damaged holds allowed, priority must have been set to 0' );
 723     is( $hold->found,  'W', 'If ReservesNeedReturns is 0 and damaged holds allowed, found must have been set waiting' );
 724     $hold->delete;
 725
 726     my $hold_1 = place_item_hold( $patron, $item, $library, $priority );
 727     is( $hold_1->found,  'W', 'First hold on item is set to waiting with ReservesNeedReturns set to 0' );
 728     is( $hold_1->priority, 0, 'First hold on item is set to waiting with ReservesNeedReturns set to 0' );
 729     $hold = place_item_hold( $patron_2, $item, $library, $priority );
 730     is( $hold->priority, 1, 'If ReservesNeedReturns is 0 but item already on hold priority must be set to 1' );
 731     $hold->delete;
 732     $hold_1->delete;
 733
 734     my $transfer = $builder->build_object({
 735         class => "Koha::Item::Transfers",
 736         value => {
 737           itemnumber  => $item->itemnumber,
 738           datearrived => undef,
 739         }
 740     });
 741     $item->damaged(0)->store;
 742     $hold = place_item_hold( $patron, $item, $library, $priority );
 743     is( $hold->found, undef, 'If ReservesNeedReturns is 0 but item in transit the hold must not be set to waiting' );
 744     is( $hold->priority, 1,  'If ReservesNeedReturns is 0 but item in transit the hold must not be set to waiting' );
 745     $hold->delete;
 746     $transfer->delete;
 747
 748     $hold = place_item_hold( $patron, $item, $library, $priority );
 749     is( $hold->priority, 0, 'If ReservesNeedReturns is 0 and no other status, priority must have been set to 0' );
 750     is( $hold->found, 'W', 'If ReservesNeedReturns is 0 and no other status, found must have been set waiting' );
 751     $hold_1 = place_item_hold( $patron, $item, $library, $priority );
 752     is( $hold_1->priority, 1, 'If ReservesNeedReturns is 0 but item has a hold priority is 1' );
 753     $hold_1->suspend(1)->store; # We suspend the hold
 754     $hold->delete; # Delete the waiting hold
 755     $hold = place_item_hold( $patron, $item, $library, $priority );
 756     is( $hold->priority, 0, 'If ReservesNeedReturns is 0 and other hold(s) suspended, priority must have been set to 0' );
 757     is( $hold->found, 'W', 'If ReservesNeedReturns is 0 and other  hold(s) suspended, found must have been set waiting' );
 758
 759
 760
 761
 762     t::lib::Mocks::mock_preference('ReservesNeedReturns', 1); # Don't affect other tests
 763 };
 764
 765 subtest 'ChargeReserveFee tests' => sub {
 766
 767     plan tests => 8;
 768
 769     my $library = $builder->build_object({ class => 'Koha::Libraries' });
 770     my $patron  = $builder->build_object({ class => 'Koha::Patrons' });
 771
 772     my $fee   = 20;
 773     my $title = 'A title';
 774
 775     my $context = Test::MockModule->new('C4::Context');
 776     $context->mock( userenv => { branch => $library->id } );
 777
 778     my $line = C4::Reserves::ChargeReserveFee( $patron->id, $fee, $title );
 779
 780     is( ref($line), 'Koha::Account::Line' , 'Returns a Koha::Account::Line object');
 781     ok( $line->is_debit, 'Generates a debit line' );
 782     is( $line->debit_type_code, 'RESERVE' , 'generates RESERVE debit_type');
 783     is( $line->borrowernumber, $patron->id , 'generated line belongs to the passed patron');
 784     is( $line->amount, $fee , 'amount set correctly');
 785     is( $line->amountoutstanding, $fee , 'amountoutstanding set correctly');
 786     is( $line->description, "$title" , 'description is title of reserved item');
 787     is( $line->branchcode, $library->id , "Library id is picked from userenv and stored correctly" );
 788 };
 789
 790 subtest 'reserves.item_level_hold' => sub {
 791     plan tests => 2;
 792
 793     my $item   = $builder->build_sample_item;
 794     my $patron = $builder->build_object(
 795         {
 796             class => 'Koha::Patrons',
 797             value => { branchcode => $item->homebranch }
 798         }
 799     );
 800
 801     subtest 'item level hold' => sub {
 802         plan tests => 2;
 803         my $reserve_id =
 804           AddReserve( $item->homebranch, $patron->borrowernumber,
 805             $item->biblionumber, undef, 1, undef, undef, '', '',
 806             $item->itemnumber );
 807
 808         my $hold = Koha::Holds->find($reserve_id);
 809         is( $hold->item_level_hold, 1, 'item_level_hold should be set when AddReserve is called with a specific item' );
 810
 811         # Mark it waiting
 812         ModReserveAffect( $item->itemnumber, $patron->borrowernumber, 1 );
 813
 814         # Revert the waiting status
 815         C4::Reserves::RevertWaitingStatus(
 816             { itemnumber => $item->itemnumber } );
 817
 818         $hold = Koha::Holds->find($reserve_id);
 819
 820         is( $hold->itemnumber, $item->itemnumber, 'Itemnumber should not be removed when the waiting status is revert' );
 821
 822         $hold->delete;    # cleanup
 823     };
 824
 825     subtest 'biblio level hold' => sub {
 826         plan tests => 3;
 827         my $reserve_id = AddReserve( $item->homebranch, $patron->borrowernumber,
 828             $item->biblionumber, undef, 1 );
 829
 830         my $hold = Koha::Holds->find($reserve_id);
 831         is( $hold->item_level_hold, 0, 'item_level_hold should not be set when AddReserve is called without a specific item' );
 832
 833         # Mark it waiting
 834         ModReserveAffect( $item->itemnumber, $patron->borrowernumber, 1 );
 835
 836         $hold = Koha::Holds->find($reserve_id);
 837         is( $hold->itemnumber, $item->itemnumber, 'Itemnumber should be set on hold confirmation' );
 838
 839         # Revert the waiting status
 840         C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
 841
 842         $hold = Koha::Holds->find($reserve_id);
 843         is( $hold->itemnumber, undef, 'Itemnumber should be removed when the waiting status is revert' );
 844
 845         $hold->delete;
 846     };
 847
 848 };
 849
 850 subtest 'MoveReserve additional test' => sub {
 851
 852     plan tests => 4;
 853
 854     # Create the items and patrons we need
 855     my $biblio = $builder->build_sample_biblio();
 856     my $itype = $builder->build_object({ class => "Koha::ItemTypes", value => { notforloan => 0 } });
 857     my $item_1 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber,notforloan => 0, itype => $itype->itemtype });
 858     my $item_2 = $builder->build_sample_item({ biblionumber => $biblio->biblionumber, notforloan => 0, itype => $itype->itemtype });
 859     my $patron_1 = $builder->build_object({ class => "Koha::Patrons" });
 860     my $patron_2 = $builder->build_object({ class => "Koha::Patrons" });
 861
 862     # Place a hold on the title for both patrons
 863     my $reserve_1 = AddReserve( $item_1->homebranch, $patron_1->borrowernumber, $biblio->biblionumber, undef, 1 );
 864     my $reserve_2 = AddReserve( $item_2->homebranch, $patron_2->borrowernumber, $biblio->biblionumber, undef, 1 );
 865     is($patron_1->holds->next()->reserve_id, $reserve_1, "The 1st patron has a hold");
 866     is($patron_2->holds->next()->reserve_id, $reserve_2, "The 2nd patron has a hold");
 867
 868     # Fake the holds queue
 869     $dbh->do(q{INSERT INTO hold_fill_targets VALUES (?, ?, ?, ?, ?)},undef,($patron_1->borrowernumber,$biblio->biblionumber,$item_1->itemnumber,$item_1->homebranch,0));
 870
 871     # The 2nd hold should be filed even if the item is preselected for the first hold
 872     MoveReserve($item_1->itemnumber,$patron_2->borrowernumber);
 873     is($patron_2->holds->count, 0, "The 2nd patrons no longer has a hold");
 874     is($patron_2->old_holds->next()->reserve_id, $reserve_2, "The 2nd patrons hold was filled and moved to old holds");
 875
 876 };
 877
 878 sub count_hold_print_messages {
 879     my $message_count = $dbh->selectall_arrayref(q{
 880         SELECT COUNT(*)
 881         FROM message_queue
 882         WHERE letter_code = 'HOLD'
 883         AND   message_transport_type = 'print'
 884     });
 885     return $message_count->[0]->[0];
 886 }
 887
 888 sub place_item_hold {
 889     my ($patron,$item,$library,$priority) = @_;
 890
 891     my $hold_id = C4::Reserves::AddReserve(
 892         $library->branchcode, $patron->borrowernumber,
 893         $item->biblionumber,  '',
 894         $priority,            undef,
 895         undef,                '',
 896         "title for fee",      $item->itemnumber,
 897     );
 898     my $hold = Koha::Holds->find($hold_id);
 899     return $hold;
 900 }
 901
 902 # we reached the finish
 903 $schema->storage->txn_rollback();