Koha/Patrons/Import.pm

   1 package Koha::Patrons::Import;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use Moo;
  20 use namespace::clean;
  21
  22 use Carp;
  23 use Text::CSV;
  24 use Encode qw( decode_utf8 );
  25
  26 use C4::Members;
  27 use C4::Members::Attributes qw(:all);
  28 use C4::Members::AttributeTypes;
  29
  30 use Koha::Libraries;
  31 use Koha::Patrons;
  32 use Koha::Patron::Categories;
  33 use Koha::Patron::Debarments;
  34 use Koha::DateUtils;
  35
  36 =head1 NAME
  37
  38 Koha::Patrons::Import - Perl Module containing import_patrons method exported from import_borrowers script.
  39
  40 =head1 SYNOPSIS
  41
  42 use Koha::Patrons::Import;
  43
  44 =head1 DESCRIPTION
  45
  46 This module contains one method for importing patrons in bulk.
  47
  48 =head1 FUNCTIONS
  49
  50 =head2 import_patrons
  51
  52  my $return = Koha::Patrons::Import::import_patrons($params);
  53
  54 Applies various checks and imports patrons in bulk from a csv file.
  55
  56 Further pod documentation needed here.
  57
  58 =cut
  59
  60 has 'today_iso' => ( is => 'ro', lazy => 1,
  61     default => sub { output_pref( { dt => dt_from_string(), dateonly => 1, dateformat => 'iso' } ); }, );
  62
  63 has 'text_csv' => ( is => 'rw', lazy => 1,
  64     default => sub { Text::CSV->new( { binary => 1, } ); },  );
  65
  66 sub import_patrons {
  67     my ($self, $params) = @_;
  68
  69     my $handle = $params->{file};
  70     unless( $handle ) { carp('No file handle passed in!'); return; }
  71
  72     my $matchpoint           = $params->{matchpoint};
  73     my $defaults             = $params->{defaults};
  74     my $ext_preserve         = $params->{preserve_extended_attributes};
  75     my $overwrite_cardnumber = $params->{overwrite_cardnumber};
  76     my $extended             = C4::Context->preference('ExtendedPatronAttributes');
  77     my $set_messaging_prefs  = C4::Context->preference('EnhancedMessagingPreferences');
  78
  79     my @columnkeys = $self->set_column_keys($extended);
  80     my @feedback;
  81     my @errors;
  82
  83     my $imported    = 0;
  84     my $alreadyindb = 0;
  85     my $overwritten = 0;
  86     my $invalid     = 0;
  87     my @imported_borrowers;
  88     my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
  89
  90     # Use header line to construct key to column map
  91     my %csvkeycol;
  92     my $borrowerline = <$handle>;
  93     my @csvcolumns   = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
  94     push(@feedback, { feedback => 1, name => 'headerrow', value => join( ', ', @csvcolumns ) });
  95
  96     my @criticals = qw( surname );    # there probably should be others - rm branchcode && categorycode
  97   LINE: while ( my $borrowerline = <$handle> ) {
  98         my $line_number = $.;
  99         my %borrower;
 100         my @missing_criticals;
 101
 102         my $status  = $self->text_csv->parse($borrowerline);
 103         my @columns = $self->text_csv->fields();
 104         if ( !$status ) {
 105             push @missing_criticals, { badparse => 1, line => $line_number, lineraw => decode_utf8($borrowerline) };
 106         }
 107         elsif ( @columns == @columnkeys ) {
 108             @borrower{@columnkeys} = @columns;
 109
 110             # MJR: try to fill blanks gracefully by using default values
 111             foreach my $key (@columnkeys) {
 112                 if ( $borrower{$key} !~ /\S/ ) {
 113                     $borrower{$key} = $defaults->{$key};
 114                 }
 115             }
 116         }
 117         else {
 118             # MJR: try to recover gracefully by using default values
 119             foreach my $key (@columnkeys) {
 120                 if ( defined( $csvkeycol{$key} ) and $columns[ $csvkeycol{$key} ] =~ /\S/ ) {
 121                     $borrower{$key} = $columns[ $csvkeycol{$key} ];
 122                 }
 123                 elsif ( $defaults->{$key} ) {
 124                     $borrower{$key} = $defaults->{$key};
 125                 }
 126                 elsif ( scalar grep { $key eq $_ } @criticals ) {
 127
 128                     # a critical field is undefined
 129                     push @missing_criticals, { key => $key, line => $., lineraw => decode_utf8($borrowerline) };
 130                 }
 131                 else {
 132                     $borrower{$key} = '';
 133                 }
 134             }
 135         }
 136
 137         $borrower{cardnumber} = undef if $borrower{cardnumber} eq "";
 138
 139         # Check if borrower category code exists and if it matches to a known category. Pushing error to missing_criticals otherwise.
 140         $self->check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 141
 142         # Check if branch code exists and if it matches to a branch name. Pushing error to missing_criticals otherwise.
 143         $self->check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 144
 145         # Popular spreadsheet applications make it difficult to force date outputs to be zero-padded, but we require it.
 146         $self->format_dates({borrower => \%borrower, lineraw => $borrowerline, line => $line_number, missing_criticals => \@missing_criticals, });
 147
 148         if (@missing_criticals) {
 149             foreach (@missing_criticals) {
 150                 $_->{borrowernumber} = $borrower{borrowernumber} || 'UNDEF';
 151                 $_->{surname}        = $borrower{surname}        || 'UNDEF';
 152             }
 153             $invalid++;
 154             ( 25 > scalar @errors ) and push @errors, { missing_criticals => \@missing_criticals };
 155
 156             # The first 25 errors are enough.  Keeping track of 30,000+ would destroy performance.
 157             next LINE;
 158         }
 159
 160         # Set patron attributes if extended.
 161         my $patron_attributes = $self->set_patron_attributes($extended, $borrower{patron_attributes}, \@feedback);
 162         if( $extended ) { delete $borrower{patron_attributes}; } # Not really a field in borrowers.
 163
 164         # Default date enrolled and date expiry if not already set.
 165         $borrower{dateenrolled} = $self->today_iso() unless $borrower{dateenrolled};
 166         $borrower{dateexpiry} = Koha::Patron::Categories->find( $borrower{categorycode} )->get_expiry_date( $borrower{dateenrolled} ) unless $borrower{dateexpiry};
 167
 168         my $borrowernumber;
 169         my ( $member, $patron );
 170         if ( defined($matchpoint) && ( $matchpoint eq 'cardnumber' ) && ( $borrower{'cardnumber'} ) ) {
 171             $patron = Koha::Patrons->find( { cardnumber => $borrower{'cardnumber'} } );
 172         }
 173         elsif ( defined($matchpoint) && ($matchpoint eq 'userid') && ($borrower{'userid'}) ) {
 174             $patron = Koha::Patrons->find( { userid => $borrower{userid} } );
 175         }
 176         elsif ($extended) {
 177             if ( defined($matchpoint_attr_type) ) {
 178                 foreach my $attr (@$patron_attributes) {
 179                     if ( $attr->{code} eq $matchpoint and $attr->{value} ne '' ) {
 180                         my @borrowernumbers = $matchpoint_attr_type->get_patrons( $attr->{value} );
 181                         $borrowernumber = $borrowernumbers[0] if scalar(@borrowernumbers) == 1;
 182                         $patron = Koha::Patrons->find( $borrowernumber );
 183                         last;
 184                     }
 185                 }
 186             }
 187         }
 188
 189         if ($patron) {
 190             $member = $patron->unblessed;
 191             $borrowernumber = $member->{'borrowernumber'};
 192         } else {
 193             $member = {};
 194         }
 195
 196         if ( C4::Members::checkcardnumber( $borrower{cardnumber}, $borrowernumber ) ) {
 197             push @errors,
 198               {
 199                 invalid_cardnumber => 1,
 200                 borrowernumber     => $borrowernumber,
 201                 cardnumber         => $borrower{cardnumber}
 202               };
 203             $invalid++;
 204             next;
 205         }
 206
 207
 208         # Check if the userid provided does not exist yet
 209         if (    defined($matchpoint)
 210             and $matchpoint ne 'userid'
 211             and exists $borrower{userid}
 212             and $borrower{userid}
 213             and not ( $borrowernumber ? $patron->userid( $borrower{userid} )->has_valid_userid : Koha::Patron->new( { userid => $borrower{userid} } )->has_valid_userid )
 214         ) {
 215             push @errors, { duplicate_userid => 1, userid => $borrower{userid} };
 216             $invalid++;
 217             next LINE;
 218         }
 219
 220         my $relationship        = $borrower{relationship};
 221         my $guarantor_id        = $borrower{guarantor_id};
 222         delete $borrower{relationship};
 223         delete $borrower{guarantor_id};
 224
 225         if ($borrowernumber) {
 226
 227             # borrower exists
 228             unless ($overwrite_cardnumber) {
 229                 $alreadyindb++;
 230                 push(
 231                     @feedback,
 232                     {
 233                         already_in_db => 1,
 234                         value         => $borrower{'surname'} . ' / ' . $borrowernumber
 235                     }
 236                 );
 237                 next LINE;
 238             }
 239             $borrower{'borrowernumber'} = $borrowernumber;
 240             for my $col ( keys %borrower ) {
 241
 242                 # use values from extant patron unless our csv file includes this column or we provided a default.
 243                 # FIXME : You cannot update a field with a  perl-evaluated false value using the defaults.
 244
 245                 # The password is always encrypted, skip it!
 246                 next if $col eq 'password';
 247
 248                 unless ( exists( $csvkeycol{$col} ) || $defaults->{$col} ) {
 249                     $borrower{$col} = $member->{$col} if ( $member->{$col} );
 250                 }
 251             }
 252
 253             my $patron = Koha::Patrons->find( $borrowernumber );
 254             eval { $patron->set(\%borrower)->store };
 255             if ( $@ ) {
 256                 $invalid++;
 257
 258                 push(
 259                     @errors,
 260                     {
 261                         # TODO We can raise a better error
 262                         name  => 'lastinvalid',
 263                         value => $borrower{'surname'} . ' / ' . $borrowernumber
 264                     }
 265                 );
 266                 next LINE;
 267             }
 268             # Don't add a new restriction if the existing 'combined' restriction matches this one
 269             if ( $borrower{debarred} && ( ( $borrower{debarred} ne $member->{debarred} ) || ( $borrower{debarredcomment} ne $member->{debarredcomment} ) ) ) {
 270
 271                 # Check to see if this debarment already exists
 272                 my $debarrments = GetDebarments(
 273                     {
 274                         borrowernumber => $borrowernumber,
 275                         expiration     => $borrower{debarred},
 276                         comment        => $borrower{debarredcomment}
 277                     }
 278                 );
 279
 280                 # If it doesn't, then add it!
 281                 unless (@$debarrments) {
 282                     AddDebarment(
 283                         {
 284                             borrowernumber => $borrowernumber,
 285                             expiration     => $borrower{debarred},
 286                             comment        => $borrower{debarredcomment}
 287                         }
 288                     );
 289                 }
 290             }
 291             if ($extended) {
 292                 if ($ext_preserve) {
 293                     my $old_attributes = GetBorrowerAttributes($borrowernumber);
 294                     $patron_attributes = extended_attributes_merge( $old_attributes, $patron_attributes );
 295                 }
 296                 push @errors, { unknown_error => 1 }
 297                   unless SetBorrowerAttributes( $borrower{'borrowernumber'}, $patron_attributes, 'no_branch_limit' );
 298             }
 299             $overwritten++;
 300             push(
 301                 @feedback,
 302                 {
 303                     feedback => 1,
 304                     name     => 'lastoverwritten',
 305                     value    => $borrower{'surname'} . ' / ' . $borrowernumber
 306                 }
 307             );
 308         }
 309         else {
 310             my $patron = eval {
 311                 Koha::Patron->new(\%borrower)->store;
 312             };
 313             unless ( $@ ) {
 314
 315                 if ( $patron->is_debarred ) {
 316                     AddDebarment(
 317                         {
 318                             borrowernumber => $patron->borrowernumber,
 319                             expiration     => $patron->debarred,
 320                             comment        => $patron->debarredcomment,
 321                         }
 322                     );
 323                 }
 324
 325                 if ($extended) {
 326                     SetBorrowerAttributes( $patron->borrowernumber, $patron_attributes );
 327                 }
 328
 329                 if ($set_messaging_prefs) {
 330                     C4::Members::Messaging::SetMessagingPreferencesFromDefaults(
 331                         {
 332                             borrowernumber => $patron->borrowernumber,
 333                             categorycode   => $patron->categorycode,
 334                         }
 335                     );
 336                 }
 337
 338                 $imported++;
 339                 push @imported_borrowers, $patron->borrowernumber; #for patronlist
 340                 push(
 341                     @feedback,
 342                     {
 343                         feedback => 1,
 344                         name     => 'lastimported',
 345                         value    => $patron->surname . ' / ' . $patron->borrowernumber,
 346                     }
 347                 );
 348             }
 349             else {
 350                 $invalid++;
 351                 push @errors, { unknown_error => 1 };
 352                 push(
 353                     @errors,
 354                     {
 355                         name  => 'lastinvalid',
 356                         value => $borrower{'surname'} . ' / Create patron',
 357                     }
 358                 );
 359             }
 360         }
 361
 362         # Add a guarantor if we are given a relationship
 363         if ( $guarantor_id ) {
 364             Koha::Patron::Relationship->new(
 365                 {
 366                     guarantee_id => $borrowernumber,
 367                     relationship => $relationship,
 368                     guarantor_id => $guarantor_id,
 369                 }
 370             )->store();
 371         }
 372     }
 373
 374     return {
 375         feedback      => \@feedback,
 376         errors        => \@errors,
 377         imported      => $imported,
 378         overwritten   => $overwritten,
 379         already_in_db => $alreadyindb,
 380         invalid       => $invalid,
 381         imported_borrowers => \@imported_borrowers,
 382     };
 383 }
 384
 385 =head2 prepare_columns
 386
 387  my @csvcolumns = $self->prepare_columns({headerrow => $borrowerline, keycol => \%csvkeycol, errors => \@errors, });
 388
 389 Returns an array of all column key and populates a hash of colunm key positions.
 390
 391 =cut
 392
 393 sub prepare_columns {
 394     my ($self, $params) = @_;
 395
 396     my $status = $self->text_csv->parse($params->{headerrow});
 397     unless( $status ) {
 398         push( @{$params->{errors}}, { badheader => 1, line => 1, lineraw => $params->{headerrow} });
 399         return;
 400     }
 401
 402     my @csvcolumns = $self->text_csv->fields();
 403     my $col = 0;
 404     foreach my $keycol (@csvcolumns) {
 405         # columnkeys don't contain whitespace, but some stupid tools add it
 406         $keycol =~ s/ +//g;
 407         $keycol =~ s/^\N{BOM}//; # Strip BOM if exists, otherwise it will be part of first column key
 408         $params->{keycol}->{$keycol} = $col++;
 409     }
 410
 411     return @csvcolumns;
 412 }
 413
 414 =head2 set_attribute_types
 415
 416  my $matchpoint_attr_type = $self->set_attribute_types({ extended => $extended, matchpoint => $matchpoint, });
 417
 418 Returns an attribute type based on matchpoint parameter.
 419
 420 =cut
 421
 422 sub set_attribute_types {
 423     my ($self, $params) = @_;
 424
 425     my $attribute_types;
 426     if( $params->{extended} ) {
 427         $attribute_types = C4::Members::AttributeTypes->fetch($params->{matchpoint});
 428     }
 429
 430     return $attribute_types;
 431 }
 432
 433 =head2 set_column_keys
 434
 435  my @columnkeys = set_column_keys($extended);
 436
 437 Returns an array of borrowers' table columns.
 438
 439 =cut
 440
 441 sub set_column_keys {
 442     my ($self, $extended) = @_;
 443
 444     my @columnkeys = map { $_ ne 'borrowernumber' ? $_ : () } Koha::Patrons->columns();
 445     push( @columnkeys, 'patron_attributes' ) if $extended;
 446
 447     return @columnkeys;
 448 }
 449
 450 =head2 set_patron_attributes
 451
 452  my $patron_attributes = set_patron_attributes($extended, $borrower{patron_attributes}, $feedback);
 453
 454 Returns a reference to array of hashrefs data structure as expected by SetBorrowerAttributes.
 455
 456 =cut
 457
 458 sub set_patron_attributes {
 459     my ($self, $extended, $patron_attributes, $feedback) = @_;
 460
 461     unless( $extended ) { return; }
 462     unless( defined($patron_attributes) ) { return; }
 463
 464     # Fixup double quotes in case we are passed smart quotes
 465     $patron_attributes =~ s/\xe2\x80\x9c/"/g;
 466     $patron_attributes =~ s/\xe2\x80\x9d/"/g;
 467
 468     push (@$feedback, { feedback => 1, name => 'attribute string', value => $patron_attributes });
 469
 470     my $result = extended_attributes_code_value_arrayref($patron_attributes);
 471
 472     return $result;
 473 }
 474
 475 =head2 check_branch_code
 476
 477  check_branch_code($borrower{branchcode}, $borrowerline, $line_number, \@missing_criticals);
 478
 479 Pushes a 'missing_criticals' error entry if no branch code or branch code does not map to a branch name.
 480
 481 =cut
 482
 483 sub check_branch_code {
 484     my ($self, $branchcode, $borrowerline, $line_number, $missing_criticals) = @_;
 485
 486     # No branch code
 487     unless( $branchcode ) {
 488         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => decode_utf8($borrowerline), });
 489         return;
 490     }
 491
 492     # look for branch code
 493     my $library = Koha::Libraries->find( $branchcode );
 494     unless( $library ) {
 495         push (@$missing_criticals, { key => 'branchcode', line => $line_number, lineraw => decode_utf8($borrowerline),
 496                                      value => $branchcode, branch_map => 1, });
 497     }
 498 }
 499
 500 =head2 check_borrower_category
 501
 502  check_borrower_category($borrower{categorycode}, $borrowerline, $line_number, \@missing_criticals);
 503
 504 Pushes a 'missing_criticals' error entry if no category code or category code does not map to a known category.
 505
 506 =cut
 507
 508 sub check_borrower_category {
 509     my ($self, $categorycode, $borrowerline, $line_number, $missing_criticals) = @_;
 510
 511     # No branch code
 512     unless( $categorycode ) {
 513         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => decode_utf8($borrowerline), });
 514         return;
 515     }
 516
 517     # Looking for borrower category
 518     my $category = Koha::Patron::Categories->find($categorycode);
 519     unless( $category ) {
 520         push (@$missing_criticals, { key => 'categorycode', line => $line_number, lineraw => decode_utf8($borrowerline),
 521                                      value => $categorycode, category_map => 1, });
 522     }
 523 }
 524
 525 =head2 format_dates
 526
 527  format_dates({borrower => \%borrower, lineraw => $lineraw, line => $line_number, missing_criticals => \@missing_criticals, });
 528
 529 Pushes a 'missing_criticals' error entry for each of the 3 date types dateofbirth, dateenrolled and dateexpiry if it can not
 530 be formatted to the chosen date format. Populates the correctly formatted date otherwise.
 531
 532 =cut
 533
 534 sub format_dates {
 535     my ($self, $params) = @_;
 536
 537     foreach my $date_type (qw(dateofbirth dateenrolled dateexpiry date_renewed)) {
 538         my $tempdate = $params->{borrower}->{$date_type} or next();
 539         my $formatted_date = eval { output_pref( { dt => dt_from_string( $tempdate ), dateonly => 1, dateformat => 'iso' } ); };
 540
 541         if ($formatted_date) {
 542             $params->{borrower}->{$date_type} = $formatted_date;
 543         } else {
 544             $params->{borrower}->{$date_type} = '';
 545             push (@{$params->{missing_criticals}}, { key => $date_type, line => $params->{line}, lineraw => decode_utf8($params->{lineraw}), bad_date => 1 });
 546         }
 547     }
 548 }
 549
 550 1;
 551
 552 =head1 AUTHOR
 553
 554 Koha Team
 555
 556 =cut