C4/Members/Attributes.pm

   1 package C4::Members::Attributes;
   2
   3 # Copyright (C) 2008 LibLime
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use Text::CSV;      # Don't be tempted to use Text::CSV::Unicode -- even in binary mode it fails.
  24 use C4::Context;
  25 use C4::Members::AttributeTypes;
  26
  27 use vars qw($VERSION @ISA @EXPORT_OK @EXPORT %EXPORT_TAGS);
  28 our ($csv, $AttributeTypes);
  29
  30 BEGIN {
  31     # set the version for version checking
  32     $VERSION = 3.01;
  33     @ISA = qw(Exporter);
  34     @EXPORT_OK = qw(GetBorrowerAttributes GetBorrowerAttributeValue CheckUniqueness SetBorrowerAttributes
  35                     extended_attributes_code_value_arrayref extended_attributes_merge
  36                                         SearchIdMatchingAttribute);
  37     %EXPORT_TAGS = ( all => \@EXPORT_OK );
  38 }
  39
  40 =head1 NAME
  41
  42 C4::Members::Attributes - manage extend patron attributes
  43
  44 =head1 SYNOPSIS
  45
  46   use C4::Members::Attributes;
  47   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
  48
  49 =head1 FUNCTIONS
  50
  51 =head2 GetBorrowerAttributes
  52
  53   my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber[, $opac_only]);
  54
  55 Retrieve an arrayref of extended attributes associated with the
  56 patron specified by C<$borrowernumber>.  Each entry in the arrayref
  57 is a hashref containing the following keys:
  58
  59 code (attribute type code)
  60 description (attribute type description)
  61 value (attribute value)
  62 value_description (attribute value description (if associated with an authorised value))
  63 password (password, if any, associated with attribute
  64
  65 If the C<$opac_only> parameter is present and has a true value, only the attributes
  66 marked for OPAC display are returned.
  67
  68 =cut
  69
  70 sub GetBorrowerAttributes {
  71     my $borrowernumber = shift;
  72     my $opac_only = @_ ? shift : 0;
  73
  74     my $dbh = C4::Context->dbh();
  75     my $query = "SELECT code, description, attribute, lib, password
  76                  FROM borrower_attributes
  77                  JOIN borrower_attribute_types USING (code)
  78                  LEFT JOIN authorised_values ON (category = authorised_value_category AND attribute = authorised_value)
  79                  WHERE borrowernumber = ?";
  80     $query .= "\nAND opac_display = 1" if $opac_only;
  81     $query .= "\nORDER BY code, attribute";
  82     my $sth = $dbh->prepare_cached($query);
  83     $sth->execute($borrowernumber);
  84     my @results = ();
  85     while (my $row = $sth->fetchrow_hashref()) {
  86         push @results, {
  87             code              => $row->{'code'},
  88             description       => $row->{'description'},
  89             value             => $row->{'attribute'},
  90             value_description => $row->{'lib'},
  91             password          => $row->{'password'},
  92         }
  93     }
  94     return \@results;
  95 }
  96
  97 =head2 GetBorrowerAttributeValue
  98
  99   my $value = C4::Members::Attributes::GetBorrowerAttributeValue($borrowernumber, $attribute_code);
 100
 101 Retrieve the value of an extended attribute C<$attribute_code> associated with the
 102 patron specified by C<$borrowernumber>.
 103
 104 =cut
 105
 106 sub GetBorrowerAttributeValue {
 107     my $borrowernumber = shift;
 108     my $code = shift;
 109
 110     my $dbh = C4::Context->dbh();
 111     my $query = "SELECT attribute
 112                  FROM borrower_attributes
 113                  WHERE borrowernumber = ?
 114                  AND code = ?";
 115     my $value = $dbh->selectrow_array($query, undef, $borrowernumber, $code);
 116     return $value;
 117 }
 118
 119 =head2 SearchIdMatchingAttribute
 120
 121   my $matching_records = C4::Members::Attributes::SearchIdMatchingAttribute($filter);
 122
 123 =cut
 124
 125 sub SearchIdMatchingAttribute{
 126     my $filter = shift;
 127     my $finalfilter=$filter->[0];
 128     my $dbh   = C4::Context->dbh();
 129     my $query = qq{
 130 SELECT borrowernumber
 131 FROM borrower_attributes
 132 JOIN borrower_attribute_types USING (code)
 133 WHERE staff_searchable = 1
 134 AND attribute like ?};
 135     my $sth = $dbh->prepare_cached($query);
 136     $sth->execute("%$finalfilter%");
 137     return $sth->fetchall_arrayref;
 138 }
 139
 140 =head2 CheckUniqueness
 141
 142   my $ok = CheckUniqueness($code, $value[, $borrowernumber]);
 143
 144 Given an attribute type and value, verify if would violate
 145 a unique_id restriction if added to the patron.  The
 146 optional C<$borrowernumber> is the patron that the attribute
 147 value would be added to, if known.
 148
 149 Returns false if the C<$code> is not valid or the
 150 value would violate the uniqueness constraint.
 151
 152 =cut
 153
 154 sub CheckUniqueness {
 155     my $code = shift;
 156     my $value = shift;
 157     my $borrowernumber = @_ ? shift : undef;
 158
 159     my $attr_type = C4::Members::AttributeTypes->fetch($code);
 160
 161     return 0 unless defined $attr_type;
 162     return 1 unless $attr_type->unique_id();
 163
 164     my $dbh = C4::Context->dbh;
 165     my $sth;
 166     if (defined($borrowernumber)) {
 167         $sth = $dbh->prepare("SELECT COUNT(*)
 168                               FROM borrower_attributes
 169                               WHERE code = ?
 170                               AND attribute = ?
 171                               AND borrowernumber <> ?");
 172         $sth->execute($code, $value, $borrowernumber);
 173     } else {
 174         $sth = $dbh->prepare("SELECT COUNT(*)
 175                               FROM borrower_attributes
 176                               WHERE code = ?
 177                               AND attribute = ?");
 178         $sth->execute($code, $value);
 179     }
 180     my ($count) = $sth->fetchrow_array;
 181     return ($count == 0);
 182 }
 183
 184 =head2 SetBorrowerAttributes
 185
 186   SetBorrowerAttributes($borrowernumber, [ { code => 'CODE', value => 'value', password => 'password' }, ... ] );
 187
 188 Set patron attributes for the patron identified by C<$borrowernumber>,
 189 replacing any that existed previously.
 190
 191 =cut
 192
 193 sub SetBorrowerAttributes {
 194     my $borrowernumber = shift;
 195     my $attr_list = shift;
 196
 197     my $dbh = C4::Context->dbh;
 198     my $delsth = $dbh->prepare("DELETE FROM borrower_attributes WHERE borrowernumber = ?");
 199     $delsth->execute($borrowernumber);
 200
 201     my $sth = $dbh->prepare("INSERT INTO borrower_attributes (borrowernumber, code, attribute, password)
 202                              VALUES (?, ?, ?, ?)");
 203     foreach my $attr (@$attr_list) {
 204         $attr->{password} = undef unless exists $attr->{password};
 205         $sth->execute($borrowernumber, $attr->{code}, $attr->{value}, $attr->{password});
 206     }
 207 }
 208
 209 =head2 extended_attributes_code_value_arrayref
 210
 211    my $patron_attributes = "homeroom:1150605,grade:01,extradata:foobar";
 212    my $aref = extended_attributes_code_value_arrayref($patron_attributes);
 213
 214 Takes a comma-delimited CSV-style string argument and returns the kind of data structure that SetBorrowerAttributes wants,
 215 namely a reference to array of hashrefs like:
 216  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 217
 218 Caches Text::CSV parser object for efficiency.
 219
 220 =cut
 221
 222 sub extended_attributes_code_value_arrayref {
 223     my $string = shift or return;
 224     $csv or $csv = Text::CSV->new({binary => 1});  # binary needed for non-ASCII Unicode
 225     my $ok   = $csv->parse($string);  # parse field again to get subfields!
 226     my @list = $csv->fields();
 227     # TODO: error handling (check $ok)
 228     return [
 229         sort {&_sort_by_code($a,$b)}
 230         map { map { my @arr = split /:/, $_, 2; { code => $arr[0], value => $arr[1] } } $_ }
 231         @list
 232     ];
 233     # nested map because of split
 234 }
 235
 236 =head2 extended_attributes_merge
 237
 238   my $old_attributes = extended_attributes_code_value_arrayref("homeroom:224,grade:04,deanslist:2007,deanslist:2008,somedata:xxx");
 239   my $new_attributes = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2009,extradata:foobar");
 240   my $merged = extended_attributes_merge($patron_attributes, $new_attributes, 1);
 241
 242   # assuming deanslist is a repeatable code, value same as:
 243   # $merged = extended_attributes_code_value_arrayref("homeroom:115,grade:05,deanslist:2007,deanslist:2008,deanslist:2009,extradata:foobar,somedata:xxx");
 244
 245 Takes three arguments.  The first two are references to array of hashrefs, each like:
 246  [ { code => 'CODE', value => 'value' }, { code => 'CODE2', value => 'othervalue' } ... ]
 247
 248 The third option specifies whether repeatable codes are clobbered or collected.  True for non-clobber.
 249
 250 Returns one reference to (merged) array of hashref.
 251
 252 Caches results of C4::Members::AttributeTypes::GetAttributeTypes_hashref(1) for efficiency.
 253
 254 =cut
 255
 256 sub extended_attributes_merge {
 257     my $old = shift or return;
 258     my $new = shift or return $old;
 259     my $keep = @_ ? shift : 0;
 260     $AttributeTypes or $AttributeTypes = C4::Members::AttributeTypes::GetAttributeTypes_hashref(1);
 261     my @merged = @$old;
 262     foreach my $att (@$new) {
 263         unless ($att->{code}) {
 264             warn "Cannot merge element: no 'code' defined";
 265             next;
 266         }
 267         unless ($AttributeTypes->{$att->{code}}) {
 268             warn "Cannot merge element: unrecognized code = '$att->{code}'";
 269             next;
 270         }
 271         unless ($AttributeTypes->{$att->{code}}->{repeatable} and $keep) {
 272             @merged = grep {$att->{code} ne $_->{code}} @merged;    # filter out any existing attributes of the same code
 273         }
 274         push @merged, $att;
 275     }
 276     return [( sort {&_sort_by_code($a,$b)} @merged )];
 277 }
 278
 279 sub _sort_by_code {
 280     my ($x, $y) = @_;
 281     defined ($x->{code}) or return -1;
 282     defined ($y->{code}) or return 1;
 283     return $x->{code} cmp $y->{code} || $x->{value} cmp $y->{value};
 284 }
 285
 286 =head1 AUTHOR
 287
 288 Koha Development Team <http://koha-community.org/>
 289
 290 Galen Charlton <galen.charlton@liblime.com>
 291
 292 =cut
 293
 294 1;