C4/Members/Attributes.pm

   1 package C4::Members::Attributes;
   2
   3 # Copyright (C) 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use Text::CSV;      # Don't be tempted to use Text::CSV::Unicode -- even in binary mode it fails.
  24 use C4::Context;
  25 use C4::Members::AttributeTypes;
  26
  27 use vars qw($VERSION @ISA @EXPORT_OK @EXPORT %EXPORT_TAGS);
  28 our ($csv, $AttributeTypes);
  29
  30 BEGIN {
  31     # set the version for version checking
  32     $VERSION = 3.01;
  33     @ISA = qw(Exporter);
  34     @EXPORT_OK = qw(GetBorrowerAttributes GetBorrowerAttributeValue CheckUniqueness SetBorrowerAttributes
  35                     extended_attributes_code_value_arrayref extended_attributes_merge
  36                                         SearchIdMatchingAttribute);
  37     %EXPORT_TAGS = ( all => \@EXPORT_OK );
  38 }
  39
  40 =head1 NAME
  41
  42 C4::Members::Attributes - manage extend patron attributes
  43
  44 =head1 SYNOPSIS
  45
  46   use C4::Members::Attributes;
  47   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
  48
  49 =head1 FUNCTIONS
  50
  51 =head2 GetBorrowerAttributes
  52
  53   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber[, $opac_only]);
  54
  55 Retrieve an arrayref of extended attributes associated with the
  56 patron specified by C<$borrowernumber>.  Each entry in the arrayref
  57 is a hashref containing the following keys:
  58
  59 code (attribute type code)
  60 description (attribute type description)
  61 value (attribute value)
  62 value_description (attribute value description (if associated with an authorised value))
  63 password (password, if any, associated with attribute
  64
  65 If the C<$opac_only> parameter is present and has a true value, only the attributes
  66 marked for OPAC display are returned.
  67
  68 =cut
  69
  70 sub GetBorrowerAttributes {
  71     my $borrowernumber = shift;
  72     my $opac_only = @_ ? shift : 0;
  73
  74     my $dbh = C4::Context->dbh();
  75     my $query = "SELECT code, description, attribute, lib, password, display_checkout, category_code, class
  76                  FROM borrower_attributes
  77                  JOIN borrower_attribute_types USING (code)
  78                  LEFT JOIN authorised_values ON (category = authorised_value_category AND attribute = authorised_value)
  79                  WHERE borrowernumber = ?";
  80     $query .= "\nAND opac_display = 1" if $opac_only;
  81     $query .= "\nORDER BY code, attribute";
  82     my $sth = $dbh->prepare_cached($query);
  83     $sth->execute($borrowernumber);
  84     my @results = ();
  85     while (my $row = $sth->fetchrow_hashref()) {
  86         push @results, {
  87             code              => $row->{'code'},
  88             description       => $row->{'description'},
  89             value             => $row->{'attribute'},
  90             value_description => $row->{'lib'},
  91             password          => $row->{'password'},
  92             display_checkout  => $row->{'display_checkout'},
  93             category_code     => $row->{'category_code'},
  94             class             => $row->{'class'},
  95         }
  96     }
  97     return \@results;
  98 }
  99
 100 =head2 GetAttributes
 101
 102   my $attributes = C4::Members::Attributes::GetAttributes([$opac_only]);
 103
 104 Retrieve an arrayref of extended attribute codes
 105
 106 =cut
 107
 108 sub GetAttributes {
 109     my ($opac_only) = @_;
 110
 111     my $dbh = C4::Context->dbh();
 112     my $query = "SELECT code FROM borrower_attribute_types";
 113     $query .= "\nWHERE opac_display = 1" if $opac_only;
 114     $query .= "\nORDER BY code";
 115     return $dbh->selectcol_arrayref($query);
 116 }
 117
 118 =head2 GetBorrowerAttributeValue
 119
 120   my $value = C4::Members::Attributes::GetBorrowerAttributeValue($borrowernumber, $attribute_code);
 121
 122 Retrieve the value of an extended attribute C<$attribute_code> associated with the
 123 patron specified by C<$borrowernumber>.
 124
 125 =cut
 126
 127 sub GetBorrowerAttributeValue {
 128     my $borrowernumber = shift;
 129     my $code = shift;
 130
 131     my $dbh = C4::Context->dbh();
 132     my $query = "SELECT attribute
 133                  FROM borrower_attributes
 134                  WHERE borrowernumber = ?
 135                  AND code = ?";
 136     my $value = $dbh->selectrow_array($query, undef, $borrowernumber, $code);
 137     return $value;
 138 }
 139
 140 =head2 SearchIdMatchingAttribute
 141
 142   my $matching_borrowernumbers = C4::Members::Attributes::SearchIdMatchingAttribute($filter);
 143
 144 =cut
 145
 146 sub SearchIdMatchingAttribute{
 147     my $filter = shift;
 148     $filter = [$filter] unless ref $filter;
 149
 150     my $dbh   = C4::Context->dbh();
 151     my $query = qq{
 152 SELECT DISTINCT borrowernumber
 153 FROM borrower_attributes
 154 JOIN borrower_attribute_types USING (code)
 155 WHERE staff_searchable = 1
 156 AND (} . join (" OR ", map "attribute like ?", @$filter) .qq{)};
 157     my $sth = $dbh->prepare_cached($query);
 158     $sth->execute(map "%$_%", @$filter);
 159     return [map $_->[0], @{ $sth->fetchall_arrayref }];
 160 }
 161
 162 =head2 CheckUniqueness
 163
 164   my $ok = CheckUniqueness($code, $value[, $borrowernumber]);
 165
 166 Given an attribute type and value, verify if would violate
 167 a unique_id restriction if added to the patron.  The
 168 optional C<$borrowernumber> is the patron that the attribute
 169 value would be added to, if known.
 170
 171 Returns false if the C<$code> is not valid or the
 172 value would violate the uniqueness constraint.
 173
 174 =cut
 175
 176 sub CheckUniqueness {
 177     my $code = shift;
 178     my $value = shift;
 179     my $borrowernumber = @_ ? shift : undef;
 180
 181     my $attr_type = C4::Members::AttributeTypes->fetch($code);
 182
 183     return 0 unless defined $attr_type;
 184     return 1 unless $attr_type->unique_id();
 185
 186     my $dbh = C4::Context->dbh;
 187     my $sth;
 188     if (defined($borrowernumber)) {
 189         $sth = $dbh->prepare("SELECT COUNT(*)
 190                               FROM borrower_attributes
 191                               WHERE code = ?
 192                               AND attribute = ?
 193                               AND borrowernumber <> ?");
 194         $sth->execute($code, $value, $borrowernumber);
 195     } else {
 196         $sth = $dbh->prepare("SELECT COUNT(*)
 197                               FROM borrower_attributes
 198                               WHERE code = ?
 199                               AND attribute = ?");
 200         $sth->execute($code, $value);
 201     }
 202     my ($count) = $sth->fetchrow_array;
 203     return ($count == 0);
 204 }
 205
 206 =head2 SetBorrowerAttributes
 207
 208   SetBorrowerAttributes($borrowernumber, [ { code => 'CODE', value => 'value', password => 'password' }, ... ] );
 209
 210 Set patron attributes for the patron identified by C<$borrowernumber>,
 211 replacing any that existed previously.
 212
 213 =cut
 214
 215 sub SetBorrowerAttributes {
 216     my $borrowernumber = shift;
 217     my $attr_list = shift;
 218
 219     my $dbh = C4::Context->dbh;
 220     my $delsth = $dbh->prepare("DELETE FROM borrower_attributes WHERE borrowernumber = ?");
 221     $delsth->execute($borrowernumber);
 222
 223     my $sth = $dbh->prepare("INSERT INTO borrower_attributes (borrowernumber, code, attribute, password)
 224                              VALUES (?, ?, ?, ?)");
 225     foreach my $attr (@$attr_list) {
 226         $attr->{password} = undef unless exists $attr->{password};
 227         $sth->execute($borrowernumber, $attr->{code}, $attr->{value}, $attr->{password});
 228         if ($sth->err) {
 229             warn sprintf('Database returned the following error: %s', $sth->errstr);
 230             return; # bail immediately on errors
 231         }
 232     }
 233     return 1; # borower attributes successfully set
 234 }
 235
 236 =head2 extended_attributes_code_value_arrayref
 237
 238    my $patron_attributes = "homeroom:1150605,grade:01,extradata:foobar";
 239    my $aref = extended_attributes_code_value_arrayref($patron_attributes);
 240
 241 Takes a comma-delimited CSV-style string argument and returns the kind of data structure that SetBorrowerAttributes wants,
 242 namely a reference to array of hashrefs like:
 243  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 244
 245 Caches Text::CSV parser object for efficiency.
 246
 247 =cut
 248
 249 sub extended_attributes_code_value_arrayref {
 250     my $string = shift or return;
 251     $csv or $csv = Text::CSV->new({binary => 1});  # binary needed for non-ASCII Unicode
 252     my $ok   = $csv->parse($string);  # parse field again to get subfields!
 253     my @list = $csv->fields();
 254     # TODO: error handling (check $ok)
 255     return [
 256         sort {&_sort_by_code($a,$b)}
 257         map { map { my @arr = split /:/, $_, 2; { code => $arr[0], value => $arr[1] } } $_ }
 258         @list
 259     ];
 260     # nested map because of split
 261 }
 262
 263 =head2 extended_attributes_merge
 264
 265   my $old_attributes = extended_attributes_code_value_arrayref("homeroom:224,grade:04,deanslist:2007,deanslist:2008,somedata:xxx");
 266   my $new_attributes = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2009,extradata:foobar");
 267   my $merged = extended_attributes_merge($patron_attributes, $new_attributes, 1);
 268
 269   # assuming deanslist is a repeatable code, value same as:
 270   # $merged = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2007,deanslist:2008,deanslist:2009,extradata:foobar,somedata:xxx");
 271
 272 Takes three arguments.  The first two are references to array of hashrefs, each like:
 273  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 274
 275 The third option specifies whether repeatable codes are clobbered or collected.  True for non-clobber.
 276
 277 Returns one reference to (merged) array of hashref.
 278
 279 Caches results of C4::Members::AttributeTypes::GetAttributeTypes_hashref(1) for efficiency.
 280
 281 =cut
 282
 283 sub extended_attributes_merge {
 284     my $old = shift or return;
 285     my $new = shift or return $old;
 286     my $keep = @_ ? shift : 0;
 287     $AttributeTypes or $AttributeTypes = C4::Members::AttributeTypes::GetAttributeTypes_hashref(1);
 288     my @merged = @$old;
 289     foreach my $att (@$new) {
 290         unless ($att->{code}) {
 291             warn "Cannot merge element: no 'code' defined";
 292             next;
 293         }
 294         unless ($AttributeTypes->{$att->{code}}) {
 295             warn "Cannot merge element: unrecognized code = '$att->{code}'";
 296             next;
 297         }
 298         unless ($AttributeTypes->{$att->{code}}->{repeatable} and $keep) {
 299             @merged = grep {$att->{code} ne $_->{code}} @merged;    # filter out any existing attributes of the same code
 300         }
 301         push @merged, $att;
 302     }
 303     return [( sort {&_sort_by_code($a,$b)} @merged )];
 304 }
 305
 306 sub _sort_by_code {
 307     my ($x, $y) = @_;
 308     defined ($x->{code}) or return -1;
 309     defined ($y->{code}) or return 1;
 310     return $x->{code} cmp $y->{code} || $x->{value} cmp $y->{value};
 311 }
 312
 313 =head1 AUTHOR
 314
 315 Koha Development Team <http://koha-community.org/>
 316
 317 Galen Charlton <galen.charlton@liblime.com>
 318
 319 =cut
 320
 321 1;