acqui/lateorders.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright 2005 Biblibre
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 lateorders.pl
  23
  24 =head1 DESCRIPTION
  25
  26 this script shows late orders for a specific supplier, branch and delay
  27 given on input arg.
  28
  29 =head1 CGI PARAMETERS
  30
  31 =over 4
  32
  33 =item booksellerid
  34 To know on which supplier this script have to display late order.
  35
  36 =item delay
  37 To know the time boundary. Default value is 30 days.
  38
  39 =item branch
  40 To know on which branch this script have to display late order.
  41
  42 =back
  43
  44 =cut
  45
  46 use Modern::Perl;
  47 use CGI qw ( -utf8 );
  48 use C4::Bookseller qw( GetBooksellersWithLateOrders );
  49 use C4::Auth;
  50 use C4::Koha;
  51 use C4::Output;
  52 use C4::Context;
  53 use C4::Acquisition;
  54 use C4::Letters;
  55 use Koha::DateUtils;
  56 use Koha::Acquisition::Orders;
  57 use Koha::CsvProfiles;
  58
  59 my $input = new CGI;
  60 my ($template, $loggedinuser, $cookie) = get_template_and_user(
  61     {
  62         template_name   => "acqui/lateorders.tt",
  63         query           => $input,
  64         type            => "intranet",
  65         authnotrequired => 0,
  66         flagsrequired   => { acquisition => 'order_receive' },
  67         debug           => 1,
  68     }
  69 );
  70
  71 my $booksellerid = $input->param('booksellerid');
  72 my $delay        = $input->param('delay') // 0;
  73
  74 # Get the "date from" param if !defined is today
  75 my $estimateddeliverydatefrom = $input->param('estimateddeliverydatefrom');
  76 my $estimateddeliverydateto   = $input->param('estimateddeliverydateto');
  77
  78 my $estimateddeliverydatefrom_dt =
  79   $estimateddeliverydatefrom
  80   ? dt_from_string($estimateddeliverydatefrom)
  81   : undef;
  82
  83 # Get the "date to" param. If it is not defined and $delay is not defined too, it is the today's date.
  84 my $estimateddeliverydateto_dt = $estimateddeliverydateto
  85     ? dt_from_string($estimateddeliverydateto)
  86     : ( not defined $delay and not defined $estimateddeliverydatefrom)
  87         ? dt_from_string()
  88         : undef;
  89
  90 # Format the output of "date from" and "date to"
  91 if ($estimateddeliverydatefrom_dt) {
  92     $estimateddeliverydatefrom = output_pref({dt => $estimateddeliverydatefrom_dt, dateonly => 1});
  93 }
  94 if ($estimateddeliverydateto_dt) {
  95     $estimateddeliverydateto = output_pref({dt => $estimateddeliverydateto_dt, dateonly => 1});
  96 }
  97
  98 my $branch     = $input->param('branch');
  99 my $op         = $input->param('op');
 100
 101 my @errors = ();
 102 if ( $delay and not $delay =~ /^\d{1,3}$/ ) {
 103     push @errors, {delay_digits => 1, bad_delay => $delay};
 104 }
 105
 106 if ($op and $op eq "send_alert"){
 107     my @ordernums = $input->multi_param("ordernumber");
 108     my $err;
 109     eval {
 110         $err = SendAlerts( 'claimacquisition', \@ordernums, $input->param("letter_code") );
 111         if ( not ref $err or not exists $err->{error} ) {
 112             Koha::Acquisition::Orders->find($_)->claim() for @ordernums;
 113         }
 114     };
 115
 116     if ( ref $err and exists $err->{error} and $err->{error} eq "no_email" ) {
 117         $template->{VARS}->{'error_claim'} = "no_email";
 118     } elsif ( ref $err and exists $err->{error} and $err->{error} eq "no_order_selected"){
 119         $template->{VARS}->{'error_claim'} = "no_order_selected";
 120     } elsif ( $@ or ref $err and exists $err->{error} ) {
 121         $template->param(error_claim => $@ || $err->{error});
 122     } else {
 123         $template->{VARS}->{'info_claim'} = 1;
 124     }
 125 }
 126
 127 my @parameters = ( $delay );
 128 push @parameters, $estimateddeliverydatefrom_dt
 129     ? $estimateddeliverydatefrom_dt->ymd()
 130     : undef;
 131
 132 push @parameters, $estimateddeliverydateto_dt
 133     ? $estimateddeliverydateto_dt->ymd()
 134     : undef;
 135
 136 my @lateorders = Koha::Acquisition::Orders->filter_by_lates(
 137     {
 138         delay        => $delay,
 139         (
 140             $estimateddeliverydatefrom_dt
 141             ? ( estimated_from => $estimateddeliverydatefrom_dt )
 142             : ()
 143         ),
 144         (
 145             $estimateddeliverydateto_dt
 146             ? ( estimated_to => $estimateddeliverydateto_dt )
 147             : ()
 148         )
 149     },
 150 )->as_list;
 151
 152 my $booksellers = Koha::Acquisition::Booksellers->search(
 153     {
 154         id => {
 155             -in => map { $_->basket->booksellerid } @lateorders
 156         },
 157     }
 158 );
 159
 160 @lateorders = grep { $_->basket->booksellerid eq $booksellerid } @lateorders if $booksellerid;
 161
 162 my $letters = GetLetters({ module => "claimacquisition" });
 163
 164 $template->param(ERROR_LOOP => \@errors) if (@errors);
 165 $template->param(
 166     lateorders => \@lateorders,
 167     booksellers => $booksellers,
 168     bookseller_filter => ( $booksellerid ? $booksellers->find($booksellerid) : undef),
 169         delay => $delay,
 170     letters => $letters,
 171     estimateddeliverydatefrom => $estimateddeliverydatefrom,
 172     estimateddeliverydateto   => $estimateddeliverydateto,
 173         intranetcolorstylesheet => C4::Context->preference("intranetcolorstylesheet"),
 174     csv_profiles         => [ Koha::CsvProfiles->search({ type => 'sql', used_for => 'late_orders' }) ],
 175 );
 176 output_html_with_http_headers $input, $cookie, $template->output;