Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 # See http://www.koha.org/wiki/?page=KohaInstaller
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27
  28 my $DEBUG = 0;
  29 die "perl 5.6.1 or later required" unless ($] >= 5.006001);
  30
  31 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  32
  33 my $dirtree = hashdir('.');
  34 my %result = ();
  35
  36 =head1 NAME
  37
  38 Makefile.PL - Koha packager and installer
  39
  40 =head1 SYNOPSIS
  41
  42 =head2 BASIC INSTALLATION
  43
  44         perl Makefile.PL
  45         make
  46         sudo make install
  47
  48 =head2 PACKAGING RELEASE TARBALLS
  49
  50         make manifest tardist
  51         make manifest zipdist
  52
  53 =head2 CLEANING UP
  54
  55         make clean
  56
  57 =head1 DESCRIPTION
  58
  59 This is a packager and installer that uses
  60 ExtUtils::MakeMaker, which is fairly common
  61 on perl systems.
  62 As well as building tar or zip files
  63 and installing with the above commands,
  64 it allows us to check pre-requisites
  65 and generate configuration files.
  66
  67 =head1 VARIABLES
  68
  69 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  70
  71 Basic metadata about this software.
  72
  73 =head2 NO_META
  74
  75 Suppress generation of META.yml file.
  76
  77 =head2 PREREQ_PM
  78
  79 Hash of perl modules and versions required.
  80
  81 =head2 PM
  82
  83 Hash of file mappings
  84
  85 =head2 PL_FILES
  86
  87 This is a hash of PL scripts to run after installation and
  88 the files to ask them to generate.
  89 Maybe use the values from CONFIGURE
  90 to generate initial configuration files in future.
  91
  92 =cut
  93
  94 =head2 target_map
  95
  96 This is a hash mapping directories and files in the
  97 source tree to installation target directories.  The rules
  98 for this mapping are:
  99
 100 =over 4
 101
 102 =item If a directory or file is specified, it and its
 103 contents will be copied to the installation target directory.
 104
 105 =item If a subdirectory of a mapped directory is specified,
 106 its target overrides the parent's target for that subdirectory.
 107
 108 =item The value of each map entry may either be a scalar containing
 109 one target or a reference to a hash containing 'target' and 'trimdir'
 110 keys.
 111
 112 =item Any files at the top level of the source tree that are
 113 not included in the map will not be installed.
 114
 115 =item Any directories at the top level of the source tree
 116 that are not included in the map will be installed in
 117 INTRANET_CGI_DIR.  This is a sensible default given the
 118 current organization of the source tree, but (FIXME) it
 119 would be better to reorganize the source tree to better
 120 match the installation system, to allow adding new directories
 121 without having to adjust Makefile.PL each time.  The idea
 122 is to make the C<$target_map> hash as minimal as possible.
 123
 124 =back
 125
 126 The permitted installation targets are:
 127
 128 =over 4
 129
 130 =item INTRANET_CGI_DIR
 131
 132 CGI scripts for intranet (staff) interface.
 133
 134 =item INTRANET_TMPL_DIR
 135
 136 HTML templates for the intranet interface.
 137
 138 =item INTRANET_WWW_DIR
 139
 140 HTML files, images, etc. for DocumentRoot for the intranet interface.
 141
 142 =item OPAC_CGI_DIR
 143
 144 CGI scripts for OPAC (public) interface.
 145
 146 =item OPAC_TMPL_DIR
 147
 148 HTML templates for the OPAC interface.
 149
 150 =item OPAC_WWW_DIR
 151
 152 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 153
 154 =item PERL_MODULE_DIR
 155
 156 Perl modules (at present just the C4 modules) that are intimately
 157 tied to Koha.  Depending on the installation options, these
 158 may or may not be installed one of the standard directories
 159 in Perl's default @LIB.
 160
 161 =item KOHA_CONF_DIR
 162
 163 Directory for Koha configuration files.
 164
 165 =item ZEBRA_CONF_DIR
 166
 167 Directory for Zebra configuration files.
 168
 169 =item ZEBRA_LOCK_DIR
 170
 171 Directory for Zebra's lock files.
 172
 173 =item ZEBRA_DATA_DIR
 174
 175 Directory for Zebra's data files.
 176
 177 =item ZEBRA_RUN_DIR
 178
 179 Directory for Zebra's UNIX-domain sockets.
 180
 181 =item MISC_DIR
 182
 183 Directory for for miscellaenous scripts, among other
 184 things the translation toolkit and RSS feed tools.
 185
 186 =item SCRIPT_DIR
 187
 188 Directory for command-line scripts and daemons.
 189
 190 =item MAN_DIR
 191
 192 Directory for man pages created from POD -- will mostly
 193 contain information of interest to Koha developers.
 194
 195 =item DOC_DIR
 196
 197 Directory for Koha documentation accessed from the
 198 command-line, e.g., READMEs.
 199
 200 =item LOG_DIR
 201
 202 Directory for Apache and Zebra logs produced by Koha.
 203
 204 =item NONE
 205
 206 This is a dummy target used to explicitly state
 207 that a given file or directory is not to be installed.
 208 This is used either for parts of the installer itself
 209 or for development tools that are not applicable to a
 210 production installation.
 211
 212 =back
 213
 214 =cut
 215
 216 my $target_map = {
 217   './about.pl'                  => 'INTRANET_CGI_DIR',
 218   './acqui'                     => 'INTRANET_CGI_DIR',
 219   './admin'                     => 'INTRANET_CGI_DIR',
 220   './authorities'               => 'INTRANET_CGI_DIR',
 221   './C4'                        => 'PERL_MODULE_DIR',
 222   './C4/SIP/t'                  => 'NONE',
 223   './C4/SIP/koha_test'          => 'NONE',
 224   './C4/tests'                  => 'NONE',
 225   './catalogue'                 => 'INTRANET_CGI_DIR',
 226   './cataloguing'               => 'INTRANET_CGI_DIR',
 227   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 228   './check_sysprefs.pl'         => 'NONE',
 229   './circ'                      => 'INTRANET_CGI_DIR',
 230   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 231   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 232   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 233   './help.pl'                   => 'INTRANET_CGI_DIR',
 234   './installer-CPAN.pl'         => 'NONE',
 235   './installer'                 => 'INTRANET_CGI_DIR',
 236   './koha-tmpl/errors'          => {target => 'INTRANET_CGI_DIR', trimdir => 2},
 237   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 238   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 239   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 240   './labels'                    => 'INTRANET_CGI_DIR',
 241   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 242   './Makefile.PL'               => 'NONE',
 243   './MANIFEST.SKIP'             => 'NONE',
 244   './members'                   => 'INTRANET_CGI_DIR',
 245   './misc'                      => { target => 'SCRIPT_DIR', trimdir => -1 },
 246   './misc/info'                 => { target => 'DOC_DIR', trimdir => 2 },
 247   './misc/release notes'        => { target => 'DOC_DIR', trimdir => 2 },
 248   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 249   './misc/installer_devel_notes' => 'NONE',
 250   './opac'                      => 'OPAC_CGI_DIR',
 251   './README.txt'                => 'NONE',
 252   './reports'                   => 'INTRANET_CGI_DIR',
 253   './reserve'                   => 'INTRANET_CGI_DIR',
 254   './reviews'                   => 'INTRANET_CGI_DIR',
 255   './rewrite-config.PL'         => 'NONE',
 256   './reviews'                   => 'INTRANET_CGI_DIR',
 257   './rss'                       => 'MISC_DIR',
 258   './serials'                   => 'INTRANET_CGI_DIR',
 259   './skel'                      => 'NONE',
 260   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 261   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 262   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 263   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 264   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 265   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 266   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 267   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 268   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 269   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 270   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 271   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 272   './sms'                       => 'INTRANET_CGI_DIR',
 273   './suggestion'                => 'INTRANET_CGI_DIR',
 274   './svc'                       => 'INTRANET_CGI_DIR',
 275   './t'                         => 'NONE',
 276   './tmp'                       => 'NONE', # FIXME need to determine whether
 277                                            # Koha generates any persistent temp files
 278                                            # that should go in /var/tmp/koha
 279   './tools'                     => 'INTRANET_CGI_DIR',
 280   './virtualshelves'            => 'INTRANET_CGI_DIR',
 281   # ignore files and directories created by the install itself
 282   './pm_to_blib'                => 'NONE',
 283   './blib'                      => 'NONE',
 284 };
 285
 286 =head1 CONFIGURATION OPTIONS
 287
 288 The following configuration options are used by the installer.
 289
 290 =over 4
 291
 292 =item INSTALL_MODE
 293
 294 Specifies whether installation will be FHS-compliant (default,
 295 assumes user has root), put everything under
 296 a single directory (for users installing on a web host
 297 that allows CGI scripts and a MySQL database but not root
 298 access), or development (for a developer who wants to run
 299 Koha from a git clone with no fuss).
 300
 301 =item INSTALL_BASE
 302
 303 Directory under which most components will go.  Default
 304 value will vary depending on INSTALL_MODE.
 305
 306 =item DB_TYPE
 307
 308 Type of DBMS (e.g., mysql or Pg).
 309
 310 =item DB_HOST
 311
 312 Name of DBMS server.
 313
 314 =item DB_PORT
 315
 316 Port that DBMS server is listening on.
 317
 318 =item DB_NAME
 319
 320 Name of the DBMS database for Koha.
 321
 322 =item DB_USER
 323
 324 Name of DBMS user account for Koha's database.
 325
 326 =item DB_PASS
 327
 328 Pasword of DMBS user account for Koha's database.
 329
 330 =item INSTALL_ZEBRA
 331
 332 Whether to install Zebra configuration files and data
 333 directories.
 334
 335 =item ZEBRA_MARC_FORMAT
 336
 337 Specifies format of MARC records to be indexed by Zebra.
 338
 339 =item ZEBRA_LANGUAGE
 340
 341 Specifies primary language of records that will be
 342 indexed by Zebra.
 343
 344 =item ZEBRA_USER
 345
 346 Internal Zebra user account for the index.
 347
 348 =item ZEBRA_PASS
 349
 350 Internal Zebra user account's password.
 351
 352 =item KOHA_USER
 353
 354 System user account that will own Koha's files.
 355
 356 =item KOHA_GROUP
 357
 358 System group that will own Koha's files.
 359
 360 =back
 361
 362 =cut
 363
 364 # default configuration options
 365 my %config_defaults = (
 366   'INSTALL_MODE'      => 'standard',
 367   'INSTALL_BASE'      => '/usr/share/koha',
 368   'DB_TYPE'           => 'mysql',
 369   'DB_HOST'           => 'localhost',
 370   'DB_NAME'           => 'koha',
 371   'DB_USER'           => 'kohaadmin',
 372   'DB_PASS'           => 'katikoan',
 373   'INSTALL_ZEBRA'     => 'yes',
 374   'ZEBRA_MARC_FORMAT' => 'marc21',
 375   'ZEBRA_LANGUAGE'    => 'en',
 376   'ZEBRA_USER'        => 'kohauser',
 377   'ZEBRA_PASS'        => 'zebrastripes',
 378   'KOHA_USER'         => 'koha',
 379   'KOHA_GROUP'        => 'koha',
 380 );
 381
 382 # valid values for certain configuration options
 383 my %valid_config_values = (
 384   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 385   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 386   'INSTALL_ZEBRA' => { 'yes' => 1, 'no' => 1 },
 387   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 388   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'fr' => 1 }, # FIXME should generate from contents of distribution
 389 );
 390
 391 my %config = get_configuration(\%config_defaults, \%valid_config_values);
 392 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 393 display_configuration(\%config, $target_directories);
 394 my $file_map = {};
 395 get_file_map($target_map, $dirtree, $file_map, $config{'INSTALL_ZEBRA'} eq "yes" ? 1: 0);
 396
 397 my $pl_files = {
 398       'rewrite-config.PL' => [
 399          'blib/KOHA_CONF_DIR/koha-conf.xml',
 400          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 401          ]
 402 };
 403
 404 if ($config{'INSTALL_ZEBRA'} eq "yes") {
 405     push @{ $pl_files->{'rewrite-config.PL'} }, (
 406         'blib/ZEBRA_CONF_DIR/etc/passwd',
 407         'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 408         'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg'
 409     );
 410 }
 411
 412 if ($config{'INSTALL_MODE'} ne "dev") {
 413     push @{ $pl_files->{'rewrite-config.PL'} }, (
 414         'blib/PERL_MODULE_DIR/C4/Context.pm'
 415     );
 416 }
 417
 418 WriteMakefile(
 419     NAME => 'koha',
 420     #VERSION => strftime('2.9.%Y%m%d%H',gmtime),
 421     VERSION_FROM => 'kohaversion.pl',
 422     ABSTRACT => 'Award-winning integrated library system (ILS) and Web OPAC',
 423     AUTHOR => 'Koha Developers <koha-devel@nongnu.org>',
 424     NO_META => 1,
 425     PREREQ_PM => {
 426 'CGI' => 3.15,
 427 'CGI::Carp' => 1.29,
 428 'CGI::Session' => '4.10',
 429 'Class::Factory::Util' => 1.7,
 430 'Class::Accessor' => 0.30,
 431 'DBD::mysql' => 3.0008,
 432 'DBI' => 1.53,
 433 'Data::Dumper' => 2.121_08,
 434 'Date::Calc' => 5.4,
 435 'Date::Manip' => 5.44,
 436 'Digest::MD5' => 2.36,
 437 'File::Temp' => 0.16,
 438 'GD::Barcode::UPCE' => 1.1,
 439 'Getopt::Long' => 2.35,
 440 'Getopt::Std' => 1.05,
 441 'HTML::Template::Pro' => 0.65,
 442 'HTTP::Cookies' => 1.39,
 443 'HTTP::Request::Common' => 1.26,
 444 'LWP::Simple' => 1.41,
 445 'LWP::UserAgent' => 2.033,
 446 'Lingua::Stem' => 0.82,
 447 'List::Util' => 1.18,
 448 'Locale::Language' => 2.07,
 449 'MARC::Charset' => 0.98,
 450 'MARC::Crosswalk::DublinCore' => 0.02,
 451 'MARC::File::XML' => 0.88,
 452 'MARC::Record' => 2.00,
 453 'MIME::Base64' => 3.07,
 454 'MIME::QuotedPrint' => 3.07,
 455 'Mail::Sendmail' => 0.79,
 456 'Net::Z3950::ZOOM' => 1.16,
 457 'PDF::API2' => 2.000,
 458 'PDF::API2::Page' => 2.000,
 459 'PDF::API2::Util' => 2.000,
 460 'PDF::Reuse' => 0.33,
 461 'PDF::Reuse::Barcode' => 0.05,
 462 'POSIX' => 1.09,
 463 'Schedule::At' => 1.06,
 464 'Term::ANSIColor' => 1.10,
 465 'Test' => 1.25,
 466 'Test::Harness' => 2.56,
 467 'Test::More' => 0.62,
 468 'Text::CSV' => 0.01,
 469 'Text::CSV_XS' => 0.32,
 470 'Text::Wrap' => 2005.082401,
 471 'Time::HiRes' => 1.86,
 472 'Time::localtime' => 1.02,
 473 'Unicode::Normalize' => 0.32,
 474 'XML::Dumper' => 0.81,
 475 'XML::LibXML' => 1.59,
 476 'XML::SAX::ParserFactory' => 1.01,
 477 'XML::Simple' => 2.14,
 478 'XML::RSS' => 1.31,
 479         },
 480
 481         # File tree mapping
 482         PM => $file_map,
 483
 484     # Man pages generated from POD
 485     INSTALLMAN1DIR => File::Spec->catdir($target_directories->{'MAN_DIR'}, 'man1'),
 486     INSTALLMAN3DIR => File::Spec->catdir($target_directories->{'MAN_DIR'}, 'man3'),
 487
 488    PL_FILES => $pl_files,
 489
 490 );
 491
 492 =head1 FUNCTIONS
 493
 494 =head2 hashdir
 495
 496 This function recurses through the directory structure and builds
 497 a hash of hashes containing the structure with arrays holding filenames.
 498 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 499
 500 =cut
 501
 502 sub hashdir{
 503     my $dir = shift;
 504     opendir my $dh, $dir or die $!;
 505     my $tree = {}->{$dir} = {};
 506     while( my $file = readdir($dh) ) {
 507         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 508         my $path = $dir .'/' . $file;
 509         $tree->{$file} = hashdir($path), next if -d $path;
 510         push @{$tree->{'.'}}, $file;
 511     }
 512     return $tree;
 513 }
 514
 515 =head2 get_file_map
 516
 517 This function combines the target_map and file hash to
 518 map each source file to its destination relative to
 519 the set of installation targets.
 520
 521 Output will be a hash mapping from each source file
 522 to its destination value, like this:
 523
 524 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 525
 526 =cut
 527
 528 sub get_file_map {
 529     my $target_map = shift;
 530     my $dirtree = shift;
 531     my $file_map = shift;
 532     my $install_zebra = shift;
 533     my $curr_path = @_ ? shift : ['.'];
 534
 535     # Traverse the directory tree.
 536     # For each file or directory, identify the
 537     # most specific match in the target_map
 538     foreach my $dir (sort keys %{ $dirtree }) {
 539         if ($dir eq '.') {
 540             # deal with files in directory
 541             foreach my $file (sort @{ $dirtree->{$dir} }) {
 542                 my $targetdir = undef;
 543                 my $matchlevel = undef;
 544                 # first, see if there is a match on this specific
 545                 # file in the target map
 546                 my $filepath = join("/", @$curr_path, $file);
 547                 if (exists $target_map->{$filepath}) {
 548                     $targetdir = $target_map->{$filepath};
 549                     $matchlevel = scalar(@$curr_path) + 1;
 550                 } else {
 551                     # no match on the specific file; look for
 552                     # a directory match
 553                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 554                         my $dirpath = join("/", @$curr_path[0..$i]);
 555                         if (exists $target_map->{$dirpath}) {
 556                             $targetdir = $target_map->{$dirpath};
 557                             $matchlevel = $i + 1;
 558                             last;
 559                         }
 560                     }
 561                 }
 562                 if (defined $targetdir) {
 563                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel, $install_zebra);
 564                 } else {
 565                     my $path = join("/", @$curr_path);
 566                     print "failed to map: $path/$file\n" if $DEBUG;
 567                 }
 568             }
 569         } else {
 570             # dealing with subdirectory
 571             push @$curr_path, $dir;
 572             get_file_map($target_map, $dirtree->{$dir}, $file_map, $install_zebra, $curr_path);
 573             pop @$curr_path;
 574         }
 575     }
 576 }
 577
 578 sub _add_to_file_map {
 579     my $file_map = shift;
 580     my $targetdir = shift;
 581     my $curr_path = shift;
 582     my $file = shift;
 583     my $matchlevel = shift;
 584     my $install_zebra = shift;
 585     my $dest_path = @_ ? shift : $curr_path;
 586
 587     # The target can be one of the following:
 588     # 1. scalar representing target symbol
 589     # 2. hash ref containing target and trimdir keys
 590     #
 591     # Consequently, this routine traverses this structure,
 592     # calling itself recursively, until it deals with
 593     # all of the scalar target symbols.
 594     if (ref $targetdir eq 'HASH') {
 595         my $subtarget = $targetdir->{target};
 596         if (exists $targetdir->{trimdir}) {
 597             # if we get here, we've specified that
 598             # rather than installing the file to
 599             # $(TARGET)/matching/dirs/subdirs/file,
 600             # we want to install it to
 601             # $(TARGET)/subdirs/file
 602             #
 603             # Note that this the only place where
 604             # $matchlevel is used.
 605             my @new_dest_path = @$dest_path;
 606             if ($targetdir->{trimdir} == -1)  {
 607                 splice @new_dest_path, 0, $matchlevel;
 608             } else {
 609                 splice @new_dest_path, 0, $targetdir->{trimdir};
 610             }
 611             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra, \@new_dest_path);
 612         } else {
 613             # actually getting here means that the
 614             # target was unnecessarily listed
 615             # as a hash, but we'll forgive that
 616             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra);
 617         }
 618     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 619         my $source = File::Spec->catfile(@$curr_path, $file);
 620         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 621         #print "$source => $destination\n"; # DEBUG
 622         # quote spaces in file names
 623         # FIXME: this is of questionable portability and
 624         # probably depends on user's make recognizing this
 625         # quoting syntax -- probably better to remove
 626         # spaces and shell metacharacters from all file names
 627         $source =~ s/ /\\ /g;
 628         $destination =~ s/ /\\ /g;
 629
 630         $file_map->{$source} = $destination unless (!$install_zebra and $targetdir =~ /ZEBRA/);
 631     }
 632 }
 633
 634 =head2 get_configuration_options
 635
 636 This prompts the user for various configuration options.
 637
 638 =cut
 639
 640 sub get_configuration {
 641   my $defaults = shift;
 642   my $valid_values = shift;
 643   my %config = ();
 644
 645   my $msg = q(
 646 By default, Koha can be installed in one of three ways:
 647
 648 standard: Install files in conformance with the Filesystem
 649           Hierarchy Standard (FHS).  This is the default mode
 650           and should be used when installing a production
 651           Koha system.  On Unix systems, root access is
 652           needed to complete a standard installation.
 653
 654 single:   Install files under a single directory.  This option
 655           is useful for installing Koha without root access, e.g.,
 656           on a web host that allows CGI scripts and MySQL databases
 657           but requires the user to keep all files under the user's
 658           HOME directory.
 659
 660 dev:      Create a set of symbolic links and configuration files to
 661           allow Koha to run directly from the source distribution.
 662           This mode is useful for developers who want to run
 663           Koha from a git clone.
 664
 665 Installation mode);
 666     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 667     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values);
 668
 669     # set message and default value for INSTALL_BASE
 670     # depending on value of INSTALL_MODE
 671     my $install_base_default = $defaults->{'INSTALL_BASE'};
 672     if ($config{'INSTALL_MODE'} eq 'dev') {
 673         $msg = q(
 674 Please specify the directory in which to install Koha's
 675 active configuration files and (if applicable) the
 676 Zebra database.  Koha's CGI scripts and templates will
 677 be run from the current directory.
 678
 679 Configuration directory:);
 680         # FIXME - home directory portability consideration apply
 681         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha-dev" : "/usr/share/koha-dev";
 682     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 683         $msg = "\nPlease specify the directory in which to install Koha";
 684         # FIXME -- we're assuming under a 'single' mode install
 685         # that user will likely want to install under the home
 686         # directory.  This is OK in and of itself, but we should
 687         # use File::HomeDir to locate the home directory portably.
 688         # This is deferred for now because File::HomeDir is not yet
 689         # core.
 690         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : "/usr/share/koha";
 691     } else {
 692         # must be standard
 693         $msg = q(
 694 Please specify the directory under which most Koha files
 695 will be installed.
 696
 697 Note that if you are planning in installing more than
 698 one instance of Koha, you may want to modify the last
 699 component of the directory path, which will be used
 700 as the package name in the FHS layout.
 701
 702 Base installation directory);
 703     }
 704     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values);
 705     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 706
 707     if ($config{'INSTALL_MODE'} eq "standard") {
 708         $msg = q(
 709 Since you are using the 'standard' install
 710 mode, you should run 'make install' as root.
 711 However, it is recommended that a non-root
 712 user (on Unix and Linux platforms) have
 713 ownership of Koha's files, including the
 714 Zebra indexes if applicable.
 715
 716 Please specify a user account.  This
 717 user account does not need to exist
 718 right now, but it needs to exist
 719 before you run 'make install'.  Please
 720 note that for security reasons, this
 721 user should not be the same as the user
 722 account Apache runs under.
 723
 724 User account);
 725         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values);
 726
 727         $msg = q(
 728 Please specify the group that should own
 729 Koha's files.  As above, this group need
 730 not exist right now, but should be created
 731 before you run 'make install'.
 732
 733 Group);
 734         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values);
 735     }
 736
 737     $msg = q(
 738 Please specify which database engine you will use
 739 to store data in Koha.  The choices are MySQL and
 740 PostgreSQL; please note that at the moment
 741 PostgreSQL support is highly experimental.
 742
 743 DBMS to use);
 744     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 745     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values);
 746
 747     $msg = q(
 748 Please specify the name or address of your
 749 database server.  Note that the database
 750 does not have to exist at this point, it
 751 can be created after running 'make install'
 752 and before you try using Koha for the first time.
 753
 754 Database server);
 755     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values);
 756
 757     $msg = q(
 758 Please specify the port used to connect to the
 759 DMBS);
 760     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 761     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values);
 762
 763     $msg = q(
 764 Please specify the name of the database to be
 765 used by Koha);
 766     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values);
 767
 768     $msg = q(
 769 Please specify the user that owns the database to be
 770 used by Koha);
 771     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values);
 772
 773     $msg = q(
 774 Please specify the password of the user that owns the
 775 database to be used by Koha);
 776     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values);
 777
 778     $msg = q(
 779 Koha can use the Zebra search engine for high-performance
 780 searching of bibliographic and authority records.  If you
 781 have installed the Zebra software and would like to use it,
 782 please answer 'yes' to the following question.  Otherwise,
 783 Koha will default to using its internal search engine.
 784
 785 Please note that if you choose *NOT* to install Zebra,
 786 koha-conf.xml will still contain some references to Zebra
 787 settings.  Those references will be ignored by Koha.
 788
 789 Install the Zebra configuration files?);
 790     $msg .= _add_valid_values_disp('INSTALL_ZEBRA', $valid_values);
 791     $config{'INSTALL_ZEBRA'} = _get_value('INSTALL_ZEBRA', $msg, $defaults->{'INSTALL_ZEBRA'}, $valid_values);
 792
 793     if ($config{'INSTALL_ZEBRA'} eq 'yes') {
 794         $msg = q(
 795 Since you've chosen to use Zebra with Koha,
 796 you must specify the primary MARC format of the
 797 records to be indexed by Zebra.
 798
 799 Koha provides Zebra configuration files for MARC 21
 800 and UNIMARC.
 801
 802 MARC format for Zebra indexing);
 803         $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 804         $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values);
 805         $msg = q(
 806 Koha supplies Zebra configuration files tuned for
 807 searching either English (en) or French (fr) MARC
 808 records.
 809
 810 Primary language for Zebra indexing);
 811         $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 812         $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values);
 813
 814         $msg = q(
 815 Please specify Zebra database user);
 816         $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values);
 817
 818         $msg = q(
 819 Please specify the Zebra database password);
 820         $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values);
 821
 822     }
 823
 824     print "\n\n";
 825     return %config;
 826 }
 827
 828 sub _add_valid_values_disp {
 829     my $key = shift;
 830     my $valid_values = shift;
 831
 832     my $disp = "";
 833     if (exists $valid_values->{$key}) {
 834         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
 835     }
 836     return $disp;
 837 }
 838
 839 sub _get_value {
 840     my $key = shift;
 841     my $msg = shift;
 842     my $default = shift;
 843     my $valid_values = shift;
 844
 845     # override default value from environment
 846     if (exists $ENV{$key}) {
 847         $default = $ENV{$key};
 848         $msg .= " (default from environment)";
 849     }
 850
 851     my $val = prompt($msg, $default);
 852     while (exists $valid_values->{$key} and not exists $valid_values->{$key}->{$val}) {
 853         my $retry_msg = "Value '$val' is not a valid option.\n";
 854         $retry_msg .= "Please enter a value";
 855         $retry_msg .= _add_valid_values_disp($key, $valid_values);
 856         $val = prompt($retry_msg, $default);
 857     }
 858     return $val;
 859 }
 860
 861 =head2 get_target_directories
 862
 863 Creates a hash mapping from symbols for installation target
 864 directories to actual directory paths.
 865
 866 Also returns a hash indicating targets for which
 867 files need not be copied -- this is used for the 'dev'
 868 mode installation, where some files are installed in place.
 869
 870 =cut
 871
 872 sub get_target_directories {
 873     my $config = shift;
 874
 875     my $base = $config->{'INSTALL_BASE'};
 876     my $mode = $config->{'INSTALL_MODE'};
 877
 878     # get last component of install base directory
 879     # to treat as package name
 880     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
 881     my @basedir = File::Spec->splitdir($directories);
 882     my $package = pop @basedir;
 883
 884     my %dirmap = ();
 885     my %skipdirs = ();
 886     if ($mode eq 'single') {
 887         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 888         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 889         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 890         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 891         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 892         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 893         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 894         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 895         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 896         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
 897         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 898         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 899         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 900         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 901         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 902         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 903         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 904     } elsif ($mode eq 'dev') {
 905         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
 906         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
 907         $skipdirs{'INTRANET_CGI_DIR'} = 1;
 908         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
 909         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
 910         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
 911         $skipdirs{'INTRANET_WWW_DIR'} = 1;
 912         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir, 'opac');
 913         $skipdirs{'OPAC_CGI_DIR'} = 1;
 914         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
 915         $skipdirs{'OPAC_TMPL_DIR'} = 1;
 916         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
 917         $skipdirs{'OPAC_WWW_DIR'} = 1;
 918         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
 919         $skipdirs{'PERL_MODULE_DIR'} = 1;
 920         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
 921         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
 922         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
 923         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 924         $skipdirs{'SCRIPT_DIR'} = 1;
 925         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 926         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 927         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
 928         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
 929         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
 930         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
 931     } else {
 932         # mode is standard, i.e., 'fhs'
 933         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
 934         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
 935         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
 936         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
 937         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
 938         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
 939         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
 940         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
 941         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
 942         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
 943         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
 944         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
 945         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
 946         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
 947         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
 948         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
 949         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
 950     }
 951
 952     _get_env_overrides(\%dirmap);
 953     _get_argv_overrides(\%dirmap);
 954
 955     return \%dirmap, \%skipdirs;
 956 }
 957
 958 sub _get_env_overrides {
 959     my $dirmap = shift;
 960
 961     foreach my $key (keys %$dirmap) {
 962         if (exists $ENV{$key}) {
 963             $dirmap->{$key} = $ENV{$key};
 964             print "Setting $key from environment\n";
 965         }
 966     }
 967 }
 968
 969 sub _get_argv_overrides {
 970     my $dirmap = shift;
 971
 972     my @new_argv = ();
 973     for (my $i = 0; $i <= $#ARGV; $i++) {
 974         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
 975             $dirmap->{$1} = $2;
 976         } else {
 977             push @new_argv, $ARGV[$i];
 978         }
 979     }
 980     @ARGV = @new_argv;
 981 }
 982
 983 sub display_configuration {
 984     my $config = shift;
 985     my $dirmap = shift;
 986     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
 987     foreach my $key (sort keys %$config) {
 988         print sprintf("%-25.25s%s\n", $key, $config->{$key});
 989     }
 990
 991     print "\nand in the following directories:\n\n";
 992     foreach my $key (sort keys %$dirmap) {
 993         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
 994     }
 995     print "\n\nTo change any configuration setting, please run\n";
 996     print "perl Makefile.PL again.  To override one of the target\n";
 997     print "directories, you can do so on the command line like this:\n";
 998     print "\nperl Makefile.PL PERL_MODULE_DIR=/usr/share/perl/5.8\n\n";
 999     print "You can also set different default values for parameters\n";
1000     print "or override directory locations by using environment variables.\n";
1001     print "\nFor example:\n\n";
1002     print "export DB_USER=my_koha\n";
1003     print "perl Makefile.PL\n";
1004     print "\nor\n\n";
1005     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1006 }
1007
1008 package MY;
1009
1010 sub test {
1011     my $self = shift;
1012     my $test = $self->SUPER::test(@_);
1013     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1014     return $test;
1015 }
1016
1017 sub install {
1018     my $self = shift;
1019     my $install = "";
1020     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1021     # This means that we're completely overriding EU::MM's default
1022     # installation and uninstallation targets.
1023     foreach my $key (sort keys %$target_directories) {
1024         $install .= qq(
1025 KOHA_INST_$key = blib/$key
1026 KOHA_DEST_$key = $target_directories->{$key}
1027 ) unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1028     }
1029
1030     $install .= qq(
1031 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1032 \t\$(NOECHO) \$(NOOP)
1033 );
1034     $install .= "install_koha ::\n";
1035     $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1036     foreach my $key (sort keys %$target_directories) {
1037         $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1038             unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1039     }
1040     $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1041     $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1042
1043     $install .= "\n";
1044     $install .= "set_koha_ownership ::\n";
1045     if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1046         foreach my $key (sort keys %$target_directories) {
1047             $install .= "\t\$(NOECHO) chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key)\n"
1048                 unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1049         }
1050     } else {
1051         $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1052     }
1053
1054     $install .= "\n";
1055     $install .= "set_koha_permissions ::\n";
1056     # This is necessary because EU::MM installs files
1057     # as either 0444 or 0555, and we want the owner
1058     # of Koha's files to have write permission by default.
1059     foreach my $key (sort keys %$target_directories) {
1060         $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1061             unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1062     }
1063     $install .= "\n";
1064
1065     $install .= "warn_koha_env_vars ::\n";
1066     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1067     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1068     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1069     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1070     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1071     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1072     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1073     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$target_directories->{'PERL_MODULE_DIR'}\n";
1074     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1075     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1076     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1077
1078     return $install;
1079 }
1080
1081 sub postamble {
1082     # put directory mappings into Makefile
1083     # so that Make will export as environment
1084     # variables -- this is for the use of
1085     # rewrite-confg.PL
1086     my $env = join("\n", map { "export __${_}__ = $target_directories->{$_}" } keys %$target_directories);
1087     $env .= "\n\n";
1088     $env .= join("\n", map { "export __${_}__ = $config{$_}" } keys %config);
1089     return "$env\n";
1090 }
1091
1092 __END__
1093
1094
1095 =head1 SEE ALSO
1096
1097 ExtUtils::MakeMaker(3)
1098
1099 =head1 AUTHORS
1100
1101 MJ Ray mjr at phonecoop.coop
1102 Galen Charlton galen.charlton at liblime.com
1103
1104 =cut
1105 FIXME: deal with .htaccess