tools/upload-cover-image.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2011 C & P Bibliography Services
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19 #
  20 #
  21 #
  22
  23 =head1 NAME
  24
  25 upload-cover-image.pl - Script for handling uploading of both single and bulk coverimages and importing them into the database.
  26
  27 =head1 SYNOPSIS
  28
  29 upload-cover-image.pl
  30
  31 =head1 DESCRIPTION
  32
  33 This script is called and presents the user with an interface allowing him/her to upload a single cover image or bulk cover images via a zip file.
  34 Images will be resized into thumbnails of 140x200 pixels and larger images of
  35 800x600 pixels. If the images that are uploaded are larger, they will be
  36 resized, maintaining aspect ratio.
  37
  38 =cut
  39
  40 use Modern::Perl;
  41
  42 use File::Temp;
  43 use CGI qw ( -utf8 );
  44 use GD;
  45 use C4::Context;
  46 use C4::Auth qw( get_template_and_user );
  47 use C4::Output qw( output_html_with_http_headers );
  48 use Koha::Biblios;
  49 use Koha::CoverImages;
  50 use Koha::Items;
  51 use Koha::UploadedFiles;
  52 use C4::Log qw( logaction );
  53
  54 my $input = CGI->new;
  55
  56 my $fileID = $input->param('uploadedfileid');
  57 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  58     {
  59         template_name   => "tools/upload-images.tt",
  60         query           => $input,
  61         type            => "intranet",
  62         flagsrequired   => { tools => 'upload_local_cover_images' },
  63     }
  64 );
  65
  66 my $filetype       = $input->param('filetype');
  67 my $biblionumber   = $input->param('biblionumber');
  68 my $itemnumber     = $input->param('itemnumber');
  69 #my $uploadfilename = $input->param('uploadfile'); # obsolete?
  70 my $replace        = !C4::Context->preference("AllowMultipleCovers")
  71   || $input->param('replace');
  72 my $op        = $input->param('op');
  73
  74 my $error;
  75
  76 my $biblio;
  77 my $cover_images;
  78 my $item;
  79
  80 if ( $itemnumber ) {
  81     $item = Koha::Items->find($itemnumber);
  82     $biblionumber = $item->biblionumber;
  83     $biblio = Koha::Biblios->find( $biblionumber );
  84     $cover_images = $item->cover_images->as_list;
  85 } elsif ( $biblionumber ){
  86     $biblio = Koha::Biblios->find( $biblionumber );
  87     $cover_images = $biblio->cover_images->as_list;
  88 }
  89
  90 $template->param(
  91     filetype     => $filetype,
  92     biblio       => $biblio,
  93     biblionumber => $biblionumber,
  94     itemnumber   => $itemnumber,
  95     cover_images => $cover_images,
  96 );
  97
  98 my $total = 0;
  99 my @results;
 100
 101 if ($fileID) {
 102     my $upload = Koha::UploadedFiles->find( $fileID );
 103     if ( $filetype eq 'image' ) {
 104         my $fh       = $upload->file_handle;
 105         my $srcimage = GD::Image->new($fh);
 106         $fh->close if $fh;
 107         if ( defined $srcimage ) {
 108             eval {
 109                 if ( $replace ) {
 110                     if ( $itemnumber ) {
 111                         Koha::Items->find($itemnumber)->cover_images->delete;
 112                     } elsif ( $biblionumber ) {
 113                         Koha::Biblios->find($biblionumber)->cover_images->search({ itemnumber => undef })->delete;
 114                     }
 115                 }
 116
 117                 Koha::CoverImage->new(
 118                     {
 119                         biblionumber => $biblionumber,
 120                         itemnumber   => $itemnumber,
 121                         src_image    => $srcimage
 122                     }
 123                 )->store;
 124             };
 125
 126             if ($@) {
 127                 warn $@;
 128                 $error = 'DBERR';
 129             }
 130             else {
 131                 $total = 1;
 132             }
 133         }
 134         else {
 135             $error = 'OPNIMG';
 136         }
 137         undef $srcimage;
 138     }
 139     else {
 140         my $filename = $upload->full_path;
 141         my $dirname = File::Temp::tempdir( CLEANUP => 1 );
 142         qx/unzip $filename -d $dirname/;
 143         my $exit_code = $?;
 144         unless ( $exit_code == 0 ) {
 145             $error = 'UZIPFAIL';
 146         }
 147         else {
 148             my @directories;
 149             push @directories, "$dirname";
 150             foreach my $recursive_dir (@directories) {
 151                 my $dir;
 152                 opendir $dir, $recursive_dir;
 153                 while ( my $entry = readdir $dir ) {
 154                     push @directories, "$recursive_dir/$entry"
 155                       if ( -d "$recursive_dir/$entry" and $entry !~ /^[._]/ );
 156                 }
 157                 closedir $dir;
 158             }
 159             foreach my $dir (@directories) {
 160                 my $file;
 161                 if ( -e "$dir/idlink.txt" ) {
 162                     $file = "$dir/idlink.txt";
 163                 }
 164                 elsif ( -e "$dir/datalink.txt" ) {
 165                     $file = "$dir/datalink.txt";
 166                 }
 167                 else {
 168                     next;
 169                 }
 170                 if ( open( my $fh, '<', $file ) ) {
 171                     while ( my $line = <$fh> ) {
 172                         my $delim =
 173                             ( $line =~ /\t/ ) ? "\t"
 174                           : ( $line =~ /,/ )  ? ","
 175                           :                     "";
 176
 177                         unless ( $delim eq "," || $delim eq "\t" ) {
 178                             warn
 179 "Unrecognized or missing field delimeter. Please verify that you are using either a ',' or a 'tab'";
 180                             $error = 'DELERR';
 181                         }
 182                         else {
 183                             ( $biblionumber, $filename ) = split $delim, $line, 2;
 184                             $biblionumber =~
 185                               s/[\"\r\n]//g;    # remove offensive characters
 186                             $filename =~ s/[\"\r\n]//g;
 187                             $filename =~ s/^\s+//;
 188                             $filename =~ s/\s+$//;
 189                             if (C4::Context->preference("CataloguingLog")) {
 190                                 logaction('CATALOGUING', 'MODIFY', $biblionumber, "biblio cover image: $filename");
 191                             }
 192                             my $srcimage = GD::Image->new("$dir/$filename");
 193                             my $biblio;
 194                             my $item;
 195                             if ( defined $srcimage ) {
 196                                 $total++;
 197                                 eval {
 198                                     if ( $replace ) {
 199                                         if ( $biblionumber ) {
 200                                             $biblio = Koha::Biblios->find( $biblionumber );
 201                                             $biblio->cover_images->delete;
 202                                         } elsif ( $itemnumber ) {
 203                                             $item = Koha::Items->find($itemnumber);
 204                                             $item->cover_images->delete;
 205                                             $biblio = Koha::Biblios->find( $item->{biblionumber} );
 206                                         }
 207                                     } else {
 208                                         if( $biblionumber ){
 209                                             $biblio = Koha::Biblios->find( $biblionumber );
 210                                         } elsif ( $itemnumber ){
 211                                             $item = Koha::Items->find($itemnumber);
 212                                             $biblio = Koha::Biblios->find( $item->{biblionumber} );
 213                                         } else {
 214                                             warn "Problem.";
 215                                         }
 216                                     }
 217
 218                                     push @results, {
 219                                         biblionumber => $biblionumber,
 220                                         itemnumber => $itemnumber,
 221                                         title => $biblio->title
 222                                     };
 223
 224                                     Koha::CoverImage->new(
 225                                         {
 226                                             biblionumber => $biblionumber,
 227                                             itemnumber   => $itemnumber,
 228                                             src_image    => $srcimage
 229                                         }
 230                                     )->store;
 231                                 };
 232
 233                                 if ($@) {
 234                                     $error = 'DBERR';
 235                                 }
 236                             }
 237                             else {
 238                                 $error = 'OPNIMG';
 239                             }
 240                             undef $srcimage;
 241                         }
 242                     }
 243                     close($fh);
 244                 }
 245                 else {
 246                     $error = 'OPNLINK';
 247                 }
 248             }
 249         }
 250     }
 251     if( $error ){
 252         $template->param(
 253             total        => $total,
 254             uploadimage  => 1,
 255             error        => $error,
 256             biblionumber => $biblionumber || Koha::Items->find($itemnumber)->biblionumber,
 257             itemnumber   => $itemnumber,
 258         );
 259     } elsif ( @results ){
 260         $template->param(
 261             total        => $total,
 262             uploadimage  => 1,
 263             results      => \@results
 264         );
 265     } else {
 266         print $input->redirect("/cgi-bin/koha/tools/upload-cover-image.pl?biblionumber=$biblionumber&itemnumber=$itemnumber");
 267     }
 268 }
 269
 270 output_html_with_http_headers $input, $cookie, $template->output;
 271
 272 exit 0;
 273
 274 =head1 AUTHORS
 275
 276 Written by Jared Camins-Esakov of C & P Bibliography Services, in part based on
 277 code by Koustubha Kale of Anant Corporation and Chris Nighswonger of Foundation
 278 Bible College.
 279
 280 =cut