catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to acomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158
 159 use URI::Escape;
 160
 161 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 162 # create a new CGI object
 163 # FIXME: no_undef_params needs to be tested
 164 use CGI qw('-no_undef_params' -utf8 );
 165 my $cgi = new CGI;
 166
 167 # decide which template to use
 168 my $template_name;
 169 my $template_type;
 170 my @params = $cgi->multi_param("limit");
 171 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 172     $template_name = 'catalogue/results.tt';
 173     $template_type = 'results';
 174 }
 175 else {
 176     $template_name = 'catalogue/advsearch.tt';
 177     $template_type = 'advsearch';
 178 }
 179 # load the template
 180 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 181     template_name => $template_name,
 182     query => $cgi,
 183     type => "intranet",
 184     authnotrequired => 0,
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     $template->param(
 198         holdfor => $cgi->cookie("holdfor"),
 199         holdfor_surname => $holdfor_patron->surname,
 200         holdfor_firstname => $holdfor_patron->firstname,
 201         holdfor_cardnumber => $holdfor_patron->cardnumber,
 202     );
 203 }
 204
 205 # get biblionumbers stored in the cart
 206 my @cart_list;
 207
 208 if($cgi->cookie("intranet_bib_list")){
 209     my $cart_list = $cgi->cookie("intranet_bib_list");
 210     @cart_list = split(/\//, $cart_list);
 211 }
 212
 213 my @search_groups =
 214   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 215 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 216
 217 $template->param(
 218     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 219     search_groups    => \@search_groups,
 220 );
 221
 222 # load the Type stuff
 223 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 224 # the index parameter is different for item-level itemtypes
 225 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 226 my @advancedsearchesloop;
 227 my $cnt;
 228 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 229 my @advanced_search_types = split(/\|/, $advanced_search_types);
 230
 231 foreach my $advanced_srch_type (@advanced_search_types) {
 232     $advanced_srch_type =~ s/^\s*//;
 233     $advanced_srch_type =~ s/\s*$//;
 234    if ($advanced_srch_type eq 'itemtypes') {
 235    # itemtype is a special case, since it's not defined in authorized values
 236         my @itypesloop;
 237         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 238             my %row =(  number=>$cnt++,
 239                 ccl => "$itype_or_itemtype,phr",
 240                 code => $thisitemtype,
 241                 description => $itemtypes->{$thisitemtype}->{translated_description},
 242                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 243             );
 244             push @itypesloop, \%row;
 245         }
 246         my %search_code = (  advanced_search_type => $advanced_srch_type,
 247                              code_loop => \@itypesloop );
 248         push @advancedsearchesloop, \%search_code;
 249     } else {
 250     # covers all the other cases: non-itemtype authorized values
 251        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 252         my @authvalueloop;
 253         for my $thisitemtype (@$advsearchtypes) {
 254                 my %row =(
 255                                 number=>$cnt++,
 256                                 ccl => $advanced_srch_type,
 257                 code => $thisitemtype->{authorised_value},
 258                 description => $thisitemtype->{'lib'},
 259                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 260                 );
 261                 push @authvalueloop, \%row;
 262         }
 263         my %search_code = (  advanced_search_type => $advanced_srch_type,
 264                              code_loop => \@authvalueloop );
 265         push @advancedsearchesloop, \%search_code;
 266     }
 267 }
 268 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 269 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 270 my $advancedsearchesloop = prepare_adv_search_types($types);
 271 $template->param(advancedsearchesloop => $advancedsearchesloop);
 272
 273 # The following should only be loaded if we're bringing up the advanced search template
 274 if ( $template_type eq 'advsearch' ) {
 275
 276     # load the servers (used for searching -- to do federated searching, etc.)
 277     my $primary_servers_loop;# = displayPrimaryServers();
 278     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 279
 280     my $secondary_servers_loop;
 281     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 282
 283     # set the default sorting
 284     if (   C4::Context->preference('OPACdefaultSortField')
 285         && C4::Context->preference('OPACdefaultSortOrder') ) {
 286         my $default_sort_by =
 287             C4::Context->preference('defaultSortField') . '_'
 288           . C4::Context->preference('defaultSortOrder');
 289         $template->param( sort_by => $default_sort_by  );
 290     }
 291
 292     # determine what to display next to the search boxes (ie, boolean option
 293     # shouldn't appear on the first one, scan indexes should, adding a new
 294     # box should only appear on the last, etc.
 295     my @search_boxes_array;
 296     my $search_boxes_count = 3; # begin whith 3 boxes
 297     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 298     for (my $i=1;$i<=$search_boxes_count;$i++) {
 299         # if it's the first one, don't display boolean option, but show scan indexes
 300         if ($i==1) {
 301             push @search_boxes_array, {scan_index => 1};
 302         }
 303         # if it's the last one, show the 'add field' box
 304         elsif ($i==$search_boxes_count) {
 305             push @search_boxes_array,
 306                 {
 307                 boolean => 1,
 308                 add_field => 1,
 309                 };
 310         }
 311         else {
 312             push @search_boxes_array,
 313                 {
 314                 boolean => 1,
 315                 };
 316         }
 317
 318     }
 319     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 320                       search_boxes_loop => \@search_boxes_array);
 321
 322     # load the language limits (for search)
 323     my $languages_limit_loop = getLanguages($lang, 1);
 324     $template->param(search_languages_loop => $languages_limit_loop,);
 325
 326     # Expanded search options in advanced search:
 327     # use the global setting by default, but let the user override it
 328     {
 329         my $expanded = $cgi->param('expanded_options');
 330         $expanded = C4::Context->preference("expandedSearchOption") || 0
 331             if !defined($expanded) || $expanded !~ /^0|1$/;
 332         $template->param( expanded_options => $expanded );
 333     }
 334
 335     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 336
 337     output_html_with_http_headers $cgi, $cookie, $template->output;
 338     exit;
 339 }
 340
 341 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 342
 343 # Fetch the paramater list as a hash in scalar context:
 344 #  * returns paramater list as tied hash ref
 345 #  * we can edit the values by changing the key
 346 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 347 my $params = $cgi->Vars;
 348
 349 # Params that can have more than one value
 350 # sort by is used to sort the query
 351 # in theory can have more than one but generally there's just one
 352 my @sort_by;
 353 my $default_sort_by;
 354 if (   C4::Context->preference('defaultSortField')
 355     && C4::Context->preference('defaultSortOrder') ) {
 356     $default_sort_by =
 357         C4::Context->preference('defaultSortField') . '_'
 358       . C4::Context->preference('defaultSortOrder');
 359 }
 360
 361 @sort_by = $cgi->multi_param('sort_by');
 362 $sort_by[0] = $default_sort_by unless $sort_by[0];
 363 foreach my $sort (@sort_by) {
 364     $template->param($sort => 1) if $sort;
 365 }
 366 $template->param('sort_by' => $sort_by[0]);
 367
 368 # Use the servers defined, or just search our local catalog(default)
 369 my @servers = $cgi->multi_param('server');
 370 unless (@servers) {
 371     #FIXME: this should be handled using Context.pm
 372     @servers = ("biblioserver");
 373     # @servers = C4::Context->config("biblioserver");
 374 }
 375 # operators include boolean and proximity operators and are used
 376 # to evaluate multiple operands
 377 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 378
 379 # indexes are query qualifiers, like 'title', 'author', etc. They
 380 # can be single or multiple parameters separated by comma: kw,right-Truncation
 381 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 382
 383 # if a simple index (only one)  display the index used in the top search box
 384 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 385     my $idx = "ms_".$indexes[0];
 386     $idx =~ s/\,/comma/g;  # template toolkit doesnt like variables with a , in it
 387     $template->param($idx => 1);
 388 }
 389
 390 # an operand can be a single term, a phrase, or a complete ccl query
 391 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 392
 393 # limits are use to limit to results to a pre-defined category such as branch or language
 394 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 395 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 396 my %is_nolimit = map { $_ => 1 } @nolimits;
 397 @limits = grep { not $is_nolimit{$_} } @limits;
 398
 399 if($params->{'multibranchlimit'}) {
 400     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 401     my @libraries = $search_group->all_libraries;
 402     my $multibranch = '('.join( " or ", map { 'branch: ' . $_->branchcode } @libraries ) .')';
 403     push @limits, $multibranch if ($multibranch ne  '()');
 404 }
 405
 406 my $available;
 407 foreach my $limit(@limits) {
 408     if ($limit =~/available/) {
 409         $available = 1;
 410     }
 411 }
 412 $template->param(available => $available);
 413
 414 # append year limits if they exist
 415 my $limit_yr;
 416 my $limit_yr_value;
 417 if ($params->{'limit-yr'}) {
 418     if ($params->{'limit-yr'} =~ /\d{4}/) {
 419         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 420         $limit_yr_value = $params->{'limit-yr'};
 421     }
 422     push @limits,$limit_yr;
 423     #FIXME: Should return a error to the user, incorect date format specified
 424 }
 425
 426 # convert indexes and operands to corresponding parameter names for the z3950 search
 427 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 428 my $z3950par;
 429 my $indexes2z3950 = {
 430     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 431     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 432     ti=>'title', 'ti,phr'=>'title', se=>'title'
 433 };
 434 for (my $ii = 0; $ii < @operands; ++$ii)
 435 {
 436     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 437     if (defined $name && defined $operands[$ii])
 438     {
 439         $z3950par ||= {};
 440         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 441     }
 442 }
 443
 444
 445 # Params that can only have one value
 446 my $scan = $params->{'scan'};
 447 my $count = C4::Context->preference('numSearchResults') || 20;
 448 my $results_per_page = $params->{'count'} || $count;
 449 my $offset = $params->{'offset'} || 0;
 450 $offset = 0 if $offset < 0;
 451 my $page = $cgi->param('page') || 1;
 452 #my $offset = ($page-1)*$results_per_page;
 453 my $expanded_facet = $params->{'expand'};
 454
 455 # Define some global variables
 456 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 457
 458 my $builder = Koha::SearchEngine::QueryBuilder->new(
 459     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 460 my $searcher = Koha::SearchEngine::Search->new(
 461     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 462
 463 ## I. BUILD THE QUERY
 464 (
 465     $error,             $query, $simple_query, $query_cgi,
 466     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 467     $query_type
 468   )
 469   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 470     \@sort_by, $scan, $lang );
 471
 472 ## parse the query_cgi string and put it into a form suitable for <input>s
 473 my @query_inputs;
 474 my $scan_index_to_use;
 475 my $scan_search_term_to_use;
 476
 477 if ($query_cgi) {
 478     for my $this_cgi ( split('&', $query_cgi) ) {
 479         next unless $this_cgi;
 480         $this_cgi =~ m/(.*?)=(.*)/;
 481         my $input_name = $1;
 482         my $input_value = $2;
 483         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 484         if ($input_name eq 'idx') {
 485             $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 486         }
 487         if ($input_name eq 'q') {
 488             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 489         }
 490     }
 491 }
 492
 493 $template->param ( QUERY_INPUTS => \@query_inputs,
 494                    scan_index_to_use => $scan_index_to_use,
 495                    scan_search_term_to_use => $scan_search_term_to_use );
 496
 497 ## parse the limit_cgi string and put it into a form suitable for <input>s
 498 my @limit_inputs;
 499 if ($limit_cgi) {
 500     for my $this_cgi ( split('&', $limit_cgi) ) {
 501         next unless $this_cgi;
 502         # handle special case limit-yr
 503         if ($this_cgi =~ /yr,st-numeric/) {
 504             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 505             next;
 506         }
 507         $this_cgi =~ m/(.*=)(.*)/;
 508         my $input_name = $1;
 509         my $input_value = $2;
 510         $input_name =~ s/=$//;
 511         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 512     }
 513 }
 514 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 515
 516 ## II. DO THE SEARCH AND GET THE RESULTS
 517 my $total = 0; # the total results for the whole set
 518 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 519 my $results_hashref;
 520
 521 eval {
 522     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 523     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 524         $query,            $simple_query, \@sort_by,       \@servers,
 525         $results_per_page, $offset,       $expanded_facet, undef,
 526         $itemtypes,        $query_type,   $scan
 527     );
 528 };
 529
 530 if ($@ || $error) {
 531     $template->param(query_error => $error.$@);
 532     output_html_with_http_headers $cgi, $cookie, $template->output;
 533     exit;
 534 }
 535
 536 # At this point, each server has given us a result set
 537 # now we build that set for template display
 538 my @sup_results_array;
 539 for (my $i=0;$i<@servers;$i++) {
 540     my $server = $servers[$i];
 541     if ($server =~/biblioserver/) { # this is the local bibliographic server
 542         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 543         my $page = $cgi->param('page') || 0;
 544         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 545                                        $results_hashref->{$server}->{"RECORDS"});
 546         $total = $total + $hits;
 547
 548         # Search history
 549         if (C4::Context->preference('EnableSearchHistory')) {
 550             unless ( $offset ) {
 551                 my $path_info = $cgi->url(-path_info=>1);
 552                 my $query_cgi_history = $cgi->url(-query=>1);
 553                 $query_cgi_history =~ s/^$path_info\?//;
 554                 $query_cgi_history =~ s/;/&/g;
 555                 my $query_desc_history = $query_desc;
 556                 $query_desc_history .= ", $limit_desc"
 557                     if $limit_desc;
 558
 559                 C4::Search::History::add({
 560                     userid => $borrowernumber,
 561                     sessionid => $cgi->cookie("CGISESSID"),
 562                     query_desc => $query_desc_history,
 563                     query_cgi => $query_cgi_history,
 564                     total => $total,
 565                     type => "biblio",
 566                 });
 567             }
 568             $template->param( EnableSearchHistory => 1 );
 569         }
 570
 571         ## If there's just one result, redirect to the detail page
 572         if ($total == 1) {
 573             my $biblionumber = $newresults[0]->{biblionumber};
 574             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 575             my $views = { C4::Search::enabled_staff_search_views };
 576             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 577                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 578             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 579                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 580             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 581                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 582             } else {
 583                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 584             }
 585             exit;
 586         }
 587
 588         # set up parameters if user wishes to re-run the search
 589         # as a Z39.50 search
 590         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 591
 592         if ($hits) {
 593             $template->param(total => $hits);
 594             if ($limit_cgi) {
 595                 my $limit_cgi_not_availablity = $limit_cgi;
 596                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 597                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 598             }
 599             $template->param(limit_cgi => $limit_cgi);
 600             $template->param(query_cgi => $query_cgi);
 601             $template->param(query_desc => $query_desc);
 602             $template->param(limit_desc => $limit_desc);
 603             $template->param(offset     => $offset);
 604             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 605             if ($query_desc || $limit_desc) {
 606                 $template->param(searchdesc => 1);
 607             }
 608             $template->param(results_per_page =>  $results_per_page);
 609             # must define a value for size if not present in DB
 610             # in order to avoid problems generated by the default size value in TT
 611             foreach my $line (@newresults) {
 612                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 613                 # while we're checking each line, see if item is in the cart
 614                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 615                     $line->{'incart'} = 1;
 616                 }
 617             }
 618             $template->param(SEARCH_RESULTS => \@newresults);
 619             ## FIXME: add a global function for this, it's better than the current global one
 620             ## Build the page numbers on the bottom of the page
 621             my @page_numbers;
 622             # total number of pages there will be
 623             my $pages = ceil($hits / $results_per_page);
 624             my $last_page_offset = ( $pages -1 ) * $results_per_page;
 625             # default page number
 626             my $current_page_number = 1;
 627             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 628             my $previous_page_offset;
 629             if ( $offset >= $results_per_page ) {
 630                 $previous_page_offset = $offset - $results_per_page;
 631             }
 632             my $next_page_offset = $offset + $results_per_page;
 633             # If we're within the first 10 pages, keep it simple
 634             #warn "current page:".$current_page_number;
 635             if ($current_page_number < 10) {
 636                 # just show the first 10 pages
 637                 # Loop through the pages
 638                 my $pages_to_show = 10;
 639                 $pages_to_show = $pages if $pages<10;
 640                 for (my $i=1; $i<=$pages_to_show;$i++) {
 641                     # the offset for this page
 642                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 643                     # the page number for this page
 644                     my $this_page_number = $i;
 645                     # put it in the array
 646                     push @page_numbers,
 647                       { offset    => $this_offset,
 648                         pg        => $this_page_number,
 649                         # it should only be highlighted if it's the current page
 650                         highlight => $this_page_number == $current_page_number,
 651                         sort_by   => join ' ', @sort_by
 652                       };
 653
 654                 }
 655
 656             }
 657
 658             # now, show twenty pages, with the current one smack in the middle
 659             else {
 660                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 661                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 662                     my $this_page_number = $i-9;
 663                     if ( $this_page_number <= $pages ) {
 664                         push @page_numbers,
 665                           { offset    => $this_offset,
 666                             pg        => $this_page_number,
 667                             highlight => $this_page_number == $current_page_number,
 668                             sort_by   => join ' ', @sort_by
 669                           };
 670                     }
 671                 }
 672             }
 673             # FIXME: no previous_page_offset when pages < 2
 674             $template->param(   PAGE_NUMBERS => \@page_numbers,
 675                                 last_page_offset => $last_page_offset,
 676                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 677             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 678         }
 679
 680
 681         # no hits
 682         else {
 683             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 684         }
 685
 686     } # end of the if local
 687
 688     # asynchronously search the authority server
 689     elsif ($server =~/authorityserver/) { # this is the local authority server
 690         my @inner_sup_results_array;
 691         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 692             my $marc_record_object = C4::Search::new_record_from_zebra(
 693                 'authorityserver',
 694                 $sup_record
 695             );
 696             # warn "Authority Found: ".$marc_record_object->as_formatted();
 697             push @inner_sup_results_array, {
 698                 'title' => $marc_record_object->field(100)->subfield('a'),
 699                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 700             };
 701         }
 702         push @sup_results_array, {  servername => $server,
 703                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 704     }
 705     # FIXME: can add support for other targets as needed here
 706     $template->param(           outer_sup_results_loop => \@sup_results_array);
 707 } #/end of the for loop
 708 #$template->param(FEDERATED_RESULTS => \@results_array);
 709
 710 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 711
 712 my $gotonumber = $cgi->param('gotoNumber');
 713 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 714     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 715 }
 716 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 717 my $gotopage = $cgi->param('gotoPage');
 718 $template->{'VARS'}->{'gotoPage'} = $gotopage
 719   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 720
 721 for my $facet ( @$facets ) {
 722     for my $entry ( @{ $facet->{facets} } ) {
 723         my $index = $entry->{type_link_value};
 724         my $value = $entry->{facet_link_value};
 725         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 726     }
 727 }
 728
 729 $template->param(
 730             #classlist => $classlist,
 731             total => $total,
 732             opacfacets => 1,
 733             facets_loop => $facets,
 734             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 735             scan => $scan,
 736             search_error => $error,
 737 );
 738
 739 if ($query_desc || $limit_desc) {
 740     $template->param(searchdesc => 1);
 741 }
 742
 743 # VI. BUILD THE TEMPLATE
 744
 745 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 746     {
 747         borrowernumber => $borrowernumber,
 748         add_allowed    => 1,
 749         category       => 1,
 750     }
 751 );
 752 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 753     {
 754         borrowernumber => $borrowernumber,
 755         add_allowed    => 1,
 756         category       => 2,
 757     }
 758 );
 759
 760
 761 $template->param(
 762     add_to_some_private_shelves => $some_private_shelves,
 763     add_to_some_public_shelves  => $some_public_shelves,
 764 );
 765
 766 output_html_with_http_headers $cgi, $cookie, $template->output;
 767
 768
 769 =head2 prepare_adv_search_types
 770
 771     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 772     my @advanced_search_types = prepare_adv_search_types($type);
 773
 774 Different types can be searched for in the advanced search. This takes the
 775 system preference that defines these types and parses it into an arrayref for
 776 the template.
 777
 778 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 779 It also accounts for the "item-level_itypes" system preference.
 780
 781 =cut
 782
 783 sub prepare_adv_search_types {
 784     my ($types) = @_;
 785
 786     my @advanced_search_types = split( /\|/, $types );
 787
 788     # the index parameter is different for item-level itemtypes
 789     my $itype_or_itemtype =
 790       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 791     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 792
 793     my ( $cnt, @result );
 794     foreach my $advanced_srch_type (@advanced_search_types) {
 795         $advanced_srch_type =~ s/^\s*//;
 796         $advanced_srch_type =~ s/\s*$//;
 797         if ( $advanced_srch_type eq 'itemtypes' ) {
 798
 799        # itemtype is a special case, since it's not defined in authorized values
 800             my @itypesloop;
 801             foreach my $thisitemtype (
 802                 sort {
 803                     $itemtypes->{$a}->{'translated_description'}
 804                       cmp $itemtypes->{$b}->{'translated_description'}
 805                 } keys %$itemtypes
 806               )
 807             {
 808                 my %row = (
 809                     number      => $cnt++,
 810                     ccl         => "$itype_or_itemtype,phr",
 811                     code        => $thisitemtype,
 812                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 813                     imageurl    => getitemtypeimagelocation(
 814                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 815                     ),
 816                 );
 817                 push @itypesloop, \%row;
 818             }
 819             my %search_code = (
 820                 advanced_search_type => $advanced_srch_type,
 821                 code_loop            => \@itypesloop
 822             );
 823             push @result, \%search_code;
 824         }
 825         else {
 826             # covers all the other cases: non-itemtype authorized values
 827             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 828             my @authvalueloop;
 829             for my $thisitemtype (@$advsearchtypes) {
 830                 my %row = (
 831                     number      => $cnt++,
 832                     ccl         => $advanced_srch_type,
 833                     code        => $thisitemtype->{authorised_value},
 834                     description => $thisitemtype->{'lib'},
 835                     imageurl    => getitemtypeimagelocation(
 836                         'intranet', $thisitemtype->{'imageurl'}
 837                     ),
 838                 );
 839                 push @authvalueloop, \%row;
 840             }
 841             my %search_code = (
 842                 advanced_search_type => $advanced_srch_type,
 843                 code_loop            => \@authvalueloop
 844             );
 845             push @result, \%search_code;
 846         }
 847     }
 848     return \@result;
 849 }