tools/additional-contents.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Script to manage the opac news.
   6 # written 11/04
   7 # Casta�eda, Carlos Sebastian - seba3c@yahoo.com.ar - Physics Library UNLP Argentina
   8 # Modified to include news to KOHA intranet - tgarip@neu.edu.tr NEU library -Cyprus
   9 # Copyright 2000-2002 Katipo Communications
  10 # Copyright (C) 2013    Mark Tompsett
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 use Modern::Perl;
  26 use CGI qw ( -utf8 );
  27 use C4::Auth qw(get_template_and_user);
  28 use C4::Koha;
  29 use C4::Context;
  30 use C4::Log qw( logaction );
  31 use C4::Output qw(output_html_with_http_headers);
  32 use C4::Languages qw(getTranslatedLanguages);
  33 use Koha::DateUtils qw( dt_from_string output_pref );
  34
  35 use Koha::AdditionalContents;
  36
  37 my $cgi = CGI->new;
  38
  39 my $op             = $cgi->param('op') || 'list';
  40 my $id             = $cgi->param('id');
  41 my $category       = $cgi->param('category') || 'news';
  42 my $wysiwyg;
  43 my $redirect       = $cgi->param('redirect');
  44 my $editmode;
  45
  46 if( $cgi->param('editmode') ){
  47     $wysiwyg = $cgi->param('editmode') eq "wysiwyg" ? 1 : 0;
  48 } else {
  49     $wysiwyg = C4::Context->preference("AdditionalContentsEditor") eq "tinymce" ? 1 : 0;
  50 }
  51
  52 $editmode = $wysiwyg eq 1 ? "wysiwyg" : "text";
  53
  54 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  55     {
  56         template_name   => "tools/additional-contents.tt",
  57         query           => $cgi,
  58         type            => "intranet",
  59         flagsrequired   => { tools => 'edit_additional_contents' },
  60     }
  61 );
  62
  63 my @messages;
  64 if ( $op eq 'add_form' ) {
  65
  66     my $additional_content = Koha::AdditionalContents->find($id);
  67     my $translated_contents;
  68     if ( $additional_content ) {
  69         $translated_contents = {
  70             map { $_->lang => $_ } Koha::AdditionalContents->search(
  71                 {
  72                     category   => $additional_content->category,
  73                     code       => $additional_content->code,
  74                     location   => $additional_content->location,
  75                     branchcode => $additional_content->branchcode,
  76                 }
  77             )->as_list
  78         };
  79         $category = $additional_content->category;
  80     }
  81     $template->param(
  82         additional_content => $additional_content,
  83         translated_contents => $translated_contents,
  84     );
  85 }
  86 elsif ( $op eq 'add_validate' ) {
  87     my $location   = $cgi->param('location');
  88     my $code       = $cgi->param('code');
  89     my $branchcode = $cgi->param('branchcode') || undef;
  90     my $idnew      = $cgi->param('idnew');
  91
  92     my @lang       = $cgi->multi_param('lang');
  93
  94     my $expirationdate = $cgi->param('expirationdate');
  95     my $published_on = $cgi->param('published_on');
  96     my $number = $cgi->param('number');
  97
  98     my $original_default = $idnew ? Koha::AdditionalContents->find($idnew) : undef;
  99
 100     my $success = 1;
 101     for my $lang ( sort {$a ne 'default'} @lang ) { # Process 'default' first
 102         my $title   = $cgi->param( 'title_' . $lang );
 103         my $content = $cgi->param( 'content_' . $lang );
 104         # Force a default record
 105         $content ||= '<!-- no_content -->' if $lang eq 'default';
 106
 107         my $additional_content = Koha::AdditionalContents->find(
 108             {
 109                 category   => $category,
 110                 code       => $code,
 111                 branchcode => $original_default ? $original_default->branchcode : $branchcode,
 112                 lang       => $lang,
 113             }
 114         );
 115         # Delete if title or content is empty
 116         if( $lang ne 'default' && !$title && !$content ) {
 117             if ( $additional_content ) {
 118                 eval { $additional_content->delete };
 119                 unless ($@) {
 120                     logaction('NEWS', 'DELETE' , undef, sprintf("%s|%s|%s|%s", $additional_content->code, $additional_content->title, $additional_content->lang, $additional_content->content));
 121                 }
 122             }
 123             next;
 124         } elsif ( $additional_content ) {
 125             my $updated;
 126             eval {
 127                 $additional_content->set(
 128                     {
 129                         category       => $category,
 130                         code           => $code,
 131                         location       => $location,
 132                         branchcode     => $branchcode,
 133                         title          => $title,
 134                         content        => $content,
 135                         lang           => $lang,
 136                         expirationdate => $expirationdate,
 137                         published_on   => $published_on,
 138                         number         => $number,
 139                         borrowernumber => $borrowernumber,
 140                     }
 141                 );
 142                 $updated = $additional_content->_result->get_dirty_columns;
 143                 $additional_content->store;
 144                 $id = $additional_content->idnew;
 145             };
 146             if ($@) {
 147                 $success = 0;
 148                 push @messages, { type => 'error', code => 'error_on_update' };
 149                 last;
 150             }
 151
 152             logaction('NEWS', 'MODIFY' , undef, sprintf("%s|%s|%s|%s", $code, $title, $lang, $content))
 153                 if C4::Context->preference("NewsLog") && $updated;
 154         }
 155         else {
 156             my $additional_content = Koha::AdditionalContent->new(
 157                 {
 158                     category       => $category,
 159                     code           => $code || 'tmp_code',
 160                     location       => $location,
 161                     branchcode     => $branchcode,
 162                     title          => $title,
 163                     content        => $content,
 164                     lang           => $lang,
 165                     expirationdate => $expirationdate,
 166                     published_on   => $published_on,
 167                     number         => $number,
 168                     borrowernumber => $borrowernumber,
 169                 }
 170             )->store;
 171             eval {
 172                 $additional_content->store;
 173                 unless ($code) {
 174                     $additional_content->discard_changes;
 175                     $code = $category eq 'news'
 176                       ? 'News_' . $additional_content->idnew
 177                       : $location . '_' . $additional_content->idnew;
 178                     $additional_content->code($code)->store;
 179                     $id = $additional_content->idnew;
 180                 }
 181             };
 182             if ($@) {
 183                 $success = 0;
 184                 push @messages, { type => 'error', code => 'error_on_insert' };
 185                 last;
 186             }
 187
 188             logaction('NEWS', 'ADD' , undef, sprintf("%s|%s|%s|%s", $code, $title, $lang, $content))
 189                 if C4::Context->preference("NewsLog");
 190         }
 191
 192     }
 193
 194     if( $redirect eq "just_save" ){
 195         print $cgi->redirect("/cgi-bin/koha/tools/additional-contents.pl?op=add_form&id=$id&category=$category&editmode=$editmode&redirect=done");
 196         exit;
 197     } else {
 198         $op = 'list';
 199     }
 200 }
 201 elsif ( $op eq 'delete_confirmed' ) {
 202     my @ids = $cgi->multi_param('ids');
 203     my $deleted = eval {
 204
 205         my $schema = Koha::Database->new->schema;
 206         $schema->txn_do(
 207             sub {
 208                 my $contents =
 209                   Koha::AdditionalContents->search( { idnew => \@ids } );
 210
 211                 while ( my $c = $contents->next ) {
 212                     Koha::AdditionalContents->search( { code => $c->code } )->delete;
 213                     if ( C4::Context->preference("NewsLog") ) {
 214                         logaction('NEWS', 'DELETE' , undef, sprintf("%s|%s|%s|%s", $c->code, $c->title, $c->lang, $c->content));
 215                     }
 216                 }
 217             }
 218         );
 219     };
 220
 221     if ( $@ or not $deleted ) {
 222         push @messages, { type => 'error', code => 'error_on_delete' };
 223     }
 224     else {
 225         push @messages, { type => 'message', code => 'success_on_delete' };
 226     }
 227
 228     $op = 'list';
 229 }
 230
 231 if ( $op eq 'list' ) {
 232     my $additional_contents = Koha::AdditionalContents->search(
 233         { category => $category, lang => 'default' },
 234         { order_by => { -desc => 'published_on' } }
 235     );
 236     $template->param( additional_contents => $additional_contents );
 237 }
 238
 239 my $translated_languages = C4::Languages::getTranslatedLanguages;
 240 my @languages;
 241 for my $language (@$translated_languages) {
 242     for my $sublanguage ( @{ $language->{sublanguages_loop} } ) {
 243         if ( $language->{plural} ) {
 244             push @languages,
 245               {
 246                 lang        => $sublanguage->{rfc4646_subtag},
 247                 description => $sublanguage->{native_description} . ' '
 248                   . $sublanguage->{region_description} . ' ('
 249                   . $sublanguage->{rfc4646_subtag} . ')',
 250               };
 251         }
 252         else {
 253             push @languages,
 254               {
 255                 lang        => $sublanguage->{rfc4646_subtag},
 256                 description => $sublanguage->{native_description} . ' ('
 257                   . $sublanguage->{rfc4646_subtag} . ')',
 258               };
 259         }
 260     }
 261 }
 262 unshift @languages, {lang => 'default'} if @languages;
 263
 264 $template->param(
 265     op        => $op,
 266     category  => $category,
 267     wysiwyg   => $wysiwyg,
 268     editmode  => $editmode,
 269     languages => \@languages,
 270 );
 271
 272 output_html_with_http_headers $cgi, $cookie, $template->output;