tools/export.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use CGI qw ( -utf8 );
  21 use MARC::File::XML;
  22 use List::MoreUtils qw(uniq);
  23 use C4::Auth;
  24 use C4::Output;
  25
  26 use Koha::Authority::Types;
  27 use Koha::Biblioitems;
  28 use Koha::CsvProfiles;
  29 use Koha::Database;
  30 use Koha::DateUtils qw( dt_from_string output_pref );
  31 use Koha::Exporter::Record;
  32 use Koha::ItemTypes;
  33 use Koha::Libraries;
  34
  35 my $query = CGI->new;
  36
  37 my $dont_export_items = $query->param("dont_export_item") || 0;
  38 my $record_type       = $query->param("record_type");
  39 my $op                = $query->param("op") || '';
  40 my $output_format     = $query->param("format") || $query->param("output_format") || 'iso2709';
  41 my $backupdir         = C4::Context->config('backupdir');
  42 my $filename;
  43 if ( $record_type eq 'auths' ) {
  44     $filename = $query->param("filename_auth") || ( $output_format eq 'xml' ? 'koha.xml' : 'koha.mrc' );
  45 } else {
  46     $filename = $query->param("filename") || ( $output_format eq 'csv' ? 'koha.csv' : 'koha.mrc' );
  47 }
  48 $filename =~ s/(\r|\n)//;
  49
  50 my $dbh = C4::Context->dbh;
  51
  52 my @record_ids;
  53 # biblionumbers is sent from circulation.pl only
  54 if ( $query->param("biblionumbers") ) {
  55     $record_type = 'bibs';
  56     @record_ids = $query->multi_param("biblionumbers");
  57 }
  58
  59 # Default value for output_format is 'iso2709'
  60 $output_format ||= 'iso2709';
  61 # Retrocompatibility for the format parameter
  62 $output_format = 'iso2709' if $output_format eq 'marc';
  63
  64 my ( $template, $loggedinuser, $cookie, $flags ) = get_template_and_user(
  65     {
  66         template_name   => "tools/export.tt",
  67         query           => $query,
  68         type            => "intranet",
  69         flagsrequired   => { tools => 'export_catalog' },
  70         debug           => 1,
  71     }
  72 );
  73
  74 my @branch = $query->multi_param("branch");
  75
  76 my @messages;
  77 if ( $op eq 'export' ) {
  78     my $filename = $query->param('id_list_file');
  79     if ( $filename ) {
  80         my $mimetype = $query->uploadInfo($filename)->{'Content-Type'};
  81         my @valid_mimetypes = qw( application/octet-stream text/csv text/plain application/vnd.ms-excel );
  82         unless ( grep { $_ eq $mimetype } @valid_mimetypes ) {
  83             push @messages, { type => 'alert', code => 'invalid_mimetype' };
  84             $op = '';
  85         }
  86     }
  87 }
  88
  89 if ( $op eq "export" ) {
  90
  91     my $export_remove_fields = $query->param("export_remove_fields") || q||;
  92     my @biblionumbers      = $query->multi_param("biblionumbers");
  93     my @itemnumbers        = $query->multi_param("itemnumbers");
  94     my $strip_items_not_from_libraries =  $query->param('strip_items_not_from_libraries');
  95
  96     my $libraries = Koha::Libraries->search_filtered->unblessed;
  97     my $only_export_items_for_branches = $strip_items_not_from_libraries ? \@branch : undef;
  98     my @branchcodes;
  99     for my $branchcode ( @branch ) {
 100         if ( grep { $_->{branchcode} eq $branchcode } @$libraries ) {
 101             push @branchcodes, $branchcode;
 102         }
 103     }
 104
 105     if ( $record_type eq 'bibs' or $record_type eq 'auths' ) {
 106         # No need to retrieve the record_ids if we already get them
 107         unless ( @record_ids ) {
 108             if ( $record_type eq 'bibs' ) {
 109                 my $starting_biblionumber = $query->param("StartingBiblionumber");
 110                 my $ending_biblionumber   = $query->param("EndingBiblionumber");
 111                 my $itemtype             = $query->param("itemtype");
 112                 my $start_callnumber     = $query->param("start_callnumber");
 113                 my $end_callnumber       = $query->param("end_callnumber");
 114                 my $start_accession =
 115                   ( $query->param("start_accession") )
 116                   ? dt_from_string( scalar $query->param("start_accession") )
 117                   : '';
 118                 my $end_accession =
 119                   ( $query->param("end_accession") )
 120                   ? dt_from_string( scalar $query->param("end_accession") )
 121                   : '';
 122
 123
 124                 my $conditions = {
 125                     ( $starting_biblionumber or $ending_biblionumber )
 126                         ? (
 127                             "me.biblionumber" => {
 128                                 ( $starting_biblionumber ? ( '>=' => $starting_biblionumber ) : () ),
 129                                 ( $ending_biblionumber   ? ( '<=' => $ending_biblionumber   ) : () ),
 130                             }
 131                         )
 132                         : (),
 133
 134                     ( $start_callnumber or $end_callnumber )
 135                         ? (
 136                             'items.itemcallnumber' => {
 137                                 ( $start_callnumber ? ( '>=' => $start_callnumber ) : () ),
 138                                 ( $end_callnumber   ? ( '<=' => $end_callnumber   ) : () ),
 139                             }
 140                         )
 141                         : (),
 142
 143                     ( $start_accession or $end_accession )
 144                         ? (
 145                             'items.dateaccessioned' => {
 146                                 ( $start_accession ? ( '>=' => $start_accession ) : () ),
 147                                 ( $end_accession   ? ( '<=' => $end_accession   ) : () ),
 148                             }
 149                         )
 150                         : (),
 151                     ( @branchcodes ? ( 'items.homebranch' => { in => \@branchcodes } ) : () ),
 152                     ( $itemtype
 153                         ?
 154                           C4::Context->preference('item-level_itypes')
 155                             ? ( 'items.itype' => $itemtype )
 156                             : ( 'me.itemtype' => $itemtype )
 157                         : ()
 158                     ),
 159
 160                 };
 161                 my $biblioitems = Koha::Biblioitems->search( $conditions, { join => 'items', columns => 'biblionumber' } );
 162                 while ( my $biblioitem = $biblioitems->next ) {
 163                     push @record_ids, $biblioitem->biblionumber;
 164                 }
 165             }
 166             elsif ( $record_type eq 'auths' ) {
 167                 my $starting_authid = $query->param('starting_authid');
 168                 my $ending_authid   = $query->param('ending_authid');
 169                 my $authtype        = $query->param('authtype');
 170
 171                 my $conditions = {
 172                     ( $starting_authid or $ending_authid )
 173                         ? (
 174                             authid => {
 175                                 ( $starting_authid ? ( '>=' => $starting_authid ) : () ),
 176                                 ( $ending_authid   ? ( '<=' => $ending_authid   ) : () ),
 177                             }
 178                         )
 179                         : (),
 180                     ( $authtype ? ( authtypecode => $authtype ) : () ),
 181                 };
 182                 # Koha::MetadataRecord::Authority is not a Koha::Object...
 183                 my $authorities = Koha::Database->new->schema->resultset('AuthHeader')->search( $conditions );
 184                 @record_ids = map { $_->authid } $authorities->all;
 185             }
 186         }
 187
 188         @record_ids = uniq @record_ids;
 189         if ( @record_ids and my $filefh = $query->upload("id_list_file") ) {
 190             my @filter_record_ids = <$filefh>;
 191             @filter_record_ids = map { my $id = $_; $id =~ s/[\r\n]*$//; $id } @filter_record_ids;
 192             # intersection
 193             my %record_ids = map { $_ => 1 } @record_ids;
 194             @record_ids = grep $record_ids{$_}, @filter_record_ids;
 195         }
 196
 197         print CGI->new->header(
 198             -type       => 'application/octet-stream',
 199             -charset    => 'utf-8',
 200             -attachment => $filename,
 201         );
 202
 203         my $csv_profile_id = $query->param('csv_profile_id');
 204         Koha::Exporter::Record::export(
 205             {   record_type        => $record_type,
 206                 record_ids         => \@record_ids,
 207                 format             => $output_format,
 208                 filename           => $filename,
 209                 itemnumbers        => \@itemnumbers,
 210                 dont_export_fields => $export_remove_fields,
 211                 csv_profile_id     => $csv_profile_id,
 212                 export_items       => (not $dont_export_items),
 213                 only_export_items_for_branches => $only_export_items_for_branches,
 214             }
 215         );
 216     }
 217     elsif ( $record_type eq 'db' or $record_type eq 'conf' ) {
 218         my $successful_export;
 219
 220         if ( $flags->{superlibrarian}
 221             and (
 222                     $record_type eq 'db' and C4::Context->config('backup_db_via_tools')
 223                  or
 224                     $record_type eq 'conf' and C4::Context->config('backup_conf_via_tools')
 225             )
 226         ) {
 227             binmode STDOUT, ':encoding(UTF-8)';
 228
 229             my $charset  = 'utf-8';
 230             my $mimetype = 'application/octet-stream';
 231             if ( $filename =~ m/\.gz$/ ) {
 232                 $mimetype = 'application/x-gzip';
 233                 $charset  = '';
 234                 binmode STDOUT;
 235             }
 236             elsif ( $filename =~ m/\.bz2$/ ) {
 237                 $mimetype = 'application/x-bzip2';
 238                 binmode STDOUT;
 239                 $charset = '';
 240             }
 241             print $query->header(
 242                 -type       => $mimetype,
 243                 -charset    => $charset,
 244                 -attachment => $filename,
 245             );
 246
 247             my $extension = $record_type eq 'db' ? 'sql' : 'tar';
 248
 249             $successful_export = download_backup(
 250                 {
 251                     directory => $backupdir,
 252                     extension => $extension,
 253                     filename  => $filename,
 254                 }
 255             );
 256             unless ($successful_export) {
 257                 my $remotehost = $query->remote_host();
 258                 $remotehost =~ s/(\n|\r)//;
 259                 warn
 260     "A suspicious attempt was made to download the " . ( $record_type eq 'db' ? 'db' : 'configuration' ) . "at '$filename' by someone at "
 261                   . $remotehost . "\n";
 262             }
 263         }
 264     }
 265
 266     exit;
 267 }
 268
 269 else {
 270
 271     my $itemtypes = Koha::ItemTypes->search_with_localization;
 272
 273     my $authority_types = Koha::Authority::Types->search( {}, { order_by => ['authtypecode'] } );
 274
 275     my $libraries = Koha::Libraries->search_filtered({}, { order_by => ['branchname'] })->unblessed;
 276     for my $library ( @$libraries ) {
 277         $library->{selected} = 1 if grep { $library->{branchcode} eq $_ } @branch;
 278     }
 279
 280     if (   $flags->{superlibrarian}
 281         && C4::Context->config('backup_db_via_tools')
 282         && $backupdir
 283         && -d $backupdir )
 284     {
 285         $template->{VARS}->{'allow_db_export'} = 1;
 286         $template->{VARS}->{'dbfiles'}         = getbackupfilelist(
 287             { directory => "$backupdir", extension => 'sql' } );
 288     }
 289
 290     if (   $flags->{superlibrarian}
 291         && C4::Context->config('backup_conf_via_tools')
 292         && $backupdir
 293         && -d $backupdir )
 294     {
 295         $template->{VARS}->{'allow_conf_export'} = 1;
 296         $template->{VARS}->{'conffiles'}         = getbackupfilelist(
 297             { directory => "$backupdir", extension => 'tar' } );
 298     }
 299
 300     $template->param(
 301         libraries                => $libraries,
 302         itemtypes                => $itemtypes,
 303         authority_types          => $authority_types,
 304         export_remove_fields     => C4::Context->preference("ExportRemoveFields"),
 305         csv_profiles             => [ Koha::CsvProfiles->search({ type => 'marc', used_for => 'export_records' }) ],
 306         messages                 => \@messages,
 307     );
 308
 309     output_html_with_http_headers $query, $cookie, $template->output;
 310 }
 311
 312 sub getbackupfilelist {
 313     my $args      = shift;
 314     my $directory = $args->{directory};
 315     my $extension = $args->{extension};
 316     my @files;
 317
 318     if ( opendir( my $dir, $directory ) ) {
 319         while ( my $file = readdir($dir) ) {
 320             next unless ( $file =~ m/\.$extension(\.(gz|bz2|xz))?/ );
 321             push @files, $file
 322               if ( -f "$directory/$file" && -r "$directory/$file" );
 323         }
 324         closedir($dir);
 325     }
 326     return \@files;
 327 }
 328
 329 sub download_backup {
 330     my $args      = shift;
 331     my $directory = $args->{directory};
 332     my $extension = $args->{extension};
 333     my $filename  = $args->{filename};
 334
 335     return unless ( $directory && -d $directory );
 336     return unless ( $filename =~ m/\.$extension(\.(gz|bz2|xz))?$/ );
 337     return if ( $filename =~ m#/# );
 338     $filename = "$directory/$filename";
 339     return unless ( -f $filename && -r $filename );
 340     return unless ( open( my $dump, '<', $filename ) );
 341     binmode $dump;
 342
 343     while ( read( $dump, my $data, 64 * 1024 ) ) {
 344         print $data;
 345     }
 346     close($dump);
 347     return 1;
 348 }