tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth;
  46 use C4::Context;
  47 use C4::Output;
  48 use C4::Letters;
  49 use C4::Log;
  50
  51 use Koha::Patron::Attribute::Types;
  52
  53 # $protected_letters = protected_letters()
  54 # - return a hashref of letter_codes representing letters that should never be deleted
  55 sub protected_letters {
  56     my $dbh = C4::Context->dbh;
  57     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  58     return { map { $_->[0] => 1 } @{$codes} };
  59 }
  60
  61 our $input       = CGI->new;
  62 my $searchfield = $input->param('searchfield');
  63 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  64 our $branchcode  = $input->param('branchcode');
  65 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  66 my $code        = $input->param('code');
  67 my $module      = $input->param('module') || '';
  68 my $content     = $input->param('content');
  69 my $op          = $input->param('op') || '';
  70 my $redirect    = $input->param('redirect');
  71 my $section     = $input->param('section');
  72
  73 my $dbh = C4::Context->dbh;
  74
  75 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  76     {
  77         template_name   => 'tools/letter.tt',
  78         query           => $input,
  79         type            => 'intranet',
  80         flagsrequired   => { tools => 'edit_notices' },
  81         debug           => 1,
  82     }
  83 );
  84
  85 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  86   ?  C4::Context->userenv()->{'branch'}
  87   : undef;
  88 # we show only the TMPL_VAR names $op
  89
  90 $template->param(
  91     independant_branch => $my_branch,
  92         script_name => $script_name,
  93   searchfield => $searchfield,
  94     branchcode => $branchcode,
  95     section => $section,
  96         action => $script_name
  97 );
  98
  99 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
 100     add_validate();
 101     if( $redirect eq "just_save" ){
 102         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done&section=$section");
 103         exit;
 104     } else {
 105         $op = q{}; # we return to the default screen for the next operation
 106     }
 107 }
 108 if ($op eq 'copy_form') {
 109     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 110     my $branchcode = $input->param('branchcode');
 111     add_form($oldbranchcode, $module, $code);
 112     $template->param(
 113         oldbranchcode => $oldbranchcode,
 114         branchcode => $branchcode,
 115         copying => 1,
 116         modify => 0,
 117     );
 118 }
 119 elsif ( $op eq 'add_form' ) {
 120     add_form($branchcode, $module, $code);
 121 }
 122 elsif ( $op eq 'delete_confirm' ) {
 123     delete_confirm($branchcode, $module, $code);
 124 }
 125 elsif ( $op eq 'delete_confirmed' ) {
 126     delete_confirmed($branchcode, $module, $code);
 127     $op = q{}; # next operation is to return to default screen
 128 }
 129 else {
 130     default_display($branchcode,$searchfield);
 131 }
 132
 133 # Do this last as delete_confirmed resets
 134 if ($op) {
 135     $template->param($op  => 1);
 136 } else {
 137     $template->param(no_op_set => 1);
 138 }
 139
 140 output_html_with_http_headers $input, $cookie, $template->output;
 141
 142 sub add_form {
 143     my ( $branchcode,$module, $code ) = @_;
 144
 145     my $letters;
 146     # if code has been passed we can identify letter and its an update action
 147     if ($code) {
 148         $letters = C4::Letters::GetLetterTemplates(
 149             {
 150                 branchcode => $branchcode,
 151                 module     => $module,
 152                 code       => $code,
 153             }
 154         );
 155     }
 156
 157     my $message_transport_types = GetMessageTransportTypes();
 158     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 159     my %letters = ( default => { templates => $templates } );
 160
 161     if ( C4::Context->preference('TranslateNotices') ) {
 162         my $translated_languages =
 163           C4::Languages::getTranslatedLanguages( 'opac',
 164             C4::Context->preference('template') );
 165         for my $language (@$translated_languages) {
 166             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 167                 if ( $language->{plural} ) {
 168                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 169                         description => $sublanguage->{native_description}
 170                           . ' '
 171                           . $sublanguage->{region_description} . ' ('
 172                           . $sublanguage->{rfc4646_subtag} . ')',
 173                         templates => { %$templates },
 174                     };
 175                 }
 176                 else {
 177                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 178                         description => $sublanguage->{native_description}
 179                           . ' ('
 180                           . $sublanguage->{rfc4646_subtag} . ')',
 181                         templates => { %$templates },
 182                     };
 183                 }
 184             }
 185         }
 186         $template->param( languages => $translated_languages );
 187     }
 188     if ($letters) {
 189         $template->param(
 190             modify     => 1,
 191             code       => $code,
 192         );
 193         my $first_flag_name = 1;
 194         my $lang;
 195         # The letter name is contained into each mtt row.
 196         # So we can only sent the first one to the template.
 197         for my $letter ( @$letters ) {
 198             # The letter_name
 199             if ( $first_flag_name and $letter->{name} ) {
 200                 $template->param(
 201                     letter_name=> $letter->{name},
 202                 );
 203                 $first_flag_name = 0;
 204             }
 205
 206             my $lang = $letter->{lang};
 207             my $mtt = $letter->{message_transport_type};
 208             $letters{ $lang }{templates}{$mtt} = {
 209                 message_transport_type => $letter->{message_transport_type},
 210                 is_html    => $letter->{is_html},
 211                 updated_on => $letter->{updated_on},
 212                 title      => $letter->{title},
 213                 content    => $letter->{content} // '',
 214             };
 215         }
 216     }
 217     else {
 218         $template->param( adding => 1 );
 219     }
 220
 221     $template->param(
 222         letters => \%letters,
 223     );
 224
 225     my $field_selection;
 226     push @{$field_selection}, add_fields('branches');
 227     if ($module eq 'reserves') {
 228         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 229     }
 230     elsif ( $module eq 'acquisition' ) {
 231         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 232     }
 233     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 234         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 235     }
 236     elsif ($module eq 'claimissues') {
 237         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription', 'biblio', 'biblioitems');
 238     }
 239     elsif ($module eq 'serial') {
 240         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 241     }
 242     elsif ($module eq 'suggestions') {
 243         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 244     }
 245     else {
 246         push @{$field_selection}, add_fields('biblio','biblioitems'),
 247             add_fields('items'),
 248             {value => 'items.content', text => 'items.content'},
 249             {value => 'items.fine',    text => 'items.fine'},
 250             add_fields('borrowers');
 251         if ($module eq 'circulation') {
 252             push @{$field_selection}, add_fields('opac_news');
 253
 254         }
 255
 256         if ( $module eq 'circulation' and $code and ( $code eq "CHECKIN" or $code eq "CHECKINSLIP" ) ) {
 257             push @{$field_selection}, add_fields('old_issues');
 258         } else {
 259             push @{$field_selection}, add_fields('issues');
 260         }
 261
 262         if ( $module eq 'circulation' and $code and $code =~ /^AR_/  ) {
 263             push @{$field_selection}, add_fields('article_requests');
 264         }
 265
 266         if ( $module eq 'members' and $code and $code eq 'PROBLEM_REPORT' ) {
 267             push @{$field_selection}, add_fields('problem_reports');
 268         }
 269
 270         if ( $module eq 'ill' ) {
 271             push @{$field_selection}, add_fields('illrequests');
 272         }
 273     }
 274
 275     my $preview_is_available = 0;
 276
 277     if ($code) {
 278         $preview_is_available = grep {$_ eq $code } qw( CHECKIN CHECKOUT HOLD_SLIP );
 279     }
 280
 281     $template->param(
 282         module     => $module,
 283         SQLfieldnames => $field_selection,
 284         branchcode => $branchcode,
 285         preview_is_available => $preview_is_available,
 286     );
 287     return;
 288 }
 289
 290 sub add_validate {
 291     my $dbh        = C4::Context->dbh;
 292     my $branchcode    = $input->param('branchcode');
 293     my $module        = $input->param('module');
 294     my $oldmodule     = $input->param('oldmodule');
 295     my $code          = $input->param('code');
 296     my $name          = $input->param('name');
 297     my @mtt           = $input->multi_param('message_transport_type');
 298     my @title         = $input->multi_param('title');
 299     my @content       = $input->multi_param('content');
 300     my @lang          = $input->multi_param('lang');
 301     for my $mtt ( @mtt ) {
 302         my $lang = shift @lang;
 303         my $is_html = $input->param("is_html_$mtt\_$lang");
 304         my $title   = shift @title;
 305         my $content = shift @content;
 306         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 307
 308         # getletter can return the default letter even if we pass a branchcode
 309         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 310         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 311             $letter = undef;
 312         }
 313         unless ( $title and $content ) {
 314             # Delete this mtt if no title or content given
 315             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 316             next;
 317         }
 318         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 319             logaction( 'NOTICES', 'MODIFY', $letter->{id}, $content,
 320                 'Intranet' )
 321               if ( C4::Context->preference("NoticesLog")
 322                 && $content ne $letter->{content} );
 323             $dbh->do(
 324                 q{
 325                     UPDATE letter
 326                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 327                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ? AND lang = ?
 328                 },
 329                 undef,
 330                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 331                 $branchcode, $oldmodule, $code, $mtt, $lang
 332             );
 333         } else {
 334             my $letter = Koha::Notice::Template->new(
 335                 {
 336                     branchcode             => $branchcode,
 337                     module                 => $module,
 338                     code                   => $code,
 339                     name                   => $name,
 340                     is_html                => $is_html,
 341                     title                  => $title,
 342                     content                => $content,
 343                     message_transport_type => $mtt,
 344                     lang                   => $lang
 345                 }
 346             )->store;
 347             logaction( 'NOTICES', 'CREATE', $letter->id, $letter->content,
 348                 'Intranet' )
 349               if C4::Context->preference("NoticesLog");
 350         }
 351     }
 352     # set up default display
 353     default_display($branchcode);
 354     return 1;
 355 }
 356
 357 sub delete_confirm {
 358     my ($branchcode, $module, $code) = @_;
 359     my $dbh = C4::Context->dbh;
 360     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 361     my @values = values %$letter;
 362     $template->param(
 363         letter => $letter,
 364     );
 365     return;
 366 }
 367
 368 sub delete_confirmed {
 369     my ( $branchcode, $module, $code, $mtt, $lang ) = @_;
 370     my $letters = Koha::Notice::Templates->search(
 371         {
 372             branchcode => $branchcode || '',
 373             module     => $module,
 374             code       => $code,
 375             ( $mtt ? ( message_transport_type => $mtt ) : () ),
 376             ( $lang ? ( lang => $lang ) : () ),
 377         }
 378     );
 379     while ( my $letter = $letters->next ) {
 380         logaction( 'NOTICES', 'DELETE', $letter->id, $letter->content,
 381             'Intranet' )
 382           if C4::Context->preference("NoticesLog");
 383         $letter->delete;
 384     }
 385
 386     # setup default display for screen
 387     default_display($branchcode);
 388     return;
 389 }
 390
 391 sub retrieve_letters {
 392     my ($branchcode, $searchstring) = @_;
 393
 394     $branchcode = $my_branch if $branchcode && $my_branch;
 395
 396     my $dbh = C4::Context->dbh;
 397     my ($sql, @where, @args);
 398     $sql = "SELECT branchcode, module, code, name, branchname, MAX(updated_on) as updated_on
 399             FROM letter
 400             LEFT OUTER JOIN branches USING (branchcode)
 401     ";
 402     if ($searchstring && $searchstring=~m/(\S+)/) {
 403         $searchstring = $1 . q{%};
 404         push @where, 'code LIKE ?';
 405         push @args, $searchstring;
 406     }
 407     elsif ($branchcode) {
 408         push @where, 'branchcode = ?';
 409         push @args, $branchcode || '';
 410     }
 411     elsif ($my_branch) {
 412         push @where, "(branchcode = ? OR branchcode = '')";
 413         push @args, $my_branch;
 414     }
 415
 416     $sql .= " WHERE ".join(" AND ", @where) if @where;
 417     $sql .= " GROUP BY branchcode,module,code,name,branchname";
 418
 419     $sql .= " ORDER BY module, code, branchcode";
 420
 421     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 422 }
 423
 424 sub default_display {
 425     my ($branchcode, $searchfield) = @_;
 426
 427     unless ( defined $branchcode ) {
 428         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 429             $branchcode = C4::Context::mybranch();
 430         }
 431     }
 432
 433     if ( $searchfield  ) {
 434         $template->param( search      => 1 );
 435     }
 436     my $results = retrieve_letters($branchcode,$searchfield);
 437
 438     my $loop_data = [];
 439     my $protected_letters = protected_letters();
 440     foreach my $row (@{$results}) {
 441         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 442         push @{$loop_data}, $row;
 443
 444     }
 445
 446     $template->param(
 447         letter => $loop_data,
 448         branchcode => $branchcode,
 449     );
 450 }
 451
 452 sub add_fields {
 453     my @tables = @_;
 454     my @fields = ();
 455
 456     for my $table (@tables) {
 457         push @fields, get_columns_for($table);
 458
 459     }
 460     return @fields;
 461 }
 462
 463 sub get_columns_for {
 464     my $table = shift;
 465 # FIXME untranslatable
 466     my %column_map = (
 467         aqbooksellers => '---BOOKSELLERS---',
 468         aqorders      => '---ORDERS---',
 469         serial        => '---SERIALS---',
 470         reserves      => '---HOLDS---',
 471         suggestions   => '---SUGGESTIONS---',
 472     );
 473     my @fields = ();
 474     if (exists $column_map{$table} ) {
 475         push @fields, {
 476             value => q{},
 477             text  => $column_map{$table} ,
 478         };
 479     }
 480     else {
 481         my $tlabel = '---' . uc $table;
 482         $tlabel.= '---';
 483         push @fields, {
 484             value => q{},
 485             text  => $tlabel,
 486         };
 487     }
 488
 489     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 490     my $table_prefix = $table . q|.|;
 491     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 492     for my $row (@{$rows}) {
 493         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 494         push @fields, {
 495             value => $table_prefix . $row->{Field},
 496             text  => $table_prefix . $row->{Field},
 497         }
 498     }
 499     if ($table eq 'borrowers') {
 500         my $attribute_types = Koha::Patron::Attribute::Types->search(
 501             {},
 502             { order_by => 'code' },
 503         );
 504         while ( my $at = $attribute_types->next ) {
 505             push @fields, {
 506                 value => "borrower-attribute:" . $at->code,
 507                 text  => "attribute:" . $at->code,
 508             }
 509         }
 510     }
 511     return @fields;
 512 }