bug 8215: (followup) make sure C4::CourseReserves doesn't export anything
[koha.git] / C4 / Auth_with_ldap.pm
1 package C4::Auth_with_ldap;
2
3 # Copyright 2000-2002 Katipo Communications
4 #
5 # This file is part of Koha.
6 #
7 # Koha is free software; you can redistribute it and/or modify it under the
8 # terms of the GNU General Public License as published by the Free Software
9 # Foundation; either version 2 of the License, or (at your option) any later
10 # version.
11 #
12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License along
17 # with Koha; if not, write to the Free Software Foundation, Inc.,
18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
19
20 use strict;
21 #use warnings; FIXME - Bug 2505
22 use Digest::MD5 qw(md5_base64);
23
24 use C4::Debug;
25 use C4::Context;
26 use C4::Members qw(AddMember changepassword);
27 use C4::Members::Attributes;
28 use C4::Members::AttributeTypes;
29 use C4::Utils qw( :all );
30 use List::MoreUtils qw( any );
31 use Net::LDAP;
32 use Net::LDAP::Filter;
33
34 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
35
36 BEGIN {
37         require Exporter;
38     $VERSION = 3.07.00.049;     # set the version for version checking
39         @ISA    = qw(Exporter);
40         @EXPORT = qw( checkpw_ldap );
41 }
42
43 # Redefine checkpw_ldap:
44 # connect to LDAP (named or anonymous)
45 # ~ retrieves $userid from KOHA_CONF mapping
46 # ~ then compares $password with userPassword 
47 # ~ then gets the LDAP entry
48 # ~ and calls the memberadd if necessary
49
50 sub ldapserver_error {
51         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
52 }
53
54 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
55 my $context = C4::Context->new()        or die 'C4::Context->new failed';
56 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
57 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
58 my $base      = $ldap->{base}           or die ldapserver_error('base');
59 $ldapname     = $ldap->{user}           ;
60 $ldappassword = $ldap->{pass}           ;
61 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
62 my @mapkeys = keys %mapping;
63 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
64 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
66
67 my %config = (
68         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
69     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
70        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
71 );
72
73 sub description {
74         my $result = shift or return;
75         return "LDAP error #" . $result->code
76                         . ": " . $result->error_name . "\n"
77                         . "# " . $result->error_text . "\n";
78 }
79
80 sub search_method {
81     my $db     = shift or return;
82     my $userid = shift or return;
83         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
84         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
85         my $search = $db->search(
86                   base => $base,
87                 filter => $filter,
88                 # attrs => ['*'],
89         ) or die "LDAP search failed to return object.";
90         my $count = $search->count;
91         if ($search->code > 0) {
92                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
93                 return 0;
94         }
95         if ($count != 1) {
96                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
97                 return 0;
98         }
99     return $search;
100 }
101
102 sub checkpw_ldap {
103     my ($dbh, $userid, $password) = @_;
104     my @hosts = split(',', $prefhost);
105     my $db = Net::LDAP->new(\@hosts);
106         #$debug and $db->debug(5);
107     my $userldapentry;
108
109   if ( $ldap->{auth_by_bind} ) {
110     # Perform an anonymous bind
111     my $res = $db->bind;
112     if ( $res->code ) {
113       $debug and warn "Anonymous LDAP bind failed: ". description($res);
114       return 0;
115     }
116
117     # Perform a LDAP search for the given username
118     my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
119     $userldapentry = $search->shift_entry;
120
121     # Perform a LDAP bind for the given username using the matched DN
122     $res = $db->bind( $userldapentry->dn, password => $password );
123     if ( $res->code ) {
124       $debug and warn "LDAP bind failed as kohauser $userid: ". description($res);
125       return 0;
126     }
127
128   } else {
129                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
130                 if ($res->code) {               # connection refused
131                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
132                         return 0;
133                 }
134         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
135         $userldapentry = $search->shift_entry;
136                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
137                 if ($cmpmesg->code != 6) {
138                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
139                         return 0;
140                 }
141         }
142
143     # To get here, LDAP has accepted our user's login attempt.
144     # But we still have work to do.  See perldoc below for detailed breakdown.
145
146     my (%borrower);
147         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
148
149     if (( $borrowernumber and $config{update}   ) or
150         (!$borrowernumber and $config{replicate})   ) {
151         %borrower = ldap_entry_2_hash($userldapentry,$userid);
152         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
153     }
154
155     if ($borrowernumber) {
156         if ($config{update}) { # A1, B1
157             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
158             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
159         } else { # C1, D1
160             # maybe update just the password?
161                 return(1, $cardnumber, $local_userid);
162         }
163     } elsif ($config{replicate}) { # A2, C2
164         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
165    } else {
166         return 0;   # B2, D2
167     }
168         if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
169         my $extended_patron_attributes;
170         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
171                 my $code = $attribute_type->{code};
172                 if ( exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) { # skip empty values
173                         push @$extended_patron_attributes, { code => $code, value => $borrower{$code} };
174                 }
175         }
176                 my @errors;
177                 #Check before add
178                 for (my $i; $i< scalar(@$extended_patron_attributes)-1;$i++) {
179                         my $attr=$extended_patron_attributes->[$i];
180                         unless (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
181                                 unshift @errors, $i;
182                                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
183                         }
184                 }
185                 #Removing erroneous attributes
186                 foreach my $index (@errors){
187                         @$extended_patron_attributes=splice(@$extended_patron_attributes,$index,1);
188                 }
189            C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, $extended_patron_attributes);
190         }
191 return(1, $cardnumber, $userid);
192 }
193
194 # Pass LDAP entry object and local cardnumber (userid).
195 # Returns borrower hash.
196 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
197 # Ensure that mandatory fields are correctly filled!
198 #
199 sub ldap_entry_2_hash {
200         my $userldapentry = shift;
201         my %borrower = ( cardnumber => shift );
202         my %memberhash;
203         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash. 
204         if ($debug) {
205                 print STDERR "\nkeys(\%\$userldapentry) = " . join(', ', keys %$userldapentry), "\n", $userldapentry->dump();
206                 foreach (keys %$userldapentry) {
207                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
208                         hashdump("LDAP key: ",$userldapentry->{$_});
209                 }
210         }
211         my $x = $userldapentry->{attrs} or return;
212         foreach (keys %$x) {
213                 $memberhash{$_} = join ' ', @{$x->{$_}};        
214                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
215         }
216         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
217                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
218         foreach my $key (keys %mapping) {
219                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
220                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
221                 unless (defined $data) { 
222                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
223                 }
224                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
225         }
226         $borrower{initials} = $memberhash{initials} || 
227                 ( substr($borrower{'firstname'},0,1)
228                 . substr($borrower{ 'surname' },0,1)
229                 . " ");
230
231         # check if categorycode exists, if not, fallback to default from koha-conf.xml
232         my $dbh = C4::Context->dbh;
233         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
234         $sth->execute( uc($borrower{'categorycode'}) );
235         unless ( my $row = $sth->fetchrow_hashref ) {
236                 my $default = $mapping{'categorycode'}->{content};
237                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
238                 $borrower{'categorycode'} = $default
239         }
240
241         return %borrower;
242 }
243
244 sub exists_local {
245         my $arg = shift;
246         my $dbh = C4::Context->dbh;
247         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
248
249         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
250         $sth->execute($arg);
251         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
252         ($sth->rows == 1) and return $sth->fetchrow;
253
254         $sth = $dbh->prepare("$select WHERE cardnumber=?");
255         $sth->execute($arg);
256         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
257         ($sth->rows == 1) and return $sth->fetchrow;
258         return 0;
259 }
260
261 sub _do_changepassword {
262     my ($userid, $borrowerid, $digest) = @_;
263     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
264     changepassword($userid, $borrowerid, $digest);
265
266         # Confirm changes
267         my $sth = C4::Context->dbh->prepare("SELECT password,cardnumber FROM borrowers WHERE borrowernumber=? ");
268         $sth->execute($borrowerid);
269         if ($sth->rows) {
270                 my ($md5password, $cardnum) = $sth->fetchrow;
271         ($digest eq $md5password) and return $cardnum;
272                 warn "Password mismatch after update to cardnumber=$cardnum (borrowernumber=$borrowerid)";
273                 return;
274         }
275         die "Unexpected error after password update to userid/borrowernumber: $userid / $borrowerid.";
276 }
277
278 sub update_local {
279         my   $userid   = shift             or return;
280         my   $digest   = md5_base64(shift) or return;
281         my $borrowerid = shift             or return;
282         my $borrower   = shift             or return;
283         my @keys = keys %$borrower;
284         my $dbh = C4::Context->dbh;
285         my $query = "UPDATE  borrowers\nSET     " . 
286                 join(',', map {"$_=?"} @keys) .
287                 "\nWHERE   borrowernumber=? "; 
288         my $sth = $dbh->prepare($query);
289         if ($debug) {
290                 print STDERR $query, "\n",
291                         join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
292                 print STDERR "\nuserid = $userid\n";
293         }
294         $sth->execute(
295                 ((map {$borrower->{$_}} @keys), $borrowerid)
296         );
297
298         # MODIFY PASSWORD/LOGIN
299         _do_changepassword($userid, $borrowerid, $digest);
300 }
301
302 1;
303 __END__
304
305 =head1 NAME
306
307 C4::Auth - Authenticates Koha users
308
309 =head1 SYNOPSIS
310
311   use C4::Auth_with_ldap;
312
313 =head1 LDAP Configuration
314
315     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
316         working LDAP servers.
317         To use it :
318            * Modify ldapserver element in KOHA_CONF
319            * Establish field mapping in <mapping> element.
320
321         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
322         the username would match the "uid" field, and the password should match the "userpassword" field.
323
324         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).  
325         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
326
327         mysql> show COLUMNS from borrowers;
328                 +---------------------+--------------+------+-----+---------+----------------+
329                 | Field               | Type         | Null | Key | Default | Extra          |
330                 +---------------------+--------------+------+-----+---------+----------------+
331                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
332                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
333                 | surname             | mediumtext   | NO   |     | NULL    |                |
334                 | firstname           | text         | YES  |     | NULL    |                |
335                 | title               | mediumtext   | YES  |     | NULL    |                |
336                 | othernames          | mediumtext   | YES  |     | NULL    |                |
337                 | initials            | text         | YES  |     | NULL    |                |
338                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
339                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
340                 | address             | mediumtext   | NO   |     | NULL    |                |
341                 | address2            | text         | YES  |     | NULL    |                |
342                 | city                | mediumtext   | NO   |     | NULL    |                |
343                 | state               | mediumtext   | YES  |     | NULL    |                |
344                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
345                 | country             | text         | YES  |     | NULL    |                |
346                 | email               | mediumtext   | YES  |     | NULL    |                |
347                 | phone               | text         | YES  |     | NULL    |                |
348                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
349                 | fax                 | mediumtext   | YES  |     | NULL    |                |
350                 | emailpro            | text         | YES  |     | NULL    |                |
351                 | phonepro            | text         | YES  |     | NULL    |                |
352                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
353                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
354                 | B_address           | varchar(100) | YES  |     | NULL    |                |
355                 | B_address2          | text         | YES  |     | NULL    |                |
356                 | B_city              | mediumtext   | YES  |     | NULL    |                |
357                 | B_state             | mediumtext   | YES  |     | NULL    |                |
358                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
359                 | B_country           | text         | YES  |     | NULL    |                |
360                 | B_email             | text         | YES  |     | NULL    |                |
361                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
362                 | dateofbirth         | date         | YES  |     | NULL    |                |
363                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
364                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
365                 | dateenrolled        | date         | YES  |     | NULL    |                |
366                 | dateexpiry          | date         | YES  |     | NULL    |                |
367                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
368                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
369                 | debarred            | date         | YES  |     | NULL    |                |
370                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
371                 | contactname         | mediumtext   | YES  |     | NULL    |                |
372                 | contactfirstname    | text         | YES  |     | NULL    |                |
373                 | contacttitle        | text         | YES  |     | NULL    |                |
374                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
375                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
376                 | relationship        | varchar(100) | YES  |     | NULL    |                |
377                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
378                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
379                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
380                 | password            | varchar(30)  | YES  |     | NULL    |                |
381                 | flags               | int(11)      | YES  |     | NULL    |                |
382                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
383                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
384                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
385                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
386                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
387                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
388                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
389                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
390                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
391                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
392                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
393                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
394                 | altcontactcountry   | text         | YES  |     | NULL    |                |
395                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
396                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
397                 | privacy             | int(11)      | NO   |     | 1       |                |
398                 +---------------------+--------------+------+-----+---------+----------------+
399                 66 rows in set (0.00 sec)
400                 Where Null="NO", the field is required.
401
402 =head1 KOHA_CONF and field mapping
403
404 Example XML stanza for LDAP configuration in KOHA_CONF.
405
406  <config>
407   ...
408   <useldapserver>1</useldapserver>
409   <!-- LDAP SERVER (optional) -->
410   <ldapserver id="ldapserver">
411     <hostname>localhost</hostname>
412     <base>dc=metavore,dc=com</base>
413     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
414     <pass>metavore</pass>          <!-- password, if not anonymous -->
415     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
416     <update>1</update>             <!-- update existing users in Koha database -->
417     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
418                                         password comparison, e.g., to use Active Directory -->
419     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
420       <firstname    is="givenname"      ></firstname>
421       <surname      is="sn"             ></surname>
422       <address      is="postaladdress"  ></address>
423       <city         is="l"              >Athens, OH</city>
424       <zipcode      is="postalcode"     ></zipcode>
425       <branchcode   is="branch"         >MAIN</branchcode>
426       <userid       is="uid"            ></userid>
427       <password     is="userpassword"   ></password>
428       <email        is="mail"           ></email>
429       <categorycode is="employeetype"   >PT</categorycode>
430       <phone        is="telephonenumber"></phone>
431     </mapping> 
432   </ldapserver> 
433  </config>
434
435 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
436 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
437 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
438 patron).  
439
440 =head1 CONFIGURATION
441
442 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on 
443 your configuration and the presence of a matching Koha user in your local DB:
444
445                          LOCAL_USER
446  OPTION UPDATE REPLICATE  EXISTS?  RESULT
447    A1      1       1        1      OK : We're updating them anyway.
448    A2      1       1        0      OK : We're adding them anyway.
449    B1      1       0        1      OK : We update them.
450    B2      1       0        0     FAIL: We cannot add new user.
451    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
452    C2      0       1        0      OK : We add the new user.
453    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
454    D2      0       0        0     FAIL: We cannot add new user.
455
456 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
457 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for 
458 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
459
460 If you choose NOT to update local users, the borrowers table will not be affected at all.
461 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
462 the local table never contained the LDAP values.  
463
464 =head2 auth_by_bind
465
466 Binds as the user instead of retrieving their record.  Recommended if update disabled.
467
468 =head2 principal_name
469
470 Provides an optional sprintf-style format for manipulating the userid before the bind.
471 Even though the userPrincipalName is one intended target, any uniquely identifying
472 attribute that the server allows to be used for binding could be used.
473
474 Currently, principal_name only operates when auth_by_bind is enabled.
475
476 =head2 Active Directory 
477
478 The auth_by_bind and principal_name settings are recommended for Active Directory.
479
480 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
481 we would typically under openldap.  Instead of:
482
483     distinguishedName: CN=barnes.7,DC=my_company,DC=com
484
485 We might get:
486
487     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
488
489 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
490 in Koha userids.  But the userPrincipalName should be consistent, something like:
491
492     userPrincipalName: barnes.7@my_company.com
493
494 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
495 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values 
496 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
497 like this:
498     <principal_name>%s@core.my_company.com</principal_name>
499
500 The user of the previous example, barnes.7, would then attempt to bind as:
501     barnes.7@core.my_company.com
502
503 =head1 SEE ALSO
504
505 CGI(3)
506
507 Net::LDAP()
508
509 XML::Simple()
510
511 Digest::MD5(3)
512
513 sprintf()
514
515 =cut
516
517 # For reference, here's an important difference in the data structure we rely on.
518 # ========================================
519 # Using attrs instead of {asn}->attributes
520 # ========================================
521 #
522 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
523 #       LDAP key: ->{             cn}->{           sss} = sss
524 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
525 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
526 #
527 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
528 #       LDAP key: ->{      givenname}->{Steve} = Steve
529 #