tools/batch_record_modification.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2013 BibLibre
   6 #
   7 # Koha is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as
   9 # published by the Free Software Foundation; either version 3
  10 # of the License, or (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General
  18 # Public License along with Koha; if not, see
  19 # <http://www.gnu.org/licenses>
  20
  21 use Modern::Perl;
  22
  23 use CGI;
  24 use List::MoreUtils qw( uniq );
  25 use JSON qw( encode_json );
  26 use Try::Tiny;
  27
  28 use C4::Auth qw( get_template_and_user );
  29 use C4::Output qw( output_html_with_http_headers );
  30 use C4::AuthoritiesMarc qw( BuildSummary ModAuthority );
  31 use C4::Biblio qw( GetMarcBiblio ModBiblio );
  32 use C4::MarcModificationTemplates qw( GetModificationTemplateActions GetModificationTemplates );
  33
  34 use Koha::Biblios;
  35 use Koha::BackgroundJob::BatchUpdateBiblio;
  36 use Koha::BackgroundJob::BatchUpdateAuthority;
  37 use Koha::MetadataRecord::Authority;
  38 use Koha::Virtualshelves;
  39
  40 my $input = CGI->new;
  41 our $dbh = C4::Context->dbh;
  42 my $op = $input->param('op') // q|form|;
  43 my $recordtype = $input->param('recordtype') // 'biblio';
  44 my $mmtid = $input->param('marc_modification_template_id');
  45
  46 my ( @messages );
  47
  48 my ( $template, $loggedinuser, $cookie ) = get_template_and_user({
  49         template_name => 'tools/batch_record_modification.tt',
  50         query => $input,
  51         type => "intranet",
  52         flagsrequired => { tools => 'records_batchmod' },
  53 });
  54
  55 my $sessionID = $input->cookie("CGISESSID");
  56
  57 my @templates = GetModificationTemplates( $mmtid );
  58 unless ( @templates ) {
  59     $op = 'error';
  60     $template->param(
  61         view => 'errors',
  62         errors => ['no_template_defined'],
  63     );
  64     output_html_with_http_headers $input, $cookie, $template->output;
  65     exit;
  66 }
  67
  68 if ( $mmtid ) {
  69     my @actions = GetModificationTemplateActions( $mmtid );
  70     unless ( @actions ) {
  71         $op = 'form';
  72         push @messages, {
  73             type => 'error',
  74             code => 'no_action_defined_for_the_template',
  75             mmtid => $mmtid,
  76         };
  77     }
  78 }
  79
  80 if ( $op eq 'form' ) {
  81     # Display the form
  82     $template->param(
  83         view => 'form',
  84     );
  85 } elsif ( $op eq 'list' ) {
  86     # List all records to process
  87     my ( @records, @record_ids );
  88     if ( my $bib_list = $input->param('bib_list') ) {
  89         # Come from the basket
  90         @record_ids = split /\//, $bib_list;
  91         $recordtype = 'biblio';
  92     } elsif ( my $uploadfile = $input->param('uploadfile') ) {
  93         # A file of id is given
  94         binmode $uploadfile, ':encoding(UTF-8)';
  95         while ( my $content = <$uploadfile> ) {
  96             next unless $content;
  97             $content =~ s/[\r\n]*$//;
  98             push @record_ids, $content if $content;
  99         }
 100     } elsif ( my $shelf_number = $input->param('shelf_number') ) {
 101         my $shelf = Koha::Virtualshelves->find($shelf_number);
 102         my $contents = $shelf->get_contents;
 103         while ( my $content = $contents->next ) {
 104             my $biblionumber = $content->biblionumber;
 105             push @record_ids, $biblionumber;
 106         }
 107     } else {
 108         # The user enters manually the list of id
 109         push @record_ids, split( /\s\n/, $input->param('recordnumber_list') );
 110     }
 111
 112     for my $record_id ( uniq @record_ids ) {
 113         if ( $recordtype eq 'biblio' ) {
 114             # Retrieve biblio information
 115             my $biblio = Koha::Biblios->find( $record_id );
 116             unless ( $biblio ) {
 117                 push @messages, {
 118                     type => 'warning',
 119                     code => 'biblio_not_exists',
 120                     biblionumber => $record_id,
 121                 };
 122                 next;
 123             }
 124             push @records, $biblio;
 125         } else {
 126             # Retrieve authority information
 127             my $authority = Koha::MetadataRecord::Authority->get_from_authid( $record_id );
 128             unless ( $authority ) {
 129                 push @messages, {
 130                     type => 'warning',
 131                     code => 'authority_not_exists',
 132                     authid => $record_id,
 133                 };
 134                 next;
 135             }
 136
 137             push @records, {
 138                 authid => $record_id,
 139                 summary => C4::AuthoritiesMarc::BuildSummary( $authority->record, $record_id ),
 140             };
 141         }
 142     }
 143     $template->param(
 144         records => \@records,
 145         mmtid => $mmtid,
 146         view => 'list',
 147     );
 148 } elsif ( $op eq 'modify' ) {
 149     # We want to modify selected records!
 150     my @record_ids = $input->multi_param('record_id');
 151
 152     try {
 153         my $params = {
 154             mmtid       => $mmtid,
 155             record_ids  => \@record_ids,
 156         };
 157
 158         my $job_id =
 159           $recordtype eq 'biblio'
 160           ? Koha::BackgroundJob::BatchUpdateBiblio->new->enqueue($params)
 161           : Koha::BackgroundJob::BatchUpdateAuthority->new->enqueue($params);
 162
 163         $template->param(
 164             view => 'enqueued',
 165             job_id => $job_id,
 166         );
 167     } catch {
 168         push @messages, {
 169             type => 'error',
 170             code => 'cannot_enqueue_job',
 171             error => $_,
 172         };
 173         $template->param( view => 'errors' );
 174     };
 175 }
 176
 177 $template->param(
 178     messages => \@messages,
 179     recordtype => $recordtype,
 180     MarcModificationTemplatesLoop => \@templates,
 181 );
 182
 183 output_html_with_http_headers $input, $cookie, $template->output;