misc/cronjobs/fines.pl

   1 #!/usr/bin/perl
   2
   3 #  This script loops through each overdue item, determines the fine,
   4 #  and updates the total amount of fines due by each user.  It relies on
   5 #  the existence of /tmp/fines, which is created by ???
   6 # Doesn't really rely on it, it relys on being able to write to /tmp/
   7 # It creates the fines file
   8 #
   9 #  This script is meant to be run nightly out of cron.
  10
  11 # Copyright 2000-2002 Katipo Communications
  12 # Copyright 2011 PTFS-Europe Ltd
  13 #
  14 # This file is part of Koha.
  15 #
  16 # Koha is free software; you can redistribute it and/or modify it
  17 # under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 3 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # Koha is distributed in the hope that it will be useful, but
  22 # WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  24 # GNU General Public License for more details.
  25 #
  26 # You should have received a copy of the GNU General Public License
  27 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  28
  29 use strict;
  30 use warnings;
  31 use 5.010;
  32
  33 use Koha::Script -cron;
  34 use C4::Context;
  35 use C4::Overdues qw( Getoverdues CalcFine UpdateFine );
  36 use Getopt::Long qw( GetOptions );
  37 use Carp qw( carp croak );
  38 use File::Spec;
  39 use Try::Tiny qw( catch try );
  40
  41 use Koha::Calendar;
  42 use Koha::DateUtils qw( dt_from_string output_pref );
  43 use Koha::Patrons;
  44 use C4::Log qw( cronlogaction );
  45
  46 my $help;
  47 my $verbose;
  48 my $output_dir;
  49 my $log;
  50 my $maxdays;
  51
  52 GetOptions(
  53     'h|help'    => \$help,
  54     'v|verbose' => \$verbose,
  55     'l|log'     => \$log,
  56     'o|out:s'   => \$output_dir,
  57     'm|maxdays:i' => \$maxdays,
  58 );
  59 my $usage = << 'ENDUSAGE';
  60
  61 This script calculates and charges overdue fines
  62 to patron accounts.  The Koha system preference 'finesMode' controls
  63 whether the fines are calculated and charged to the patron accounts ("Calculate and charge");
  64 or not calculated ("Don't calculate").
  65
  66 This script has the following parameters :
  67     -h --help: this message
  68     -l --log: log the output to a file (optional if the -o parameter is given)
  69     -o --out:  ouput directory for logs (defaults to env or /tmp if !exist)
  70     -v --verbose
  71     -m --maxdays: how many days back of overdues to process
  72
  73 ENDUSAGE
  74
  75 if ($help) {
  76     print $usage;
  77     exit;
  78 }
  79
  80 my $script_handler = Koha::Script->new({ script => $0 });
  81
  82 try {
  83     $script_handler->lock_exec;
  84 }
  85 catch {
  86     my $message = "Skipping execution of $0 ($_)";
  87     print STDERR "$message\n"
  88         if $verbose;
  89     cronlogaction( $message );
  90     exit;
  91 };
  92
  93 cronlogaction();
  94
  95 my @borrower_fields =
  96   qw(cardnumber categorycode surname firstname email phone address citystate);
  97 my @item_fields  = qw(itemnumber barcode date_due);
  98 my @other_fields = qw(days_overdue fine);
  99 my $libname      = C4::Context->preference('LibraryName');
 100 my $control      = C4::Context->preference('CircControl');
 101 my $mode         = C4::Context->preference('finesMode');
 102 my $delim = "\t";    # ?  C4::Context->preference('CSVDelimiter') || "\t";
 103
 104 my %is_holiday;
 105 my $today = dt_from_string();
 106 my $filename;
 107 if ($log or $output_dir) {
 108     $filename = get_filename($output_dir);
 109 }
 110
 111 my $fh;
 112 if ($filename) {
 113     open $fh, '>>', $filename or croak "Cannot write file $filename: $!";
 114     print {$fh} join $delim, ( @borrower_fields, @item_fields, @other_fields );
 115     print {$fh} "\n";
 116 }
 117 my $counted = 0;
 118 my $updated = 0;
 119 my $params;
 120 $params->{maximumdays} = $maxdays if $maxdays;
 121 my $overdues = Getoverdues($params);
 122 for my $overdue ( @{$overdues} ) {
 123     next if $overdue->{itemlost};
 124
 125     if ( !defined $overdue->{borrowernumber} ) {
 126         carp
 127 "ERROR in Getoverdues : issues.borrowernumber IS NULL.  Repair 'issues' table now!  Skipping record.\n";
 128         next;
 129     }
 130     my $patron = Koha::Patrons->find( $overdue->{borrowernumber} );
 131     my $branchcode =
 132         ( $control eq 'ItemHomeLibrary' ) ? $overdue->{homebranch}
 133       : ( $control eq 'PatronLibrary' )   ? $patron->branchcode
 134       :                                     $overdue->{branchcode};
 135
 136 # In final case, CircControl must be PickupLibrary. (branchcode comes from issues table here).
 137     if ( !exists $is_holiday{$branchcode} ) {
 138         $is_holiday{$branchcode} = set_holiday( $branchcode, $today );
 139     }
 140
 141     my $datedue = dt_from_string( $overdue->{date_due} );
 142     if ( DateTime->compare( $datedue, $today ) == 1 ) {
 143         next;    # not overdue
 144     }
 145     ++$counted;
 146
 147     my ( $amount, $unitcounttotal, $unitcount ) =
 148       CalcFine( $overdue, $patron->categorycode,
 149         $branchcode, $datedue, $today );
 150
 151     # Don't update the fine if today is a holiday.
 152     # This ensures that dropbox mode will remove the correct amount of fine.
 153     if (
 154         $mode eq 'production'
 155         && ( !$is_holiday{$branchcode}
 156             || C4::Context->preference('ChargeFinesOnClosedDays') )
 157         && ( $amount && $amount > 0 )
 158       )
 159     {
 160         UpdateFine(
 161             {
 162                 issue_id       => $overdue->{issue_id},
 163                 itemnumber     => $overdue->{itemnumber},
 164                 borrowernumber => $overdue->{borrowernumber},
 165                 amount         => $amount,
 166                 due            => output_pref($datedue),
 167             }
 168         );
 169         $updated++;
 170     }
 171     my $borrower = $patron->unblessed;
 172     if ($filename) {
 173         my @cells;
 174         push @cells,
 175           map { defined $borrower->{$_} ? $borrower->{$_} : q{} }
 176           @borrower_fields;
 177         push @cells, map { $overdue->{$_} } @item_fields;
 178         push @cells, $unitcounttotal, $amount;
 179         say {$fh} join $delim, @cells;
 180     }
 181 }
 182 if ($filename){
 183     close $fh;
 184 }
 185
 186 if ($verbose) {
 187     my $overdue_items = @{$overdues};
 188     print <<"EOM";
 189 Fines assessment -- $today
 190 EOM
 191     if ($filename) {
 192         say "Saved to $filename";
 193     }
 194     print <<"EOM";
 195 Number of Overdue Items:
 196      counted $overdue_items
 197     reported $counted
 198      updated $updated
 199
 200 EOM
 201 }
 202
 203 sub set_holiday {
 204     my ( $branch, $dt ) = @_;
 205
 206     my $calendar = Koha::Calendar->new( branchcode => $branch );
 207     return $calendar->is_holiday($dt);
 208 }
 209
 210 sub get_filename {
 211     my $directory = shift;
 212     if ( !$directory ) {
 213         $directory = C4::Context::temporary_directory;
 214     }
 215     if ( !-d $directory ) {
 216         carp "Could not write to $directory ... does not exist!";
 217     }
 218     my $name = C4::Context->config('database');
 219     $name =~ s/\W//;
 220     $name .= join q{}, q{_}, $today->ymd(), '.log';
 221     $name = File::Spec->catfile( $directory, $name );
 222     if ($verbose && $log) {
 223         say "writing to $name";
 224     }
 225     return $name;
 226 }