koha-tmpl/opac-tmpl/prog/en/xslt/MARC21slimUtils.xsl

   1 <?xml version='1.0'?>
   2 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   3 <xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4         <xsl:template name="datafield">
   5                 <xsl:param name="tag"/>
   6                 <xsl:param name="ind1"><xsl:text> </xsl:text></xsl:param>
   7                 <xsl:param name="ind2"><xsl:text> </xsl:text></xsl:param>
   8                 <xsl:param name="subfields"/>
   9                 <xsl:element name="datafield">
  10                         <xsl:attribute name="tag">
  11                                 <xsl:value-of select="$tag"/>
  12                         </xsl:attribute>
  13                         <xsl:attribute name="ind1">
  14                                 <xsl:value-of select="$ind1"/>
  15                         </xsl:attribute>
  16                         <xsl:attribute name="ind2">
  17                                 <xsl:value-of select="$ind2"/>
  18                         </xsl:attribute>
  19                         <xsl:copy-of select="$subfields"/>
  20                 </xsl:element>
  21         </xsl:template>
  22
  23         <xsl:template name="subfieldSelect">
  24                 <xsl:param name="codes"/>
  25                 <xsl:param name="delimeter"><xsl:text> </xsl:text></xsl:param>
  26                 <xsl:param name="subdivCodes"/>
  27                 <xsl:param name="subdivDelimiter"/>
  28         <xsl:param name="prefix"/>
  29         <xsl:param name="suffix"/>
  30                 <xsl:variable name="str">
  31                         <xsl:for-each select="marc:subfield">
  32                                 <xsl:if test="contains($codes, @code)">
  33                     <xsl:if test="contains($subdivCodes, @code)">
  34                         <xsl:value-of select="$subdivDelimiter"/>
  35                     </xsl:if>
  36                                         <xsl:value-of select="$prefix"/><xsl:value-of select="text()"/><xsl:value-of select="$suffix"/><xsl:value-of select="$delimeter"/>
  37                                 </xsl:if>
  38                         </xsl:for-each>
  39                 </xsl:variable>
  40                 <xsl:value-of select="substring($str,1,string-length($str)-string-length($delimeter))"/>
  41         </xsl:template>
  42
  43         <xsl:template name="buildSpaces">
  44                 <xsl:param name="spaces"/>
  45                 <xsl:param name="char"><xsl:text> </xsl:text></xsl:param>
  46                 <xsl:if test="$spaces>0">
  47                         <xsl:value-of select="$char"/>
  48                         <xsl:call-template name="buildSpaces">
  49                                 <xsl:with-param name="spaces" select="$spaces - 1"/>
  50                                 <xsl:with-param name="char" select="$char"/>
  51                         </xsl:call-template>
  52                 </xsl:if>
  53         </xsl:template>
  54
  55         <xsl:template name="chopPunctuation">
  56                 <xsl:param name="chopString"/>
  57                 <xsl:variable name="length" select="string-length($chopString)"/>
  58                 <xsl:choose>
  59                         <xsl:when test="$length=0"/>
  60                         <xsl:when test="contains('.:,;/ ', substring($chopString,$length,1))">
  61                                 <xsl:call-template name="chopPunctuation">
  62                                         <xsl:with-param name="chopString" select="substring($chopString,1,$length - 1)"/>
  63                                 </xsl:call-template>
  64                         </xsl:when>
  65                         <xsl:when test="not($chopString)"/>
  66                         <xsl:otherwise><xsl:value-of select="$chopString"/></xsl:otherwise>
  67                 </xsl:choose>
  68         </xsl:template>
  69
  70         <!-- Function extractControlNumber is used to extract the control number (record number) from MARC tags 773/80/85 [etc.] subfield $w.
  71              Parameter: control number string.
  72              Assumes LOC convention: (OrgCode)recordNumber.
  73              If OrgCode is not present, return full string.
  74              Additionally, handle various brackets/parentheses. Chop leading and trailing spaces.
  75         -->
  76         <xsl:template name="extractControlNumber">
  77             <xsl:param name="subfieldW"/>
  78             <xsl:variable name="tranW" select="translate($subfieldW,']})&gt;','))))')"/>
  79             <xsl:choose>
  80               <xsl:when test="contains($tranW,')')">
  81                 <xsl:value-of select="normalize-space(translate(substring-after($tranW,')'),'[]{}()&lt;&gt;',''))"/>
  82               </xsl:when>
  83               <xsl:otherwise>
  84                 <xsl:value-of select="normalize-space($subfieldW)"/>
  85               </xsl:otherwise>
  86             </xsl:choose>
  87         </xsl:template>
  88
  89     <!-- Function m880Select:  Display Alternate Graphic Representation (MARC 880) for selected latin "base"tags
  90         - should be called immediately before the corresonding latin tags are processed
  91         - tags in right-to-left languages are displayed floating right
  92         * Parameter:
  93            + basetags: display these tags if found in linkage section ( subfield 6) of tag 880
  94            + codes: display these subfields codes
  95         * Options:
  96             - class: wrap output in <span class="$class">...</span>
  97             - label: prefix each(!) tag with label $label
  98             - bibno: link to biblionumber $bibno
  99             - index: build a search link using index $index with subfield $a as key; if subfield $9 is present use index 'an' with key $9 instead.
 100          * Limitations:
 101             - displays every field on a separate line (to switch between rtl and ltr)
 102          * Pitfalls:
 103            (!) output might be empty
 104     -->
 105     <xsl:template name="m880Select">
 106          <xsl:param name="basetags"/> <!-- e.g.  100,700,110,710 -->
 107         <xsl:param name="codes"/> <!-- e.g. abc  -->
 108         <xsl:param name="class"/> <!-- e.g. results_summary -->
 109         <xsl:param name="label"/> <!-- e.g.  Edition -->
 110         <xsl:param name="bibno"/>
 111         <xsl:param name="index"/> <!-- e.g.  au -->
 112
 113         <xsl:for-each select="marc:datafield[@tag=880]">
 114             <xsl:variable name="code6" select="marc:subfield[@code=6]"/>
 115             <xsl:if test="contains(string($basetags), substring($code6,1,3))">
 116                 <span>
 117                     <xsl:choose>
 118                     <xsl:when test="boolean($class) and substring($code6,string-length($code6)-1,2) ='/r'">
 119                         <xsl:attribute name="class"><xsl:value-of select="$class"/> m880</xsl:attribute>
 120                         <xsl:attribute name="dir">rtl</xsl:attribute>
 121                     </xsl:when>
 122                      <xsl:when test="boolean($class)">
 123                         <xsl:attribute name="class"><xsl:value-of select="$class"/></xsl:attribute>
 124                         <xsl:attribute name="style">display:block; </xsl:attribute>
 125                     </xsl:when>
 126                      <xsl:when test="substring($code6,string-length($code6)-1,2) ='/r'">
 127                         <xsl:attribute name="class"><xsl:value-of select="$class"/> m880</xsl:attribute>
 128                     </xsl:when>
 129                     </xsl:choose>
 130                     <xsl:if test="boolean($label)">
 131                         <span class="label">
 132                             <xsl:value-of select="$label"/>
 133                         </span>
 134                     </xsl:if>
 135                     <xsl:variable name="str">
 136                         <xsl:for-each select="marc:subfield">
 137                             <xsl:if test="contains($codes, @code)">
 138                                 <xsl:value-of select="text()"/>
 139                                 <xsl:text> </xsl:text>
 140                             </xsl:if>
 141                         </xsl:for-each>
 142                     </xsl:variable>
 143                     <xsl:choose>
 144                         <xsl:when test="boolean($bibno)">
 145                             <a>
 146                                 <xsl:attribute name="href">/cgi-bin/koha/opac-detail.pl?biblionumber=<xsl:value-of  select="$bibno"/></xsl:attribute>
 147                                 <xsl:value-of select="$str"/>
 148                             </a>
 149                         </xsl:when>
 150                        <xsl:when test="boolean($index) and boolean(marc:subfield[@code=9])">
 151                             <a>
 152                                 <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=an:<xsl:value-of  select="marc:subfield[@code=9]"/></xsl:attribute>
 153                                   <xsl:value-of select="$str"/>
 154                             </a>
 155                         </xsl:when>
 156                         <xsl:when test="boolean($index)">
 157                             <a>
 158                                 <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=<xsl:value-of  select="$index"/>:<xsl:value-of  select="marc:subfield[@code='a']"/></xsl:attribute>
 159                                 <xsl:value-of select="$str"/>
 160                             </a>
 161                         </xsl:when>
 162                         <xsl:otherwise>
 163                             <xsl:value-of select="$str"/>
 164                         </xsl:otherwise>
 165                     </xsl:choose>
 166                 </span>
 167             </xsl:if>
 168         </xsl:for-each>
 169
 170     </xsl:template>
 171
 172 </xsl:stylesheet>
 173
 174 <!-- Stylus Studio meta-information - (c)1998-2002 eXcelon Corp.
 175 <metaInformation>
 176 <scenarios/><MapperInfo srcSchemaPath="" srcSchemaRoot="" srcSchemaPathIsRelative="yes" srcSchemaInterpretAsXML="no" destSchemaPath="" destSchemaRoot="" destSchemaPathIsRelative="yes" destSchemaInterpretAsXML="no"/>
 177 </metaInformation>
 178 -->