tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth;
  46 use C4::Context;
  47 use C4::Output;
  48 use C4::Letters;
  49
  50 use Koha::Patron::Attribute::Types;
  51
  52 # $protected_letters = protected_letters()
  53 # - return a hashref of letter_codes representing letters that should never be deleted
  54 sub protected_letters {
  55     my $dbh = C4::Context->dbh;
  56     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  57     return { map { $_->[0] => 1 } @{$codes} };
  58 }
  59
  60 our $input       = new CGI;
  61 my $searchfield = $input->param('searchfield');
  62 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  63 our $branchcode  = $input->param('branchcode');
  64 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $redirect    = $input->param('redirect');
  70 my $section     = $input->param('section');
  71
  72 my $dbh = C4::Context->dbh;
  73
  74 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  75     {
  76         template_name   => 'tools/letter.tt',
  77         query           => $input,
  78         type            => 'intranet',
  79         flagsrequired   => { tools => 'edit_notices' },
  80         debug           => 1,
  81     }
  82 );
  83
  84 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  85   ?  C4::Context->userenv()->{'branch'}
  86   : undef;
  87 # we show only the TMPL_VAR names $op
  88
  89 $template->param(
  90     independant_branch => $my_branch,
  91         script_name => $script_name,
  92   searchfield => $searchfield,
  93     branchcode => $branchcode,
  94     section => $section,
  95         action => $script_name
  96 );
  97
  98 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  99     add_validate();
 100     if( $redirect eq "just_save" ){
 101         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done&section=$section");
 102         exit;
 103     } else {
 104         $op = q{}; # we return to the default screen for the next operation
 105     }
 106 }
 107 if ($op eq 'copy_form') {
 108     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 109     my $branchcode = $input->param('branchcode');
 110     add_form($oldbranchcode, $module, $code);
 111     $template->param(
 112         oldbranchcode => $oldbranchcode,
 113         branchcode => $branchcode,
 114         copying => 1,
 115         modify => 0,
 116     );
 117 }
 118 elsif ( $op eq 'add_form' ) {
 119     add_form($branchcode, $module, $code);
 120 }
 121 elsif ( $op eq 'delete_confirm' ) {
 122     delete_confirm($branchcode, $module, $code);
 123 }
 124 elsif ( $op eq 'delete_confirmed' ) {
 125     delete_confirmed($branchcode, $module, $code);
 126     $op = q{}; # next operation is to return to default screen
 127 }
 128 else {
 129     default_display($branchcode,$searchfield);
 130 }
 131
 132 # Do this last as delete_confirmed resets
 133 if ($op) {
 134     $template->param($op  => 1);
 135 } else {
 136     $template->param(no_op_set => 1);
 137 }
 138
 139 output_html_with_http_headers $input, $cookie, $template->output;
 140
 141 sub add_form {
 142     my ( $branchcode,$module, $code ) = @_;
 143
 144     my $letters;
 145     # if code has been passed we can identify letter and its an update action
 146     if ($code) {
 147         $letters = C4::Letters::GetLetterTemplates(
 148             {
 149                 branchcode => $branchcode,
 150                 module     => $module,
 151                 code       => $code,
 152             }
 153         );
 154     }
 155
 156     my $message_transport_types = GetMessageTransportTypes();
 157     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 158     my %letters = ( default => { templates => $templates } );
 159
 160     if ( C4::Context->preference('TranslateNotices') ) {
 161         my $translated_languages =
 162           C4::Languages::getTranslatedLanguages( 'opac',
 163             C4::Context->preference('template') );
 164         for my $language (@$translated_languages) {
 165             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 166                 if ( $language->{plural} ) {
 167                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 168                         description => $sublanguage->{native_description}
 169                           . ' '
 170                           . $sublanguage->{region_description} . ' ('
 171                           . $sublanguage->{rfc4646_subtag} . ')',
 172                         templates => { %$templates },
 173                     };
 174                 }
 175                 else {
 176                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 177                         description => $sublanguage->{native_description}
 178                           . ' ('
 179                           . $sublanguage->{rfc4646_subtag} . ')',
 180                         templates => { %$templates },
 181                     };
 182                 }
 183             }
 184         }
 185         $template->param( languages => $translated_languages );
 186     }
 187     if ($letters) {
 188         $template->param(
 189             modify     => 1,
 190             code       => $code,
 191         );
 192         my $first_flag_name = 1;
 193         my ( $lang, @templates );
 194         # The letter name is contained into each mtt row.
 195         # So we can only sent the first one to the template.
 196         for my $letter ( @$letters ) {
 197             # The letter_name
 198             if ( $first_flag_name and $letter->{name} ) {
 199                 $template->param(
 200                     letter_name=> $letter->{name},
 201                 );
 202                 $first_flag_name = 0;
 203             }
 204
 205             my $lang = $letter->{lang};
 206             my $mtt = $letter->{message_transport_type};
 207             $letters{ $lang }{templates}{$mtt} = {
 208                 message_transport_type => $letter->{message_transport_type},
 209                 is_html    => $letter->{is_html},
 210                 title      => $letter->{title},
 211                 content    => $letter->{content} // '',
 212             };
 213         }
 214     }
 215     else {
 216         $template->param( adding => 1 );
 217     }
 218
 219     $template->param(
 220         letters => \%letters,
 221     );
 222
 223     my $field_selection;
 224     push @{$field_selection}, add_fields('branches');
 225     if ($module eq 'reserves') {
 226         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 227     }
 228     elsif ( $module eq 'acquisition' ) {
 229         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 230     }
 231     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 232         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 233     }
 234     elsif ($module eq 'claimissues') {
 235         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription', 'biblio', 'biblioitems');
 236     }
 237     elsif ($module eq 'serial') {
 238         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 239     }
 240     elsif ($module eq 'suggestions') {
 241         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 242     }
 243     else {
 244         push @{$field_selection}, add_fields('biblio','biblioitems'),
 245             add_fields('items'),
 246             {value => 'items.content', text => 'items.content'},
 247             {value => 'items.fine',    text => 'items.fine'},
 248             add_fields('borrowers');
 249         if ($module eq 'circulation') {
 250             push @{$field_selection}, add_fields('opac_news');
 251
 252         }
 253
 254         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 255             push @{$field_selection}, add_fields('old_issues');
 256         } else {
 257             push @{$field_selection}, add_fields('issues');
 258         }
 259
 260         if ( $module eq 'circulation' and $code and $code =~ /^AR_/  ) {
 261             push @{$field_selection}, add_fields('article_requests');
 262         }
 263     }
 264
 265     my $preview_is_available = 0;
 266
 267     if ($code) {
 268         $preview_is_available = grep {/^$code$/} qw( CHECKIN CHECKOUT HOLD_SLIP );
 269     }
 270
 271     $template->param(
 272         module     => $module,
 273         SQLfieldnames => $field_selection,
 274         branchcode => $branchcode,
 275         preview_is_available => $preview_is_available,
 276     );
 277     return;
 278 }
 279
 280 sub add_validate {
 281     my $dbh        = C4::Context->dbh;
 282     my $branchcode    = $input->param('branchcode');
 283     my $module        = $input->param('module');
 284     my $oldmodule     = $input->param('oldmodule');
 285     my $code          = $input->param('code');
 286     my $name          = $input->param('name');
 287     my @mtt           = $input->multi_param('message_transport_type');
 288     my @title         = $input->multi_param('title');
 289     my @content       = $input->multi_param('content');
 290     my @lang          = $input->multi_param('lang');
 291     for my $mtt ( @mtt ) {
 292         my $lang = shift @lang;
 293         my $is_html = $input->param("is_html_$mtt\_$lang");
 294         my $title   = shift @title;
 295         my $content = shift @content;
 296         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 297
 298         # getletter can return the default letter even if we pass a branchcode
 299         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 300         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 301             $letter = undef;
 302         }
 303         unless ( $title and $content ) {
 304             # Delete this mtt if no title or content given
 305             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 306             next;
 307         }
 308         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 309             $dbh->do(
 310                 q{
 311                     UPDATE letter
 312                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 313                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ? AND lang = ?
 314                 },
 315                 undef,
 316                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 317                 $branchcode, $oldmodule, $code, $mtt, $lang
 318             );
 319         } else {
 320             $dbh->do(
 321                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type, lang) VALUES (?,?,?,?,?,?,?,?,?)},
 322                 undef,
 323                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt, $lang
 324             );
 325         }
 326     }
 327     # set up default display
 328     default_display($branchcode);
 329     return 1;
 330 }
 331
 332 sub delete_confirm {
 333     my ($branchcode, $module, $code) = @_;
 334     my $dbh = C4::Context->dbh;
 335     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 336     my @values = values %$letter;
 337     $template->param(
 338         letter => $letter,
 339     );
 340     return;
 341 }
 342
 343 sub delete_confirmed {
 344     my ($branchcode, $module, $code, $mtt, $lang) = @_;
 345     C4::Letters::DelLetter(
 346         {
 347             branchcode => $branchcode || '',
 348             module     => $module,
 349             code       => $code,
 350             mtt        => $mtt,
 351             lang       => $lang,
 352         }
 353     );
 354     # setup default display for screen
 355     default_display($branchcode);
 356     return;
 357 }
 358
 359 sub retrieve_letters {
 360     my ($branchcode, $searchstring) = @_;
 361
 362     $branchcode = $my_branch if $branchcode && $my_branch;
 363
 364     my $dbh = C4::Context->dbh;
 365     my ($sql, @where, @args);
 366     $sql = "SELECT branchcode, module, code, name, branchname
 367             FROM letter
 368             LEFT OUTER JOIN branches USING (branchcode)
 369     ";
 370     if ($searchstring && $searchstring=~m/(\S+)/) {
 371         $searchstring = $1 . q{%};
 372         push @where, 'code LIKE ?';
 373         push @args, $searchstring;
 374     }
 375     elsif ($branchcode) {
 376         push @where, 'branchcode = ?';
 377         push @args, $branchcode || '';
 378     }
 379     elsif ($my_branch) {
 380         push @where, "(branchcode = ? OR branchcode = '')";
 381         push @args, $my_branch;
 382     }
 383
 384     $sql .= " WHERE ".join(" AND ", @where) if @where;
 385     $sql .= " GROUP BY branchcode,module,code,name,branchname";
 386
 387     $sql .= " ORDER BY module, code, branchcode";
 388
 389     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 390 }
 391
 392 sub default_display {
 393     my ($branchcode, $searchfield) = @_;
 394
 395     unless ( defined $branchcode ) {
 396         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 397             $branchcode = C4::Context::mybranch();
 398         }
 399     }
 400
 401     if ( $searchfield  ) {
 402         $template->param( search      => 1 );
 403     }
 404     my $results = retrieve_letters($branchcode,$searchfield);
 405
 406     my $loop_data = [];
 407     my $protected_letters = protected_letters();
 408     foreach my $row (@{$results}) {
 409         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 410         push @{$loop_data}, $row;
 411
 412     }
 413
 414     $template->param(
 415         letter => $loop_data,
 416         branchcode => $branchcode,
 417     );
 418 }
 419
 420 sub add_fields {
 421     my @tables = @_;
 422     my @fields = ();
 423
 424     for my $table (@tables) {
 425         push @fields, get_columns_for($table);
 426
 427     }
 428     return @fields;
 429 }
 430
 431 sub get_columns_for {
 432     my $table = shift;
 433 # FIXME untranslatable
 434     my %column_map = (
 435         aqbooksellers => '---BOOKSELLERS---',
 436         aqorders      => '---ORDERS---',
 437         serial        => '---SERIALS---',
 438         reserves      => '---HOLDS---',
 439         suggestions   => '---SUGGESTIONS---',
 440     );
 441     my @fields = ();
 442     if (exists $column_map{$table} ) {
 443         push @fields, {
 444             value => q{},
 445             text  => $column_map{$table} ,
 446         };
 447     }
 448     else {
 449         my $tlabel = '---' . uc $table;
 450         $tlabel.= '---';
 451         push @fields, {
 452             value => q{},
 453             text  => $tlabel,
 454         };
 455     }
 456
 457     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 458     my $table_prefix = $table . q|.|;
 459     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 460     for my $row (@{$rows}) {
 461         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 462         push @fields, {
 463             value => $table_prefix . $row->{Field},
 464             text  => $table_prefix . $row->{Field},
 465         }
 466     }
 467     if ($table eq 'borrowers') {
 468         my $attribute_types = Koha::Patron::Attribute::Types->search(
 469             {},
 470             { order_by => 'code' },
 471         );
 472         while ( my $at = $attribute_types->next ) {
 473             push @fields, {
 474                 value => "borrower-attribute:" . $at->code,
 475                 text  => "attribute:" . $at->code,
 476             }
 477         }
 478     }
 479     return @fields;
 480 }