about.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Pat Eyler 2003
   4 # Copyright Biblibre 2006
   5 # Parts Copyright Liblime 2008
   6 # Parts Copyright Chris Nighswonger 2010
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24
  25 use CGI qw ( -utf8 );
  26 use DateTime::TimeZone;
  27 use File::Spec;
  28 use List::MoreUtils qw/ any /;
  29 use LWP::Simple;
  30 use Module::Load::Conditional qw(can_load);
  31 use XML::Simple;
  32 use Config;
  33 use Search::Elasticsearch;
  34 use Try::Tiny;
  35
  36 use C4::Output;
  37 use C4::Auth;
  38 use C4::Context;
  39 use C4::Installer;
  40
  41 use Koha;
  42 use Koha::DateUtils qw(dt_from_string output_pref);
  43 use Koha::Acquisition::Currencies;
  44 use Koha::Patron::Categories;
  45 use Koha::Patrons;
  46 use Koha::Caches;
  47 use Koha::Config::SysPrefs;
  48 use Koha::Illrequest::Config;
  49 use Koha::SearchEngine::Elasticsearch;
  50
  51 use C4::Members::Statistics;
  52
  53
  54 #use Smart::Comments '####';
  55
  56 my $query = new CGI;
  57 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  58     {
  59         template_name   => "about.tt",
  60         query           => $query,
  61         type            => "intranet",
  62         authnotrequired => 0,
  63         flagsrequired   => { catalogue => 1 },
  64         debug           => 1,
  65     }
  66 );
  67
  68 my $config_timezone = C4::Context->config('timezone') // '';
  69 my $config_invalid  = !DateTime::TimeZone->is_valid_name( $config_timezone );
  70 my $env_timezone    = $ENV{TZ} // '';
  71 my $env_invalid     = !DateTime::TimeZone->is_valid_name( $env_timezone );
  72 my $actual_bad_tz_fallback = 0;
  73
  74 if ( $config_timezone ne '' &&
  75      $config_invalid ) {
  76     # Bad config
  77     $actual_bad_tz_fallback = 1;
  78 }
  79 elsif ( $config_timezone eq '' &&
  80         $env_timezone    ne '' &&
  81         $env_invalid ) {
  82     # No config, but bad ENV{TZ}
  83     $actual_bad_tz_fallback = 1;
  84 }
  85
  86 my $time_zone = {
  87     actual                 => C4::Context->tz->name,
  88     actual_bad_tz_fallback => $actual_bad_tz_fallback,
  89     config                 => $config_timezone,
  90     config_invalid         => $config_invalid,
  91     environment            => $env_timezone,
  92     environment_invalid    => $env_invalid
  93 };
  94
  95 $template->param(
  96     time_zone              => $time_zone,
  97     current_date_and_time  => output_pref({ dt => dt_from_string(), dateformat => 'iso' })
  98 );
  99
 100 my $perl_path = $^X;
 101 if ($^O ne 'VMS') {
 102     $perl_path .= $Config{_exe} unless $perl_path =~ m/$Config{_exe}$/i;
 103 }
 104
 105 my $zebraVersion = `zebraidx -V`;
 106
 107 # Check running PSGI env
 108 if ( any { /(^psgi\.|^plack\.)/i } keys %ENV ) {
 109     $template->param(
 110         is_psgi => 1,
 111         psgi_server => ($ENV{ PLACK_ENV }) ? "Plack ($ENV{PLACK_ENV})" :
 112                        ($ENV{ MOD_PERL })  ? "mod_perl ($ENV{MOD_PERL})" :
 113                                              'Unknown'
 114     );
 115 }
 116
 117 # Memcached configuration
 118 my $memcached_servers   = $ENV{MEMCACHED_SERVERS} || C4::Context->config('memcached_servers');
 119 my $memcached_namespace = $ENV{MEMCACHED_NAMESPACE} || C4::Context->config('memcached_namespace') // 'koha';
 120
 121 my $cache = Koha::Caches->get_instance;
 122 my $effective_caching_method = ref($cache->cache);
 123 # Memcached may have been running when plack has been initialized but could have been stopped since
 124 # FIXME What are the consequences of that??
 125 my $is_memcached_still_active = $cache->set_in_cache('test_for_about_page', "just a simple value");
 126
 127 my $where_is_memcached_config = 'nowhere';
 128 if ( $ENV{MEMCACHED_SERVERS} and C4::Context->config('memcached_servers') ) {
 129     $where_is_memcached_config = 'both';
 130 } elsif ( $ENV{MEMCACHED_SERVERS} and not C4::Context->config('memcached_servers') ) {
 131     $where_is_memcached_config = 'ENV_only';
 132 } elsif ( C4::Context->config('memcached_servers') ) {
 133     $where_is_memcached_config = 'config_only';
 134 }
 135
 136 $template->param(
 137     effective_caching_method => $effective_caching_method,
 138     memcached_servers   => $memcached_servers,
 139     memcached_namespace => $memcached_namespace,
 140     is_memcached_still_active => $is_memcached_still_active,
 141     where_is_memcached_config => $where_is_memcached_config,
 142     memcached_running   => Koha::Caches->get_instance->memcached_cache,
 143 );
 144
 145 # Additional system information for warnings
 146
 147 my $warnStatisticsFieldsError;
 148 my $prefStatisticsFields = C4::Context->preference('StatisticsFields');
 149 if ($prefStatisticsFields) {
 150     $warnStatisticsFieldsError = $prefStatisticsFields
 151         unless ( $prefStatisticsFields eq C4::Members::Statistics->get_fields() );
 152 }
 153
 154 my $prefAutoCreateAuthorities = C4::Context->preference('AutoCreateAuthorities');
 155 my $prefBiblioAddsAuthorities = C4::Context->preference('BiblioAddsAuthorities');
 156 my $warnPrefBiblioAddsAuthorities = ( $prefAutoCreateAuthorities && ( !$prefBiblioAddsAuthorities) );
 157
 158 my $prefEasyAnalyticalRecords  = C4::Context->preference('EasyAnalyticalRecords');
 159 my $prefUseControlNumber  = C4::Context->preference('UseControlNumber');
 160 my $warnPrefEasyAnalyticalRecords  = ( $prefEasyAnalyticalRecords  && $prefUseControlNumber );
 161 my $warnPrefAnonymousPatron = (
 162     C4::Context->preference('OPACPrivacy')
 163         and not C4::Context->preference('AnonymousPatron')
 164 );
 165
 166 my $anonymous_patron = Koha::Patrons->find( C4::Context->preference('AnonymousPatron') );
 167 my $warnPrefAnonymousPatron_PatronDoesNotExist = ( not $anonymous_patron and Koha::Patrons->search({ privacy => 2 })->count );
 168
 169 my $errZebraConnection = C4::Context->Zconn("biblioserver",0)->errcode();
 170
 171 my $warnIsRootUser   = (! $loggedinuser);
 172
 173 my $warnNoActiveCurrency = (! defined Koha::Acquisition::Currencies->get_active);
 174
 175 my @xml_config_warnings;
 176
 177 my $context = new C4::Context;
 178
 179 if ( ! defined C4::Context->config('zebra_bib_index_mode') ) {
 180     push @xml_config_warnings, {
 181         error => 'zebra_bib_index_mode_warn'
 182     };
 183     if ($context->{'server'}->{'biblioserver'}->{'config'} !~ /zebra-biblios-dom.cfg/) {
 184         push @xml_config_warnings, {
 185             error => 'zebra_bib_mode_seems_grs1'
 186         };
 187     }
 188     else {
 189         push @xml_config_warnings, {
 190             error => 'zebra_bib_mode_seems_dom'
 191         };
 192     }
 193 } else {
 194     push @xml_config_warnings, { error => 'zebra_bib_grs_warn' }
 195         if C4::Context->config('zebra_bib_index_mode') eq 'grs1';
 196 }
 197
 198 if ( (C4::Context->config('zebra_bib_index_mode') eq 'dom') &&
 199      ($context->{'server'}->{'biblioserver'}->{'config'} !~ /zebra-biblios-dom.cfg/) ) {
 200
 201     push @xml_config_warnings, {
 202         error => 'zebra_bib_index_mode_mismatch_warn'
 203     };
 204 }
 205
 206 if ( (C4::Context->config('zebra_bib_index_mode') eq 'grs1') &&
 207      ($context->{'server'}->{'biblioserver'}->{'config'} =~ /zebra-biblios-dom.cfg/) ) {
 208
 209     push @xml_config_warnings, {
 210         error => 'zebra_bib_index_mode_mismatch_warn'
 211     };
 212 }
 213
 214 if ( ! defined C4::Context->config('zebra_auth_index_mode') ) {
 215     push @xml_config_warnings, {
 216         error => 'zebra_auth_index_mode_warn'
 217     };
 218     if ($context->{'server'}->{'authorityserver'}->{'config'} !~ /zebra-authorities-dom.cfg/) {
 219         push @xml_config_warnings, {
 220             error => 'zebra_auth_mode_seems_grs1'
 221         };
 222     }
 223     else {
 224         push @xml_config_warnings, {
 225             error => 'zebra_auth_mode_seems_dom'
 226         };
 227     }
 228 } else {
 229     push @xml_config_warnings, { error => 'zebra_auth_grs_warn' }
 230         if C4::Context->config('zebra_auth_index_mode') eq 'grs1';
 231 }
 232
 233 if ( (C4::Context->config('zebra_auth_index_mode') eq 'dom') && ($context->{'server'}->{'authorityserver'}->{'config'} !~ /zebra-authorities-dom.cfg/) ) {
 234     push @xml_config_warnings, {
 235         error => 'zebra_auth_index_mode_mismatch_warn'
 236     };
 237 }
 238
 239 if ( (C4::Context->config('zebra_auth_index_mode') eq 'grs1') && ($context->{'server'}->{'authorityserver'}->{'config'} =~ /zebra-authorities-dom.cfg/) ) {
 240     push @xml_config_warnings, {
 241         error => 'zebra_auth_index_mode_mismatch_warn'
 242     };
 243 }
 244
 245 if ( ! defined C4::Context->config('log4perl_conf') ) {
 246     push @xml_config_warnings, {
 247         error => 'log4perl_entry_missing'
 248     }
 249 }
 250
 251 if ( ! defined C4::Context->config('upload_path') ) {
 252     if ( Koha::Config::SysPrefs->find('OPACBaseURL')->value ) {
 253         # OPACBaseURL seems to be set
 254         push @xml_config_warnings, {
 255             error => 'uploadpath_entry_missing'
 256         }
 257     } else {
 258         push @xml_config_warnings, {
 259             error => 'uploadpath_and_opacbaseurl_entry_missing'
 260         }
 261     }
 262 }
 263
 264 if ( ! defined C4::Context->config('tmp_path') ) {
 265     push @xml_config_warnings, {
 266         error             => 'tmp_path_entry_missing',
 267         effective_tmp_dir => File::Spec->tmpdir
 268     }
 269 }
 270
 271 # Test QueryParser configuration sanity
 272 if ( C4::Context->preference( 'UseQueryParser' ) ) {
 273     # Get the QueryParser configuration file name
 274     my $queryparser_file          = C4::Context->config( 'queryparser_config' );
 275     my $queryparser_fallback_file = '/etc/koha/searchengine/queryparser.yaml';
 276     # Check QueryParser is functional
 277     my $QParser = C4::Context->queryparser();
 278     my $queryparser_error = {};
 279     if ( ! defined $QParser || ref($QParser) ne 'Koha::QueryParser::Driver::PQF' ) {
 280         # Error initializing the QueryParser object
 281         # Get the used queryparser.yaml file path to report the user
 282         $queryparser_error->{ fallback } = ( defined $queryparser_file ) ? 0 : 1;
 283         $queryparser_error->{ file }     = ( defined $queryparser_file )
 284                                                 ? $queryparser_file
 285                                                 : $queryparser_fallback_file;
 286         # Report error data to the template
 287         $template->param( QueryParserError => $queryparser_error );
 288     } else {
 289         # Check for an absent queryparser_config entry in koha-conf.xml
 290         if ( ! defined $queryparser_file ) {
 291             # Not an error but a warning for the missing entry in koha-conf-xml
 292             push @xml_config_warnings, {
 293                     error => 'queryparser_entry_missing',
 294                     file  => $queryparser_fallback_file
 295             };
 296         }
 297     }
 298 }
 299
 300 # Test Zebra facets configuration
 301 if ( !defined C4::Context->config('use_zebra_facets') ) {
 302     push @xml_config_warnings, { error => 'use_zebra_facets_entry_missing' };
 303 } else {
 304     if ( C4::Context->config('use_zebra_facets') &&
 305          C4::Context->config('zebra_bib_index_mode') ) {
 306         # use_zebra_facets works with DOM
 307         push @xml_config_warnings, {
 308             error => 'use_zebra_facets_needs_dom'
 309         } if C4::Context->config('zebra_bib_index_mode') ne 'dom' ;
 310     }
 311 }
 312
 313 # ILL module checks
 314 if ( C4::Context->preference('ILLModule') ) {
 315     my $warnILLConfiguration = 0;
 316     my $ill_config_from_file = C4::Context->config("interlibrary_loans");
 317     my $ill_config = Koha::Illrequest::Config->new;
 318
 319     my $available_ill_backends =
 320       ( scalar @{ $ill_config->available_backends } > 0 );
 321
 322     # Check backends
 323     if ( !$available_ill_backends ) {
 324         $template->param( no_ill_backends => 1 );
 325         $warnILLConfiguration = 1;
 326     }
 327
 328     # Check partner_code
 329     if ( !Koha::Patron::Categories->find($ill_config->partner_code) ) {
 330         $template->param( ill_partner_code_doesnt_exist => $ill_config->partner_code );
 331         $warnILLConfiguration = 1;
 332     }
 333
 334     if ( !$ill_config_from_file->{partner_code} ) {
 335         # partner code not defined
 336         $template->param( ill_partner_code_not_defined => 1 );
 337         $warnILLConfiguration = 1;
 338     }
 339
 340     $template->param( warnILLConfiguration => $warnILLConfiguration );
 341 }
 342
 343 if ( C4::Context->preference('SearchEngine') eq 'Elasticsearch' ) {
 344     # Check ES configuration health and runtime status
 345
 346     my $es_status;
 347     my $es_config_error;
 348     my $es_running = 1;
 349
 350     my $es_conf;
 351     try {
 352         $es_conf = Koha::SearchEngine::Elasticsearch::_read_configuration();
 353     }
 354     catch {
 355         if ( ref($_) eq 'Koha::Exceptions::Config::MissingEntry' ) {
 356             $template->param( elasticsearch_fatal_config_error => $_->message );
 357             $es_config_error = 1;
 358         }
 359     };
 360     if ( !$es_config_error ) {
 361
 362         my $biblios_index_name     = $es_conf->{index_name} . "_" . $Koha::SearchEngine::BIBLIOS_INDEX;
 363         my $authorities_index_name = $es_conf->{index_name} . "_" . $Koha::SearchEngine::AUTHORITIES_INDEX;
 364
 365         my @indexes = ($biblios_index_name, $authorities_index_name);
 366         # TODO: When new indexes get added, we could have other ways to
 367         #       fetch the list of available indexes (e.g. plugins, etc)
 368         $es_status->{nodes} = $es_conf->{nodes};
 369         my $es = Search::Elasticsearch->new({ nodes => $es_conf->{nodes} });
 370
 371         foreach my $index ( @indexes ) {
 372             my $count;
 373             try {
 374                 $count = $es->indices->stats( index => $index )
 375                       ->{_all}{primaries}{docs}{count};
 376             }
 377             catch {
 378                 if ( ref($_) eq 'Search::Elasticsearch::Error::Missing' ) {
 379                     push @{ $es_status->{errors} }, "Index not found ($index)";
 380                     $count = -1;
 381                 }
 382                 elsif ( ref($_) eq 'Search::Elasticsearch::Error::NoNodes' ) {
 383                     $es_running = 0;
 384                 }
 385                 else {
 386                     # TODO: when time comes, we will cover more use cases
 387                     die $_;
 388                 }
 389             };
 390
 391             push @{ $es_status->{indexes} },
 392               {
 393                 index_name => $index,
 394                 count      => $count
 395               };
 396         }
 397         $es_status->{running} = $es_running;
 398
 399         $template->param( elasticsearch_status => $es_status );
 400     }
 401 }
 402
 403 if ( C4::Context->preference('RESTOAuth2ClientCredentials') ) {
 404     # Do we have the required deps?
 405     unless ( can_load( modules => { 'Net::OAuth2::AuthorizationServer' => undef }) ) {
 406         $template->param( oauth2_missing_deps => 1 );
 407     }
 408 }
 409
 410 # Sco Patron should not contain any other perms than circulate => self_checkout
 411 if (  C4::Context->preference('WebBasedSelfCheck')
 412       and C4::Context->preference('AutoSelfCheckAllowed')
 413 ) {
 414     my $userid = C4::Context->preference('AutoSelfCheckID');
 415     my $all_permissions = C4::Auth::get_user_subpermissions( $userid );
 416     my ( $has_self_checkout_perm, $has_other_permissions );
 417     while ( my ( $module, $permissions ) = each %$all_permissions ) {
 418         if ( $module eq 'self_check' ) {
 419             while ( my ( $permission, $flag ) = each %$permissions ) {
 420                 if ( $permission eq 'self_checkout_module' ) {
 421                     $has_self_checkout_perm = 1;
 422                 } else {
 423                     $has_other_permissions = 1;
 424                 }
 425             }
 426         } else {
 427             $has_other_permissions = 1;
 428         }
 429     }
 430     $template->param(
 431         AutoSelfCheckPatronDoesNotHaveSelfCheckPerm => not ( $has_self_checkout_perm ),
 432         AutoSelfCheckPatronHasTooManyPerm => $has_other_permissions,
 433     );
 434 }
 435
 436 {
 437     my $dbh       = C4::Context->dbh;
 438     my $patrons = $dbh->selectall_arrayref(
 439         q|select b.borrowernumber from borrowers b join deletedborrowers db on b.borrowernumber=db.borrowernumber|,
 440         { Slice => {} }
 441     );
 442     my $biblios = $dbh->selectall_arrayref(
 443         q|select b.biblionumber from biblio b join deletedbiblio db on b.biblionumber=db.biblionumber|,
 444         { Slice => {} }
 445     );
 446     my $items = $dbh->selectall_arrayref(
 447         q|select i.itemnumber from items i join deleteditems di on i.itemnumber=di.itemnumber|,
 448         { Slice => {} }
 449     );
 450     my $checkouts = $dbh->selectall_arrayref(
 451         q|select i.issue_id from issues i join old_issues oi on i.issue_id=oi.issue_id|,
 452         { Slice => {} }
 453     );
 454     my $holds = $dbh->selectall_arrayref(
 455         q|select r.reserve_id from reserves r join old_reserves o on r.reserve_id=o.reserve_id|,
 456         { Slice => {} }
 457     );
 458     if ( @$patrons or @$biblios or @$items or @$checkouts or @$holds ) {
 459         $template->param(
 460             has_ai_issues => 1,
 461             ai_patrons    => $patrons,
 462             ai_biblios    => $biblios,
 463             ai_items      => $items,
 464             ai_checkouts  => $checkouts,
 465             ai_holds      => $holds,
 466         );
 467     }
 468 }
 469 my %versions = C4::Context::get_versions();
 470
 471 $template->param(
 472     kohaVersion   => $versions{'kohaVersion'},
 473     osVersion     => $versions{'osVersion'},
 474     perlPath      => $perl_path,
 475     perlVersion   => $versions{'perlVersion'},
 476     perlIncPath   => [ map { perlinc => $_ }, @INC ],
 477     mysqlVersion  => $versions{'mysqlVersion'},
 478     apacheVersion => $versions{'apacheVersion'},
 479     zebraVersion  => $zebraVersion,
 480     prefBiblioAddsAuthorities => $prefBiblioAddsAuthorities,
 481     prefAutoCreateAuthorities => $prefAutoCreateAuthorities,
 482     warnPrefBiblioAddsAuthorities => $warnPrefBiblioAddsAuthorities,
 483     warnPrefEasyAnalyticalRecords  => $warnPrefEasyAnalyticalRecords,
 484     warnPrefAnonymousPatron => $warnPrefAnonymousPatron,
 485     warnPrefAnonymousPatron_PatronDoesNotExist => $warnPrefAnonymousPatron_PatronDoesNotExist,
 486     errZebraConnection => $errZebraConnection,
 487     warnIsRootUser => $warnIsRootUser,
 488     warnNoActiveCurrency => $warnNoActiveCurrency,
 489     warnNoTemplateCaching => ( C4::Context->config('template_cache_dir') ? 0 : 1 ),
 490     xml_config_warnings => \@xml_config_warnings,
 491     warnStatisticsFieldsError => $warnStatisticsFieldsError,
 492 );
 493
 494 my @components = ();
 495
 496 my $perl_modules = C4::Installer::PerlModules->new;
 497 $perl_modules->versions_info;
 498
 499 my @pm_types = qw(missing_pm upgrade_pm current_pm);
 500
 501 foreach my $pm_type(@pm_types) {
 502     my $modules = $perl_modules->get_attr($pm_type);
 503     foreach (@$modules) {
 504         my ($module, $stats) = each %$_;
 505         push(
 506             @components,
 507             {
 508                 name    => $module,
 509                 version => $stats->{'cur_ver'},
 510                 missing => ($pm_type eq 'missing_pm' ? 1 : 0),
 511                 upgrade => ($pm_type eq 'upgrade_pm' ? 1 : 0),
 512                 current => ($pm_type eq 'current_pm' ? 1 : 0),
 513                 require => $stats->{'required'},
 514                 reqversion => $stats->{'min_ver'},
 515             }
 516         );
 517     }
 518 }
 519
 520 @components = sort {$a->{'name'} cmp $b->{'name'}} @components;
 521
 522 my $counter=0;
 523 my $row = [];
 524 my $table = [];
 525 foreach (@components) {
 526     push (@$row, $_);
 527     unless (++$counter % 4) {
 528         push (@$table, {row => $row});
 529         $row = [];
 530     }
 531 }
 532 # Processing the last line (if there are any modules left)
 533 if (scalar(@$row) > 0) {
 534     # Extending $row to the table size
 535     $$row[3] = '';
 536     # Pushing the last line
 537     push (@$table, {row => $row});
 538 }
 539 ## ## $table
 540
 541 $template->param( table => $table );
 542
 543
 544 ## ------------------------------------------
 545 ## Koha time line code
 546
 547 #get file location
 548 my $docdir;
 549 if ( defined C4::Context->config('docdir') ) {
 550     $docdir = C4::Context->config('docdir');
 551 } else {
 552     # if no <docdir> is defined in koha-conf.xml, use the default location
 553     # this is a work-around to stop breakage on upgraded Kohas, bug 8911
 554     $docdir = C4::Context->config('intranetdir') . '/docs';
 555 }
 556
 557 if ( open( my $file, "<:encoding(UTF-8)", "$docdir" . "/history.txt" ) ) {
 558
 559     my $i = 0;
 560
 561     my @rows2 = ();
 562     my $row2  = [];
 563
 564     my @lines = <$file>;
 565     close($file);
 566
 567     shift @lines; #remove header row
 568
 569     foreach (@lines) {
 570         my ( $epoch, $date, $desc, $tag ) = split(/\t/);
 571         if(!$desc && $date=~ /(?<=\d{4})\s+/) {
 572             ($date, $desc)= ($`, $');
 573         }
 574         push(
 575             @rows2,
 576             {
 577                 date => $date,
 578                 desc => $desc,
 579             }
 580         );
 581     }
 582
 583     my $table2 = [];
 584     #foreach my $row2 (@rows2) {
 585     foreach  (@rows2) {
 586         push (@$row2, $_);
 587         push( @$table2, { row2 => $row2 } );
 588         $row2 = [];
 589     }
 590
 591     $template->param( table2 => $table2 );
 592 } else {
 593     $template->param( timeline_read_error => 1 );
 594 }
 595
 596 output_html_with_http_headers $query, $cookie, $template->output;