Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (
  30     qw( dt_from_string output_pref format_sqldatetime output_pref_due format_sqlduedatetime)
  31 );
  32
  33 =head1 DateUtils
  34
  35 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  36
  37 =head1 DESCRIPTION
  38
  39 Koha has historically only used dates not datetimes and been content to
  40 handle these as strings. It also has confused formatting with actual dates
  41 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  42
  43 =cut
  44
  45 =head2 dt_ftom_string
  46
  47 $dt = dt_from_string($date_string, [$format, $timezone ]);
  48
  49 Passed a date string returns a DateTime object format and timezone default
  50 to the system preferences. If the date string is empty DateTime->now is returned
  51
  52 =cut
  53
  54 sub dt_from_string {
  55     my ( $date_string, $date_format, $tz ) = @_;
  56     if ( !$tz ) {
  57         $tz = C4::Context->tz;
  58     }
  59     if ( !$date_format ) {
  60         $date_format = C4::Context->preference('dateformat');
  61     }
  62     if ($date_string) {
  63         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  64             return $date_string;
  65         }
  66
  67         if ( $date_format eq 'metric' ) {
  68             $date_string =~ s#-#/#g;
  69             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  70             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  71         } else {
  72             if ( $date_format eq 'iso' ) {
  73                 $date_string =~ s/-00/-01/;
  74                 if ( $date_string =~ m/^0000-0/ ) {
  75                     return;               # invalid date in db
  76                 }
  77             } elsif ( $date_format eq 'us' ) {
  78                 $date_string =~ s#-#/#g;
  79                 $date_string =~ s[/00/][/01/];
  80             } elsif ( $date_format eq 'sql' ) {
  81                 $date_string =~
  82 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  83                 return if ($date_string =~ /^0000-00-00/);
  84                 $date_string =~ s/00T/01T/;
  85             }
  86         }
  87         return DateTime::Format::DateParse->parse_datetime( $date_string,
  88             $tz->name() );
  89     }
  90     return DateTime->now( time_zone => $tz );
  91
  92 }
  93
  94 =head2 output_pref
  95
  96 $date_string = output_pref($dt, [$date_format], [$time_format] );
  97
  98 Returns a string containing the time & date formatted as per the C4::Context setting,
  99 or C<undef> if C<undef> was provided.
 100
 101 A second parameter allows overriding of the syspref value. This is for testing only
 102 In usage use the DateTime objects own methods for non standard formatting
 103
 104 A third parameter allows overriding of the TimeFormat syspref value
 105
 106 A fourth parameter allows to specify if the output format contains the hours and minutes.
 107 If it is not defined, the default value is 0;
 108
 109 =cut
 110
 111 sub output_pref {
 112     my $dt         = shift;
 113     my $force_pref = shift;         # if testing we want to override Context
 114     my $force_time = shift;
 115     my $dateonly   = shift || 0;    # if you don't want the hours and minutes
 116
 117     return unless defined $dt;
 118
 119     $dt->set_time_zone( C4::Context->tz );
 120
 121     my $pref =
 122       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 123
 124     my $time_format = $force_time || C4::Context->preference('TimeFormat');
 125     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 126
 127     given ($pref) {
 128         when (/^iso/) {
 129             return $dateonly
 130                 ? $dt->strftime("%Y-%m-%d")
 131                 : $dt->strftime("%Y-%m-%d $time");
 132         }
 133         when (/^metric/) {
 134             return $dateonly
 135                 ? $dt->strftime("%d/%m/%Y")
 136                 : $dt->strftime("%d/%m/%Y $time");
 137         }
 138         when (/^us/) {
 139
 140             return $dateonly
 141                 ? $dt->strftime("%m/%d/%Y")
 142                 : $dt->strftime("%m/%d/%Y $time");
 143         }
 144         default {
 145             return $dateonly
 146                 ? $dt->strftime("%Y-%m-%d")
 147                 : $dt->strftime("%Y-%m-%d $time");
 148         }
 149
 150     }
 151     return;
 152 }
 153
 154 =head2 output_pref_due
 155
 156 $date_string = output_pref_due($dt, [$format] );
 157
 158 Returns a string containing the time & date formatted as per the C4::Context setting
 159
 160 A second parameter allows overriding of the syspref value. This is for testing only
 161 In usage use the DateTime objects own methods for non standard formatting
 162
 163 This is effectivelyt a wrapper around output_pref for due dates
 164 the time portion is stripped if it is '23:59'
 165
 166 =cut
 167
 168 sub output_pref_due {
 169     my $disp_str = output_pref(@_);
 170     $disp_str =~ s/ 23:59//;
 171     return $disp_str;
 172 }
 173
 174 =head2 format_sqldatetime
 175
 176 $string = format_sqldatetime( $string_as_returned_from_db );
 177
 178 a convenience routine for calling dt_from_string and formatting the result
 179 with output_pref as it is a frequent activity in scripts
 180
 181 =cut
 182
 183 sub format_sqldatetime {
 184     my $str        = shift;
 185     my $force_pref = shift;    # if testing we want to override Context
 186     my $force_time = shift;
 187     my $dateonly   = shift;
 188
 189     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 190         my $dt = dt_from_string( $str, 'sql' );
 191         return q{} unless $dt;
 192         $dt->truncate( to => 'minute' );
 193         return output_pref( $dt, $force_pref, $force_time, $dateonly );
 194     }
 195     return q{};
 196 }
 197
 198 =head2 format_sqlduedatetime
 199
 200 $string = format_sqldatetime( $string_as_returned_from_db );
 201
 202 a convenience routine for calling dt_from_string and formatting the result
 203 with output_pref_due as it is a frequent activity in scripts
 204
 205 =cut
 206
 207 sub format_sqlduedatetime {
 208     my $str        = shift;
 209     my $force_pref = shift;    # if testing we want to override Context
 210     my $force_time = shift;
 211     my $dateonly   = shift;
 212
 213     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 214         my $dt = dt_from_string( $str, 'sql' );
 215         $dt->truncate( to => 'minute' );
 216         return output_pref_due( $dt, $force_pref, $force_time, $dateonly );
 217     }
 218     return q{};
 219 }
 220
 221 1;