virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode;
  24 use Carp qw( carp );
  25 use Try::Tiny qw( catch try );
  26
  27 use C4::Auth qw( get_template_and_user );
  28 use C4::Biblio qw(
  29     GetMarcBiblio
  30     GetMarcISBN
  31     GetMarcSubjects
  32 );
  33 use C4::Items qw( GetItemsInfo );
  34 use C4::Output qw(
  35     output_html_with_http_headers
  36     output_and_exit
  37 );
  38 use Koha::Email;
  39 use Koha::Virtualshelves;
  40
  41 my $query = CGI->new;
  42
  43 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  44     {
  45         template_name   => "virtualshelves/sendshelfform.tt",
  46         query           => $query,
  47         type            => "intranet",
  48         flagsrequired   => { catalogue => 1 },
  49     }
  50 );
  51
  52 my $shelfid    = $query->param('shelfid');
  53 my $to_address = $query->param('email');
  54
  55 my $shelf = Koha::Virtualshelves->find( $shelfid );
  56
  57 output_and_exit( $query, $cookie, $template, 'insufficient_permission' )
  58     if $shelf && !$shelf->can_be_viewed( $loggedinuser );
  59
  60 if ($to_address) {
  61     my $comment = $query->param('comment');
  62
  63     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  64         {
  65         template_name   => "virtualshelves/sendshelf.tt",
  66         query           => $query,
  67         type            => "intranet",
  68         flagsrequired   => { catalogue => 1 },
  69         }
  70     );
  71
  72     my $contents = $shelf->get_contents;
  73     my $marcflavour = C4::Context->preference('marcflavour');
  74     my $iso2709;
  75     my @results;
  76
  77     while ( my $content = $contents->next ) {
  78         my $biblionumber     = $content->biblionumber;
  79         my $biblio           = Koha::Biblios->find( $biblionumber ) or next;
  80         my $dat              = $biblio->unblessed;
  81         my $record           = GetMarcBiblio({
  82             biblionumber => $biblionumber,
  83             embed_items  => 1 });
  84         my $marcauthorsarray = $biblio->get_marc_authors;
  85         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  86
  87         my @items = GetItemsInfo($biblionumber);
  88
  89         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  90         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  91         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  92         $dat->{'biblionumber'} = $biblionumber;
  93         $dat->{ITEM_RESULTS}   = \@items;
  94         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
  95
  96         $iso2709 .= $record->as_usmarc();
  97
  98         push( @results, $dat );
  99     }
 100
 101     $template2->param(
 102         BIBLIO_RESULTS => \@results,
 103         comment        => $comment,
 104         shelfname      => $shelf->shelfname,
 105     );
 106
 107     # Getting template result
 108     my $template_res = $template2->output();
 109     my $body;
 110
 111     my $subject;
 112     # Analysing information and getting mail properties
 113     if ( $template_res =~ /<SUBJECT>(?<subject>.*)<END_SUBJECT>/s ) {
 114         $subject = $+{subject};
 115         $subject =~ s|\n?(.*)\n?|$1|;
 116     }
 117     else {
 118         $subject = "no subject";
 119     }
 120
 121     my $email_header = "";
 122     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 123         $email_header = $1;
 124         $email_header =~ s|\n?(.*)\n?|$1|;
 125     }
 126
 127     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 128         $body = $1;
 129         $body =~ s|\n?(.*)\n?|$1|;
 130     }
 131
 132     my $THE_body = <<END_OF_BODY;
 133 $email_header
 134 $body
 135 END_OF_BODY
 136
 137     try {
 138         my $email = Koha::Email->create(
 139             {
 140                 to      => $to_address,
 141                 subject => $subject,
 142             }
 143         );
 144         $email->text_body( $THE_body );
 145         $email->attach(
 146             Encode::encode("UTF-8", $iso2709),
 147             content_type => 'application/octet-stream',
 148             name         => 'shelf.iso2709',
 149             disposition  => 'attachment',
 150         );
 151
 152         my $library = Koha::Patrons->find( $borrowernumber )->library;
 153         $email->send_or_die({ transport => $library->smtp_server->transport });
 154         $template->param( SENT => "1" );
 155     }
 156     catch {
 157         carp "Error sending mail: $_";
 158         $template->param( error => 1 );
 159     };
 160
 161     $template->param( email => $to_address );
 162     output_html_with_http_headers $query, $cookie, $template->output;
 163
 164 }
 165 else {
 166     $template->param(
 167         shelfid => $shelfid,
 168         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 169     );
 170     output_html_with_http_headers $query, $cookie, $template->output;
 171 }