C4/Members/Attributes.pm

   1 package C4::Members::Attributes;
   2
   3 # Copyright (C) 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use Text::CSV;      # Don't be tempted to use Text::CSV::Unicode -- even in binary mode it fails.
  24 use C4::Context;
  25 use C4::Members::AttributeTypes;
  26
  27 use vars qw($VERSION @ISA @EXPORT_OK @EXPORT %EXPORT_TAGS);
  28 our ($csv, $AttributeTypes);
  29
  30 BEGIN {
  31     # set the version for version checking
  32     $VERSION = 3.07.00.049;
  33     @ISA = qw(Exporter);
  34     @EXPORT_OK = qw(GetBorrowerAttributes GetBorrowerAttributeValue CheckUniqueness SetBorrowerAttributes
  35                     DeleteBorrowerAttribute UpdateBorrowerAttribute
  36                     extended_attributes_code_value_arrayref extended_attributes_merge
  37                     SearchIdMatchingAttribute);
  38     %EXPORT_TAGS = ( all => \@EXPORT_OK );
  39 }
  40
  41 =head1 NAME
  42
  43 C4::Members::Attributes - manage extend patron attributes
  44
  45 =head1 SYNOPSIS
  46
  47   use C4::Members::Attributes;
  48   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
  49
  50 =head1 FUNCTIONS
  51
  52 =head2 GetBorrowerAttributes
  53
  54   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber[, $opac_only]);
  55
  56 Retrieve an arrayref of extended attributes associated with the
  57 patron specified by C<$borrowernumber>.  Each entry in the arrayref
  58 is a hashref containing the following keys:
  59
  60 code (attribute type code)
  61 description (attribute type description)
  62 value (attribute value)
  63 value_description (attribute value description (if associated with an authorised value))
  64 password (password, if any, associated with attribute
  65
  66 If the C<$opac_only> parameter is present and has a true value, only the attributes
  67 marked for OPAC display are returned.
  68
  69 =cut
  70
  71 sub GetBorrowerAttributes {
  72     my $borrowernumber = shift;
  73     my $opac_only = @_ ? shift : 0;
  74
  75     my $dbh = C4::Context->dbh();
  76     my $query = "SELECT code, description, attribute, lib, password, display_checkout, category_code, class
  77                  FROM borrower_attributes
  78                  JOIN borrower_attribute_types USING (code)
  79                  LEFT JOIN authorised_values ON (category = authorised_value_category AND attribute = authorised_value)
  80                  WHERE borrowernumber = ?";
  81     $query .= "\nAND opac_display = 1" if $opac_only;
  82     $query .= "\nORDER BY code, attribute";
  83     my $sth = $dbh->prepare_cached($query);
  84     $sth->execute($borrowernumber);
  85     my @results = ();
  86     while (my $row = $sth->fetchrow_hashref()) {
  87         push @results, {
  88             code              => $row->{'code'},
  89             description       => $row->{'description'},
  90             value             => $row->{'attribute'},
  91             value_description => $row->{'lib'},
  92             password          => $row->{'password'},
  93             display_checkout  => $row->{'display_checkout'},
  94             category_code     => $row->{'category_code'},
  95             class             => $row->{'class'},
  96         }
  97     }
  98     return \@results;
  99 }
 100
 101 =head2 GetAttributes
 102
 103   my $attributes = C4::Members::Attributes::GetAttributes([$opac_only]);
 104
 105 Retrieve an arrayref of extended attribute codes
 106
 107 =cut
 108
 109 sub GetAttributes {
 110     my ($opac_only) = @_;
 111
 112     my $dbh = C4::Context->dbh();
 113     my $query = "SELECT code FROM borrower_attribute_types";
 114     $query .= "\nWHERE opac_display = 1" if $opac_only;
 115     $query .= "\nORDER BY code";
 116     return $dbh->selectcol_arrayref($query);
 117 }
 118
 119 =head2 GetBorrowerAttributeValue
 120
 121   my $value = C4::Members::Attributes::GetBorrowerAttributeValue($borrowernumber, $attribute_code);
 122
 123 Retrieve the value of an extended attribute C<$attribute_code> associated with the
 124 patron specified by C<$borrowernumber>.
 125
 126 =cut
 127
 128 sub GetBorrowerAttributeValue {
 129     my $borrowernumber = shift;
 130     my $code = shift;
 131
 132     my $dbh = C4::Context->dbh();
 133     my $query = "SELECT attribute
 134                  FROM borrower_attributes
 135                  WHERE borrowernumber = ?
 136                  AND code = ?";
 137     my $value = $dbh->selectrow_array($query, undef, $borrowernumber, $code);
 138     return $value;
 139 }
 140
 141 =head2 SearchIdMatchingAttribute
 142
 143   my $matching_borrowernumbers = C4::Members::Attributes::SearchIdMatchingAttribute($filter);
 144
 145 =cut
 146
 147 sub SearchIdMatchingAttribute{
 148     my $filter = shift;
 149     $filter = [$filter] unless ref $filter;
 150
 151     my $dbh   = C4::Context->dbh();
 152     my $query = qq{
 153 SELECT DISTINCT borrowernumber
 154 FROM borrower_attributes
 155 JOIN borrower_attribute_types USING (code)
 156 WHERE staff_searchable = 1
 157 AND (} . join (" OR ", map "attribute like ?", @$filter) .qq{)};
 158     my $sth = $dbh->prepare_cached($query);
 159     $sth->execute(map "%$_%", @$filter);
 160     return [map $_->[0], @{ $sth->fetchall_arrayref }];
 161 }
 162
 163 =head2 CheckUniqueness
 164
 165   my $ok = CheckUniqueness($code, $value[, $borrowernumber]);
 166
 167 Given an attribute type and value, verify if would violate
 168 a unique_id restriction if added to the patron.  The
 169 optional C<$borrowernumber> is the patron that the attribute
 170 value would be added to, if known.
 171
 172 Returns false if the C<$code> is not valid or the
 173 value would violate the uniqueness constraint.
 174
 175 =cut
 176
 177 sub CheckUniqueness {
 178     my $code = shift;
 179     my $value = shift;
 180     my $borrowernumber = @_ ? shift : undef;
 181
 182     my $attr_type = C4::Members::AttributeTypes->fetch($code);
 183
 184     return 0 unless defined $attr_type;
 185     return 1 unless $attr_type->unique_id();
 186
 187     my $dbh = C4::Context->dbh;
 188     my $sth;
 189     if (defined($borrowernumber)) {
 190         $sth = $dbh->prepare("SELECT COUNT(*)
 191                               FROM borrower_attributes
 192                               WHERE code = ?
 193                               AND attribute = ?
 194                               AND borrowernumber <> ?");
 195         $sth->execute($code, $value, $borrowernumber);
 196     } else {
 197         $sth = $dbh->prepare("SELECT COUNT(*)
 198                               FROM borrower_attributes
 199                               WHERE code = ?
 200                               AND attribute = ?");
 201         $sth->execute($code, $value);
 202     }
 203     my ($count) = $sth->fetchrow_array;
 204     return ($count == 0);
 205 }
 206
 207 =head2 SetBorrowerAttributes
 208
 209   SetBorrowerAttributes($borrowernumber, [ { code => 'CODE', value => 'value', password => 'password' }, ... ] );
 210
 211 Set patron attributes for the patron identified by C<$borrowernumber>,
 212 replacing any that existed previously.
 213
 214 =cut
 215
 216 sub SetBorrowerAttributes {
 217     my $borrowernumber = shift;
 218     my $attr_list = shift;
 219
 220     my $dbh = C4::Context->dbh;
 221     my $delsth = $dbh->prepare("DELETE FROM borrower_attributes WHERE borrowernumber = ?");
 222     $delsth->execute($borrowernumber);
 223
 224     my $sth = $dbh->prepare("INSERT INTO borrower_attributes (borrowernumber, code, attribute, password)
 225                              VALUES (?, ?, ?, ?)");
 226     foreach my $attr (@$attr_list) {
 227         $attr->{password} = undef unless exists $attr->{password};
 228         $sth->execute($borrowernumber, $attr->{code}, $attr->{value}, $attr->{password});
 229         if ($sth->err) {
 230             warn sprintf('Database returned the following error: %s', $sth->errstr);
 231             return; # bail immediately on errors
 232         }
 233     }
 234     return 1; # borower attributes successfully set
 235 }
 236
 237 =head2 DeleteBorrowerAttribute
 238
 239   DeleteBorrowerAttribute($borrowernumber, $attribute);
 240
 241 Delete a borrower attribute for the patron identified by C<$borrowernumber> and the attribute code of C<$attribute>
 242
 243 =cut
 244 sub DeleteBorrowerAttribute {
 245     my ( $borrowernumber, $attribute ) = @_;
 246
 247     my $dbh = C4::Context->dbh;
 248     my $sth = $dbh->prepare(qq{
 249         DELETE FROM borrower_attributes
 250             WHERE borrowernumber = ?
 251             AND code = ?
 252     } );
 253     $sth->execute( $borrowernumber, $attribute->{code} );
 254 }
 255
 256 =head2 UpdateBorrowerAttribute
 257
 258   UpdateBorrowerAttribute($borrowernumber, $attribute );
 259
 260 Update a borrower attribute C<$attribute> for the patron identified by C<$borrowernumber>,
 261
 262 =cut
 263 sub UpdateBorrowerAttribute {
 264     my ( $borrowernumber, $attribute ) = @_;
 265
 266     DeleteBorrowerAttribute $borrowernumber, $attribute;
 267
 268     my $dbh = C4::Context->dbh;
 269     my $query = "INSERT INTO borrower_attributes SET attribute = ?, code = ?, borrowernumber = ?";
 270     my @params = ( $attribute->{attribute}, $attribute->{code}, $borrowernumber );
 271     if ( defined $attribute->{password} ) {
 272         $query .= ", password = ?";
 273         push @params, $attribute->{password};
 274     }
 275     my $sth = $dbh->prepare( $query );
 276
 277     $sth->execute( @params );
 278 }
 279
 280
 281 =head2 extended_attributes_code_value_arrayref
 282
 283    my $patron_attributes = "homeroom:1150605,grade:01,extradata:foobar";
 284    my $aref = extended_attributes_code_value_arrayref($patron_attributes);
 285
 286 Takes a comma-delimited CSV-style string argument and returns the kind of data structure that SetBorrowerAttributes wants,
 287 namely a reference to array of hashrefs like:
 288  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 289
 290 Caches Text::CSV parser object for efficiency.
 291
 292 =cut
 293
 294 sub extended_attributes_code_value_arrayref {
 295     my $string = shift or return;
 296     $csv or $csv = Text::CSV->new({binary => 1});  # binary needed for non-ASCII Unicode
 297     my $ok   = $csv->parse($string);  # parse field again to get subfields!
 298     my @list = $csv->fields();
 299     # TODO: error handling (check $ok)
 300     return [
 301         sort {&_sort_by_code($a,$b)}
 302         map { map { my @arr = split /:/, $_, 2; { code => $arr[0], value => $arr[1] } } $_ }
 303         @list
 304     ];
 305     # nested map because of split
 306 }
 307
 308 =head2 extended_attributes_merge
 309
 310   my $old_attributes = extended_attributes_code_value_arrayref("homeroom:224,grade:04,deanslist:2007,deanslist:2008,somedata:xxx");
 311   my $new_attributes = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2009,extradata:foobar");
 312   my $merged = extended_attributes_merge($patron_attributes, $new_attributes, 1);
 313
 314   # assuming deanslist is a repeatable code, value same as:
 315   # $merged = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2007,deanslist:2008,deanslist:2009,extradata:foobar,somedata:xxx");
 316
 317 Takes three arguments.  The first two are references to array of hashrefs, each like:
 318  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 319
 320 The third option specifies whether repeatable codes are clobbered or collected.  True for non-clobber.
 321
 322 Returns one reference to (merged) array of hashref.
 323
 324 Caches results of C4::Members::AttributeTypes::GetAttributeTypes_hashref(1) for efficiency.
 325
 326 =cut
 327
 328 sub extended_attributes_merge {
 329     my $old = shift or return;
 330     my $new = shift or return $old;
 331     my $keep = @_ ? shift : 0;
 332     $AttributeTypes or $AttributeTypes = C4::Members::AttributeTypes::GetAttributeTypes_hashref(1);
 333     my @merged = @$old;
 334     foreach my $att (@$new) {
 335         unless ($att->{code}) {
 336             warn "Cannot merge element: no 'code' defined";
 337             next;
 338         }
 339         unless ($AttributeTypes->{$att->{code}}) {
 340             warn "Cannot merge element: unrecognized code = '$att->{code}'";
 341             next;
 342         }
 343         unless ($AttributeTypes->{$att->{code}}->{repeatable} and $keep) {
 344             @merged = grep {$att->{code} ne $_->{code}} @merged;    # filter out any existing attributes of the same code
 345         }
 346         push @merged, $att;
 347     }
 348     return [( sort {&_sort_by_code($a,$b)} @merged )];
 349 }
 350
 351 sub _sort_by_code {
 352     my ($x, $y) = @_;
 353     defined ($x->{code}) or return -1;
 354     defined ($y->{code}) or return 1;
 355     return $x->{code} cmp $y->{code} || $x->{value} cmp $y->{value};
 356 }
 357
 358 =head1 AUTHOR
 359
 360 Koha Development Team <http://koha-community.org/>
 361
 362 Galen Charlton <galen.charlton@liblime.com>
 363
 364 =cut
 365
 366 1;