bug 8215: (followup) make sure C4::CourseReserves doesn't export anything
[koha.git] / members / statistics.pl
1 #!/usr/bin/perl
2
3 # Copyright 2012 BibLibre
4 # This file is part of Koha.
5 #
6 # Koha is free software; you can redistribute it and/or modify it under the
7 # terms of the GNU General Public License as published by the Free Software
8 # Foundation; either version 2 of the License, or (at your option) any later
9 # version.
10 #
11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License along with
16 # Koha; if not, write to the Free Software Foundation, Inc.,
17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
18
19 =head1 members/statistics.pl
20   Generate statistic issues for a member
21 =cut
22
23 use Modern::Perl;
24
25 use CGI;
26 use C4::Auth;
27 use C4::Branch;
28 use C4::Context;
29 use C4::Members;
30 use C4::Members::Statistics;
31 use C4::Members::Attributes qw(GetBorrowerAttributes);
32 use C4::Output;
33
34 my $input = new CGI;
35
36 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
37     {   template_name   => "members/statistics.tmpl",
38         query           => $input,
39         type            => "intranet",
40         authnotrequired => 0,
41         flagsrequired   => { borrowers => 1 },
42         debug           => 1,
43     }
44 );
45
46 my $borrowernumber = $input->param('borrowernumber');
47
48 # Set informations for the patron
49 my $borrower = GetMemberDetails( $borrowernumber, 0 );
50 if ( not defined $borrower ) {
51     $template->param (unknowuser => 1);
52     output_html_with_http_headers $input, $cookie, $template->output;
53     exit;
54 }
55
56 foreach my $key ( keys %$borrower ) {
57     $template->param( $key => $borrower->{$key} );
58 }
59 $template->param(
60     categoryname    => $borrower->{'description'},
61     branchname      => GetBranchName($borrower->{'branchcode'}),
62 );
63 # Construct column names
64 my $fields = C4::Members::Statistics::get_fields();
65 our @statistic_column_names = split '\|', $fields;
66 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
67 our @column_names = ( @statistic_column_names, @value_column_names );
68
69 # Get statistics
70 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
71 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
72 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
73 my $r = merge (
74     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
75 );
76
77 add_actual_state( $r );
78 my ( $total, $datas ) = build_array( $r );
79
80 # Gettings sums
81 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
82 my $count_total_issues = $total->{count_total_issues_today} || 0;
83 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
84 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
85
86 if (C4::Context->preference('ExtendedPatronAttributes')) {
87     my $attributes = GetBorrowerAttributes($borrowernumber);
88     $template->param(
89         ExtendedPatronAttributes => 1,
90         extendedattributes => $attributes
91     );
92 }
93
94 my ($picture, $dberror) = GetPatronImage($borrower->{'cardnumber'});
95 $template->param( picture => 1 ) if $picture;
96
97 $template->param(
98     statisticsview => 1,
99     datas          => $datas,
100     column_names   => \@statistic_column_names,
101     length_keys    => scalar( @statistic_column_names),
102     count_total_issues => $count_total_issues,
103     count_total_issues_returned => $count_total_issues_returned,
104     count_total_precedent_state => $count_total_precedent_state,
105     count_total_actual_state => $count_total_actual_state,
106     RoutingSerials => C4::Context->preference('RoutingSerials'),
107 );
108
109 output_html_with_http_headers $input, $cookie, $template->output;
110
111
112 =head1 FUNCTIONS
113
114 =head2 add_actual_state
115   Add a 'count_actual_state' key in all hashes
116   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
117 =cut
118 sub add_actual_state {
119     my ( $array ) = @_;
120     for my $hash ( @$array ) {
121         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
122     }
123 }
124
125 =head2 build_array
126   Build a new array containing values of hashes.
127   It used by template whitch display silly values.
128   ex:
129     $array = [
130       {
131         'count_total_issues_returned_today' => 1,
132         'ccode' => 'ccode',
133         'count_actual_state' => 1,
134         'count_precedent_state' => 1,
135         'homebranch' => 'homebranch',
136         'count_total_issues_today' => 1,
137         'itype' => 'itype'
138       }
139     ];
140   and returns:
141     [
142       [
143         'homebranch',
144         'itype',
145         'ccode',
146         1,
147         1,
148         1,
149         1
150       ]
151     ];
152
153 =cut
154 sub build_array {
155     my ( $array ) = @_;
156     my ( @r, $total );
157     for my $hash ( @$array) {
158         my @line;
159         for my $cn ( ( @column_names, 'count_actual_state') ) {
160             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
161                 $hash->{$cn} //= 0;
162                 if ( exists $total->{$cn} ) {
163                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
164                 } else {
165                     $total->{$cn} = $hash->{$cn};
166                 }
167             }
168             push @line, $hash->{$cn};
169         }
170         push @r, \@line;
171     }
172     return ( $total, \@r );
173 }
174
175 =head2 merge
176   Merge hashes with the same statistic column names into one
177   param: array, a arrayref of arrayrefs
178   ex:
179   @array = (
180      {
181        'ccode' => 'ccode',
182        'count_precedent_state' => '1',
183        'homebranch' => 'homebranch',
184        'itype' => 'itype'
185      },
186      {
187        'count_total_issues_returned_today' => '1',
188        'ccode' => 'ccode',
189        'homebranch' => 'homebranch',
190        'itype' => 'itype'
191      }
192    );
193    and returns:
194    [
195      {
196        'count_total_issues_returned_today' => '1',
197        'ccode' => 'ccode',
198        'count_precedent_state' => '1',
199        'homebranch' => 'homebranch',
200        'itype' => 'itype'
201      }
202    ];
203
204 =cut
205 sub merge {
206     my @array = @_;
207     my @r;
208     for my $h ( @array ) {
209         my $exists = 0;
210         for my $ch ( @r ) {
211             $exists = 1;
212             for my $cn ( @statistic_column_names ) {
213                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
214                     $exists = 0;
215                     last;
216                 }
217             }
218             if ($exists){
219                 for my $cn ( @value_column_names ) {
220                     next if not exists $h->{$cn};
221                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
222                 }
223                 last;
224             }
225         }
226
227         if ( not $exists ) {push @r, $h;}
228     }
229     return \@r;
230 }