Bug 15631: Koha::Cities - remove getzipnamecity
[koha.git] / C4 / Members.pm
1 package C4::Members;
2
3 # Copyright 2000-2003 Katipo Communications
4 # Copyright 2010 BibLibre
5 # Parts Copyright 2010 Catalyst IT
6 #
7 # This file is part of Koha.
8 #
9 # Koha is free software; you can redistribute it and/or modify it
10 # under the terms of the GNU General Public License as published by
11 # the Free Software Foundation; either version 3 of the License, or
12 # (at your option) any later version.
13 #
14 # Koha is distributed in the hope that it will be useful, but
15 # WITHOUT ANY WARRANTY; without even the implied warranty of
16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
17 # GNU General Public License for more details.
18 #
19 # You should have received a copy of the GNU General Public License
20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
21
22
23 use strict;
24 #use warnings; FIXME - Bug 2505
25 use C4::Context;
26 use String::Random qw( random_string );
27 use Date::Calc qw/Today Add_Delta_YM check_date Date_to_Days/;
28 use C4::Log; # logaction
29 use C4::Overdues;
30 use C4::Reserves;
31 use C4::Accounts;
32 use C4::Biblio;
33 use C4::Letters;
34 use C4::Members::Attributes qw(SearchIdMatchingAttribute UpdateBorrowerAttribute);
35 use C4::NewsChannels; #get slip news
36 use DateTime;
37 use Koha::Database;
38 use Koha::DateUtils;
39 use Koha::Borrower::Debarments qw(IsDebarred);
40 use Text::Unaccent qw( unac_string );
41 use Koha::AuthUtils qw(hash_password);
42 use Koha::Database;
43
44 our ($VERSION,@ISA,@EXPORT,@EXPORT_OK,$debug);
45
46 use Module::Load::Conditional qw( can_load );
47 if ( ! can_load( modules => { 'Koha::NorwegianPatronDB' => undef } ) ) {
48    $debug && warn "Unable to load Koha::NorwegianPatronDB";
49 }
50
51
52 BEGIN {
53     $VERSION = 3.07.00.049;
54     $debug = $ENV{DEBUG} || 0;
55     require Exporter;
56     @ISA = qw(Exporter);
57     #Get data
58     push @EXPORT, qw(
59         &Search
60         &GetMemberDetails
61         &GetMemberRelatives
62         &GetMember
63
64         &GetGuarantees
65
66         &GetMemberIssuesAndFines
67         &GetPendingIssues
68         &GetAllIssues
69
70         &getidcity
71
72         &GetFirstValidEmailAddress
73         &GetNoticeEmailAddress
74
75         &GetAge
76         &GetCities
77         &GetSortDetails
78         &GetTitles
79
80         &GetPatronImage
81         &PutPatronImage
82         &RmPatronImage
83
84         &GetHideLostItemsPreference
85
86         &IsMemberBlocked
87         &GetMemberAccountRecords
88         &GetBorNotifyAcctRecord
89
90         &GetborCatFromCatType
91         &GetBorrowercategory
92         GetBorrowerCategorycode
93         &GetBorrowercategoryList
94
95         &GetBorrowersToExpunge
96         &GetBorrowersWhoHaveNeverBorrowed
97         &GetBorrowersWithIssuesHistoryOlderThan
98
99         &GetExpiryDate
100         &GetUpcomingMembershipExpires
101
102         &AddMessage
103         &DeleteMessage
104         &GetMessages
105         &GetMessagesCount
106
107         &IssueSlip
108         GetBorrowersWithEmail
109
110         HasOverdues
111         GetOverduesForPatron
112     );
113
114     #Modify data
115     push @EXPORT, qw(
116         &ModMember
117         &changepassword
118     );
119
120     #Delete data
121     push @EXPORT, qw(
122         &DelMember
123     );
124
125     #Insert data
126     push @EXPORT, qw(
127         &AddMember
128         &AddMember_Opac
129         &MoveMemberToDeleted
130         &ExtendMemberSubscriptionTo
131     );
132
133     #Check data
134     push @EXPORT, qw(
135         &checkuniquemember
136         &checkuserpassword
137         &Check_Userid
138         &Generate_Userid
139         &fixup_cardnumber
140         &checkcardnumber
141     );
142 }
143
144 =head1 NAME
145
146 C4::Members - Perl Module containing convenience functions for member handling
147
148 =head1 SYNOPSIS
149
150 use C4::Members;
151
152 =head1 DESCRIPTION
153
154 This module contains routines for adding, modifying and deleting members/patrons/borrowers 
155
156 =head1 FUNCTIONS
157
158 =head2 GetMemberDetails
159
160 ($borrower) = &GetMemberDetails($borrowernumber, $cardnumber);
161
162 Looks up a patron and returns information about him or her. If
163 C<$borrowernumber> is true (nonzero), C<&GetMemberDetails> looks
164 up the borrower by number; otherwise, it looks up the borrower by card
165 number.
166
167 C<$borrower> is a reference-to-hash whose keys are the fields of the
168 borrowers table in the Koha database. In addition,
169 C<$borrower-E<gt>{flags}> is a hash giving more detailed information
170 about the patron. Its keys act as flags :
171
172     if $borrower->{flags}->{LOST} {
173         # Patron's card was reported lost
174     }
175
176 If the state of a flag means that the patron should not be
177 allowed to borrow any more books, then it will have a C<noissues> key
178 with a true value.
179
180 See patronflags for more details.
181
182 C<$borrower-E<gt>{authflags}> is a hash giving more detailed information
183 about the top-level permissions flags set for the borrower.  For example,
184 if a user has the "editcatalogue" permission,
185 C<$borrower-E<gt>{authflags}-E<gt>{editcatalogue}> will exist and have
186 the value "1".
187
188 =cut
189
190 sub GetMemberDetails {
191     my ( $borrowernumber, $cardnumber ) = @_;
192     my $dbh = C4::Context->dbh;
193     my $query;
194     my $sth;
195     if ($borrowernumber) {
196         $sth = $dbh->prepare("
197             SELECT borrowers.*,
198                    category_type,
199                    categories.description,
200                    categories.BlockExpiredPatronOpacActions,
201                    reservefee,
202                    enrolmentperiod
203             FROM borrowers
204             LEFT JOIN categories ON borrowers.categorycode=categories.categorycode
205             WHERE borrowernumber = ?
206         ");
207         $sth->execute($borrowernumber);
208     }
209     elsif ($cardnumber) {
210         $sth = $dbh->prepare("
211             SELECT borrowers.*,
212                    category_type,
213                    categories.description,
214                    categories.BlockExpiredPatronOpacActions,
215                    reservefee,
216                    enrolmentperiod
217             FROM borrowers
218             LEFT JOIN categories ON borrowers.categorycode = categories.categorycode
219             WHERE cardnumber = ?
220         ");
221         $sth->execute($cardnumber);
222     }
223     else {
224         return;
225     }
226     my $borrower = $sth->fetchrow_hashref;
227     return unless $borrower;
228     my ($amount) = GetMemberAccountRecords($borrower->{borrowernumber});
229     $borrower->{'amountoutstanding'} = $amount;
230     # FIXME - patronflags calls GetMemberAccountRecords... just have patronflags return $amount
231     my $flags = patronflags( $borrower);
232     my $accessflagshash;
233
234     $sth = $dbh->prepare("select bit,flag from userflags");
235     $sth->execute;
236     while ( my ( $bit, $flag ) = $sth->fetchrow ) {
237         if ( $borrower->{'flags'} && $borrower->{'flags'} & 2**$bit ) {
238             $accessflagshash->{$flag} = 1;
239         }
240     }
241     $borrower->{'flags'}     = $flags;
242     $borrower->{'authflags'} = $accessflagshash;
243
244     # Handle setting the true behavior for BlockExpiredPatronOpacActions
245     $borrower->{'BlockExpiredPatronOpacActions'} =
246       C4::Context->preference('BlockExpiredPatronOpacActions')
247       if ( $borrower->{'BlockExpiredPatronOpacActions'} == -1 );
248
249     $borrower->{'is_expired'} = 0;
250     $borrower->{'is_expired'} = 1 if
251       defined($borrower->{dateexpiry}) &&
252       $borrower->{'dateexpiry'} ne '0000-00-00' &&
253       Date_to_Days( Today() ) >
254       Date_to_Days( split /-/, $borrower->{'dateexpiry'} );
255
256     return ($borrower);    #, $flags, $accessflagshash);
257 }
258
259 =head2 patronflags
260
261  $flags = &patronflags($patron);
262
263 This function is not exported.
264
265 The following will be set where applicable:
266  $flags->{CHARGES}->{amount}        Amount of debt
267  $flags->{CHARGES}->{noissues}      Set if debt amount >$5.00 (or syspref noissuescharge)
268  $flags->{CHARGES}->{message}       Message -- deprecated
269
270  $flags->{CREDITS}->{amount}        Amount of credit
271  $flags->{CREDITS}->{message}       Message -- deprecated
272
273  $flags->{  GNA  }                  Patron has no valid address
274  $flags->{  GNA  }->{noissues}      Set for each GNA
275  $flags->{  GNA  }->{message}       "Borrower has no valid address" -- deprecated
276
277  $flags->{ LOST  }                  Patron's card reported lost
278  $flags->{ LOST  }->{noissues}      Set for each LOST
279  $flags->{ LOST  }->{message}       Message -- deprecated
280
281  $flags->{DBARRED}                  Set if patron debarred, no access
282  $flags->{DBARRED}->{noissues}      Set for each DBARRED
283  $flags->{DBARRED}->{message}       Message -- deprecated
284
285  $flags->{ NOTES }
286  $flags->{ NOTES }->{message}       The note itself.  NOT deprecated
287
288  $flags->{ ODUES }                  Set if patron has overdue books.
289  $flags->{ ODUES }->{message}       "Yes"  -- deprecated
290  $flags->{ ODUES }->{itemlist}      ref-to-array: list of overdue books
291  $flags->{ ODUES }->{itemlisttext}  Text list of overdue items -- deprecated
292
293  $flags->{WAITING}                  Set if any of patron's reserves are available
294  $flags->{WAITING}->{message}       Message -- deprecated
295  $flags->{WAITING}->{itemlist}      ref-to-array: list of available items
296
297 =over 
298
299 =item C<$flags-E<gt>{ODUES}-E<gt>{itemlist}> is a reference-to-array listing the
300 overdue items. Its elements are references-to-hash, each describing an
301 overdue item. The keys are selected fields from the issues, biblio,
302 biblioitems, and items tables of the Koha database.
303
304 =item C<$flags-E<gt>{ODUES}-E<gt>{itemlisttext}> is a string giving a text listing of
305 the overdue items, one per line.  Deprecated.
306
307 =item C<$flags-E<gt>{WAITING}-E<gt>{itemlist}> is a reference-to-array listing the
308 available items. Each element is a reference-to-hash whose keys are
309 fields from the reserves table of the Koha database.
310
311 =back
312
313 All the "message" fields that include language generated in this function are deprecated, 
314 because such strings belong properly in the display layer.
315
316 The "message" field that comes from the DB is OK.
317
318 =cut
319
320 # TODO: use {anonymous => hashes} instead of a dozen %flaginfo
321 # FIXME rename this function.
322 sub patronflags {
323     my %flags;
324     my ( $patroninformation) = @_;
325     my $dbh=C4::Context->dbh;
326     my ($balance, $owing) = GetMemberAccountBalance( $patroninformation->{'borrowernumber'});
327     if ( $owing > 0 ) {
328         my %flaginfo;
329         my $noissuescharge = C4::Context->preference("noissuescharge") || 5;
330         $flaginfo{'message'} = sprintf 'Patron owes %.02f', $owing;
331         $flaginfo{'amount'}  = sprintf "%.02f", $owing;
332         if ( $owing > $noissuescharge && !C4::Context->preference("AllowFineOverride") ) {
333             $flaginfo{'noissues'} = 1;
334         }
335         $flags{'CHARGES'} = \%flaginfo;
336     }
337     elsif ( $balance < 0 ) {
338         my %flaginfo;
339         $flaginfo{'message'} = sprintf 'Patron has credit of %.02f', -$balance;
340         $flaginfo{'amount'}  = sprintf "%.02f", $balance;
341         $flags{'CREDITS'} = \%flaginfo;
342     }
343     if (   $patroninformation->{'gonenoaddress'}
344         && $patroninformation->{'gonenoaddress'} == 1 )
345     {
346         my %flaginfo;
347         $flaginfo{'message'}  = 'Borrower has no valid address.';
348         $flaginfo{'noissues'} = 1;
349         $flags{'GNA'}         = \%flaginfo;
350     }
351     if ( $patroninformation->{'lost'} && $patroninformation->{'lost'} == 1 ) {
352         my %flaginfo;
353         $flaginfo{'message'}  = 'Borrower\'s card reported lost.';
354         $flaginfo{'noissues'} = 1;
355         $flags{'LOST'}        = \%flaginfo;
356     }
357     if ( $patroninformation->{'debarred'} && check_date( split( /-/, $patroninformation->{'debarred'} ) ) ) {
358         if ( Date_to_Days(Date::Calc::Today) < Date_to_Days( split( /-/, $patroninformation->{'debarred'} ) ) ) {
359             my %flaginfo;
360             $flaginfo{'debarredcomment'} = $patroninformation->{'debarredcomment'};
361             $flaginfo{'message'}         = $patroninformation->{'debarredcomment'};
362             $flaginfo{'noissues'}        = 1;
363             $flaginfo{'dateend'}         = $patroninformation->{'debarred'};
364             $flags{'DBARRED'}           = \%flaginfo;
365         }
366     }
367     if (   $patroninformation->{'borrowernotes'}
368         && $patroninformation->{'borrowernotes'} )
369     {
370         my %flaginfo;
371         $flaginfo{'message'} = $patroninformation->{'borrowernotes'};
372         $flags{'NOTES'}      = \%flaginfo;
373     }
374     my ( $odues, $itemsoverdue ) = C4::Overdues::checkoverdues($patroninformation->{'borrowernumber'});
375     if ( $odues && $odues > 0 ) {
376         my %flaginfo;
377         $flaginfo{'message'}  = "Yes";
378         $flaginfo{'itemlist'} = $itemsoverdue;
379         foreach ( sort { $a->{'date_due'} cmp $b->{'date_due'} }
380             @$itemsoverdue )
381         {
382             $flaginfo{'itemlisttext'} .=
383               "$_->{'date_due'} $_->{'barcode'} $_->{'title'} \n";  # newline is display layer
384         }
385         $flags{'ODUES'} = \%flaginfo;
386     }
387     my @itemswaiting = C4::Reserves::GetReservesFromBorrowernumber( $patroninformation->{'borrowernumber'},'W' );
388     my $nowaiting = scalar @itemswaiting;
389     if ( $nowaiting > 0 ) {
390         my %flaginfo;
391         $flaginfo{'message'}  = "Reserved items available";
392         $flaginfo{'itemlist'} = \@itemswaiting;
393         $flags{'WAITING'}     = \%flaginfo;
394     }
395     return ( \%flags );
396 }
397
398
399 =head2 GetMember
400
401   $borrower = &GetMember(%information);
402
403 Retrieve the first patron record meeting on criteria listed in the
404 C<%information> hash, which should contain one or more
405 pairs of borrowers column names and values, e.g.,
406
407    $borrower = GetMember(borrowernumber => id);
408
409 C<&GetBorrower> returns a reference-to-hash whose keys are the fields of
410 the C<borrowers> table in the Koha database.
411
412 FIXME: GetMember() is used throughout the code as a lookup
413 on a unique key such as the borrowernumber, but this meaning is not
414 enforced in the routine itself.
415
416 =cut
417
418 #'
419 sub GetMember {
420     my ( %information ) = @_;
421     if (exists $information{borrowernumber} && !defined $information{borrowernumber}) {
422         #passing mysql's kohaadmin?? Makes no sense as a query
423         return;
424     }
425     my $dbh = C4::Context->dbh;
426     my $select =
427     q{SELECT borrowers.*, categories.category_type, categories.description
428     FROM borrowers 
429     LEFT JOIN categories on borrowers.categorycode=categories.categorycode WHERE };
430     my $more_p = 0;
431     my @values = ();
432     for (keys %information ) {
433         if ($more_p) {
434             $select .= ' AND ';
435         }
436         else {
437             $more_p++;
438         }
439
440         if (defined $information{$_}) {
441             $select .= "$_ = ?";
442             push @values, $information{$_};
443         }
444         else {
445             $select .= "$_ IS NULL";
446         }
447     }
448     $debug && warn $select, " ",values %information;
449     my $sth = $dbh->prepare("$select");
450     $sth->execute(map{$information{$_}} keys %information);
451     my $data = $sth->fetchall_arrayref({});
452     #FIXME interface to this routine now allows generation of a result set
453     #so whole array should be returned but bowhere in the current code expects this
454     if (@{$data} ) {
455         return $data->[0];
456     }
457
458     return;
459 }
460
461 =head2 GetMemberRelatives
462
463  @borrowernumbers = GetMemberRelatives($borrowernumber);
464
465  C<GetMemberRelatives> returns a borrowersnumber's list of guarantor/guarantees of the member given in parameter
466
467 =cut
468
469 sub GetMemberRelatives {
470     my $borrowernumber = shift;
471     my $dbh = C4::Context->dbh;
472     my @glist;
473
474     # Getting guarantor
475     my $query = "SELECT guarantorid FROM borrowers WHERE borrowernumber=?";
476     my $sth = $dbh->prepare($query);
477     $sth->execute($borrowernumber);
478     my $data = $sth->fetchrow_arrayref();
479     push @glist, $data->[0] if $data->[0];
480     my $guarantor = $data->[0] ? $data->[0] : undef;
481
482     # Getting guarantees
483     $query = "SELECT borrowernumber FROM borrowers WHERE guarantorid=?";
484     $sth = $dbh->prepare($query);
485     $sth->execute($borrowernumber);
486     while ($data = $sth->fetchrow_arrayref()) {
487        push @glist, $data->[0];
488     }
489
490     # Getting sibling guarantees
491     if ($guarantor) {
492         $query = "SELECT borrowernumber FROM borrowers WHERE guarantorid=?";
493         $sth = $dbh->prepare($query);
494         $sth->execute($guarantor);
495         while ($data = $sth->fetchrow_arrayref()) {
496            push @glist, $data->[0] if ($data->[0] != $borrowernumber);
497         }
498     }
499
500     return @glist;
501 }
502
503 =head2 IsMemberBlocked
504
505   my ($block_status, $count) = IsMemberBlocked( $borrowernumber );
506
507 Returns whether a patron is restricted or has overdue items that may result
508 in a block of circulation privileges.
509
510 C<$block_status> can have the following values:
511
512 1 if the patron is currently restricted, in which case
513 C<$count> is the expiration date (9999-12-31 for indefinite)
514
515 -1 if the patron has overdue items, in which case C<$count> is the number of them
516
517 0 if the patron has no overdue items or outstanding fine days, in which case C<$count> is 0
518
519 Existing active restrictions are checked before current overdue items.
520
521 =cut
522
523 sub IsMemberBlocked {
524     my $borrowernumber = shift;
525     my $dbh            = C4::Context->dbh;
526
527     my $blockeddate = Koha::Borrower::Debarments::IsDebarred($borrowernumber);
528
529     return ( 1, $blockeddate ) if $blockeddate;
530
531     # if he have late issues
532     my $sth = $dbh->prepare(
533         "SELECT COUNT(*) as latedocs
534          FROM issues
535          WHERE borrowernumber = ?
536          AND date_due < now()"
537     );
538     $sth->execute($borrowernumber);
539     my $latedocs = $sth->fetchrow_hashref->{'latedocs'};
540
541     return ( -1, $latedocs ) if $latedocs > 0;
542
543     return ( 0, 0 );
544 }
545
546 =head2 GetMemberIssuesAndFines
547
548   ($overdue_count, $issue_count, $total_fines) = &GetMemberIssuesAndFines($borrowernumber);
549
550 Returns aggregate data about items borrowed by the patron with the
551 given borrowernumber.
552
553 C<&GetMemberIssuesAndFines> returns a three-element array.  C<$overdue_count> is the
554 number of overdue items the patron currently has borrowed. C<$issue_count> is the
555 number of books the patron currently has borrowed.  C<$total_fines> is
556 the total fine currently due by the borrower.
557
558 =cut
559
560 #'
561 sub GetMemberIssuesAndFines {
562     my ( $borrowernumber ) = @_;
563     my $dbh   = C4::Context->dbh;
564     my $query = "SELECT COUNT(*) FROM issues WHERE borrowernumber = ?";
565
566     $debug and warn $query."\n";
567     my $sth = $dbh->prepare($query);
568     $sth->execute($borrowernumber);
569     my $issue_count = $sth->fetchrow_arrayref->[0];
570
571     $sth = $dbh->prepare(
572         "SELECT COUNT(*) FROM issues 
573          WHERE borrowernumber = ? 
574          AND date_due < now()"
575     );
576     $sth->execute($borrowernumber);
577     my $overdue_count = $sth->fetchrow_arrayref->[0];
578
579     $sth = $dbh->prepare("SELECT SUM(amountoutstanding) FROM accountlines WHERE borrowernumber = ?");
580     $sth->execute($borrowernumber);
581     my $total_fines = $sth->fetchrow_arrayref->[0];
582
583     return ($overdue_count, $issue_count, $total_fines);
584 }
585
586
587 =head2 columns
588
589   my @columns = C4::Member::columns();
590
591 Returns an array of borrowers' table columns on success,
592 and an empty array on failure.
593
594 =cut
595
596 sub columns {
597
598     # Pure ANSI SQL goodness.
599     my $sql = 'SELECT * FROM borrowers WHERE 1=0;';
600
601     # Get the database handle.
602     my $dbh = C4::Context->dbh;
603
604     # Run the SQL statement to load STH's readonly properties.
605     my $sth = $dbh->prepare($sql);
606     my $rv = $sth->execute();
607
608     # This only fails if the table doesn't exist.
609     # This will always be called AFTER an install or upgrade,
610     # so borrowers will exist!
611     my @data;
612     if ($sth->{NUM_OF_FIELDS}>0) {
613         @data = @{$sth->{NAME}};
614     }
615     else {
616         @data = ();
617     }
618     return @data;
619 }
620
621
622 =head2 ModMember
623
624   my $success = ModMember(borrowernumber => $borrowernumber,
625                                             [ field => value ]... );
626
627 Modify borrower's data.  All date fields should ALREADY be in ISO format.
628
629 return :
630 true on success, or false on failure
631
632 =cut
633
634 sub ModMember {
635     my (%data) = @_;
636     # test to know if you must update or not the borrower password
637     if (exists $data{password}) {
638         if ($data{password} eq '****' or $data{password} eq '') {
639             delete $data{password};
640         } else {
641             if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
642                 # Update the hashed PIN in borrower_sync.hashed_pin, before Koha hashes it
643                 Koha::NorwegianPatronDB::NLUpdateHashedPIN( $data{'borrowernumber'}, $data{password} );
644             }
645             $data{password} = hash_password($data{password});
646         }
647     }
648
649     my $old_categorycode = GetBorrowerCategorycode( $data{borrowernumber} );
650
651     # get only the columns of a borrower
652     my $schema = Koha::Database->new()->schema;
653     my @columns = $schema->source('Borrower')->columns;
654     my $new_borrower = { map { join(' ', @columns) =~ /$_/ ? ( $_ => $data{$_} ) : () } keys(%data) };
655     delete $new_borrower->{flags};
656
657     $new_borrower->{dateofbirth}     ||= undef if exists $new_borrower->{dateofbirth};
658     $new_borrower->{dateenrolled}    ||= undef if exists $new_borrower->{dateenrolled};
659     $new_borrower->{dateexpiry}      ||= undef if exists $new_borrower->{dateexpiry};
660     $new_borrower->{debarred}        ||= undef if exists $new_borrower->{debarred};
661     $new_borrower->{sms_provider_id} ||= undef if exists $new_borrower->{sms_provider_id};
662
663     my $rs = $schema->resultset('Borrower')->search({
664         borrowernumber => $new_borrower->{borrowernumber},
665      });
666
667     my $execute_success = $rs->update($new_borrower);
668     if ($execute_success ne '0E0') { # only proceed if the update was a success
669
670         # ok if its an adult (type) it may have borrowers that depend on it as a guarantor
671         # so when we update information for an adult we should check for guarantees and update the relevant part
672         # of their records, ie addresses and phone numbers
673         my $borrowercategory= GetBorrowercategory( $data{'category_type'} );
674         if ( exists  $borrowercategory->{'category_type'} && $borrowercategory->{'category_type'} eq ('A' || 'S') ) {
675             # is adult check guarantees;
676             UpdateGuarantees(%data);
677         }
678
679         # If the patron changes to a category with enrollment fee, we add a fee
680         if ( $data{categorycode} and $data{categorycode} ne $old_categorycode ) {
681             if ( C4::Context->preference('FeeOnChangePatronCategory') ) {
682                 AddEnrolmentFeeIfNeeded( $data{categorycode}, $data{borrowernumber} );
683             }
684         }
685
686         # If NorwegianPatronDBEnable is enabled, we set syncstatus to something that a
687         # cronjob will use for syncing with NL
688         if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
689             my $borrowersync = Koha::Database->new->schema->resultset('BorrowerSync')->find({
690                 'synctype'       => 'norwegianpatrondb',
691                 'borrowernumber' => $data{'borrowernumber'}
692             });
693             # Do not set to "edited" if syncstatus is "new". We need to sync as new before
694             # we can sync as changed. And the "new sync" will pick up all changes since
695             # the patron was created anyway.
696             if ( $borrowersync->syncstatus ne 'new' && $borrowersync->syncstatus ne 'delete' ) {
697                 $borrowersync->update( { 'syncstatus' => 'edited' } );
698             }
699             # Set the value of 'sync'
700             $borrowersync->update( { 'sync' => $data{'sync'} } );
701             # Try to do the live sync
702             Koha::NorwegianPatronDB::NLSync({ 'borrowernumber' => $data{'borrowernumber'} });
703         }
704
705         logaction("MEMBERS", "MODIFY", $data{'borrowernumber'}, "UPDATE (executed w/ arg: $data{'borrowernumber'})") if C4::Context->preference("BorrowersLog");
706     }
707     return $execute_success;
708 }
709
710 =head2 AddMember
711
712   $borrowernumber = &AddMember(%borrower);
713
714 insert new borrower into table
715
716 (%borrower keys are database columns. Database columns could be
717 different in different versions. Please look into database for correct
718 column names.)
719
720 Returns the borrowernumber upon success
721
722 Returns as undef upon any db error without further processing
723
724 =cut
725
726 #'
727 sub AddMember {
728     my (%data) = @_;
729     my $dbh = C4::Context->dbh;
730     my $schema = Koha::Database->new()->schema;
731
732     # generate a proper login if none provided
733     $data{'userid'} = Generate_Userid( $data{'borrowernumber'}, $data{'firstname'}, $data{'surname'} )
734       if ( $data{'userid'} eq '' || !Check_Userid( $data{'userid'} ) );
735
736     # add expiration date if it isn't already there
737     unless ( $data{'dateexpiry'} ) {
738         $data{'dateexpiry'} = GetExpiryDate( $data{'categorycode'}, output_pref( { dt => dt_from_string, dateonly => 1, dateformat => 'iso' } ) );
739     }
740
741     # add enrollment date if it isn't already there
742     unless ( $data{'dateenrolled'} ) {
743         $data{'dateenrolled'} = output_pref( { dt => dt_from_string, dateonly => 1, dateformat => 'iso' } );
744     }
745
746     my $patron_category = $schema->resultset('Category')->find( $data{'categorycode'} );
747     $data{'privacy'} =
748         $patron_category->default_privacy() eq 'default' ? 1
749       : $patron_category->default_privacy() eq 'never'   ? 2
750       : $patron_category->default_privacy() eq 'forever' ? 0
751       :                                                    undef;
752     # Make a copy of the plain text password for later use
753     my $plain_text_password = $data{'password'};
754
755     # create a disabled account if no password provided
756     $data{'password'} = ($data{'password'})? hash_password($data{'password'}) : '!';
757
758     # we don't want invalid dates in the db (mysql has a bad habit of inserting 0000-00-00
759     $data{'dateofbirth'} = undef if( not $data{'dateofbirth'} );
760     $data{'debarred'} = undef if ( not $data{'debarred'} );
761
762     # get only the columns of Borrower
763     my @columns = $schema->source('Borrower')->columns;
764     my $new_member = { map { join(' ',@columns) =~ /$_/ ? ( $_ => $data{$_} )  : () } keys(%data) } ;
765     delete $new_member->{borrowernumber};
766
767     my $rs = $schema->resultset('Borrower');
768     $data{borrowernumber} = $rs->create($new_member)->id;
769
770     # If NorwegianPatronDBEnable is enabled, we set syncstatus to something that a
771     # cronjob will use for syncing with NL
772     if ( exists $data{'borrowernumber'} && C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
773         Koha::Database->new->schema->resultset('BorrowerSync')->create({
774             'borrowernumber' => $data{'borrowernumber'},
775             'synctype'       => 'norwegianpatrondb',
776             'sync'           => 1,
777             'syncstatus'     => 'new',
778             'hashed_pin'     => Koha::NorwegianPatronDB::NLEncryptPIN( $plain_text_password ),
779         });
780     }
781
782     # mysql_insertid is probably bad.  not necessarily accurate and mysql-specific at best.
783     logaction("MEMBERS", "CREATE", $data{'borrowernumber'}, "") if C4::Context->preference("BorrowersLog");
784
785     AddEnrolmentFeeIfNeeded( $data{categorycode}, $data{borrowernumber} );
786
787     return $data{borrowernumber};
788 }
789
790 =head2 Check_Userid
791
792     my $uniqueness = Check_Userid($userid,$borrowernumber);
793
794     $borrowernumber is optional (i.e. it can contain a blank value). If $userid is passed with a blank $borrowernumber variable, the database will be checked for all instances of that userid (i.e. userid=? AND borrowernumber != '').
795
796     If $borrowernumber is provided, the database will be checked for every instance of that userid coupled with a different borrower(number) than the one provided.
797
798     return :
799         0 for not unique (i.e. this $userid already exists)
800         1 for unique (i.e. this $userid does not exist, or this $userid/$borrowernumber combination already exists)
801
802 =cut
803
804 sub Check_Userid {
805     my ( $uid, $borrowernumber ) = @_;
806
807     return 0 unless ($uid); # userid is a unique column, we should assume NULL is not unique
808
809     return 0 if ( $uid eq C4::Context->config('user') );
810
811     my $rs = Koha::Database->new()->schema()->resultset('Borrower');
812
813     my $params;
814     $params->{userid} = $uid;
815     $params->{borrowernumber} = { '!=' => $borrowernumber } if ($borrowernumber);
816
817     my $count = $rs->count( $params );
818
819     return $count ? 0 : 1;
820 }
821
822 =head2 Generate_Userid
823
824     my $newuid = Generate_Userid($borrowernumber, $firstname, $surname);
825
826     Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
827
828     $borrowernumber is optional (i.e. it can contain a blank value). A value is passed when generating a new userid for an existing borrower. When a new userid is created for a new borrower, a blank value is passed to this sub.
829
830     return :
831         new userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $newuid is unique, or a higher numeric value if Check_Userid finds an existing match for the $newuid in the database).
832
833 =cut
834
835 sub Generate_Userid {
836   my ($borrowernumber, $firstname, $surname) = @_;
837   my $newuid;
838   my $offset = 0;
839   #The script will "do" the following code and increment the $offset until Check_Userid = 1 (i.e. until $newuid comes back as unique)
840   do {
841     $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
842     $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
843     $newuid = lc(($firstname)? "$firstname.$surname" : $surname);
844     $newuid = unac_string('utf-8',$newuid);
845     $newuid .= $offset unless $offset == 0;
846     $offset++;
847
848    } while (!Check_Userid($newuid,$borrowernumber));
849
850    return $newuid;
851 }
852
853 sub changepassword {
854     my ( $uid, $member, $digest ) = @_;
855     my $dbh = C4::Context->dbh;
856
857 #Make sure the userid chosen is unique and not theirs if non-empty. If it is not,
858 #Then we need to tell the user and have them create a new one.
859     my $resultcode;
860     my $sth =
861       $dbh->prepare(
862         "SELECT * FROM borrowers WHERE userid=? AND borrowernumber != ?");
863     $sth->execute( $uid, $member );
864     if ( ( $uid ne '' ) && ( my $row = $sth->fetchrow_hashref ) ) {
865         $resultcode=0;
866     }
867     else {
868         #Everything is good so we can update the information.
869         $sth =
870           $dbh->prepare(
871             "update borrowers set userid=?, password=? where borrowernumber=?");
872         $sth->execute( $uid, $digest, $member );
873         $resultcode=1;
874     }
875     
876     logaction("MEMBERS", "CHANGE PASS", $member, "") if C4::Context->preference("BorrowersLog");
877     return $resultcode;    
878 }
879
880
881
882 =head2 fixup_cardnumber
883
884 Warning: The caller is responsible for locking the members table in write
885 mode, to avoid database corruption.
886
887 =cut
888
889 use vars qw( @weightings );
890 my @weightings = ( 8, 4, 6, 3, 5, 2, 1 );
891
892 sub fixup_cardnumber {
893     my ($cardnumber) = @_;
894     my $autonumber_members = C4::Context->boolean_preference('autoMemberNum') || 0;
895
896     # Find out whether member numbers should be generated
897     # automatically. Should be either "1" or something else.
898     # Defaults to "0", which is interpreted as "no".
899
900     #     if ($cardnumber !~ /\S/ && $autonumber_members) {
901     ($autonumber_members) or return $cardnumber;
902     my $checkdigit = C4::Context->preference('checkdigit');
903     my $dbh = C4::Context->dbh;
904     if ( $checkdigit and $checkdigit eq 'katipo' ) {
905
906         # if checkdigit is selected, calculate katipo-style cardnumber.
907         # otherwise, just use the max()
908         # purpose: generate checksum'd member numbers.
909         # We'll assume we just got the max value of digits 2-8 of member #'s
910         # from the database and our job is to increment that by one,
911         # determine the 1st and 9th digits and return the full string.
912         my $sth = $dbh->prepare(
913             "select max(substring(borrowers.cardnumber,2,7)) as new_num from borrowers"
914         );
915         $sth->execute;
916         my $data = $sth->fetchrow_hashref;
917         $cardnumber = $data->{new_num};
918         if ( !$cardnumber ) {    # If DB has no values,
919             $cardnumber = 1000000;    # start at 1000000
920         } else {
921             $cardnumber += 1;
922         }
923
924         my $sum = 0;
925         for ( my $i = 0 ; $i < 8 ; $i += 1 ) {
926             # read weightings, left to right, 1 char at a time
927             my $temp1 = $weightings[$i];
928
929             # sequence left to right, 1 char at a time
930             my $temp2 = substr( $cardnumber, $i, 1 );
931
932             # mult each char 1-7 by its corresponding weighting
933             $sum += $temp1 * $temp2;
934         }
935
936         my $rem = ( $sum % 11 );
937         $rem = 'X' if $rem == 10;
938
939         return "V$cardnumber$rem";
940      } else {
941
942         my $sth = $dbh->prepare(
943             'SELECT MAX( CAST( cardnumber AS SIGNED ) ) FROM borrowers WHERE cardnumber REGEXP "^-?[0-9]+$"'
944         );
945         $sth->execute;
946         my ($result) = $sth->fetchrow;
947         return $result + 1;
948     }
949     return $cardnumber;     # just here as a fallback/reminder 
950 }
951
952 =head2 GetGuarantees
953
954   ($num_children, $children_arrayref) = &GetGuarantees($parent_borrno);
955   $child0_cardno = $children_arrayref->[0]{"cardnumber"};
956   $child0_borrno = $children_arrayref->[0]{"borrowernumber"};
957
958 C<&GetGuarantees> takes a borrower number (e.g., that of a patron
959 with children) and looks up the borrowers who are guaranteed by that
960 borrower (i.e., the patron's children).
961
962 C<&GetGuarantees> returns two values: an integer giving the number of
963 borrowers guaranteed by C<$parent_borrno>, and a reference to an array
964 of references to hash, which gives the actual results.
965
966 =cut
967
968 #'
969 sub GetGuarantees {
970     my ($borrowernumber) = @_;
971     my $dbh              = C4::Context->dbh;
972     my $sth              =
973       $dbh->prepare(
974 "select cardnumber,borrowernumber, firstname, surname from borrowers where guarantorid=?"
975       );
976     $sth->execute($borrowernumber);
977
978     my @dat;
979     my $data = $sth->fetchall_arrayref({}); 
980     return ( scalar(@$data), $data );
981 }
982
983 =head2 UpdateGuarantees
984
985   &UpdateGuarantees($parent_borrno);
986   
987
988 C<&UpdateGuarantees> borrower data for an adult and updates all the guarantees
989 with the modified information
990
991 =cut
992
993 #'
994 sub UpdateGuarantees {
995     my %data = shift;
996     my $dbh = C4::Context->dbh;
997     my ( $count, $guarantees ) = GetGuarantees( $data{'borrowernumber'} );
998     foreach my $guarantee (@$guarantees){
999         my $guaquery = qq|UPDATE borrowers 
1000               SET address=?,fax=?,B_city=?,mobile=?,city=?,phone=?
1001               WHERE borrowernumber=?
1002         |;
1003         my $sth = $dbh->prepare($guaquery);
1004         $sth->execute($data{'address'},$data{'fax'},$data{'B_city'},$data{'mobile'},$data{'city'},$data{'phone'},$guarantee->{'borrowernumber'});
1005     }
1006 }
1007 =head2 GetPendingIssues
1008
1009   my $issues = &GetPendingIssues(@borrowernumber);
1010
1011 Looks up what the patron with the given borrowernumber has borrowed.
1012
1013 C<&GetPendingIssues> returns a
1014 reference-to-array where each element is a reference-to-hash; the
1015 keys are the fields from the C<issues>, C<biblio>, and C<items> tables.
1016 The keys include C<biblioitems> fields except marc and marcxml.
1017
1018 =cut
1019
1020 #'
1021 sub GetPendingIssues {
1022     my @borrowernumbers = @_;
1023
1024     unless (@borrowernumbers ) { # return a ref_to_array
1025         return \@borrowernumbers; # to not cause surprise to caller
1026     }
1027
1028     # Borrowers part of the query
1029     my $bquery = '';
1030     for (my $i = 0; $i < @borrowernumbers; $i++) {
1031         $bquery .= ' issues.borrowernumber = ?';
1032         if ($i < $#borrowernumbers ) {
1033             $bquery .= ' OR';
1034         }
1035     }
1036
1037     # must avoid biblioitems.* to prevent large marc and marcxml fields from killing performance
1038     # FIXME: namespace collision: each table has "timestamp" fields.  Which one is "timestamp" ?
1039     # FIXME: circ/ciculation.pl tries to sort by timestamp!
1040     # FIXME: namespace collision: other collisions possible.
1041     # FIXME: most of this data isn't really being used by callers.
1042     my $query =
1043    "SELECT issues.*,
1044             items.*,
1045            biblio.*,
1046            biblioitems.volume,
1047            biblioitems.number,
1048            biblioitems.itemtype,
1049            biblioitems.isbn,
1050            biblioitems.issn,
1051            biblioitems.publicationyear,
1052            biblioitems.publishercode,
1053            biblioitems.volumedate,
1054            biblioitems.volumedesc,
1055            biblioitems.lccn,
1056            biblioitems.url,
1057            borrowers.firstname,
1058            borrowers.surname,
1059            borrowers.cardnumber,
1060            issues.timestamp AS timestamp,
1061            issues.renewals  AS renewals,
1062            issues.borrowernumber AS borrowernumber,
1063             items.renewals  AS totalrenewals
1064     FROM   issues
1065     LEFT JOIN items       ON items.itemnumber       =      issues.itemnumber
1066     LEFT JOIN biblio      ON items.biblionumber     =      biblio.biblionumber
1067     LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
1068     LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
1069     WHERE
1070       $bquery
1071     ORDER BY issues.issuedate"
1072     ;
1073
1074     my $sth = C4::Context->dbh->prepare($query);
1075     $sth->execute(@borrowernumbers);
1076     my $data = $sth->fetchall_arrayref({});
1077     my $today = dt_from_string;
1078     foreach (@{$data}) {
1079         if ($_->{issuedate}) {
1080             $_->{issuedate} = dt_from_string($_->{issuedate}, 'sql');
1081         }
1082         $_->{date_due_sql} = $_->{date_due};
1083         # FIXME no need to have this value
1084         $_->{date_due} or next;
1085         $_->{date_due_sql} = $_->{date_due};
1086         # FIXME no need to have this value
1087         $_->{date_due} = dt_from_string($_->{date_due}, 'sql');
1088         if ( DateTime->compare($_->{date_due}, $today) == -1 ) {
1089             $_->{overdue} = 1;
1090         }
1091     }
1092     return $data;
1093 }
1094
1095 =head2 GetAllIssues
1096
1097   $issues = &GetAllIssues($borrowernumber, $sortkey, $limit);
1098
1099 Looks up what the patron with the given borrowernumber has borrowed,
1100 and sorts the results.
1101
1102 C<$sortkey> is the name of a field on which to sort the results. This
1103 should be the name of a field in the C<issues>, C<biblio>,
1104 C<biblioitems>, or C<items> table in the Koha database.
1105
1106 C<$limit> is the maximum number of results to return.
1107
1108 C<&GetAllIssues> an arrayref, C<$issues>, of hashrefs, the keys of which
1109 are the fields from the C<issues>, C<biblio>, C<biblioitems>, and
1110 C<items> tables of the Koha database.
1111
1112 =cut
1113
1114 #'
1115 sub GetAllIssues {
1116     my ( $borrowernumber, $order, $limit ) = @_;
1117
1118     return unless $borrowernumber;
1119     $order = 'date_due desc' unless $order;
1120
1121     my $dbh = C4::Context->dbh;
1122     my $query =
1123 'SELECT *, issues.timestamp as issuestimestamp, issues.renewals AS renewals,items.renewals AS totalrenewals,items.timestamp AS itemstimestamp
1124   FROM issues 
1125   LEFT JOIN items on items.itemnumber=issues.itemnumber
1126   LEFT JOIN biblio ON items.biblionumber=biblio.biblionumber
1127   LEFT JOIN biblioitems ON items.biblioitemnumber=biblioitems.biblioitemnumber
1128   WHERE borrowernumber=? 
1129   UNION ALL
1130   SELECT *, old_issues.timestamp as issuestimestamp, old_issues.renewals AS renewals,items.renewals AS totalrenewals,items.timestamp AS itemstimestamp 
1131   FROM old_issues 
1132   LEFT JOIN items on items.itemnumber=old_issues.itemnumber
1133   LEFT JOIN biblio ON items.biblionumber=biblio.biblionumber
1134   LEFT JOIN biblioitems ON items.biblioitemnumber=biblioitems.biblioitemnumber
1135   WHERE borrowernumber=? AND old_issues.itemnumber IS NOT NULL
1136   order by ' . $order;
1137     if ($limit) {
1138         $query .= " limit $limit";
1139     }
1140
1141     my $sth = $dbh->prepare($query);
1142     $sth->execute( $borrowernumber, $borrowernumber );
1143     return $sth->fetchall_arrayref( {} );
1144 }
1145
1146
1147 =head2 GetMemberAccountRecords
1148
1149   ($total, $acctlines, $count) = &GetMemberAccountRecords($borrowernumber);
1150
1151 Looks up accounting data for the patron with the given borrowernumber.
1152
1153 C<&GetMemberAccountRecords> returns a three-element array. C<$acctlines> is a
1154 reference-to-array, where each element is a reference-to-hash; the
1155 keys are the fields of the C<accountlines> table in the Koha database.
1156 C<$count> is the number of elements in C<$acctlines>. C<$total> is the
1157 total amount outstanding for all of the account lines.
1158
1159 =cut
1160
1161 sub GetMemberAccountRecords {
1162     my ($borrowernumber) = @_;
1163     my $dbh = C4::Context->dbh;
1164     my @acctlines;
1165     my $numlines = 0;
1166     my $strsth      = qq(
1167                         SELECT * 
1168                         FROM accountlines 
1169                         WHERE borrowernumber=?);
1170     $strsth.=" ORDER BY accountlines_id desc";
1171     my $sth= $dbh->prepare( $strsth );
1172     $sth->execute( $borrowernumber );
1173
1174     my $total = 0;
1175     while ( my $data = $sth->fetchrow_hashref ) {
1176         if ( $data->{itemnumber} ) {
1177             my $biblio = GetBiblioFromItemNumber( $data->{itemnumber} );
1178             $data->{biblionumber} = $biblio->{biblionumber};
1179             $data->{title}        = $biblio->{title};
1180         }
1181         $acctlines[$numlines] = $data;
1182         $numlines++;
1183         $total += int(1000 * $data->{'amountoutstanding'}); # convert float to integer to avoid round-off errors
1184     }
1185     $total /= 1000;
1186     return ( $total, \@acctlines,$numlines);
1187 }
1188
1189 =head2 GetMemberAccountBalance
1190
1191   ($total_balance, $non_issue_balance, $other_charges) = &GetMemberAccountBalance($borrowernumber);
1192
1193 Calculates amount immediately owing by the patron - non-issue charges.
1194 Based on GetMemberAccountRecords.
1195 Charges exempt from non-issue are:
1196 * Res (reserves)
1197 * Rent (rental) if RentalsInNoissuesCharge syspref is set to false
1198 * Manual invoices if ManInvInNoissuesCharge syspref is set to false
1199
1200 =cut
1201
1202 sub GetMemberAccountBalance {
1203     my ($borrowernumber) = @_;
1204
1205     my $ACCOUNT_TYPE_LENGTH = 5; # this is plain ridiculous...
1206
1207     my @not_fines;
1208     push @not_fines, 'Res' unless C4::Context->preference('HoldsInNoissuesCharge');
1209     push @not_fines, 'Rent' unless C4::Context->preference('RentalsInNoissuesCharge');
1210     unless ( C4::Context->preference('ManInvInNoissuesCharge') ) {
1211         my $dbh = C4::Context->dbh;
1212         my $man_inv_types = $dbh->selectcol_arrayref(qq{SELECT authorised_value FROM authorised_values WHERE category = 'MANUAL_INV'});
1213         push @not_fines, map substr($_, 0, $ACCOUNT_TYPE_LENGTH), @$man_inv_types;
1214     }
1215     my %not_fine = map {$_ => 1} @not_fines;
1216
1217     my ($total, $acctlines) = GetMemberAccountRecords($borrowernumber);
1218     my $other_charges = 0;
1219     foreach (@$acctlines) {
1220         $other_charges += $_->{amountoutstanding} if $not_fine{ substr($_->{accounttype}, 0, $ACCOUNT_TYPE_LENGTH) };
1221     }
1222
1223     return ( $total, $total - $other_charges, $other_charges);
1224 }
1225
1226 =head2 GetBorNotifyAcctRecord
1227
1228   ($total, $acctlines, $count) = &GetBorNotifyAcctRecord($params,$notifyid);
1229
1230 Looks up accounting data for the patron with the given borrowernumber per file number.
1231
1232 C<&GetBorNotifyAcctRecord> returns a three-element array. C<$acctlines> is a
1233 reference-to-array, where each element is a reference-to-hash; the
1234 keys are the fields of the C<accountlines> table in the Koha database.
1235 C<$count> is the number of elements in C<$acctlines>. C<$total> is the
1236 total amount outstanding for all of the account lines.
1237
1238 =cut
1239
1240 sub GetBorNotifyAcctRecord {
1241     my ( $borrowernumber, $notifyid ) = @_;
1242     my $dbh = C4::Context->dbh;
1243     my @acctlines;
1244     my $numlines = 0;
1245     my $sth = $dbh->prepare(
1246             "SELECT * 
1247                 FROM accountlines 
1248                 WHERE borrowernumber=? 
1249                     AND notify_id=? 
1250                     AND amountoutstanding != '0' 
1251                 ORDER BY notify_id,accounttype
1252                 ");
1253
1254     $sth->execute( $borrowernumber, $notifyid );
1255     my $total = 0;
1256     while ( my $data = $sth->fetchrow_hashref ) {
1257         if ( $data->{itemnumber} ) {
1258             my $biblio = GetBiblioFromItemNumber( $data->{itemnumber} );
1259             $data->{biblionumber} = $biblio->{biblionumber};
1260             $data->{title}        = $biblio->{title};
1261         }
1262         $acctlines[$numlines] = $data;
1263         $numlines++;
1264         $total += int(100 * $data->{'amountoutstanding'});
1265     }
1266     $total /= 100;
1267     return ( $total, \@acctlines, $numlines );
1268 }
1269
1270 =head2 checkuniquemember (OUEST-PROVENCE)
1271
1272   ($result,$categorycode)  = &checkuniquemember($collectivity,$surname,$firstname,$dateofbirth);
1273
1274 Checks that a member exists or not in the database.
1275
1276 C<&result> is nonzero (=exist) or 0 (=does not exist)
1277 C<&categorycode> is from categorycode table
1278 C<&collectivity> is 1 (= we add a collectivity) or 0 (= we add a physical member)
1279 C<&surname> is the surname
1280 C<&firstname> is the firstname (only if collectivity=0)
1281 C<&dateofbirth> is the date of birth in ISO format (only if collectivity=0)
1282
1283 =cut
1284
1285 # FIXME: This function is not legitimate.  Multiple patrons might have the same first/last name and birthdate.
1286 # This is especially true since first name is not even a required field.
1287
1288 sub checkuniquemember {
1289     my ( $collectivity, $surname, $firstname, $dateofbirth ) = @_;
1290     my $dbh = C4::Context->dbh;
1291     my $request = ($collectivity) ?
1292         "SELECT borrowernumber,categorycode FROM borrowers WHERE surname=? " :
1293             ($dateofbirth) ?
1294             "SELECT borrowernumber,categorycode FROM borrowers WHERE surname=? and firstname=?  and dateofbirth=?" :
1295             "SELECT borrowernumber,categorycode FROM borrowers WHERE surname=? and firstname=?";
1296     my $sth = $dbh->prepare($request);
1297     if ($collectivity) {
1298         $sth->execute( uc($surname) );
1299     } elsif($dateofbirth){
1300         $sth->execute( uc($surname), ucfirst($firstname), $dateofbirth );
1301     }else{
1302         $sth->execute( uc($surname), ucfirst($firstname));
1303     }
1304     my @data = $sth->fetchrow;
1305     ( $data[0] ) and return $data[0], $data[1];
1306     return 0;
1307 }
1308
1309 sub checkcardnumber {
1310     my ( $cardnumber, $borrowernumber ) = @_;
1311
1312     # If cardnumber is null, we assume they're allowed.
1313     return 0 unless defined $cardnumber;
1314
1315     my $dbh = C4::Context->dbh;
1316     my $query = "SELECT * FROM borrowers WHERE cardnumber=?";
1317     $query .= " AND borrowernumber <> ?" if ($borrowernumber);
1318     my $sth = $dbh->prepare($query);
1319     $sth->execute(
1320         $cardnumber,
1321         ( $borrowernumber ? $borrowernumber : () )
1322     );
1323
1324     return 1 if $sth->fetchrow_hashref;
1325
1326     my ( $min_length, $max_length ) = get_cardnumber_length();
1327     return 2
1328         if length $cardnumber > $max_length
1329         or length $cardnumber < $min_length;
1330
1331     return 0;
1332 }
1333
1334 =head2 get_cardnumber_length
1335
1336     my ($min, $max) = C4::Members::get_cardnumber_length()
1337
1338 Returns the minimum and maximum length for patron cardnumbers as
1339 determined by the CardnumberLength system preference, the
1340 BorrowerMandatoryField system preference, and the width of the
1341 database column.
1342
1343 =cut
1344
1345 sub get_cardnumber_length {
1346     my ( $min, $max ) = ( 0, 16 ); # borrowers.cardnumber is a nullable varchar(16)
1347     $min = 1 if C4::Context->preference('BorrowerMandatoryField') =~ /cardnumber/;
1348     if ( my $cardnumber_length = C4::Context->preference('CardnumberLength') ) {
1349         # Is integer and length match
1350         if ( $cardnumber_length =~ m|^\d+$| ) {
1351             $min = $max = $cardnumber_length
1352                 if $cardnumber_length >= $min
1353                     and $cardnumber_length <= $max;
1354         }
1355         # Else assuming it is a range
1356         elsif ( $cardnumber_length =~ m|(\d*),(\d*)| ) {
1357             $min = $1 if $1 and $min < $1;
1358             $max = $2 if $2 and $max > $2;
1359         }
1360
1361     }
1362     return ( $min, $max );
1363 }
1364
1365 =head2 getdcity (OUEST-PROVENCE)
1366
1367 recover cityid  with city_name condition
1368
1369 =cut
1370
1371 sub getidcity {
1372     my ($city_name) = @_;
1373     my $dbh = C4::Context->dbh;
1374     my $sth = $dbh->prepare("select cityid from cities where city_name=? ");
1375     $sth->execute($city_name);
1376     my $data = $sth->fetchrow;
1377     return $data;
1378 }
1379
1380 =head2 GetFirstValidEmailAddress
1381
1382   $email = GetFirstValidEmailAddress($borrowernumber);
1383
1384 Return the first valid email address for a borrower, given the borrowernumber.  For now, the order 
1385 is defined as email, emailpro, B_email.  Returns the empty string if the borrower has no email 
1386 addresses.
1387
1388 =cut
1389
1390 sub GetFirstValidEmailAddress {
1391     my $borrowernumber = shift;
1392     my $dbh = C4::Context->dbh;
1393     my $sth = $dbh->prepare( "SELECT email, emailpro, B_email FROM borrowers where borrowernumber = ? ");
1394     $sth->execute( $borrowernumber );
1395     my $data = $sth->fetchrow_hashref;
1396
1397     if ($data->{'email'}) {
1398        return $data->{'email'};
1399     } elsif ($data->{'emailpro'}) {
1400        return $data->{'emailpro'};
1401     } elsif ($data->{'B_email'}) {
1402        return $data->{'B_email'};
1403     } else {
1404        return '';
1405     }
1406 }
1407
1408 =head2 GetNoticeEmailAddress
1409
1410   $email = GetNoticeEmailAddress($borrowernumber);
1411
1412 Return the email address of borrower used for notices, given the borrowernumber.
1413 Returns the empty string if no email address.
1414
1415 =cut
1416
1417 sub GetNoticeEmailAddress {
1418     my $borrowernumber = shift;
1419
1420     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1421     # if syspref is set to 'first valid' (value == OFF), look up email address
1422     if ( $which_address eq 'OFF' ) {
1423         return GetFirstValidEmailAddress($borrowernumber);
1424     }
1425     # specified email address field
1426     my $dbh = C4::Context->dbh;
1427     my $sth = $dbh->prepare( qq{
1428         SELECT $which_address AS primaryemail
1429         FROM borrowers
1430         WHERE borrowernumber=?
1431     } );
1432     $sth->execute($borrowernumber);
1433     my $data = $sth->fetchrow_hashref;
1434     return $data->{'primaryemail'} || '';
1435 }
1436
1437 =head2 GetExpiryDate 
1438
1439   $expirydate = GetExpiryDate($categorycode, $dateenrolled);
1440
1441 Calculate expiry date given a categorycode and starting date.  Date argument must be in ISO format.
1442 Return date is also in ISO format.
1443
1444 =cut
1445
1446 sub GetExpiryDate {
1447     my ( $categorycode, $dateenrolled ) = @_;
1448     my $enrolments;
1449     if ($categorycode) {
1450         my $dbh = C4::Context->dbh;
1451         my $sth = $dbh->prepare("SELECT enrolmentperiod,enrolmentperioddate FROM categories WHERE categorycode=?");
1452         $sth->execute($categorycode);
1453         $enrolments = $sth->fetchrow_hashref;
1454     }
1455     # die "GetExpiryDate: for enrollmentperiod $enrolmentperiod (category '$categorycode') starting $dateenrolled.\n";
1456     my @date = split (/-/,$dateenrolled);
1457     if($enrolments->{enrolmentperiod}){
1458         return sprintf("%04d-%02d-%02d", Add_Delta_YM(@date,0,$enrolments->{enrolmentperiod}));
1459     }else{
1460         return $enrolments->{enrolmentperioddate};
1461     }
1462 }
1463
1464 =head2 GetUpcomingMembershipExpires
1465
1466   my $upcoming_mem_expires = GetUpcomingMembershipExpires();
1467
1468 =cut
1469
1470 sub GetUpcomingMembershipExpires {
1471     my $dbh = C4::Context->dbh;
1472     my $days = C4::Context->preference("MembershipExpiryDaysNotice") || 0;
1473     my $dateexpiry = output_pref({ dt => (dt_from_string()->add( days => $days)), dateformat => 'iso', dateonly => 1 });
1474
1475     my $query = "
1476         SELECT borrowers.*, categories.description,
1477         branches.branchname, branches.branchemail FROM borrowers
1478         LEFT JOIN branches on borrowers.branchcode = branches.branchcode
1479         LEFT JOIN categories on borrowers.categorycode = categories.categorycode
1480         WHERE dateexpiry = ?;
1481     ";
1482     my $sth = $dbh->prepare($query);
1483     $sth->execute($dateexpiry);
1484     my $results = $sth->fetchall_arrayref({});
1485     return $results;
1486 }
1487
1488 =head2 GetborCatFromCatType
1489
1490   ($codes_arrayref, $labels_hashref) = &GetborCatFromCatType();
1491
1492 Looks up the different types of borrowers in the database. Returns two
1493 elements: a reference-to-array, which lists the borrower category
1494 codes, and a reference-to-hash, which maps the borrower category codes
1495 to category descriptions.
1496
1497 =cut
1498
1499 #'
1500 sub GetborCatFromCatType {
1501     my ( $category_type, $action, $no_branch_limit ) = @_;
1502
1503     my $branch_limit = $no_branch_limit
1504         ? 0
1505         : C4::Context->userenv ? C4::Context->userenv->{"branch"} : "";
1506
1507     # FIXME - This API  seems both limited and dangerous.
1508     my $dbh     = C4::Context->dbh;
1509
1510     my $request = qq{
1511         SELECT categories.categorycode, categories.description
1512         FROM categories
1513     };
1514     $request .= qq{
1515         LEFT JOIN categories_branches ON categories.categorycode = categories_branches.categorycode
1516     } if $branch_limit;
1517     if($action) {
1518         $request .= " $action ";
1519         $request .= " AND (branchcode = ? OR branchcode IS NULL) GROUP BY description" if $branch_limit;
1520     } else {
1521         $request .= " WHERE branchcode = ? OR branchcode IS NULL GROUP BY description" if $branch_limit;
1522     }
1523     $request .= " ORDER BY categorycode";
1524
1525     my $sth = $dbh->prepare($request);
1526     $sth->execute(
1527         $action ? $category_type : (),
1528         $branch_limit ? $branch_limit : ()
1529     );
1530
1531     my %labels;
1532     my @codes;
1533
1534     while ( my $data = $sth->fetchrow_hashref ) {
1535         push @codes, $data->{'categorycode'};
1536         $labels{ $data->{'categorycode'} } = $data->{'description'};
1537     }
1538     $sth->finish;
1539     return ( \@codes, \%labels );
1540 }
1541
1542 =head2 GetBorrowercategory
1543
1544   $hashref = &GetBorrowercategory($categorycode);
1545
1546 Given the borrower's category code, the function returns the corresponding
1547 data hashref for a comprehensive information display.
1548
1549 =cut
1550
1551 sub GetBorrowercategory {
1552     my ($catcode) = @_;
1553     my $dbh       = C4::Context->dbh;
1554     if ($catcode){
1555         my $sth       =
1556         $dbh->prepare(
1557     "SELECT description,dateofbirthrequired,upperagelimit,category_type 
1558     FROM categories 
1559     WHERE categorycode = ?"
1560         );
1561         $sth->execute($catcode);
1562         my $data =
1563         $sth->fetchrow_hashref;
1564         return $data;
1565     } 
1566     return;  
1567 }    # sub getborrowercategory
1568
1569
1570 =head2 GetBorrowerCategorycode
1571
1572     $categorycode = &GetBorrowerCategoryCode( $borrowernumber );
1573
1574 Given the borrowernumber, the function returns the corresponding categorycode
1575
1576 =cut
1577
1578 sub GetBorrowerCategorycode {
1579     my ( $borrowernumber ) = @_;
1580     my $dbh = C4::Context->dbh;
1581     my $sth = $dbh->prepare( qq{
1582         SELECT categorycode
1583         FROM borrowers
1584         WHERE borrowernumber = ?
1585     } );
1586     $sth->execute( $borrowernumber );
1587     return $sth->fetchrow;
1588 }
1589
1590 =head2 GetBorrowercategoryList
1591
1592   $arrayref_hashref = &GetBorrowercategoryList;
1593 If no category code provided, the function returns all the categories.
1594
1595 =cut
1596
1597 sub GetBorrowercategoryList {
1598     my $no_branch_limit = @_ ? shift : 0;
1599     my $branch_limit = $no_branch_limit
1600         ? 0
1601         : C4::Context->userenv ? C4::Context->userenv->{"branch"} : "";
1602     my $dbh       = C4::Context->dbh;
1603     my $query = "SELECT categories.* FROM categories";
1604     $query .= qq{
1605         LEFT JOIN categories_branches ON categories.categorycode = categories_branches.categorycode
1606         WHERE branchcode = ? OR branchcode IS NULL GROUP BY description
1607     } if $branch_limit;
1608     $query .= " ORDER BY description";
1609     my $sth = $dbh->prepare( $query );
1610     $sth->execute( $branch_limit ? $branch_limit : () );
1611     my $data = $sth->fetchall_arrayref( {} );
1612     $sth->finish;
1613     return $data;
1614 }    # sub getborrowercategory
1615
1616 =head2 GetAge
1617
1618   $dateofbirth,$date = &GetAge($date);
1619
1620 this function return the borrowers age with the value of dateofbirth
1621
1622 =cut
1623
1624 #'
1625 sub GetAge{
1626     my ( $date, $date_ref ) = @_;
1627
1628     if ( not defined $date_ref ) {
1629         $date_ref = sprintf( '%04d-%02d-%02d', Today() );
1630     }
1631
1632     my ( $year1, $month1, $day1 ) = split /-/, $date;
1633     my ( $year2, $month2, $day2 ) = split /-/, $date_ref;
1634
1635     my $age = $year2 - $year1;
1636     if ( $month1 . $day1 > $month2 . $day2 ) {
1637         $age--;
1638     }
1639
1640     return $age;
1641 }    # sub get_age
1642
1643 =head2 SetAge
1644
1645   $borrower = C4::Members::SetAge($borrower, $datetimeduration);
1646   $borrower = C4::Members::SetAge($borrower, '0015-12-10');
1647   $borrower = C4::Members::SetAge($borrower, $datetimeduration, $datetime_reference);
1648
1649   eval { $borrower = C4::Members::SetAge($borrower, '015-1-10'); };
1650   if ($@) {print $@;} #Catch a bad ISO Date or kill your script!
1651
1652 This function sets the borrower's dateofbirth to match the given age.
1653 Optionally relative to the given $datetime_reference.
1654
1655 @PARAM1 koha.borrowers-object
1656 @PARAM2 DateTime::Duration-object as the desired age
1657         OR a ISO 8601 Date. (To make the API more pleasant)
1658 @PARAM3 DateTime-object as the relative date, defaults to now().
1659 RETURNS The given borrower reference @PARAM1.
1660 DIES    If there was an error with the ISO Date handling.
1661
1662 =cut
1663
1664 #'
1665 sub SetAge{
1666     my ( $borrower, $datetimeduration, $datetime_ref ) = @_;
1667     $datetime_ref = DateTime->now() unless $datetime_ref;
1668
1669     if ($datetimeduration && ref $datetimeduration ne 'DateTime::Duration') {
1670         if ($datetimeduration =~ /^(\d{4})-(\d{2})-(\d{2})/) {
1671             $datetimeduration = DateTime::Duration->new(years => $1, months => $2, days => $3);
1672         }
1673         else {
1674             die "C4::Members::SetAge($borrower, $datetimeduration), datetimeduration not a valid ISO 8601 Date!\n";
1675         }
1676     }
1677
1678     my $new_datetime_ref = $datetime_ref->clone();
1679     $new_datetime_ref->subtract_duration( $datetimeduration );
1680
1681     $borrower->{dateofbirth} = $new_datetime_ref->ymd();
1682
1683     return $borrower;
1684 }    # sub SetAge
1685
1686 =head2 GetCities
1687
1688   $cityarrayref = GetCities();
1689
1690   Returns an array_ref of the entries in the cities table
1691   If there are entries in the table an empty row is returned
1692   This is currently only used to populate a popup in memberentry
1693
1694 =cut
1695
1696 sub GetCities {
1697
1698     my $dbh   = C4::Context->dbh;
1699     my $city_arr = $dbh->selectall_arrayref(
1700         q|SELECT cityid,city_zipcode,city_name,city_state,city_country FROM cities ORDER BY city_name|,
1701         { Slice => {} });
1702     if ( @{$city_arr} ) {
1703         unshift @{$city_arr}, {
1704             city_zipcode => q{},
1705             city_name    => q{},
1706             cityid       => q{},
1707             city_state   => q{},
1708             city_country => q{},
1709         };
1710     }
1711
1712     return  $city_arr;
1713 }
1714
1715 =head2 GetSortDetails (OUEST-PROVENCE)
1716
1717   ($lib) = &GetSortDetails($category,$sortvalue);
1718
1719 Returns the authorized value  details
1720 C<&$lib>return value of authorized value details
1721 C<&$sortvalue>this is the value of authorized value 
1722 C<&$category>this is the value of authorized value category
1723
1724 =cut
1725
1726 sub GetSortDetails {
1727     my ( $category, $sortvalue ) = @_;
1728     my $dbh   = C4::Context->dbh;
1729     my $query = qq|SELECT lib 
1730         FROM authorised_values 
1731         WHERE category=?
1732         AND authorised_value=? |;
1733     my $sth = $dbh->prepare($query);
1734     $sth->execute( $category, $sortvalue );
1735     my $lib = $sth->fetchrow;
1736     return ($lib) if ($lib);
1737     return ($sortvalue) unless ($lib);
1738 }
1739
1740 =head2 MoveMemberToDeleted
1741
1742   $result = &MoveMemberToDeleted($borrowernumber);
1743
1744 Copy the record from borrowers to deletedborrowers table.
1745 The routine returns 1 for success, undef for failure.
1746
1747 =cut
1748
1749 sub MoveMemberToDeleted {
1750     my ($member) = shift or return;
1751
1752     my $schema       = Koha::Database->new()->schema();
1753     my $borrowers_rs = $schema->resultset('Borrower');
1754     $borrowers_rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
1755     my $borrower = $borrowers_rs->find($member);
1756     return unless $borrower;
1757
1758     my $deleted = $schema->resultset('Deletedborrower')->create($borrower);
1759
1760     return $deleted ? 1 : undef;
1761 }
1762
1763 =head2 DelMember
1764
1765     DelMember($borrowernumber);
1766
1767 This function remove directly a borrower whitout writing it on deleteborrower.
1768 + Deletes reserves for the borrower
1769
1770 =cut
1771
1772 sub DelMember {
1773     my $dbh            = C4::Context->dbh;
1774     my $borrowernumber = shift;
1775     #warn "in delmember with $borrowernumber";
1776     return unless $borrowernumber;    # borrowernumber is mandatory.
1777
1778     my $query = qq|DELETE 
1779           FROM  reserves 
1780           WHERE borrowernumber=?|;
1781     my $sth = $dbh->prepare($query);
1782     $sth->execute($borrowernumber);
1783     $query = "
1784        DELETE
1785        FROM borrowers
1786        WHERE borrowernumber = ?
1787    ";
1788     $sth = $dbh->prepare($query);
1789     $sth->execute($borrowernumber);
1790     logaction("MEMBERS", "DELETE", $borrowernumber, "") if C4::Context->preference("BorrowersLog");
1791     return $sth->rows;
1792 }
1793
1794 =head2 HandleDelBorrower
1795
1796      HandleDelBorrower($borrower);
1797
1798 When a member is deleted (DelMember in Members.pm), you should call me first.
1799 This routine deletes/moves lists and entries for the deleted member/borrower.
1800 Lists owned by the borrower are deleted, but entries from the borrower to
1801 other lists are kept.
1802
1803 =cut
1804
1805 sub HandleDelBorrower {
1806     my ($borrower)= @_;
1807     my $query;
1808     my $dbh = C4::Context->dbh;
1809
1810     #Delete all lists and all shares of this borrower
1811     #Consistent with the approach Koha uses on deleting individual lists
1812     #Note that entries in virtualshelfcontents added by this borrower to
1813     #lists of others will be handled by a table constraint: the borrower
1814     #is set to NULL in those entries.
1815     $query="DELETE FROM virtualshelves WHERE owner=?";
1816     $dbh->do($query,undef,($borrower));
1817
1818     #NOTE:
1819     #We could handle the above deletes via a constraint too.
1820     #But a new BZ report 11889 has been opened to discuss another approach.
1821     #Instead of deleting we could also disown lists (based on a pref).
1822     #In that way we could save shared and public lists.
1823     #The current table constraints support that idea now.
1824     #This pref should then govern the results of other routines/methods such as
1825     #Koha::Virtualshelf->new->delete too.
1826 }
1827
1828 =head2 ExtendMemberSubscriptionTo (OUEST-PROVENCE)
1829
1830     $date = ExtendMemberSubscriptionTo($borrowerid, $date);
1831
1832 Extending the subscription to a given date or to the expiry date calculated on ISO date.
1833 Returns ISO date.
1834
1835 =cut
1836
1837 sub ExtendMemberSubscriptionTo {
1838     my ( $borrowerid,$date) = @_;
1839     my $dbh = C4::Context->dbh;
1840     my $borrower = GetMember('borrowernumber'=>$borrowerid);
1841     unless ($date){
1842       $date = (C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry') ?
1843                                         eval { output_pref( { dt => dt_from_string( $borrower->{'dateexpiry'}  ), dateonly => 1, dateformat => 'iso' } ); }
1844                                         :
1845                                         output_pref( { dt => dt_from_string, dateonly => 1, dateformat => 'iso' } );
1846       $date = GetExpiryDate( $borrower->{'categorycode'}, $date );
1847     }
1848     my $sth = $dbh->do(<<EOF);
1849 UPDATE borrowers 
1850 SET  dateexpiry='$date' 
1851 WHERE borrowernumber='$borrowerid'
1852 EOF
1853
1854     AddEnrolmentFeeIfNeeded( $borrower->{categorycode}, $borrower->{borrowernumber} );
1855
1856     logaction("MEMBERS", "RENEW", $borrower->{'borrowernumber'}, "Membership renewed")if C4::Context->preference("BorrowersLog");
1857     return $date if ($sth);
1858     return 0;
1859 }
1860
1861 =head2 GetTitles (OUEST-PROVENCE)
1862
1863   ($borrowertitle)= &GetTitles();
1864
1865 Looks up the different title . Returns array  with all borrowers title
1866
1867 =cut
1868
1869 sub GetTitles {
1870     my @borrowerTitle = split (/,|\|/,C4::Context->preference('BorrowersTitles'));
1871     unshift( @borrowerTitle, "" );
1872     my $count=@borrowerTitle;
1873     if ($count == 1){
1874         return ();
1875     }
1876     else {
1877         return ( \@borrowerTitle);
1878     }
1879 }
1880
1881 =head2 GetPatronImage
1882
1883     my ($imagedata, $dberror) = GetPatronImage($borrowernumber);
1884
1885 Returns the mimetype and binary image data of the image for the patron with the supplied borrowernumber.
1886
1887 =cut
1888
1889 sub GetPatronImage {
1890     my ($borrowernumber) = @_;
1891     warn "Borrowernumber passed to GetPatronImage is $borrowernumber" if $debug;
1892     my $dbh = C4::Context->dbh;
1893     my $query = 'SELECT mimetype, imagefile FROM patronimage WHERE borrowernumber = ?';
1894     my $sth = $dbh->prepare($query);
1895     $sth->execute($borrowernumber);
1896     my $imagedata = $sth->fetchrow_hashref;
1897     warn "Database error!" if $sth->errstr;
1898     return $imagedata, $sth->errstr;
1899 }
1900
1901 =head2 PutPatronImage
1902
1903     PutPatronImage($cardnumber, $mimetype, $imgfile);
1904
1905 Stores patron binary image data and mimetype in database.
1906 NOTE: This function is good for updating images as well as inserting new images in the database.
1907
1908 =cut
1909
1910 sub PutPatronImage {
1911     my ($cardnumber, $mimetype, $imgfile) = @_;
1912     warn "Parameters passed in: Cardnumber=$cardnumber, Mimetype=$mimetype, " . ($imgfile ? "Imagefile" : "No Imagefile") if $debug;
1913     my $dbh = C4::Context->dbh;
1914     my $query = "INSERT INTO patronimage (borrowernumber, mimetype, imagefile) VALUES ( ( SELECT borrowernumber from borrowers WHERE cardnumber = ? ),?,?) ON DUPLICATE KEY UPDATE imagefile = ?;";
1915     my $sth = $dbh->prepare($query);
1916     $sth->execute($cardnumber,$mimetype,$imgfile,$imgfile);
1917     warn "Error returned inserting $cardnumber.$mimetype." if $sth->errstr;
1918     return $sth->errstr;
1919 }
1920
1921 =head2 RmPatronImage
1922
1923     my ($dberror) = RmPatronImage($borrowernumber);
1924
1925 Removes the image for the patron with the supplied borrowernumber.
1926
1927 =cut
1928
1929 sub RmPatronImage {
1930     my ($borrowernumber) = @_;
1931     warn "Borrowernumber passed to GetPatronImage is $borrowernumber" if $debug;
1932     my $dbh = C4::Context->dbh;
1933     my $query = "DELETE FROM patronimage WHERE borrowernumber = ?;";
1934     my $sth = $dbh->prepare($query);
1935     $sth->execute($borrowernumber);
1936     my $dberror = $sth->errstr;
1937     warn "Database error!" if $sth->errstr;
1938     return $dberror;
1939 }
1940
1941 =head2 GetHideLostItemsPreference
1942
1943   $hidelostitemspref = &GetHideLostItemsPreference($borrowernumber);
1944
1945 Returns the HideLostItems preference for the patron category of the supplied borrowernumber
1946 C<&$hidelostitemspref>return value of function, 0 or 1
1947
1948 =cut
1949
1950 sub GetHideLostItemsPreference {
1951     my ($borrowernumber) = @_;
1952     my $dbh = C4::Context->dbh;
1953     my $query = "SELECT hidelostitems FROM borrowers,categories WHERE borrowers.categorycode = categories.categorycode AND borrowernumber = ?";
1954     my $sth = $dbh->prepare($query);
1955     $sth->execute($borrowernumber);
1956     my $hidelostitems = $sth->fetchrow;    
1957     return $hidelostitems;    
1958 }
1959
1960 =head2 GetBorrowersToExpunge
1961
1962   $borrowers = &GetBorrowersToExpunge(
1963       not_borrowered_since => $not_borrowered_since,
1964       expired_before       => $expired_before,
1965       category_code        => $category_code,
1966       branchcode           => $branchcode
1967   );
1968
1969   This function get all borrowers based on the given criteria.
1970
1971 =cut
1972
1973 sub GetBorrowersToExpunge {
1974     my $params = shift;
1975
1976     my $filterdate     = $params->{'not_borrowered_since'};
1977     my $filterexpiry   = $params->{'expired_before'};
1978     my $filtercategory = $params->{'category_code'};
1979     my $filterbranch   = $params->{'branchcode'} ||
1980                         ((C4::Context->preference('IndependentBranches')
1981                              && C4::Context->userenv 
1982                              && !C4::Context->IsSuperLibrarian()
1983                              && C4::Context->userenv->{branch})
1984                          ? C4::Context->userenv->{branch}
1985                          : "");  
1986
1987     my $dbh   = C4::Context->dbh;
1988     my $query = q|
1989         SELECT borrowers.borrowernumber,
1990                MAX(old_issues.timestamp) AS latestissue,
1991                MAX(issues.timestamp) AS currentissue
1992         FROM   borrowers
1993         JOIN   categories USING (categorycode)
1994         LEFT JOIN (
1995             SELECT guarantorid
1996             FROM borrowers
1997             WHERE guarantorid IS NOT NULL
1998                 AND guarantorid <> 0
1999         ) as tmp ON borrowers.borrowernumber=tmp.guarantorid
2000         LEFT JOIN old_issues USING (borrowernumber)
2001         LEFT JOIN issues USING (borrowernumber) 
2002         WHERE  category_type <> 'S'
2003         AND tmp.guarantorid IS NULL
2004    |;
2005
2006     my @query_params;
2007     if ( $filterbranch && $filterbranch ne "" ) {
2008         $query.= " AND borrowers.branchcode = ? ";
2009         push( @query_params, $filterbranch );
2010     }
2011     if ( $filterexpiry ) {
2012         $query .= " AND dateexpiry < ? ";
2013         push( @query_params, $filterexpiry );
2014     }
2015     if ( $filtercategory ) {
2016         $query .= " AND categorycode = ? ";
2017         push( @query_params, $filtercategory );
2018     }
2019     $query.=" GROUP BY borrowers.borrowernumber HAVING currentissue IS NULL ";
2020     if ( $filterdate ) {
2021         $query.=" AND ( latestissue < ? OR latestissue IS NULL ) ";
2022         push @query_params,$filterdate;
2023     }
2024     warn $query if $debug;
2025
2026     my $sth = $dbh->prepare($query);
2027     if (scalar(@query_params)>0){  
2028         $sth->execute(@query_params);
2029     } 
2030     else {
2031         $sth->execute;
2032     }      
2033     
2034     my @results;
2035     while ( my $data = $sth->fetchrow_hashref ) {
2036         push @results, $data;
2037     }
2038     return \@results;
2039 }
2040
2041 =head2 GetBorrowersWhoHaveNeverBorrowed
2042
2043   $results = &GetBorrowersWhoHaveNeverBorrowed
2044
2045 This function get all borrowers who have never borrowed.
2046
2047 I<$result> is a ref to an array which all elements are a hasref.
2048
2049 =cut
2050
2051 sub GetBorrowersWhoHaveNeverBorrowed {
2052     my $filterbranch = shift || 
2053                         ((C4::Context->preference('IndependentBranches')
2054                              && C4::Context->userenv 
2055                              && !C4::Context->IsSuperLibrarian()
2056                              && C4::Context->userenv->{branch})
2057                          ? C4::Context->userenv->{branch}
2058                          : "");  
2059     my $dbh   = C4::Context->dbh;
2060     my $query = "
2061         SELECT borrowers.borrowernumber,max(timestamp) as latestissue
2062         FROM   borrowers
2063           LEFT JOIN issues ON borrowers.borrowernumber = issues.borrowernumber
2064         WHERE issues.borrowernumber IS NULL
2065    ";
2066     my @query_params;
2067     if ($filterbranch && $filterbranch ne ""){ 
2068         $query.=" AND borrowers.branchcode= ?";
2069         push @query_params,$filterbranch;
2070     }
2071     warn $query if $debug;
2072   
2073     my $sth = $dbh->prepare($query);
2074     if (scalar(@query_params)>0){  
2075         $sth->execute(@query_params);
2076     } 
2077     else {
2078         $sth->execute;
2079     }      
2080     
2081     my @results;
2082     while ( my $data = $sth->fetchrow_hashref ) {
2083         push @results, $data;
2084     }
2085     return \@results;
2086 }
2087
2088 =head2 GetBorrowersWithIssuesHistoryOlderThan
2089
2090   $results = &GetBorrowersWithIssuesHistoryOlderThan($date)
2091
2092 this function get all borrowers who has an issue history older than I<$date> given on input arg.
2093
2094 I<$result> is a ref to an array which all elements are a hashref.
2095 This hashref is containt the number of time this borrowers has borrowed before I<$date> and the borrowernumber.
2096
2097 =cut
2098
2099 sub GetBorrowersWithIssuesHistoryOlderThan {
2100     my $dbh  = C4::Context->dbh;
2101     my $date = shift ||POSIX::strftime("%Y-%m-%d",localtime());
2102     my $filterbranch = shift || 
2103                         ((C4::Context->preference('IndependentBranches')
2104                              && C4::Context->userenv 
2105                              && !C4::Context->IsSuperLibrarian()
2106                              && C4::Context->userenv->{branch})
2107                          ? C4::Context->userenv->{branch}
2108                          : "");  
2109     my $query = "
2110        SELECT count(borrowernumber) as n,borrowernumber
2111        FROM old_issues
2112        WHERE returndate < ?
2113          AND borrowernumber IS NOT NULL 
2114     "; 
2115     my @query_params;
2116     push @query_params, $date;
2117     if ($filterbranch){
2118         $query.="   AND branchcode = ?";
2119         push @query_params, $filterbranch;
2120     }    
2121     $query.=" GROUP BY borrowernumber ";
2122     warn $query if $debug;
2123     my $sth = $dbh->prepare($query);
2124     $sth->execute(@query_params);
2125     my @results;
2126
2127     while ( my $data = $sth->fetchrow_hashref ) {
2128         push @results, $data;
2129     }
2130     return \@results;
2131 }
2132
2133 =head2 GetBorrowersNamesAndLatestIssue
2134
2135   $results = &GetBorrowersNamesAndLatestIssueList(@borrowernumbers)
2136
2137 this function get borrowers Names and surnames and Issue information.
2138
2139 I<@borrowernumbers> is an array which all elements are borrowernumbers.
2140 This hashref is containt the number of time this borrowers has borrowed before I<$date> and the borrowernumber.
2141
2142 =cut
2143
2144 sub GetBorrowersNamesAndLatestIssue {
2145     my $dbh  = C4::Context->dbh;
2146     my @borrowernumbers=@_;  
2147     my $query = "
2148        SELECT surname,lastname, phone, email,max(timestamp)
2149        FROM borrowers 
2150          LEFT JOIN issues ON borrowers.borrowernumber=issues.borrowernumber
2151        GROUP BY borrowernumber
2152    ";
2153     my $sth = $dbh->prepare($query);
2154     $sth->execute;
2155     my $results = $sth->fetchall_arrayref({});
2156     return $results;
2157 }
2158
2159 =head2 ModPrivacy
2160
2161   my $success = ModPrivacy( $borrowernumber, $privacy );
2162
2163 Update the privacy of a patron.
2164
2165 return :
2166 true on success, false on failure
2167
2168 =cut
2169
2170 sub ModPrivacy {
2171     my $borrowernumber = shift;
2172     my $privacy = shift;
2173     return unless defined $borrowernumber;
2174     return unless $borrowernumber =~ /^\d+$/;
2175
2176     return ModMember( borrowernumber => $borrowernumber,
2177                       privacy        => $privacy );
2178 }
2179
2180 =head2 AddMessage
2181
2182   AddMessage( $borrowernumber, $message_type, $message, $branchcode );
2183
2184 Adds a message to the messages table for the given borrower.
2185
2186 Returns:
2187   True on success
2188   False on failure
2189
2190 =cut
2191
2192 sub AddMessage {
2193     my ( $borrowernumber, $message_type, $message, $branchcode ) = @_;
2194
2195     my $dbh  = C4::Context->dbh;
2196
2197     if ( ! ( $borrowernumber && $message_type && $message && $branchcode ) ) {
2198       return;
2199     }
2200
2201     my $query = "INSERT INTO messages ( borrowernumber, branchcode, message_type, message ) VALUES ( ?, ?, ?, ? )";
2202     my $sth = $dbh->prepare($query);
2203     $sth->execute( $borrowernumber, $branchcode, $message_type, $message );
2204     logaction("MEMBERS", "ADDCIRCMESSAGE", $borrowernumber, $message) if C4::Context->preference("BorrowersLog");
2205     return 1;
2206 }
2207
2208 =head2 GetMessages
2209
2210   GetMessages( $borrowernumber, $type );
2211
2212 $type is message type, B for borrower, or L for Librarian.
2213 Empty type returns all messages of any type.
2214
2215 Returns all messages for the given borrowernumber
2216
2217 =cut
2218
2219 sub GetMessages {
2220     my ( $borrowernumber, $type, $branchcode ) = @_;
2221
2222     if ( ! $type ) {
2223       $type = '%';
2224     }
2225
2226     my $dbh  = C4::Context->dbh;
2227
2228     my $query = "SELECT
2229                   branches.branchname,
2230                   messages.*,
2231                   message_date,
2232                   messages.branchcode LIKE '$branchcode' AS can_delete
2233                   FROM messages, branches
2234                   WHERE borrowernumber = ?
2235                   AND message_type LIKE ?
2236                   AND messages.branchcode = branches.branchcode
2237                   ORDER BY message_date DESC";
2238     my $sth = $dbh->prepare($query);
2239     $sth->execute( $borrowernumber, $type ) ;
2240     my @results;
2241
2242     while ( my $data = $sth->fetchrow_hashref ) {
2243         $data->{message_date_formatted} = output_pref( { dt => dt_from_string( $data->{message_date} ), dateonly => 1, dateformat => 'iso' } );
2244         push @results, $data;
2245     }
2246     return \@results;
2247
2248 }
2249
2250 =head2 GetMessages
2251
2252   GetMessagesCount( $borrowernumber, $type );
2253
2254 $type is message type, B for borrower, or L for Librarian.
2255 Empty type returns all messages of any type.
2256
2257 Returns the number of messages for the given borrowernumber
2258
2259 =cut
2260
2261 sub GetMessagesCount {
2262     my ( $borrowernumber, $type, $branchcode ) = @_;
2263
2264     if ( ! $type ) {
2265       $type = '%';
2266     }
2267
2268     my $dbh  = C4::Context->dbh;
2269
2270     my $query = "SELECT COUNT(*) as MsgCount FROM messages WHERE borrowernumber = ? AND message_type LIKE ?";
2271     my $sth = $dbh->prepare($query);
2272     $sth->execute( $borrowernumber, $type ) ;
2273     my @results;
2274
2275     my $data = $sth->fetchrow_hashref;
2276     my $count = $data->{'MsgCount'};
2277
2278     return $count;
2279 }
2280
2281
2282
2283 =head2 DeleteMessage
2284
2285   DeleteMessage( $message_id );
2286
2287 =cut
2288
2289 sub DeleteMessage {
2290     my ( $message_id ) = @_;
2291
2292     my $dbh = C4::Context->dbh;
2293     my $query = "SELECT * FROM messages WHERE message_id = ?";
2294     my $sth = $dbh->prepare($query);
2295     $sth->execute( $message_id );
2296     my $message = $sth->fetchrow_hashref();
2297
2298     $query = "DELETE FROM messages WHERE message_id = ?";
2299     $sth = $dbh->prepare($query);
2300     $sth->execute( $message_id );
2301     logaction("MEMBERS", "DELCIRCMESSAGE", $message->{'borrowernumber'}, $message->{'message'}) if C4::Context->preference("BorrowersLog");
2302 }
2303
2304 =head2 IssueSlip
2305
2306   IssueSlip($branchcode, $borrowernumber, $quickslip)
2307
2308   Returns letter hash ( see C4::Letters::GetPreparedLetter )
2309
2310   $quickslip is boolean, to indicate whether we want a quick slip
2311
2312   IssueSlip populates ISSUESLIP and ISSUEQSLIP, and will make the following expansions:
2313
2314   Both slips:
2315
2316       <<branches.*>>
2317       <<borrowers.*>>
2318
2319   ISSUESLIP:
2320
2321       <checkedout>
2322          <<biblio.*>>
2323          <<items.*>>
2324          <<biblioitems.*>>
2325          <<issues.*>>
2326       </checkedout>
2327
2328       <overdue>
2329          <<biblio.*>>
2330          <<items.*>>
2331          <<biblioitems.*>>
2332          <<issues.*>>
2333       </overdue>
2334
2335       <news>
2336          <<opac_news.*>>
2337       </news>
2338
2339   ISSUEQSLIP:
2340
2341       <checkedout>
2342          <<biblio.*>>
2343          <<items.*>>
2344          <<biblioitems.*>>
2345          <<issues.*>>
2346       </checkedout>
2347
2348   NOTE: Not all table fields are available, pleasee see GetPendingIssues for a list of available fields.
2349
2350 =cut
2351
2352 sub IssueSlip {
2353     my ($branch, $borrowernumber, $quickslip) = @_;
2354
2355     # FIXME Check callers before removing this statement
2356     #return unless $borrowernumber;
2357
2358     my @issues = @{ GetPendingIssues($borrowernumber) };
2359
2360     for my $issue (@issues) {
2361         $issue->{date_due} = $issue->{date_due_sql};
2362         if ($quickslip) {
2363             my $today = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
2364             if ( substr( $issue->{issuedate}, 0, 10 ) eq $today
2365                 or substr( $issue->{lastreneweddate}, 0, 10 ) eq $today ) {
2366                   $issue->{now} = 1;
2367             };
2368         }
2369     }
2370
2371     # Sort on timestamp then on issuedate (useful for tests and could be if modified in a batch
2372     @issues = sort {
2373         my $s = $b->{timestamp} <=> $a->{timestamp};
2374         $s == 0 ?
2375              $b->{issuedate} <=> $a->{issuedate} : $s;
2376     } @issues;
2377
2378     my ($letter_code, %repeat);
2379     if ( $quickslip ) {
2380         $letter_code = 'ISSUEQSLIP';
2381         %repeat =  (
2382             'checkedout' => [ map {
2383                 'biblio'       => $_,
2384                 'items'        => $_,
2385                 'biblioitems'  => $_,
2386                 'issues'       => $_,
2387             }, grep { $_->{'now'} } @issues ],
2388         );
2389     }
2390     else {
2391         $letter_code = 'ISSUESLIP';
2392         %repeat =  (
2393             'checkedout' => [ map {
2394                 'biblio'       => $_,
2395                 'items'        => $_,
2396                 'biblioitems'  => $_,
2397                 'issues'       => $_,
2398             }, grep { !$_->{'overdue'} } @issues ],
2399
2400             'overdue' => [ map {
2401                 'biblio'       => $_,
2402                 'items'        => $_,
2403                 'biblioitems'  => $_,
2404                 'issues'       => $_,
2405             }, grep { $_->{'overdue'} } @issues ],
2406
2407             'news' => [ map {
2408                 $_->{'timestamp'} = $_->{'newdate'};
2409                 { opac_news => $_ }
2410             } @{ GetNewsToDisplay("slip",$branch) } ],
2411         );
2412     }
2413
2414     return  C4::Letters::GetPreparedLetter (
2415         module => 'circulation',
2416         letter_code => $letter_code,
2417         branchcode => $branch,
2418         tables => {
2419             'branches'    => $branch,
2420             'borrowers'   => $borrowernumber,
2421         },
2422         repeat => \%repeat,
2423     );
2424 }
2425
2426 =head2 GetBorrowersWithEmail
2427
2428     ([$borrnum,$userid], ...) = GetBorrowersWithEmail('me@example.com');
2429
2430 This gets a list of users and their basic details from their email address.
2431 As it's possible for multiple user to have the same email address, it provides
2432 you with all of them. If there is no userid for the user, there will be an
2433 C<undef> there. An empty list will be returned if there are no matches.
2434
2435 =cut
2436
2437 sub GetBorrowersWithEmail {
2438     my $email = shift;
2439
2440     my $dbh = C4::Context->dbh;
2441
2442     my $query = "SELECT borrowernumber, userid FROM borrowers WHERE email=?";
2443     my $sth=$dbh->prepare($query);
2444     $sth->execute($email);
2445     my @result = ();
2446     while (my $ref = $sth->fetch) {
2447         push @result, $ref;
2448     }
2449     die "Failure searching for borrowers by email address: $sth->errstr" if $sth->err;
2450     return @result;
2451 }
2452
2453 =head2 AddMember_Opac
2454
2455 =cut
2456
2457 sub AddMember_Opac {
2458     my ( %borrower ) = @_;
2459
2460     $borrower{'categorycode'} = C4::Context->preference('PatronSelfRegistrationDefaultCategory');
2461
2462     my $sr = new String::Random;
2463     $sr->{'A'} = [ 'A'..'Z', 'a'..'z' ];
2464     my $password = $sr->randpattern("AAAAAAAAAA");
2465     $borrower{'password'} = $password;
2466
2467     $borrower{'cardnumber'} = fixup_cardnumber();
2468
2469     my $borrowernumber = AddMember(%borrower);
2470
2471     return ( $borrowernumber, $password );
2472 }
2473
2474 =head2 AddEnrolmentFeeIfNeeded
2475
2476     AddEnrolmentFeeIfNeeded( $borrower->{categorycode}, $borrower->{borrowernumber} );
2477
2478 Add enrolment fee for a patron if needed.
2479
2480 =cut
2481
2482 sub AddEnrolmentFeeIfNeeded {
2483     my ( $categorycode, $borrowernumber ) = @_;
2484     # check for enrollment fee & add it if needed
2485     my $dbh = C4::Context->dbh;
2486     my $sth = $dbh->prepare(q{
2487         SELECT enrolmentfee
2488         FROM categories
2489         WHERE categorycode=?
2490     });
2491     $sth->execute( $categorycode );
2492     if ( $sth->err ) {
2493         warn sprintf('Database returned the following error: %s', $sth->errstr);
2494         return;
2495     }
2496     my ($enrolmentfee) = $sth->fetchrow;
2497     if ($enrolmentfee && $enrolmentfee > 0) {
2498         # insert fee in patron debts
2499         C4::Accounts::manualinvoice( $borrowernumber, '', '', 'A', $enrolmentfee );
2500     }
2501 }
2502
2503 =head2 HasOverdues
2504
2505 =cut
2506
2507 sub HasOverdues {
2508     my ( $borrowernumber ) = @_;
2509
2510     my $sql = "SELECT COUNT(*) FROM issues WHERE date_due < NOW() AND borrowernumber = ?";
2511     my $sth = C4::Context->dbh->prepare( $sql );
2512     $sth->execute( $borrowernumber );
2513     my ( $count ) = $sth->fetchrow_array();
2514
2515     return $count;
2516 }
2517
2518 =head2 DeleteExpiredOpacRegistrations
2519
2520     Delete accounts that haven't been upgraded from the 'temporary' category
2521     Returns the number of removed patrons
2522
2523 =cut
2524
2525 sub DeleteExpiredOpacRegistrations {
2526
2527     my $delay = C4::Context->preference('PatronSelfRegistrationExpireTemporaryAccountsDelay');
2528     my $category_code = C4::Context->preference('PatronSelfRegistrationDefaultCategory');
2529
2530     return 0 if not $category_code or not defined $delay or $delay eq q||;
2531
2532     my $query = qq|
2533 SELECT borrowernumber
2534 FROM borrowers
2535 WHERE categorycode = ? AND DATEDIFF( NOW(), dateenrolled ) > ? |;
2536
2537     my $dbh = C4::Context->dbh;
2538     my $sth = $dbh->prepare($query);
2539     $sth->execute( $category_code, $delay );
2540     my $cnt=0;
2541     while ( my ($borrowernumber) = $sth->fetchrow_array() ) {
2542         DelMember($borrowernumber);
2543         $cnt++;
2544     }
2545     return $cnt;
2546 }
2547
2548 =head2 DeleteUnverifiedOpacRegistrations
2549
2550     Delete all unverified self registrations in borrower_modifications,
2551     older than the specified number of days.
2552
2553 =cut
2554
2555 sub DeleteUnverifiedOpacRegistrations {
2556     my ( $days ) = @_;
2557     my $dbh = C4::Context->dbh;
2558     my $sql=qq|
2559 DELETE FROM borrower_modifications
2560 WHERE borrowernumber = 0 AND DATEDIFF( NOW(), timestamp ) > ?|;
2561     my $cnt=$dbh->do($sql, undef, ($days) );
2562     return $cnt eq '0E0'? 0: $cnt;
2563 }
2564
2565 sub GetOverduesForPatron {
2566     my ( $borrowernumber ) = @_;
2567
2568     my $sql = "
2569         SELECT *
2570         FROM issues, items, biblio, biblioitems
2571         WHERE items.itemnumber=issues.itemnumber
2572           AND biblio.biblionumber   = items.biblionumber
2573           AND biblio.biblionumber   = biblioitems.biblionumber
2574           AND issues.borrowernumber = ?
2575           AND date_due < NOW()
2576     ";
2577
2578     my $sth = C4::Context->dbh->prepare( $sql );
2579     $sth->execute( $borrowernumber );
2580
2581     return $sth->fetchall_arrayref({});
2582 }
2583
2584 END { }    # module clean-up code here (global destructor)
2585
2586 1;
2587
2588 __END__
2589
2590 =head1 AUTHOR
2591
2592 Koha Team
2593
2594 =cut