Bug 28571: Remove C4::Auth::_session_log
[koha.git] / circ / circulation.pl
1 #!/usr/bin/perl
2
3 # script to execute issuing of books
4
5 # Copyright 2000-2002 Katipo Communications
6 # copyright 2010 BibLibre
7 # Copyright 2011 PTFS-Europe Ltd.
8 # Copyright 2012 software.coop and MJ Ray
9 #
10 # This file is part of Koha.
11 #
12 # Koha is free software; you can redistribute it and/or modify it
13 # under the terms of the GNU General Public License as published by
14 # the Free Software Foundation; either version 3 of the License, or
15 # (at your option) any later version.
16 #
17 # Koha is distributed in the hope that it will be useful, but
18 # WITHOUT ANY WARRANTY; without even the implied warranty of
19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20 # GNU General Public License for more details.
21 #
22 # You should have received a copy of the GNU General Public License
23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
24
25 # FIXME There are too many calls to Koha::Patrons->find in this script
26
27 use Modern::Perl;
28 use CGI qw ( -utf8 );
29 use DateTime;
30 use DateTime::Duration;
31 use Scalar::Util qw( looks_like_number );
32 use C4::Output;
33 use C4::Auth qw/:DEFAULT get_session haspermission/;
34 use C4::Koha;
35 use C4::Circulation;
36 use C4::Utils::DataTables::Members;
37 use C4::Members;
38 use C4::Biblio;
39 use C4::Search;
40 use MARC::Record;
41 use C4::Reserves;
42 use Koha::Holds;
43 use C4::Context;
44 use CGI::Session;
45 use Koha::AuthorisedValues;
46 use Koha::CsvProfiles;
47 use Koha::Patrons;
48 use Koha::Patron::Debarments qw(GetDebarments);
49 use Koha::DateUtils;
50 use Koha::Database;
51 use Koha::BiblioFrameworks;
52 use Koha::Items;
53 use Koha::Patron::Messages;
54 use Koha::SearchEngine;
55 use Koha::SearchEngine::Search;
56 use Koha::Patron::Modifications;
57
58 use Date::Calc qw(
59   Today
60   Add_Delta_Days
61   Date_to_Days
62 );
63 use List::MoreUtils qw/uniq/;
64
65 #
66 # PARAMETERS READING
67 #
68 my $query = CGI->new;
69
70 my $override_high_holds     = $query->param('override_high_holds');
71 my $override_high_holds_tmp = $query->param('override_high_holds_tmp');
72
73 my $sessionID = $query->cookie("CGISESSID") ;
74 my $session = get_session($sessionID);
75
76 my $barcodes = [];
77 my $barcode =  $query->param('barcode');
78 my $findborrower;
79 my $autoswitched;
80 my $borrowernumber = $query->param('borrowernumber');
81
82 if (C4::Context->preference("AutoSwitchPatron") && $barcode) {
83     if (Koha::Patrons->search( { cardnumber => $barcode} )->count() > 0) {
84         $findborrower = $barcode;
85         undef $barcode;
86         undef $borrowernumber;
87         $autoswitched = 1;
88     }
89 }
90 $findborrower ||= $query->param('findborrower') || q{};
91 $findborrower =~ s|,| |g;
92
93 # Barcode given by user could be '0'
94 if ( $barcode || ( defined($barcode) && $barcode eq '0' ) ) {
95     $barcodes = [ $barcode ];
96 } else {
97     my $filefh = $query->upload('uploadfile');
98     if ( $filefh ) {
99         while ( my $content = <$filefh> ) {
100             $content =~ s/[\r\n]*$//g;
101             push @$barcodes, $content if $content;
102         }
103     } elsif ( my $list = $query->param('barcodelist') ) {
104         push @$barcodes, split( /\s\n/, $list );
105         $barcodes = [ map { $_ =~ /^\s*$/ ? () : $_ } @$barcodes ];
106     } else {
107         @$barcodes = $query->multi_param('barcodes');
108     }
109 }
110
111 $barcodes = [ uniq @$barcodes ];
112
113 my $template_name = q|circ/circulation.tt|;
114 my $patron = $borrowernumber ? Koha::Patrons->find( $borrowernumber ) : undef;
115 my $batch = $query->param('batch');
116 my $batch_allowed = 0;
117 if ( $batch && C4::Context->preference('BatchCheckouts') ) {
118     $template_name = q|circ/circulation_batch_checkouts.tt|;
119     my @batch_category_codes = split ',', C4::Context->preference('BatchCheckoutsValidCategories');
120     my $categorycode = $patron->categorycode;
121     if ( $categorycode && grep { $_ eq $categorycode } @batch_category_codes ) {
122         $batch_allowed = 1;
123     } else {
124         $barcodes = [];
125     }
126 }
127
128 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
129     {
130         template_name   => $template_name,
131         query           => $query,
132         type            => "intranet",
133         flagsrequired   => { circulate => 'circulate_remaining_permissions' },
134     }
135 );
136 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
137
138 my $force_allow_issue = $query->param('forceallow') || 0;
139 if (!C4::Auth::haspermission( C4::Context->userenv->{id} , { circulate => 'force_checkout' } )) {
140     $force_allow_issue = 0;
141 }
142 my $onsite_checkout = $query->param('onsite_checkout');
143
144 if (C4::Context->preference("OnSiteCheckoutAutoCheck") && $onsite_checkout eq "on") {
145     $template->param(onsite_checkout => $onsite_checkout);
146 }
147
148 my @failedrenews = $query->multi_param('failedrenew');    # expected to be itemnumbers
149 our %renew_failed = ();
150 for (@failedrenews) { $renew_failed{$_} = 1; }
151
152 my @failedreturns = $query->multi_param('failedreturn');
153 our %return_failed = ();
154 for (@failedreturns) { $return_failed{$_} = 1; }
155
156 my $searchtype = $query->param('searchtype') || q{contain};
157
158 my $branch = C4::Context->userenv->{'branch'};
159
160 if (C4::Context->preference("DisplayClearScreenButton")) {
161     $template->param(DisplayClearScreenButton => 1);
162 }
163
164 for my $barcode ( @$barcodes ) {
165     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
166     $barcode = barcodedecode($barcode)
167         if( $barcode && C4::Context->preference('itemBarcodeInputFilter'));
168 }
169
170 my $stickyduedate  = $query->param('stickyduedate') || $session->param('stickyduedate');
171 my $duedatespec    = $query->param('duedatespec')   || $session->param('stickyduedate');
172 $duedatespec = eval { output_pref( { dt => dt_from_string( $duedatespec ), dateformat => 'iso' }); }
173     if ( $duedatespec );
174 my $restoreduedatespec  = $query->param('restoreduedatespec') || $duedatespec || $session->param('stickyduedate');
175 if ( $restoreduedatespec && $restoreduedatespec eq "highholds_empty" ) {
176     undef $restoreduedatespec;
177 }
178 my $issueconfirmed = $query->param('issueconfirmed');
179 my $cancelreserve  = $query->param('cancelreserve');
180 my $debt_confirmed = $query->param('debt_confirmed') || 0; # Don't show the debt error dialog twice
181 my $charges        = $query->param('charges') || q{};
182
183 # Check if stickyduedate is turned off
184 if ( @$barcodes ) {
185     # was stickyduedate loaded from session?
186     if ( $stickyduedate && ! $query->param("stickyduedate") ) {
187         $session->clear( 'stickyduedate' );
188         $stickyduedate  = $query->param('stickyduedate');
189         $duedatespec    = $query->param('duedatespec');
190     }
191     $session->param('auto_renew', scalar $query->param('auto_renew'));
192 }
193 else {
194     $session->clear('auto_renew');
195 }
196
197 $template->param( auto_renew => $session->param('auto_renew') );
198
199 my ($datedue,$invalidduedate);
200
201 my $duedatespec_allow = C4::Context->preference('SpecifyDueDate');
202 if( $onsite_checkout && !$duedatespec_allow ) {
203     $datedue = output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
204     $datedue .= ' 23:59:00';
205 } elsif( $duedatespec_allow ) {
206     if ( $duedatespec ) {
207         $datedue = eval { dt_from_string( $duedatespec ) };
208         if (! $datedue ) {
209             $invalidduedate = 1;
210             $template->param( IMPOSSIBLE=>1, INVALID_DATE=>$duedatespec );
211         }
212     }
213 }
214
215 my $inprocess = (@$barcodes == 0) ? '' : $query->param('inprocess');
216 if ( @$barcodes == 0 && $charges eq 'yes' ) {
217     $template->param(
218         PAYCHARGES     => 'yes',
219         borrowernumber => $borrowernumber
220     );
221 }
222
223 #
224 # STEP 2 : FIND BORROWER
225 # if there is a list of find borrowers....
226 #
227 my $message;
228 if ($findborrower) {
229     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
230     if ( $patron ) {
231         $borrowernumber = $patron->borrowernumber;
232     } else {
233         my $dt_params = { iDisplayLength => -1 };
234         my $results = C4::Utils::DataTables::Members::search(
235             {
236                 searchmember => $findborrower,
237                 searchtype   => $searchtype,
238                 dt_params    => $dt_params,
239             }
240         );
241         my $borrowers = $results->{patrons};
242         if ( scalar @$borrowers == 1 ) {
243             $borrowernumber = $borrowers->[0]->{borrowernumber};
244             $query->param( 'borrowernumber', $borrowernumber );
245             $query->param( 'barcode',           '' );
246         } elsif ( @$borrowers ) {
247             $template->param( borrowers => $borrowers );
248         } else {
249             $query->param( 'findborrower', '' );
250             $message = "'$findborrower'";
251         }
252     }
253 }
254
255 # get the borrower information.....
256 my $balance = 0;
257 $patron ||= Koha::Patrons->find( $borrowernumber ) if $borrowernumber;
258 if ($patron) {
259
260     $template->param( borrowernumber => $patron->borrowernumber );
261     output_and_exit_if_error( $query, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
262
263     my $overdues = $patron->get_overdues;
264     my $issues = $patron->checkouts;
265     $balance = $patron->account->balance;
266
267
268     # if the expiry date is before today ie they have expired
269     if ( $patron->is_expired ) {
270         #borrowercard expired, no issues
271         $template->param(
272             noissues => ($force_allow_issue) ? 0 : "1",
273             forceallow => $force_allow_issue,
274             expired => "1",
275         );
276     }
277     # check for NotifyBorrowerDeparture
278     elsif ( $patron->is_going_to_expire ) {
279         # borrower card soon to expire warn librarian
280         $template->param( "warndeparture" => $patron->dateexpiry ,
281                         );
282         if (C4::Context->preference('ReturnBeforeExpiry')){
283             $template->param("returnbeforeexpiry" => 1);
284         }
285     }
286     $template->param(
287         overduecount => $overdues->count,
288         issuecount   => $issues->count,
289         finetotal    => $balance,
290     );
291
292     if ( $patron and $patron->is_debarred ) {
293         $template->param(
294             'userdebarred'    => $patron->debarred,
295             'debarredcomment' => $patron->debarredcomment,
296         );
297
298         if ( $patron->debarred ne "9999-12-31" ) {
299             $template->param( 'userdebarreddate' => $patron->debarred );
300         }
301     }
302
303     # Calculate and display patron's age
304     if ( !$patron->is_valid_age ) {
305         $template->param( age_limitations => 1 );
306         $template->param( age_low => $patron->category->dateofbirthrequired );
307         $template->param( age_high => $patron->category->upperagelimit );
308     }
309
310 }
311
312 #
313 # STEP 3 : ISSUING
314 #
315 #
316 if (@$barcodes) {
317   my $checkout_infos;
318   for my $barcode ( @$barcodes ) {
319
320     my $template_params = {
321         barcode         => $barcode,
322         onsite_checkout => $onsite_checkout,
323     };
324
325     # always check for blockers on issuing
326     my ( $error, $question, $alerts, $messages ) = CanBookBeIssued(
327         $patron,
328         $barcode, $datedue,
329         $inprocess,
330         undef,
331         {
332             onsite_checkout     => $onsite_checkout,
333             override_high_holds => $override_high_holds || $override_high_holds_tmp || 0,
334         }
335     );
336
337     my $blocker = $invalidduedate ? 1 : 0;
338
339     $template_params->{alert} = $alerts;
340     $template_params->{messages} = $messages;
341
342     my $item = Koha::Items->find({ barcode => $barcode });
343
344     my $biblio;
345     if ( $item ) {
346         $biblio = $item->biblio;
347     }
348
349     # Fix for bug 7494: optional checkout-time fallback search for a book
350
351     if ( $error->{'UNKNOWN_BARCODE'}
352         && C4::Context->preference("itemBarcodeFallbackSearch")
353         && not $batch
354     )
355     {
356      $template_params->{FALLBACK} = 1;
357
358         my $searcher = Koha::SearchEngine::Search->new({index => $Koha::SearchEngine::BIBLIOS_INDEX});
359         my $query = "kw=" . $barcode;
360         my ( $searcherror, $results, $total_hits ) = $searcher->simple_search_compat($query, 0, 10);
361
362         # if multiple hits, offer options to librarian
363         if ( $total_hits > 0 ) {
364             my @barcodes;
365             foreach my $hit ( @{$results} ) {
366                 my $chosen = # Maybe easier to retrieve the itemnumber from $hit?
367                   TransformMarcToKoha( C4::Search::new_record_from_zebra('biblioserver',$hit) );
368
369                 # offer all barcodes individually
370                 if ( $chosen->{barcode} ) {
371                     push @barcodes, sort split(/\s*\|\s*/, $chosen->{barcode});
372                 }
373             }
374             my $items = Koha::Items->search({ barcode => {-in => \@barcodes}});
375             $template_params->{options} = $items;
376         }
377     }
378
379     if ( $error->{DEBT_GUARANTORS} ) {
380         $template_params->{DEBT_GUARANTORS} = $error->{DEBT_GUARANTORS};
381         $template_params->{IMPOSSIBLE} = 1;
382         $blocker = 1;
383     }
384
385     if ( $error->{UNKNOWN_BARCODE} or not $onsite_checkout or not C4::Context->preference("OnSiteCheckoutsForce") ) {
386         delete $question->{'DEBT'} if ($debt_confirmed);
387         foreach my $impossible ( keys %$error ) {
388             $template_params->{$impossible} = $$error{$impossible};
389             $template_params->{IMPOSSIBLE} = 1;
390             $blocker = 1;
391         }
392     }
393
394     if( $item and ( !$blocker or $force_allow_issue ) ){
395         my $confirm_required = 0;
396         unless($issueconfirmed){
397             #  Get the item title for more information
398             my $materials = $item->materials;
399             my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({ frameworkcode => $biblio->frameworkcode, kohafield => 'items.materials', authorised_value => $materials });
400             $materials = $descriptions->{lib} // $materials;
401             $template_params->{ADDITIONAL_MATERIALS} = $materials;
402             $template_params->{itemhomebranch} = $item->homebranch;
403
404             # pass needsconfirmation to template if issuing is possible and user hasn't yet confirmed.
405             foreach my $needsconfirmation ( keys %$question ) {
406                 $template_params->{$needsconfirmation} = $$question{$needsconfirmation};
407                 $template_params->{getTitleMessageIteminfo} = $biblio->title;
408                 $template_params->{getBarcodeMessageIteminfo} = $item->barcode;
409                 $template_params->{NEEDSCONFIRMATION} = 1;
410                 $confirm_required = 1;
411             }
412         }
413         unless($confirm_required) {
414             my $switch_onsite_checkout = exists $messages->{ONSITE_CHECKOUT_WILL_BE_SWITCHED};
415             my $issue = AddIssue( $patron->unblessed, $barcode, $datedue, $cancelreserve, undef, undef, { onsite_checkout => $onsite_checkout, auto_renew => $session->param('auto_renew'), switch_onsite_checkout => $switch_onsite_checkout, } );
416             $template_params->{issue} = $issue;
417             $session->clear('auto_renew');
418             $inprocess = 1;
419         }
420     }
421
422     if ($question->{RESERVE_WAITING} or $question->{RESERVED} or $question->{TRANSFERRED} or $question->{PROCESSING}){
423         $template->param(
424             reserveborrowernumber => $question->{'resborrowernumber'},
425             reserve_id => $question->{reserve_id},
426         );
427     }
428
429
430     # FIXME If the issue is confirmed, we launch another time checkouts->count, now display the issue count after issue
431     $patron = Koha::Patrons->find( $borrowernumber );
432     $template_params->{issuecount} = $patron->checkouts->count;
433
434     if ( $item ) {
435         $template_params->{item} = $item;
436         $template_params->{biblio} = $biblio;
437         $template_params->{itembiblionumber} = $biblio->biblionumber;
438     }
439     push @$checkout_infos, $template_params;
440   }
441   unless ( $batch ) {
442     $template->param( %{$checkout_infos->[0]} );
443     $template->param( barcode => $barcodes->[0] );
444   } else {
445     my $confirmation_needed = grep { $_->{NEEDSCONFIRMATION} } @$checkout_infos;
446     $template->param(
447         checkout_infos => $checkout_infos,
448         confirmation_needed => $confirmation_needed,
449     );
450   }
451 }
452
453 ##################################################################################
454 # BUILD HTML
455 # show all reserves of this borrower, and the position of the reservation ....
456 if ($patron) {
457     my $holds = Koha::Holds->search( { borrowernumber => $borrowernumber } ); # FIXME must be Koha::Patron->holds
458     my $waiting_holds = $holds->waiting;
459     $template->param(
460         holds_count  => $holds->count(),
461         WaitingHolds => $waiting_holds,
462     );
463 }
464
465 if ( $patron ) {
466     my $noissues;
467     if ( $patron->gonenoaddress ) {
468         $template->param( gna => 1 );
469         $noissues = 1;
470     }
471     if ( $patron->lost ) {
472         $template->param( lost=> 1 );
473         $noissues = 1;
474     }
475     if ( $patron->is_debarred ) {
476         $template->param( dbarred=> 1 );
477         $noissues = 1;
478     }
479     my $account = $patron->account;
480     if( ( my $owing = $account->non_issues_charges ) > 0 ) {
481         my $noissuescharge = C4::Context->preference("noissuescharge") || 5; # FIXME If noissuescharge == 0 then 5, why??
482         $noissues ||= ( not C4::Context->preference("AllowFineOverride") and ( $owing > $noissuescharge ) );
483         $template->param(
484             charges => 1,
485             chargesamount => $owing,
486         )
487     } elsif ( $balance < 0 ) {
488         $template->param(
489             credits => 1,
490             creditsamount => -$balance,
491         );
492     }
493
494     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
495     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
496     if ( $no_issues_charge_guarantors ) {
497         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
498
499         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors ) {
500             $template->param(
501                 charges_guarantors_guarantees => $guarantors_non_issues_charges
502             );
503             $noissues = 1 unless C4::Context->preference("allowfineoverride");
504         }
505     }
506
507     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
508     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
509     if ( defined $no_issues_charge_guarantees ) {
510         my $guarantees_non_issues_charges = 0;
511         my $guarantees = $patron->guarantee_relationships->guarantees;
512         while ( my $g = $guarantees->next ) {
513             $guarantees_non_issues_charges += $g->account->non_issues_charges;
514         }
515         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees ) {
516             $template->param(
517                 charges_guarantees    => 1,
518                 chargesamount_guarantees => $guarantees_non_issues_charges,
519             );
520             $noissues = 1 unless C4::Context->preference("allowfineoverride");
521         }
522     }
523
524     if ( $patron->has_overdues ) {
525         $template->param( odues => 1 );
526     }
527
528     if ( $patron->borrowernotes ) {
529         my $borrowernotes = $patron->borrowernotes;
530         $borrowernotes =~ s#\n#<br />#g;
531         $template->param(
532             notes =>1,
533             notesmsg => $borrowernotes,
534         )
535     }
536
537     if ( $noissues ) {
538         $template->param(
539             noissues => ($force_allow_issue) ? 0 : 'true',
540             forceallow => $force_allow_issue,
541         );
542     }
543 }
544
545 my $messages = Koha::Patron::Messages->search(
546     {
547         'me.borrowernumber' => $borrowernumber,
548     },
549     {
550        join => 'manager',
551        '+select' => ['manager.surname', 'manager.firstname' ],
552        '+as' => ['manager_surname', 'manager_firstname'],
553     }
554 );
555
556 my $fast_cataloging = 0;
557 if ( Koha::BiblioFrameworks->find('FA') ) {
558     $fast_cataloging = 1 
559 }
560
561 my $view = $batch
562     ?'batch_checkout_view'
563     : 'circview';
564
565 my @relatives;
566 if ( $patron ) {
567     if ( my @guarantors = $patron->guarantor_relationships()->guarantors() ) {
568         push( @relatives, $_->id ) for @guarantors;
569         push( @relatives, $_->id ) for $patron->siblings();
570     } else {
571         push( @relatives, $_->id ) for $patron->guarantee_relationships()->guarantees();
572     }
573 }
574 my $relatives_issues_count =
575   Koha::Database->new()->schema()->resultset('Issue')
576   ->count( { borrowernumber => \@relatives } );
577
578 if ( $patron ) {
579     my $av = Koha::AuthorisedValues->search({ category => 'ROADTYPE', authorised_value => $patron->streettype });
580     my $roadtype = $av->count ? $av->next->lib : '';
581     $template->param(
582         roadtype          => $roadtype,
583         patron            => $patron,
584         categoryname      => $patron->category->description,
585         expiry            => $patron->dateexpiry,
586     );
587 }
588
589 # Restore date if changed by holds and/or save stickyduedate to session
590 if ($restoreduedatespec || $stickyduedate) {
591     $duedatespec = $restoreduedatespec || $duedatespec;
592
593     if ($stickyduedate) {
594         $session->param( 'stickyduedate', $duedatespec );
595     }
596 } elsif (defined($duedatespec) && !defined($restoreduedatespec)) {
597     undef $duedatespec;
598 }
599
600 $template->param(
601     messages           => $messages,
602     borrowernumber    => $borrowernumber,
603     branch            => $branch,
604     was_renewed       => scalar $query->param('was_renewed') ? 1 : 0,
605     barcodes          => $barcodes,
606     stickyduedate     => $stickyduedate,
607     duedatespec       => $duedatespec,
608     restoreduedatespec => $restoreduedatespec,
609     message           => $message,
610     totaldue          => sprintf('%.2f', $balance), # FIXME not used in template?
611     inprocess         => $inprocess,
612     $view             => 1,
613     batch_allowed     => $batch_allowed,
614     batch             => $batch,
615     AudioAlerts           => C4::Context->preference("AudioAlerts"),
616     fast_cataloging   => $fast_cataloging,
617     CircAutoPrintQuickSlip   => C4::Context->preference("CircAutoPrintQuickSlip"),
618     RoutingSerials => C4::Context->preference('RoutingSerials'),
619     relatives_issues_count => $relatives_issues_count,
620     relatives_borrowernumbers => \@relatives,
621 );
622
623
624 if ( C4::Context->preference("ExportCircHistory") ) {
625     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc' }) ]);
626 }
627
628 my $has_modifications = Koha::Patron::Modifications->search( { borrowernumber => $borrowernumber } )->count;
629 $template->param(
630     debt_confirmed            => $debt_confirmed,
631     SpecifyDueDate            => $duedatespec_allow,
632     PatronAutoComplete      => C4::Context->preference("PatronAutoComplete"),
633     debarments                => scalar GetDebarments({ borrowernumber => $borrowernumber }),
634     todaysdate                => output_pref( { dt => dt_from_string()->set(hour => 23)->set(minute => 59), dateformat => 'sql' } ),
635     has_modifications         => $has_modifications,
636     override_high_holds       => $override_high_holds,
637     nopermission              => scalar $query->param('nopermission'),
638     autoswitched              => $autoswitched,
639     logged_in_user            => $logged_in_user,
640 );
641
642 output_html_with_http_headers $query, $cookie, $template->output;