tools/manage-marc-import.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright (C) 2007 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 use strict;
  21
  22 # standard or CPAN modules used
  23 use CGI;
  24 use CGI::Cookie;
  25 use MARC::File::USMARC;
  26
  27 # Koha modules used
  28 use C4::Context;
  29 use C4::Auth;
  30 use C4::Input;
  31 use C4::Output;
  32 use C4::Biblio;
  33 use C4::ImportBatch;
  34 use C4::Matcher;
  35 use C4::BackgroundJob;
  36
  37 my $script_name = "/cgi-bin/koha/tools/manage-marc-import.pl";
  38
  39 my $input = new CGI;
  40 my $op = $input->param('op');
  41 my $completedJobID = $input->param('completedJobID');
  42 my $runinbackground = $input->param('runinbackground');
  43 my $import_batch_id = $input->param('import_batch_id');
  44
  45 # record list displays
  46 my $offset = $input->param('offset') || 0;
  47 my $results_per_page = $input->param('results_per_page') || 10;
  48
  49 my ($template, $loggedinuser, $cookie)
  50     = get_template_and_user({template_name => "tools/manage-marc-import.tmpl",
  51                  query => $input,
  52                  type => "intranet",
  53                  authnotrequired => 0,
  54                  flagsrequired => {parameters => 1},
  55                  debug => 1,
  56                  });
  57
  58 my %cookies = parse CGI::Cookie($cookie);
  59 my $sessionID = $cookies{'CGISESSID'}->value;
  60 my $dbh = C4::Context->dbh;
  61
  62 if ($op) {
  63     $template->param(script_name => $script_name, $op => 1);
  64 } else {
  65     $template->param(script_name => $script_name);
  66 }
  67
  68 if ($op eq "") {
  69     # displaying a list
  70     if ($import_batch_id eq "") {
  71         import_batches_list($template, $offset, $results_per_page);
  72     } else {
  73         import_biblios_list($template, $import_batch_id, $offset, $results_per_page);
  74     }
  75 } elsif ($op eq "commit-batch") {
  76     if ($completedJobID) {
  77         add_saved_job_results_to_template($template, $completedJobID);
  78     } else {
  79         commit_batch($template, $import_batch_id);
  80     }
  81     import_biblios_list($template, $import_batch_id, $offset, $results_per_page);
  82 } elsif ($op eq "revert-batch") {
  83     if ($completedJobID) {
  84         add_saved_job_results_to_template($template, $completedJobID);
  85     } else {
  86         revert_batch($template, $import_batch_id);
  87     }
  88     import_biblios_list($template, $import_batch_id, $offset, $results_per_page);
  89 } elsif ($op eq "clean-batch") {
  90     ;
  91 } elsif ($op eq "redo-matching") {
  92     my $new_matcher_id = $input->param('new_matcher_id');
  93     my $current_matcher_id = $input->param('current_matcher_id');
  94     redo_matching($template, $import_batch_id, $new_matcher_id, $current_matcher_id);
  95     import_biblios_list($template, $import_batch_id, $offset, $results_per_page);
  96 }
  97
  98 output_html_with_http_headers $input, $cookie, $template->output;
  99
 100 exit 0;
 101
 102 sub redo_matching {
 103     my ($template, $import_batch_id, $new_matcher_id, $current_matcher_id) = @_;
 104     my $rematch_failed = 0;
 105     return if not defined $new_matcher_id and not defined $current_matcher_id;
 106     return if $new_matcher_id == $current_matcher_id;
 107     my $num_with_matches = 0;
 108     if (defined $new_matcher_id and $new_matcher_id ne "") {
 109         my $matcher = C4::Matcher->fetch($new_matcher_id);
 110         if (defined $matcher) {
 111             $num_with_matches = BatchFindBibDuplicates($import_batch_id, $matcher);
 112             SetImportBatchMatcher($import_batch_id, $new_matcher_id);
 113         } else {
 114             $rematch_failed = 1;
 115         }
 116     } else {
 117         $num_with_matches = BatchFindBibDuplicates($import_batch_id, undef);
 118          SetImportBatchMatcher($import_batch_id, undef);
 119     }
 120     $template->param(rematch_failed => $rematch_failed);
 121     $template->param(rematch_attempted => 1);
 122     $template->param(num_with_matches => $num_with_matches);
 123 }
 124
 125 sub import_batches_list {
 126     my ($template, $offset, $results_per_page) = @_;
 127     my $batches = GetImportBatchRangeDesc($offset, $results_per_page);
 128
 129     my @list = ();
 130     foreach my $batch (@$batches) {
 131         push @list, {
 132             import_batch_id => $batch->{'import_batch_id'},
 133             num_biblios => $batch->{'num_biblios'},
 134             num_items => $batch->{'num_items'},
 135             upload_timestamp => $batch->{'upload_timestamp'},
 136             import_status => $batch->{'import_status'},
 137             file_name => $batch->{'file_name'},
 138             comments => $batch->{'comments'}
 139         };
 140     }
 141     $template->param(batch_list => \@list);
 142     my $num_batches = GetNumberOfNonZ3950ImportBatches();
 143     add_page_numbers($template, $offset, $results_per_page, $num_batches);
 144     $template->param(offset => $offset);
 145     $template->param(range_top => $offset + $results_per_page - 1);
 146     $template->param(num_results => $num_batches);
 147     $template->param(results_per_page => $results_per_page);
 148
 149 }
 150
 151 sub commit_batch {
 152     my ($template, $import_batch_id) = @_;
 153
 154     my $job = undef;
 155     my $callback = sub {};
 156     if ($runinbackground) {
 157         $job = put_in_background($import_batch_id);
 158         $callback = progress_callback($job);
 159     }
 160     my ($num_added, $num_updated, $num_items_added, $num_ignored) = BatchCommitBibRecords($import_batch_id, 50, $callback);
 161
 162     my $results = {
 163         did_commit => 1,
 164         num_added => $num_added,
 165         num_updated => $num_updated,
 166         num_items_added => $num_items_added,
 167         num_ignored => $num_ignored
 168     };
 169     if ($runinbackground) {
 170         $job->finish($results);
 171     } else {
 172         add_results_to_template($template, $results);
 173     }
 174 }
 175
 176 sub revert_batch {
 177     my ($template, $import_batch_id) = @_;
 178
 179     my $job = undef;
 180     my $callback = sub {};
 181     if ($runinbackground) {
 182         $job = put_in_background($import_batch_id);
 183         $callback = progress_callback($job);
 184     }
 185     my ($num_deleted, $num_errors, $num_reverted, $num_items_deleted, $num_ignored) =
 186         BatchRevertBibRecords($import_batch_id, 50, $callback);
 187
 188     my $results = {
 189         did_revert => 1,
 190         num_deleted => $num_deleted,
 191         num_items_deleted => $num_items_deleted,
 192         num_errors => $num_errors,
 193         num_reverted => $num_reverted,
 194         num_ignored => $num_ignored,
 195     };
 196     if ($runinbackground) {
 197         $job->finish($results);
 198     } else {
 199         add_results_to_template($template, $results);
 200     }
 201 }
 202
 203 sub put_in_background {
 204     my $import_batch_id = shift;
 205
 206     my $batch = GetImportBatch($import_batch_id);
 207     my $job = C4::BackgroundJob->new($sessionID, $batch->{'file_name'}, $ENV{'SCRIPT_NAME'}, $batch->{'num_biblios'});
 208     my $jobID = $job->id();
 209
 210     # fork off
 211     if (my $pid = fork) {
 212         # parent
 213         # return job ID as JSON
 214
 215         # prevent parent exiting from
 216         # destroying the kid's database handle
 217         # FIXME: according to DBI doc, this may not work for Oracle
 218         $dbh->{InactiveDestroy}  = 1;
 219
 220         my $reply = CGI->new("");
 221         print $reply->header(-type => 'text/html');
 222         print "{ jobID: '$jobID' }";
 223         exit 0;
 224     } elsif (defined $pid) {
 225         # child
 226         # close STDOUT to signal to Apache that
 227         # we're now running in the background
 228         close STDOUT;
 229         close STDERR;
 230     } else {
 231         # fork failed, so exit immediately
 232         warn "fork failed while attempting to run $ENV{'SCRIPT_NAME'} as a background job";
 233         exit 0;
 234     }
 235     return $job;
 236 }
 237
 238 sub progress_callback {
 239     my $job = shift;
 240     return sub {
 241         my $progress = shift;
 242         $job->progress($progress);
 243     }
 244 }
 245
 246 sub add_results_to_template {
 247     my $template = shift;
 248     my $results = shift;
 249     $template->param(map { $_ => $results->{$_} } keys %{ $results });
 250 }
 251
 252 sub add_saved_job_results_to_template {
 253     my $template = shift;
 254     my $completedJobID = shift;
 255     my $job = C4::BackgroundJob->fetch($sessionID, $completedJobID);
 256     my $results = $job->results();
 257     add_results_to_template($template, $results);
 258 }
 259
 260 sub import_biblios_list {
 261     my ($template, $import_batch_id, $offset, $results_per_page) = @_;
 262
 263     my $batch = GetImportBatch($import_batch_id);
 264     my $biblios = GetImportBibliosRange($import_batch_id, $offset, $results_per_page);
 265     my @list = ();
 266     foreach my $biblio (@$biblios) {
 267         my $citation = $biblio->{'title'};
 268         $citation .= " $biblio->{'author'}" if $biblio->{'author'};
 269         $citation .= " (" if $biblio->{'issn'} or $biblio->{'isbn'};
 270         $citation .= $biblio->{'isbn'} if $biblio->{'isbn'};
 271         $citation .= ", " if $biblio->{'issn'} and $biblio->{'isbn'};
 272         $citation .= $biblio->{'issn'} if $biblio->{'issn'};
 273         $citation .= ")" if $biblio->{'issn'} or $biblio->{'isbn'};
 274         my $match = GetImportRecordMatches($biblio->{'import_record_id'}, 1);
 275         push @list, {
 276             import_record_id => $biblio->{'import_record_id'},
 277             citation => $citation,
 278             status => $biblio->{'status'},
 279             record_sequence => $biblio->{'record_sequence'},
 280             overlay_status => $biblio->{'overlay_status'},
 281             match_biblionumber => $#$match > -1 ? $match->[0]->{'biblionumber'} : 0,
 282             match_citation => $#$match > -1 ? $match->[0]->{'title'} . ' ' . $match->[0]->{'author'} : '',
 283             match_score => $#$match > -1 ? $match->[0]->{'score'} : 0,
 284         };
 285     }
 286     my $num_biblios = $batch->{'num_biblios'};
 287     $template->param(biblio_list => \@list);
 288     add_page_numbers($template, $offset, $results_per_page, $num_biblios);
 289     $template->param(offset => $offset);
 290     $template->param(range_top => $offset + $results_per_page - 1);
 291     $template->param(num_results => $num_biblios);
 292     $template->param(results_per_page => $results_per_page);
 293     $template->param(import_batch_id => $import_batch_id);
 294     batch_info($template, $batch);
 295
 296 }
 297
 298 sub batch_info {
 299     my ($template, $batch) = @_;
 300     $template->param(batch_info => 1);
 301     $template->param(file_name => $batch->{'file_name'});
 302     $template->param(comments => $batch->{'comments'});
 303     $template->param(import_status => $batch->{'import_status'});
 304     $template->param(upload_timestamp => $batch->{'upload_timestamp'});
 305     $template->param(num_biblios => $batch->{'num_biblios'});
 306     $template->param(num_items => $batch->{'num_biblios'});
 307     if ($batch->{'import_status'} eq 'staged' or $batch->{'import_status'} eq 'reverted') {
 308         $template->param(can_commit => 1);
 309     }
 310     if ($batch->{'import_status'} eq 'imported') {
 311         $template->param(can_revert => 1);
 312     }
 313     if (defined $batch->{'matcher_id'}) {
 314         my $matcher = C4::Matcher->fetch($batch->{'matcher_id'});
 315         if (defined $matcher) {
 316             $template->param('current_matcher_id' => $batch->{'matcher_id'});
 317             $template->param('current_matcher_code' => $matcher->code());
 318             $template->param('current_matcher_description' => $matcher->description());
 319         }
 320     }
 321     add_matcher_list($batch->{'matcher_id'});
 322 }
 323
 324 sub add_matcher_list {
 325     my $current_matcher_id = shift;
 326     my @matchers = C4::Matcher::GetMatcherList();
 327     if (defined $current_matcher_id) {
 328         for (my $i = 0; $i <= $#matchers; $i++) {
 329             if ($matchers[$i]->{'matcher_id'} == $current_matcher_id) {
 330                 $matchers[$i]->{'selected'} = 1;
 331             }
 332         }
 333     }
 334     $template->param(available_matchers => \@matchers);
 335 }
 336
 337 sub add_page_numbers {
 338     my ($template, $offset, $results_per_page, $total_results) = @_;
 339     my $max_pages = POSIX::ceil($total_results / $results_per_page);
 340     return if $max_pages < 2;
 341     my $current_page = int($offset / $results_per_page) + 1;
 342     my @pages = ();
 343     for (my $i = 1; $i <= $max_pages; $i++) {
 344         push @pages, {
 345             page_number => $i,
 346             current_page => ($current_page == $i) ? 1 : 0,
 347             offset => ($i - 1) * $results_per_page
 348         }
 349     }
 350     $template->param(pages => \@pages);
 351 }
 352