t/db_dependent/selenium/basic_workflow.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18
  19
  20 # wget https://selenium-release.storage.googleapis.com/2.53/selenium-server-standalone-2.53.1.jar # Does not work with 3.4, did not test the ones between
  21 # sudo apt-get install xvfb firefox-esr
  22 # SELENIUM_PATH=/home/vagrant/selenium-server-standalone-2.53.1.jar
  23 # Xvfb :1 -screen 0 1024x768x24 2>&1 >/dev/null &
  24 # DISPLAY=:1 java -jar $SELENIUM_PATH
  25 #
  26 # Then you can execute the test file.
  27 #
  28 # If you get:
  29 # Wide character in print at /usr/local/share/perl/5.20.2/Test2/Formatter/TAP.pm line 105.
  30 # #                   'Koha › Patrons › Add patron test_patron_surname (Adult)'
  31 # #     doesn't match '(?^u:Patron details for test_patron_surname)'
  32 #
  33 # Ignore and retry (FIXME LATER...)
  34
  35 use Modern::Perl;
  36
  37 use Time::HiRes qw(gettimeofday);
  38 use C4::Context;
  39 use C4::Biblio qw( AddBiblio ); # We shouldn't use it
  40
  41 use Test::More tests => 20;
  42 use MARC::Record;
  43 use MARC::Field;
  44
  45 use t::lib::Selenium;
  46
  47 my $dbh      = C4::Context->dbh;
  48
  49 my $number_of_biblios_to_insert = 3;
  50 our $sample_data = {
  51     category => {
  52         categorycode    => 'TEST_CAT',
  53         description     => 'test cat description',
  54         enrolmentperiod => '12',
  55         category_type   => 'A'
  56     },
  57     patron => {
  58         surname    => 'test_patron_surname',
  59         cardnumber => '4242424242',
  60         userid     => 'test_username',
  61         password   => '1BetterPassword',
  62         password2  => '1BetterPassword'
  63     },
  64     itemtype => {
  65         itemtype     => 'IT4TEST',
  66         description  => 'Just an itemtype for tests',
  67         rentalcharge => 0,
  68         notforloan   => 0,
  69     },
  70     issuingrule => {
  71         categorycode  => 'test_cat',
  72         itemtype      => 'IT4test',
  73         branchcode    => '*',
  74         maxissueqty   => '5',
  75         issuelength   => '5',
  76         lengthunit    => 'days',
  77         renewalperiod => '5',
  78       },
  79 };
  80 our ( $borrowernumber, $start, $prev_time, $cleanup_needed );
  81
  82 SKIP: {
  83     eval { require Selenium::Remote::Driver; };
  84     skip "Selenium::Remote::Driver is needed for selenium tests.", 20 if $@;
  85
  86     $cleanup_needed = 1;
  87
  88     open my $fh, '>>', '/tmp/output.txt';
  89
  90     my $s = t::lib::Selenium->new;
  91
  92     my $driver = $s->driver;
  93     my $base_url = $s->base_url;
  94
  95     $start = gettimeofday;
  96     $prev_time = $start;
  97     $driver->get($base_url."mainpage.pl");
  98     like( $driver->get_title(), qr(Log in to Koha), );
  99     $s->auth;
 100     time_diff("main");
 101
 102     $driver->get($base_url.'admin/categories.pl');
 103     like( $driver->get_title(), qr(Patron categories), );
 104     $driver->find_element('//a[@id="newcategory"]')->click;
 105     like( $driver->get_title(), qr(New category), );
 106     $s->fill_form( $sample_data->{category} );
 107     $driver->find_element('//fieldset[@class="action"]/input[@type="submit"]')->click;
 108
 109     time_diff("add patron category");
 110     $driver->get($base_url.'/members/memberentry.pl?op=add&amp;categorycode='.$sample_data->{category}{categorycode});
 111     like( $driver->get_title(), qr(Add .*$sample_data->{category}{description}), );
 112     $s->fill_form( $sample_data->{patron} );
 113     $driver->find_element('//button[@id="saverecord"]')->click;
 114     like( $driver->get_title(), qr(Patron details for $sample_data->{patron}{surname}), );
 115
 116     ####$driver->get($base_url.'/members/members-home.pl');
 117     ####fill_form( $driver, { searchmember => $sample_data->{patron}{cardnumber} } );
 118     ####$driver->find_element('//div[@id="header_search"]/div/form/input[@type="submit"]')->click;
 119     ####like( $driver->get_title(), qr(Patron details for), );
 120
 121     time_diff("add patron");
 122
 123     $borrowernumber = $dbh->selectcol_arrayref(q|SELECT borrowernumber FROM borrowers WHERE userid=?|, {}, $sample_data->{patron}{userid} )->[0];
 124
 125     my @biblionumbers;
 126     for my $i ( 1 .. $number_of_biblios_to_insert ) {
 127         my $biblio = MARC::Record->new();
 128         my $title = 'test biblio '.$i;
 129         if ( C4::Context->preference('marcflavour') eq 'UNIMARC' ) {
 130             $biblio->append_fields(
 131                 MARC::Field->new('200', ' ', ' ', a => 'test biblio '.$i),
 132                 MARC::Field->new('200', ' ', ' ', f => 'test author '.$i),
 133             );
 134         } else {
 135             $biblio->append_fields(
 136                 MARC::Field->new('245', ' ', ' ', a => 'test biblio '.$i),
 137                 MARC::Field->new('100', ' ', ' ', a => 'test author '.$i),
 138             );
 139         }
 140         my ($biblionumber, $biblioitemnumber) = AddBiblio($biblio, '');
 141         push @biblionumbers, $biblionumber;
 142     }
 143
 144     time_diff("add biblio");
 145
 146     my $itemtype = $sample_data->{itemtype};
 147     $dbh->do(q|INSERT INTO itemtypes (itemtype, description, rentalcharge, notforloan) VALUES (?, ?, ?, ?)|, undef, $itemtype->{itemtype}, $itemtype->{description}, $itemtype->{rentalcharge}, $itemtype->{notforloan});
 148
 149     my $issuing_rules = $sample_data->{issuingrule};
 150     $dbh->do(q|INSERT INTO issuingrules (categorycode, itemtype, branchcode, maxissueqty, issuelength, lengthunit, renewalperiod) VALUES (?, ?, ?, ?, ?, ?, ?)|, undef, $issuing_rules->{categorycode}, $issuing_rules->{itemtype}, $issuing_rules->{branchcode}, $issuing_rules->{maxissueqty}, $issuing_rules->{issuelength}, $issuing_rules->{lengthunit}, $issuing_rules->{renewalperiod});
 151
 152     for my $biblionumber ( @biblionumbers ) {
 153         $driver->get($base_url."/cataloguing/additem.pl?biblionumber=$biblionumber");
 154         like( $driver->get_title(), qr(test biblio \d+ by test author), );
 155         my $form = $driver->find_element('//form[@name="f"]');
 156         my $inputs = $driver->find_child_elements($form, '//input[@type="text"]');
 157         for my $input ( @$inputs ) {
 158             next if $input->is_hidden();
 159
 160             my $id = $input->get_attribute('id');
 161             next unless $id =~ m|^tag_952_subfield|;
 162
 163             my $v;
 164
 165             # FIXME This is based on default values
 166             if (   $id =~ m|^tag_952_subfield_g|   # price
 167                 or $id =~ m|^tag_952_subfield_v| ) # replacementprice
 168             {
 169                 $v = '42';    # It's a price
 170             }
 171             elsif (
 172                 $id =~ m|^tag_952_subfield_f| #tag_952_subfield_g
 173             ) {
 174                 # It's a varchar(10)
 175                 $v = 't_value_x';
 176             }
 177             else {
 178                 $v = 't_value_bib' . $biblionumber;
 179             }
 180             $input->send_keys( $v );
 181         }
 182
 183         $driver->find_element('//input[@name="add_submit"]')->click;
 184         like( $driver->get_title(), qr($biblionumber.*Items) );
 185
 186         $dbh->do(q|UPDATE items SET notforloan=0 WHERE biblionumber=?|, {}, $biblionumber );
 187         $dbh->do(q|UPDATE biblioitems SET itemtype=? WHERE biblionumber=?|, {}, $itemtype->{itemtype}, $biblionumber);
 188         $dbh->do(q|UPDATE items SET itype=? WHERE biblionumber=?|, {}, $itemtype->{itemtype}, $biblionumber);
 189     }
 190
 191     time_diff("add items");
 192
 193     my $nb_of_checkouts = 0;
 194     for my $biblionumber ( @biblionumbers ) {
 195         $driver->get($base_url."/circ/circulation.pl?borrowernumber=".$borrowernumber);
 196         $driver->find_element('//input[@id="barcode"]')->send_keys('t_value_bib'.$biblionumber);
 197         $driver->find_element('//fieldset[@id="circ_circulation_issue"]/button[@type="submit"]')->click;
 198         $nb_of_checkouts++;
 199         like( $driver->get_title(), qr(Checking out to $sample_data->{patron}{surname}) );
 200         is( $driver->find_element('//a[@href="#checkouts"]')->get_attribute('text'), $nb_of_checkouts.' Checkout(s)', );
 201     }
 202
 203     time_diff("checkout");
 204
 205     for my $biblionumber ( @biblionumbers ) {
 206         $driver->get($base_url."/circ/returns.pl");
 207         $driver->find_element('//input[@id="barcode"]')->send_keys('t_value_bib'.$biblionumber);
 208         $driver->find_element('//form[@id="checkin-form"]/div/fieldset/input[@type="submit"]')->click;
 209         like( $driver->get_title(), qr(Check in test biblio \d+) );
 210     }
 211
 212     time_diff("checkin");
 213
 214     close $fh;
 215     $driver->quit();
 216 };
 217
 218 END {
 219     cleanup() if $cleanup_needed;
 220 };
 221
 222 sub cleanup {
 223     my $dbh = C4::Context->dbh;
 224     $dbh->do(q|DELETE FROM issues where borrowernumber=?|, {}, $borrowernumber);
 225     $dbh->do(q|DELETE FROM old_issues where borrowernumber=?|, {}, $borrowernumber);
 226     for my $i ( 1 .. $number_of_biblios_to_insert ) {
 227         $dbh->do(qq|DELETE items, biblio FROM biblio INNER JOIN items ON biblio.biblionumber = items.biblionumber WHERE biblio.title = "test biblio$i"|);
 228     };
 229     $dbh->do(q|DELETE FROM borrowers WHERE userid = ?|, {}, $sample_data->{patron}{userid});
 230     $dbh->do(q|DELETE FROM categories WHERE categorycode = ?|, {}, $sample_data->{category}{categorycode});
 231     for my $i ( 1 .. $number_of_biblios_to_insert ) {
 232         $dbh->do(qq|DELETE FROM biblio WHERE title = "test biblio $i"|);
 233     };
 234     $dbh->do(q|DELETE FROM itemtypes WHERE itemtype=?|, undef, $sample_data->{itemtype}{itemtype});
 235     $dbh->do(q|DELETE FROM issuingrules WHERE categorycode=? AND itemtype=? AND branchcode=?|, undef, $sample_data->{issuingrule}{categorycode}, $sample_data->{issuingrule}{itemtype}, $sample_data->{issuingrule}{branchcode});
 236 }
 237
 238 sub time_diff {
 239     my $lib = shift;
 240     my $now = gettimeofday;
 241     warn "CP $lib = " . sprintf("%.2f", $now - $prev_time ) . "\n";
 242     $prev_time = $now;
 243 }