Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use C4::Context;
  24
  25 use base 'Exporter';
  26 use version; our $VERSION = qv('1.0.0');
  27
  28 our @EXPORT = (
  29     qw( dt_from_string output_pref format_sqldatetime )
  30 );
  31
  32 =head1 DateUtils
  33
  34 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  35
  36 =head1 DESCRIPTION
  37
  38 Koha has historically only used dates not datetimes and been content to
  39 handle these as strings. It also has confused formatting with actual dates
  40 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  41
  42 =cut
  43
  44 =head2 dt_ftom_string
  45
  46 $dt = dt_from_string($date_string, [$format, $timezone ]);
  47
  48 Passed a date string returns a DateTime object format and timezone default
  49 to the system preferences. If the date string is empty DateTime->now is returned
  50
  51 =cut
  52
  53 sub dt_from_string {
  54     my ( $date_string, $date_format, $tz ) = @_;
  55
  56     return if $date_string and $date_string =~ m|^0000-0|;
  57
  58     $tz = C4::Context->tz unless $tz;;
  59
  60     return DateTime->now( time_zone => $tz ) unless $date_string;
  61
  62     $date_format = C4::Context->preference('dateformat') unless $date_format;
  63
  64     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  65         return $date_string;
  66     }
  67
  68     my $regex;
  69     if ( $date_format eq 'metric' ) {
  70         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  71         $regex = qr|
  72             (?<day>\d{2})
  73             /
  74             (?<month>\d{2})
  75             /
  76             (?<year>\d{4})
  77         |xms;
  78     }
  79     elsif ( $date_format eq 'us' ) {
  80         # us format is "mm/dd/yyyy[ hh:mm:ss]"
  81         $regex = qr|
  82             (?<month>\d{2})
  83             /
  84             (?<day>\d{2})
  85             /
  86             (?<year>\d{4})
  87         |xms;
  88     }
  89     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
  90         # iso format is yyyy-dd-mm[ hh:mm:ss]"
  91         $regex = qr|
  92             (?<year>\d{4})
  93             -
  94             (?<month>\d{2})
  95             -
  96             (?<day>\d{2})
  97         |xms;
  98     }
  99     else {
 100         die "Invalid dateformat parameter ($date_format)";
 101     }
 102
 103     # Add the faculative time part [hh:mm[:ss]]
 104     $regex .= qr|
 105             (
 106                 \s*
 107                 (?<hour>\d{2})
 108                 :
 109                 (?<minute>\d{2})
 110                 (
 111                     :
 112                     (?<second>\d{2})
 113                 )?
 114             )?
 115     |xms;
 116
 117     my %dt_params;
 118     if ( $date_string =~ $regex ) {
 119         %dt_params = (
 120             year   => $+{year},
 121             month  => $+{month},
 122             day    => $+{day},
 123             hour   => $+{hour},
 124             minute => $+{minute},
 125             second => $+{second},
 126         );
 127     }
 128     else {
 129         die "The given date ($date_string) does not match the date format ($date_format)";
 130     }
 131
 132     # system allows the 0th of the month
 133     $dt_params{day} = '01' if $dt_params{day} eq '00';
 134
 135     # Set default hh:mm:ss to 00:00:00
 136     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 137     $dt_params{minute} = 00 unless defined $dt_params{minute};
 138     $dt_params{second} = 00 unless defined $dt_params{second};
 139
 140     my $dt = eval {
 141         DateTime->new(
 142             %dt_params,
 143             # No TZ for dates 'infinite' => see bug 13242
 144             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 145         );
 146     };
 147     if ($@) {
 148         $tz = DateTime::TimeZone->new( name => 'floating' );
 149         $dt = DateTime->new(
 150             %dt_params,
 151             # No TZ for dates 'infinite' => see bug 13242
 152             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 153         );
 154     }
 155     return $dt;
 156 }
 157
 158 =head2 output_pref
 159
 160 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 161 $date_string = output_pref( $dt );
 162
 163 Returns a string containing the time & date formatted as per the C4::Context setting,
 164 or C<undef> if C<undef> was provided.
 165
 166 This routine can either be passed a DateTime object or or a hashref.  If it is
 167 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 168 an optional 'dateformat' to override the dateformat system preference, an
 169 optional 'timeformat' to override the TimeFormat system preference value,
 170 and an optional 'dateonly' to specify that only the formatted date string
 171 should be returned without the time.
 172
 173 =cut
 174
 175 sub output_pref {
 176     my $params = shift;
 177     my ( $dt, $force_pref, $force_time, $dateonly, $as_due_date );
 178     if ( ref $params eq 'HASH' ) {
 179         $dt         = $params->{dt};
 180         $force_pref = $params->{dateformat};         # if testing we want to override Context
 181         $force_time = $params->{timeformat};
 182         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 183         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 184     } else {
 185         $dt = $params;
 186     }
 187
 188     return unless defined $dt;
 189
 190     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 191     if ( $dt->ymd !~ /^9999/ ) {
 192         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 193         $dt->set_time_zone( $tz );
 194     }
 195
 196     my $pref =
 197       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 198
 199     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 200     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 201     my $date;
 202     if ( $pref =~ m/^iso/ ) {
 203         $date = $dateonly
 204           ? $dt->strftime("%Y-%m-%d")
 205           : $dt->strftime("%Y-%m-%d $time");
 206     }
 207     elsif ( $pref =~ m/^metric/ ) {
 208         $date = $dateonly
 209           ? $dt->strftime("%d/%m/%Y")
 210           : $dt->strftime("%d/%m/%Y $time");
 211     }
 212     elsif ( $pref =~ m/^us/ ) {
 213         $date = $dateonly
 214           ? $dt->strftime("%m/%d/%Y")
 215           : $dt->strftime("%m/%d/%Y $time");
 216     }
 217     else {
 218         $date = $dateonly
 219           ? $dt->strftime("%Y-%m-%d")
 220           : $dt->strftime("%Y-%m-%d $time");
 221     }
 222
 223     if ( $as_due_date ) {
 224         $time_format eq '12hr'
 225             ? $date =~ s| 11:59 PM$||
 226             : $date =~ s| 23:59$||;
 227     }
 228
 229     return $date;
 230 }
 231
 232 =head2 format_sqldatetime
 233
 234 $string = format_sqldatetime( $string_as_returned_from_db );
 235
 236 a convenience routine for calling dt_from_string and formatting the result
 237 with output_pref as it is a frequent activity in scripts
 238
 239 =cut
 240
 241 sub format_sqldatetime {
 242     my $str        = shift;
 243     my $force_pref = shift;    # if testing we want to override Context
 244     my $force_time = shift;
 245     my $dateonly   = shift;
 246
 247     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 248         my $dt = dt_from_string( $str, 'sql' );
 249         return q{} unless $dt;
 250         $dt->truncate( to => 'minute' );
 251         return output_pref({
 252             dt => $dt,
 253             dateformat => $force_pref,
 254             timeformat => $force_time,
 255             dateonly => $dateonly
 256         });
 257     }
 258     return q{};
 259 }
 260
 261 1;