tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth qw( get_template_and_user );
  46 use C4::Context;
  47 use C4::Output qw( output_html_with_http_headers );
  48 use C4::Letters qw( GetMessageTransportTypes );
  49 use C4::Log qw( logaction );
  50
  51 use Koha::Notice::Templates;
  52 use Koha::Patron::Attribute::Types;
  53
  54 # $protected_letters = protected_letters()
  55 # - return a hashref of letter_codes representing letters that should never be deleted
  56 sub protected_letters {
  57     my $dbh = C4::Context->dbh;
  58     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  59     return { map { $_->[0] => 1 } @{$codes} };
  60 }
  61
  62 our $input       = CGI->new;
  63 my $searchfield = $input->param('searchfield');
  64 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  65 our $branchcode  = $input->param('branchcode');
  66 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  67 my $code        = $input->param('code');
  68 my $module      = $input->param('module') || '';
  69 my $content     = $input->param('content');
  70 my $op          = $input->param('op') || '';
  71 my $redirect    = $input->param('redirect');
  72 my $section     = $input->param('section');
  73
  74 my $dbh = C4::Context->dbh;
  75
  76 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  77     {
  78         template_name   => 'tools/letter.tt',
  79         query           => $input,
  80         type            => 'intranet',
  81         flagsrequired   => { tools => 'edit_notices' },
  82     }
  83 );
  84
  85 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  86   ?  C4::Context->userenv()->{'branch'}
  87   : undef;
  88 # we show only the TMPL_VAR names $op
  89
  90 $template->param(
  91     independant_branch => $my_branch,
  92         script_name => $script_name,
  93   searchfield => $searchfield,
  94     branchcode => $branchcode,
  95     section => $section,
  96         action => $script_name
  97 );
  98
  99 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
 100     add_validate();
 101     if( $redirect eq "just_save" ){
 102         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done&section=$section");
 103         exit;
 104     } else {
 105         $op = q{}; # we return to the default screen for the next operation
 106     }
 107 }
 108 if ($op eq 'copy_form') {
 109     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 110     my $branchcode = $input->param('branchcode');
 111     add_form($oldbranchcode, $module, $code);
 112     $template->param(
 113         oldbranchcode => $oldbranchcode,
 114         branchcode => $branchcode,
 115         copying => 1,
 116         modify => 0,
 117     );
 118 }
 119 elsif ( $op eq 'add_form' ) {
 120     add_form($branchcode, $module, $code);
 121 }
 122 elsif ( $op eq 'delete_confirm' ) {
 123     delete_confirm($branchcode, $module, $code);
 124 }
 125 elsif ( $op eq 'delete_confirmed' ) {
 126     delete_confirmed($branchcode, $module, $code);
 127     $op = q{}; # next operation is to return to default screen
 128 }
 129 else {
 130     default_display($branchcode,$searchfield);
 131 }
 132
 133 # Do this last as delete_confirmed resets
 134 if ($op) {
 135     $template->param($op  => 1);
 136 } else {
 137     $template->param(no_op_set => 1);
 138 }
 139
 140 output_html_with_http_headers $input, $cookie, $template->output;
 141
 142 sub add_form {
 143     my ( $branchcode,$module, $code ) = @_;
 144
 145     my $letters;
 146     # if code has been passed we can identify letter and its an update action
 147     if ($code) {
 148         $letters = C4::Letters::GetLetterTemplates(
 149             {
 150                 branchcode => $branchcode,
 151                 module     => $module,
 152                 code       => $code,
 153             }
 154         );
 155     }
 156
 157     my $message_transport_types = GetMessageTransportTypes();
 158     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 159     my %letters = ( default => { templates => $templates } );
 160
 161     if ( C4::Context->preference('TranslateNotices') ) {
 162         my $translated_languages =
 163           C4::Languages::getTranslatedLanguages( 'opac',
 164             C4::Context->preference('template') );
 165         for my $language (@$translated_languages) {
 166             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 167                 if ( $language->{plural} ) {
 168                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 169                         description => $sublanguage->{native_description}
 170                           . ' '
 171                           . $sublanguage->{region_description} . ' ('
 172                           . $sublanguage->{rfc4646_subtag} . ')',
 173                         templates => { %$templates },
 174                     };
 175                 }
 176                 else {
 177                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 178                         description => $sublanguage->{native_description}
 179                           . ' ('
 180                           . $sublanguage->{rfc4646_subtag} . ')',
 181                         templates => { %$templates },
 182                     };
 183                 }
 184             }
 185         }
 186         $template->param( languages => $translated_languages );
 187     }
 188     if ($letters) {
 189         $template->param(
 190             modify     => 1,
 191             code       => $code,
 192         );
 193         my $first_flag_name = 1;
 194         my $lang;
 195         # The letter name is contained into each mtt row.
 196         # So we can only sent the first one to the template.
 197         for my $letter ( @$letters ) {
 198             # The letter_name
 199             if ( $first_flag_name and $letter->{name} ) {
 200                 $template->param(
 201                     letter_name=> $letter->{name},
 202                 );
 203                 $first_flag_name = 0;
 204             }
 205
 206             my $lang = $letter->{lang};
 207             my $mtt = $letter->{message_transport_type};
 208             $letters{ $lang }{templates}{$mtt} = {
 209                 message_transport_type => $letter->{message_transport_type},
 210                 is_html    => $letter->{is_html},
 211                 updated_on => $letter->{updated_on},
 212                 title      => $letter->{title},
 213                 content    => $letter->{content} // '',
 214             };
 215         }
 216     }
 217     else {
 218         $template->param( adding => 1 );
 219     }
 220
 221     $template->param(
 222         letters => \%letters,
 223     );
 224
 225     my $field_selection;
 226     push @{$field_selection}, add_fields('branches');
 227     if ($module eq 'reserves') {
 228         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 229     }
 230     elsif ( $module eq 'acquisition' ) {
 231         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 232     }
 233     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 234         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 235     }
 236     elsif ($module eq 'claimissues') {
 237         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription', 'biblio', 'biblioitems');
 238     }
 239     elsif ($module eq 'serial') {
 240         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 241     }
 242     elsif ($module eq 'suggestions') {
 243         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 244     }
 245     else {
 246         push @{$field_selection}, add_fields('biblio','biblioitems'),
 247             add_fields('items'),
 248             {value => 'items.content', text => 'items.content'},
 249             {value => 'items.fine',    text => 'items.fine'},
 250             add_fields('borrowers');
 251         if ($module eq 'circulation') {
 252             push @{$field_selection}, add_fields('additional_contents', 'recalls');
 253
 254         }
 255
 256         if ( $module eq 'circulation' and $code and ( $code eq "CHECKIN" or $code eq "CHECKINSLIP" ) ) {
 257             push @{$field_selection}, add_fields('old_issues');
 258         } else {
 259             push @{$field_selection}, add_fields('issues');
 260         }
 261
 262         if ( $module eq 'circulation' and $code and $code =~ /^AR_/  ) {
 263             push @{$field_selection}, add_fields('article_requests');
 264         }
 265
 266         if ( $module eq 'members' and $code and $code eq 'PROBLEM_REPORT' ) {
 267             push @{$field_selection}, add_fields('problem_reports');
 268         }
 269
 270         if ( $module eq 'ill' ) {
 271             push @{$field_selection}, add_fields('illrequests');
 272         }
 273     }
 274
 275     my $preview_is_available = 0;
 276
 277     if ($code) {
 278         $preview_is_available = grep {$_ eq $code } qw( CHECKIN CHECKOUT HOLD_SLIP );
 279     }
 280
 281     $template->param(
 282         module     => $module,
 283         SQLfieldnames => $field_selection,
 284         branchcode => $branchcode,
 285         preview_is_available => $preview_is_available,
 286     );
 287     return;
 288 }
 289
 290 sub add_validate {
 291     my $dbh        = C4::Context->dbh;
 292     my $branchcode    = $input->param('branchcode');
 293     my $module        = $input->param('module');
 294     my $oldmodule     = $input->param('oldmodule');
 295     my $code          = $input->param('code');
 296     my $name          = $input->param('name');
 297     my @mtt           = $input->multi_param('message_transport_type');
 298     my @title         = $input->multi_param('title');
 299     my @content       = $input->multi_param('content');
 300     my @lang          = $input->multi_param('lang');
 301     for my $mtt ( @mtt ) {
 302         my $lang = shift @lang;
 303         my $is_html = $input->param("is_html_$mtt\_$lang");
 304         my $title   = shift @title;
 305         my $content = shift @content;
 306         my $letter = Koha::Notice::Templates->find(
 307             {
 308                 module                 => $oldmodule,
 309                 code                   => $code,
 310                 branchcode             => $branchcode,
 311                 message_transport_type => $mtt,
 312                 lang                   => $lang
 313             }
 314         );
 315
 316         unless ( $title and $content ) {
 317             # Delete this mtt if no title or content given
 318             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 319             next;
 320         }
 321         elsif ( $letter ) {
 322             logaction( 'NOTICES', 'MODIFY', $letter->id, $content,
 323                 'Intranet' )
 324               if ( C4::Context->preference("NoticesLog")
 325                 && $content ne $letter->content );
 326
 327             $letter->set(
 328                 {
 329                     branchcode => $branchcode || '',
 330                     module     => $module,
 331                     name       => $name,
 332                     is_html    => $is_html || 0,
 333                     title      => $title,
 334                     content    => $content,
 335                     lang       => $lang
 336                 }
 337             )->store;
 338
 339         } else {
 340             my $letter = Koha::Notice::Template->new(
 341                 {
 342                     branchcode             => $branchcode,
 343                     module                 => $module,
 344                     code                   => $code,
 345                     name                   => $name,
 346                     is_html                => $is_html,
 347                     title                  => $title,
 348                     content                => $content,
 349                     message_transport_type => $mtt,
 350                     lang                   => $lang
 351                 }
 352             )->store;
 353             logaction( 'NOTICES', 'CREATE', $letter->id, $letter->content,
 354                 'Intranet' )
 355               if C4::Context->preference("NoticesLog");
 356         }
 357     }
 358     # set up default display
 359     default_display($branchcode);
 360     return 1;
 361 }
 362
 363 sub delete_confirm {
 364     my ($branchcode, $module, $code) = @_;
 365     my $dbh = C4::Context->dbh;
 366     my $letter = Koha::Notice::Templates->search(
 367         { module => $module, code => $code, branchcode => $branchcode } );
 368     $template->param(
 369         letter => $letter ? $letter->next : undef,
 370     );
 371     return;
 372 }
 373
 374 sub delete_confirmed {
 375     my ( $branchcode, $module, $code, $mtt, $lang ) = @_;
 376     my $letters = Koha::Notice::Templates->search(
 377         {
 378             branchcode => $branchcode || '',
 379             module     => $module,
 380             code       => $code,
 381             ( $mtt ? ( message_transport_type => $mtt ) : () ),
 382             ( $lang ? ( lang => $lang ) : () ),
 383         }
 384     );
 385     while ( my $letter = $letters->next ) {
 386         logaction( 'NOTICES', 'DELETE', $letter->id, $letter->content,
 387             'Intranet' )
 388           if C4::Context->preference("NoticesLog");
 389         $letter->delete;
 390     }
 391
 392     # setup default display for screen
 393     default_display($branchcode);
 394     return;
 395 }
 396
 397 sub retrieve_letters {
 398     my ($branchcode, $searchstring) = @_;
 399
 400     $branchcode = $my_branch if $branchcode && $my_branch;
 401
 402     my $dbh = C4::Context->dbh;
 403     my ($sql, @where, @args);
 404     $sql = "SELECT branchcode, module, code, name, branchname, MAX(updated_on) as updated_on
 405             FROM letter
 406             LEFT OUTER JOIN branches USING (branchcode)
 407     ";
 408     if ($searchstring && $searchstring=~m/(\S+)/) {
 409         $searchstring = $1 . q{%};
 410         push @where, 'code LIKE ?';
 411         push @args, $searchstring;
 412     }
 413     elsif ($branchcode) {
 414         push @where, 'branchcode = ?';
 415         push @args, $branchcode || '';
 416     }
 417     elsif ($my_branch) {
 418         push @where, "(branchcode = ? OR branchcode = '')";
 419         push @args, $my_branch;
 420     }
 421
 422     $sql .= " WHERE ".join(" AND ", @where) if @where;
 423     $sql .= " GROUP BY branchcode,module,code,name,branchname";
 424
 425     $sql .= " ORDER BY module, code, branchcode";
 426
 427     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 428 }
 429
 430 sub default_display {
 431     my ($branchcode, $searchfield) = @_;
 432
 433     unless ( defined $branchcode ) {
 434         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 435             $branchcode = C4::Context::mybranch();
 436         }
 437     }
 438
 439     if ( $searchfield  ) {
 440         $template->param( search      => 1 );
 441     }
 442     my $results = retrieve_letters($branchcode,$searchfield);
 443
 444     my $loop_data = [];
 445     my $protected_letters = protected_letters();
 446     foreach my $row (@{$results}) {
 447         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 448         push @{$loop_data}, $row;
 449
 450     }
 451
 452     $template->param(
 453         letter => $loop_data,
 454         branchcode => $branchcode,
 455     );
 456 }
 457
 458 sub add_fields {
 459     my @tables = @_;
 460     my @fields = ();
 461
 462     for my $table (@tables) {
 463         push @fields, get_columns_for($table);
 464
 465     }
 466     return @fields;
 467 }
 468
 469 sub get_columns_for {
 470     my $table = shift;
 471 # FIXME untranslatable
 472     my %column_map = (
 473         aqbooksellers => '---BOOKSELLERS---',
 474         aqorders      => '---ORDERS---',
 475         serial        => '---SERIALS---',
 476         reserves      => '---HOLDS---',
 477         suggestions   => '---SUGGESTIONS---',
 478     );
 479     my @fields = ();
 480     if (exists $column_map{$table} ) {
 481         push @fields, {
 482             value => q{},
 483             text  => $column_map{$table} ,
 484         };
 485     }
 486     else {
 487         my $tlabel = '---' . uc $table;
 488         $tlabel.= '---';
 489         push @fields, {
 490             value => q{},
 491             text  => $tlabel,
 492         };
 493     }
 494
 495     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 496     my $table_prefix = $table . q|.|;
 497     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 498     for my $row (@{$rows}) {
 499         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 500         push @fields, {
 501             value => $table_prefix . $row->{Field},
 502             text  => $table_prefix . $row->{Field},
 503         }
 504     }
 505     if ($table eq 'borrowers') {
 506         my $attribute_types = Koha::Patron::Attribute::Types->search(
 507             {},
 508             { order_by => 'code' },
 509         );
 510         while ( my $at = $attribute_types->next ) {
 511             push @fields, {
 512                 value => "borrower-attribute:" . $at->code,
 513                 text  => "attribute:" . $at->code,
 514             }
 515         }
 516     }
 517     return @fields;
 518 }