tools/export.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use CGI qw ( -utf8 );
  21 use MARC::File::XML;
  22 use List::MoreUtils qw(uniq);
  23 use C4::Auth;
  24 use C4::Output;
  25
  26 use Koha::Authority::Types;
  27 use Koha::Biblioitems;
  28 use Koha::CsvProfiles;
  29 use Koha::Database;
  30 use Koha::DateUtils qw( dt_from_string output_pref );
  31 use Koha::Exporter::Record;
  32 use Koha::ItemTypes;
  33 use Koha::Libraries;
  34
  35 my $query = new CGI;
  36
  37 my $dont_export_items = $query->param("dont_export_item") || 0;
  38 my $record_type       = $query->param("record_type");
  39 my $op                = $query->param("op") || '';
  40 my $output_format     = $query->param("format") || $query->param("output_format") || 'iso2709';
  41 my $backupdir         = C4::Context->config('backupdir');
  42 my $filename          = $query->param("filename") || ( $output_format eq 'csv' ? 'koha.csv' : 'koha.mrc' );
  43 $filename =~ s/(\r|\n)//;
  44
  45 my $dbh = C4::Context->dbh;
  46
  47 my @record_ids;
  48 # biblionumbers is sent from circulation.pl only
  49 if ( $query->param("biblionumbers") ) {
  50     $record_type = 'bibs';
  51     @record_ids = $query->multi_param("biblionumbers");
  52 }
  53
  54 # Default value for output_format is 'iso2709'
  55 $output_format ||= 'iso2709';
  56 # Retrocompatibility for the format parameter
  57 $output_format = 'iso2709' if $output_format eq 'marc';
  58
  59 my ( $template, $loggedinuser, $cookie, $flags ) = get_template_and_user(
  60     {
  61         template_name   => "tools/export.tt",
  62         query           => $query,
  63         type            => "intranet",
  64         flagsrequired   => { tools => 'export_catalog' },
  65         debug           => 1,
  66     }
  67 );
  68
  69 my @branch = $query->multi_param("branch");
  70
  71 my @messages;
  72 if ( $op eq 'export' ) {
  73     my $filename = $query->param('id_list_file');
  74     if ( $filename ) {
  75         my $mimetype = $query->uploadInfo($filename)->{'Content-Type'};
  76         my @valid_mimetypes = qw( application/octet-stream text/csv text/plain application/vnd.ms-excel );
  77         unless ( grep { /^$mimetype$/ } @valid_mimetypes ) {
  78             push @messages, { type => 'alert', code => 'invalid_mimetype' };
  79             $op = '';
  80         }
  81     }
  82 }
  83
  84 if ( $op eq "export" ) {
  85
  86     my $export_remove_fields = $query->param("export_remove_fields") || q||;
  87     my @biblionumbers      = $query->multi_param("biblionumbers");
  88     my @itemnumbers        = $query->multi_param("itemnumbers");
  89     my $strip_items_not_from_libraries =  $query->param('strip_items_not_from_libraries');
  90     my @sql_params;
  91     my $sql_query;
  92
  93     my $libraries = Koha::Libraries->search_filtered->unblessed;
  94     my $only_export_items_for_branches = $strip_items_not_from_libraries ? \@branch : undef;
  95     my @branchcodes;
  96     for my $branchcode ( @branch ) {
  97         if ( grep { $_->{branchcode} eq $branchcode } @$libraries ) {
  98             push @branchcodes, $branchcode;
  99         }
 100     }
 101
 102     if ( $record_type eq 'bibs' or $record_type eq 'auths' ) {
 103         # No need to retrieve the record_ids if we already get them
 104         unless ( @record_ids ) {
 105             if ( $record_type eq 'bibs' ) {
 106                 my $starting_biblionumber = $query->param("StartingBiblionumber");
 107                 my $ending_biblionumber   = $query->param("EndingBiblionumber");
 108                 my $itemtype             = $query->param("itemtype");
 109                 my $start_callnumber     = $query->param("start_callnumber");
 110                 my $end_callnumber       = $query->param("end_callnumber");
 111                 my $start_accession =
 112                   ( $query->param("start_accession") )
 113                   ? dt_from_string( scalar $query->param("start_accession") )
 114                   : '';
 115                 my $end_accession =
 116                   ( $query->param("end_accession") )
 117                   ? dt_from_string( scalar $query->param("end_accession") )
 118                   : '';
 119
 120
 121                 my $conditions = {
 122                     ( $starting_biblionumber or $ending_biblionumber )
 123                         ? (
 124                             "me.biblionumber" => {
 125                                 ( $starting_biblionumber ? ( '>=' => $starting_biblionumber ) : () ),
 126                                 ( $ending_biblionumber   ? ( '<=' => $ending_biblionumber   ) : () ),
 127                             }
 128                         )
 129                         : (),
 130
 131                     ( $start_callnumber or $end_callnumber )
 132                         ? (
 133                             'items.itemcallnumber' => {
 134                                 ( $start_callnumber ? ( '>=' => $start_callnumber ) : () ),
 135                                 ( $end_callnumber   ? ( '<=' => $end_callnumber   ) : () ),
 136                             }
 137                         )
 138                         : (),
 139
 140                     ( $start_accession or $end_accession )
 141                         ? (
 142                             'items.dateaccessioned' => {
 143                                 ( $start_accession ? ( '>=' => $start_accession ) : () ),
 144                                 ( $end_accession   ? ( '<=' => $end_accession   ) : () ),
 145                             }
 146                         )
 147                         : (),
 148                     ( @branchcodes ? ( 'items.homebranch' => { in => \@branchcodes } ) : () ),
 149                     ( $itemtype
 150                         ?
 151                           C4::Context->preference('item-level_itypes')
 152                             ? ( 'items.itype' => $itemtype )
 153                             : ( 'me.itemtype' => $itemtype )
 154                         : ()
 155                     ),
 156
 157                 };
 158                 my $biblioitems = Koha::Biblioitems->search( $conditions, { join => 'items', columns => 'biblionumber' } );
 159                 while ( my $biblioitem = $biblioitems->next ) {
 160                     push @record_ids, $biblioitem->biblionumber;
 161                 }
 162             }
 163             elsif ( $record_type eq 'auths' ) {
 164                 my $starting_authid = $query->param('starting_authid');
 165                 my $ending_authid   = $query->param('ending_authid');
 166                 my $authtype        = $query->param('authtype');
 167
 168                 my $conditions = {
 169                     ( $starting_authid or $ending_authid )
 170                         ? (
 171                             authid => {
 172                                 ( $starting_authid ? ( '>=' => $starting_authid ) : () ),
 173                                 ( $ending_authid   ? ( '<=' => $ending_authid   ) : () ),
 174                             }
 175                         )
 176                         : (),
 177                     ( $authtype ? ( authtypecode => $authtype ) : () ),
 178                 };
 179                 # Koha::MetadataRecord::Authority is not a Koha::Object...
 180                 my $authorities = Koha::Database->new->schema->resultset('AuthHeader')->search( $conditions );
 181                 @record_ids = map { $_->authid } $authorities->all;
 182             }
 183         }
 184
 185         @record_ids = uniq @record_ids;
 186         if ( @record_ids and my $filefh = $query->upload("id_list_file") ) {
 187             my @filter_record_ids = <$filefh>;
 188             @filter_record_ids = map { my $id = $_; $id =~ s/[\r\n]*$//; $id } @filter_record_ids;
 189             # intersection
 190             my %record_ids = map { $_ => 1 } @record_ids;
 191             @record_ids = grep $record_ids{$_}, @filter_record_ids;
 192         }
 193
 194         print CGI->new->header(
 195             -type       => 'application/octet-stream',
 196             -charset    => 'utf-8',
 197             -attachment => $filename,
 198         );
 199
 200         my $csv_profile_id = $query->param('csv_profile_id');
 201         Koha::Exporter::Record::export(
 202             {   record_type        => $record_type,
 203                 record_ids         => \@record_ids,
 204                 format             => $output_format,
 205                 filename           => $filename,
 206                 itemnumbers        => \@itemnumbers,
 207                 dont_export_fields => $export_remove_fields,
 208                 csv_profile_id     => $csv_profile_id,
 209                 export_items       => (not $dont_export_items),
 210                 only_export_items_for_branches => $only_export_items_for_branches,
 211             }
 212         );
 213     }
 214     elsif ( $record_type eq 'db' or $record_type eq 'conf' ) {
 215         my $successful_export;
 216
 217         if ( $flags->{superlibrarian}
 218             and (
 219                     $record_type eq 'db' and C4::Context->config('backup_db_via_tools')
 220                  or
 221                     $record_type eq 'conf' and C4::Context->config('backup_conf_via_tools')
 222             )
 223         ) {
 224             binmode STDOUT, ':encoding(UTF-8)';
 225
 226             my $charset  = 'utf-8';
 227             my $mimetype = 'application/octet-stream';
 228             if ( $filename =~ m/\.gz$/ ) {
 229                 $mimetype = 'application/x-gzip';
 230                 $charset  = '';
 231                 binmode STDOUT;
 232             }
 233             elsif ( $filename =~ m/\.bz2$/ ) {
 234                 $mimetype = 'application/x-bzip2';
 235                 binmode STDOUT;
 236                 $charset = '';
 237             }
 238             print $query->header(
 239                 -type       => $mimetype,
 240                 -charset    => $charset,
 241                 -attachment => $filename,
 242             );
 243
 244             my $extension = $record_type eq 'db' ? 'sql' : 'tar';
 245
 246             $successful_export = download_backup(
 247                 {
 248                     directory => $backupdir,
 249                     extension => $extension,
 250                     filename  => $filename,
 251                 }
 252             );
 253             unless ($successful_export) {
 254                 my $remotehost = $query->remote_host();
 255                 $remotehost =~ s/(\n|\r)//;
 256                 warn
 257     "A suspicious attempt was made to download the " . ( $record_type eq 'db' ? 'db' : 'configuration' ) . "at '$filename' by someone at "
 258                   . $remotehost . "\n";
 259             }
 260         }
 261     }
 262
 263     exit;
 264 }
 265
 266 else {
 267
 268     my $itemtypes = Koha::ItemTypes->search_with_localization;
 269
 270     my $authority_types = Koha::Authority::Types->search( {}, { order_by => ['authtypecode'] } );
 271
 272     my $libraries = Koha::Libraries->search_filtered({}, { order_by => ['branchname'] })->unblessed;
 273     for my $library ( @$libraries ) {
 274         $library->{selected} = 1 if grep { $library->{branchcode} eq $_ } @branch;
 275     }
 276
 277     if (   $flags->{superlibrarian}
 278         && C4::Context->config('backup_db_via_tools')
 279         && $backupdir
 280         && -d $backupdir )
 281     {
 282         $template->{VARS}->{'allow_db_export'} = 1;
 283         $template->{VARS}->{'dbfiles'}         = getbackupfilelist(
 284             { directory => "$backupdir", extension => 'sql' } );
 285     }
 286
 287     if (   $flags->{superlibrarian}
 288         && C4::Context->config('backup_conf_via_tools')
 289         && $backupdir
 290         && -d $backupdir )
 291     {
 292         $template->{VARS}->{'allow_conf_export'} = 1;
 293         $template->{VARS}->{'conffiles'}         = getbackupfilelist(
 294             { directory => "$backupdir", extension => 'tar' } );
 295     }
 296
 297     $template->param(
 298         libraries                => $libraries,
 299         itemtypes                => $itemtypes,
 300         authority_types          => $authority_types,
 301         export_remove_fields     => C4::Context->preference("ExportRemoveFields"),
 302         csv_profiles             => [ Koha::CsvProfiles->search({ type => 'marc', used_for => 'export_records' }) ],
 303         messages                 => \@messages,
 304     );
 305
 306     output_html_with_http_headers $query, $cookie, $template->output;
 307 }
 308
 309 sub getbackupfilelist {
 310     my $args      = shift;
 311     my $directory = $args->{directory};
 312     my $extension = $args->{extension};
 313     my @files;
 314
 315     if ( opendir( my $dir, $directory ) ) {
 316         while ( my $file = readdir($dir) ) {
 317             next unless ( $file =~ m/\.$extension(\.(gz|bz2|xz))?/ );
 318             push @files, $file
 319               if ( -f "$directory/$file" && -r "$directory/$file" );
 320         }
 321         closedir($dir);
 322     }
 323     return \@files;
 324 }
 325
 326 sub download_backup {
 327     my $args      = shift;
 328     my $directory = $args->{directory};
 329     my $extension = $args->{extension};
 330     my $filename  = $args->{filename};
 331
 332     return unless ( $directory && -d $directory );
 333     return unless ( $filename =~ m/\.$extension(\.(gz|bz2|xz))?$/ );
 334     return if ( $filename =~ m#/# );
 335     $filename = "$directory/$filename";
 336     return unless ( -f $filename && -r $filename );
 337     return unless ( open( my $dump, '<', $filename ) );
 338     binmode $dump;
 339
 340     while ( read( $dump, my $data, 64 * 1024 ) ) {
 341         print $data;
 342     }
 343     close($dump);
 344     return 1;
 345 }