Koha/Objects.pm

   1 package Koha::Objects;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 =head1 NAME
  27
  28 Koha::Objects - Koha Object set base class
  29
  30 =head1 SYNOPSIS
  31
  32     use Koha::Objects;
  33     my @objects = Koha::Objects->search({ borrowernumber => $borrowernumber});
  34
  35 =head1 DESCRIPTION
  36
  37 This class must be subclassed.
  38
  39 =head1 API
  40
  41 =head2 Class Methods
  42
  43 =cut
  44
  45 =head3 Koha::Objects->new();
  46
  47 my $object = Koha::Objects->new();
  48
  49 =cut
  50
  51 sub new {
  52     my ($class) = @_;
  53     my $self = {};
  54
  55     bless( $self, $class );
  56 }
  57
  58 =head3 Koha::Objects->_new_from_dbic();
  59
  60 my $object = Koha::Objects->_new_from_dbic( $resultset );
  61
  62 =cut
  63
  64 sub _new_from_dbic {
  65     my ( $class, $resultset ) = @_;
  66     my $self = { _resultset => $resultset };
  67
  68     bless( $self, $class );
  69 }
  70
  71 =head3 Koha::Objects->find();
  72
  73 my $object = Koha::Objects->find($id);
  74 my $object = Koha::Objects->find( { keypart1 => $keypart1, keypart2 => $keypart2 } );
  75
  76 =cut
  77
  78 sub find {
  79     my ( $self, $id ) = @_;
  80
  81     return unless defined($id);
  82
  83     my $result = $self->_resultset()->find($id);
  84
  85     return unless $result;
  86
  87     my $object = $self->object_class()->_new_from_dbic( $result );
  88
  89     return $object;
  90 }
  91
  92 =head3 Koha::Objects->find_or_create();
  93
  94 my $object = Koha::Objects->find_or_create( $attrs );
  95
  96 =cut
  97
  98 sub find_or_create {
  99     my ( $self, $params ) = @_;
 100
 101     my $result = $self->_resultset->find_or_create($params);
 102
 103     return unless $result;
 104
 105     my $object = $self->object_class->_new_from_dbic($result);
 106
 107     return $object;
 108 }
 109
 110 =head3 Koha::Objects->search();
 111
 112 my @objects = Koha::Objects->search($params);
 113
 114 =cut
 115
 116 sub search {
 117     my ( $self, $params, $attributes ) = @_;
 118
 119     if (wantarray) {
 120         my @dbic_rows = $self->_resultset()->search($params, $attributes);
 121
 122         return $self->_wrap(@dbic_rows);
 123
 124     }
 125     else {
 126         my $class = ref($self) ? ref($self) : $self;
 127         my $rs = $self->_resultset()->search($params, $attributes);
 128
 129         return $class->_new_from_dbic($rs);
 130     }
 131 }
 132
 133 =head3 Koha::Objects->count();
 134
 135 my @objects = Koha::Objects->count($params);
 136
 137 =cut
 138
 139 sub count {
 140     my ( $self, $params ) = @_;
 141
 142     return $self->_resultset()->count($params);
 143 }
 144
 145 =head3 Koha::Objects->pager();
 146
 147 my $pager = Koha::Objects->pager;
 148
 149 =cut
 150
 151 sub pager {
 152     my ( $self ) = @_;
 153     return $self->_resultset->pager;
 154 }
 155
 156 =head3 Koha::Objects->next();
 157
 158 my $object = Koha::Objects->next();
 159
 160 Returns the next object that is part of this set.
 161 Returns undef if there are no more objects to return.
 162
 163 =cut
 164
 165 sub next {
 166     my ( $self ) = @_;
 167
 168     my $result = $self->_resultset()->next();
 169     return unless $result;
 170
 171     my $object = $self->object_class()->_new_from_dbic( $result );
 172
 173     return $object;
 174 }
 175
 176 =head3 Koha::Objects->reset();
 177
 178 Koha::Objects->reset();
 179
 180 resets iteration so the next call to next() will start agein
 181 with the first object in a set.
 182
 183 =cut
 184
 185 sub reset {
 186     my ( $self ) = @_;
 187
 188     $self->_resultset()->reset();
 189
 190     return $self;
 191 }
 192
 193 =head3 Koha::Objects->as_list();
 194
 195 Koha::Objects->as_list();
 196
 197 Returns an arrayref of the objects in this set.
 198
 199 =cut
 200
 201 sub as_list {
 202     my ( $self ) = @_;
 203
 204     my @dbic_rows = $self->_resultset()->all();
 205
 206     my @objects = $self->_wrap(@dbic_rows);
 207
 208     return wantarray ? @objects : \@objects;
 209 }
 210
 211 =head3 Koha::Objects->unblessed
 212
 213 Returns an unblessed representation of objects.
 214
 215 =cut
 216
 217 sub unblessed {
 218     my ($self) = @_;
 219
 220     return [ map { $_->unblessed } $self->as_list ];
 221 }
 222
 223 =head3 Koha::Objects->_wrap
 224
 225 wraps the DBIC object in a corresponding Koha object
 226
 227 =cut
 228
 229 sub _wrap {
 230     my ( $self, @dbic_rows ) = @_;
 231
 232     my @objects = map { $self->object_class()->_new_from_dbic( $_ ) } @dbic_rows;
 233
 234     return @objects;
 235 }
 236
 237 =head3 Koha::Objects->_resultset
 238
 239 Returns the internal resultset or creates it if undefined
 240
 241 =cut
 242
 243 sub _resultset {
 244     my ($self) = @_;
 245
 246     if ( ref($self) ) {
 247         $self->{_resultset} ||=
 248           Koha::Database->new()->schema()->resultset( $self->_type() );
 249
 250         return $self->{_resultset};
 251     }
 252     else {
 253         return Koha::Database->new()->schema()->resultset( $self->_type() );
 254     }
 255 }
 256
 257 =head3 columns
 258
 259 my @columns = Koha::Objects->columns
 260
 261 Return the table columns
 262
 263 =cut
 264
 265 sub columns {
 266     my ( $class ) = @_;
 267     return Koha::Database->new->schema->resultset( $class->_type )->result_source->columns;
 268 }
 269
 270
 271
 272 =head3 _type
 273
 274 The _type method must be set for all child classes.
 275 The value returned by it should be the DBIC resultset name.
 276 For example, for holds, _type should return 'Reserve'.
 277
 278 =cut
 279
 280 sub _type { }
 281
 282 =head3 object_class
 283
 284 This method must be set for all child classes.
 285 The value returned by it should be the name of the Koha
 286 object class that is returned by this class.
 287 For example, for holds, object_class should return 'Koha::Hold'.
 288
 289 =cut
 290
 291 sub object_class { }
 292
 293 sub DESTROY { }
 294
 295 =head1 AUTHOR
 296
 297 Kyle M Hall <kyle@bywatersolutions.com>
 298
 299 =cut
 300
 301 1;