misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43
  44 =head1 NAME
  45
  46 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  47
  48 =head1 SYNOPSIS
  49
  50 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -library <branchcode>...] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  51
  52  Options:
  53    -help                          brief help message
  54    -man                           full documentation
  55    -n                             No email will be sent
  56    -max          <days>           maximum days overdue to deal with
  57    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  58    -csv          <filename>       populate CSV file
  59    -html         <filename>       Output html to file
  60    -itemscontent <list of fields> item information in templates
  61    -borcat       <categorycode>   category code that must be included
  62    -borcatout    <categorycode>   category code that must be excluded
  63
  64 =head1 OPTIONS
  65
  66 =over 8
  67
  68 =item B<-help>
  69
  70 Print a brief help message and exits.
  71
  72 =item B<-man>
  73
  74 Prints the manual page and exits.
  75
  76 =item B<-v>
  77
  78 Verbose. Without this flag set, only fatal errors are reported.
  79
  80 =item B<-n>
  81
  82 Do not send any email. Overdue notices that would have been sent to
  83 the patrons or to the admin are printed to standard out. CSV data (if
  84 the -csv flag is set) is written to standard out or to any csv
  85 filename given.
  86
  87 =item B<-max>
  88
  89 Items older than max days are assumed to be handled somewhere else,
  90 probably the F<longoverdues.pl> script. They are therefore ignored by
  91 this program. No notices are sent for them, and they are not added to
  92 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  93
  94 =item B<-library>
  95
  96 select overdues for one specific library. Use the value in the
  97 branches.branchcode table. This option can be repeated in order
  98 to select overdues for a group of libraries.
  99
 100 =item B<-csv>
 101
 102 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 103 sent to standard out or to a filename if provided. Otherwise, only
 104 overdues that could not be emailed are sent in CSV format to the admin.
 105
 106 =item B<-html>
 107
 108 Produces html data. if patron does not have a mail address or
 109 -n (no mail) flag is set, an html file is generated in the specified
 110 directory. This can be downloaded or futher processed by library staff.
 111
 112 =item B<-itemscontent>
 113
 114 comma separated list of fields that get substituted into templates in
 115 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 116 defaults to due date,title,barcode,author
 117
 118 Other possible values come from fields in the biblios, items and
 119 issues tables.
 120
 121 =item B<-borcat>
 122
 123 Repetable field, that permit to select only few of patrons categories.
 124
 125 =item B<-borcatout>
 126
 127 Repetable field, permis to exclude some patrons categories.
 128
 129 =item B<-t> | B<--triggered>
 130
 131 This option causes a notice to be generated if and only if
 132 an item is overdue by the number of days defined in a notice trigger.
 133
 134 By default, a notice is sent each time the script runs, which is suitable for
 135 less frequent run cron script, but requires syncing notice triggers with
 136 the  cron schedule to ensure proper behavior.
 137 Add the --triggered option for daily cron, at the risk of no notice
 138 being generated if the cron fails to run on time.
 139
 140 =item B<-list-all>
 141
 142 Default items.content lists only those items that fall in the
 143 range of the currently processing notice.
 144 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 145
 146 =back
 147
 148 =head1 DESCRIPTION
 149
 150 This script is designed to alert patrons and administrators of overdue
 151 items.
 152
 153 =head2 Configuration
 154
 155 This script pays attention to the overdue notice configuration
 156 performed in the "Overdue notice/status triggers" section of the
 157 "Tools" area of the staff interface to Koha. There, you can choose
 158 which letter templates are sent out after a configurable number of
 159 days to patrons of each library. More information about the use of this
 160 section of Koha is available in the Koha manual.
 161
 162 The templates used to craft the emails are defined in the "Tools:
 163 Notices" section of the staff interface to Koha.
 164
 165 =head2 Outgoing emails
 166
 167 Typically, messages are prepared for each patron with overdue
 168 items. Messages for whom there is no email address on file are
 169 collected and sent as attachments in a single email to each library
 170 administrator, or if that is not set, then to the email address in the
 171 C<KohaAdminEmailAddress> system preference.
 172
 173 These emails are staged in the outgoing message queue, as are messages
 174 produced by other features of Koha. This message queue must be
 175 processed regularly by the
 176 F<misc/cronjobs/process_message_queue.pl> program.
 177
 178 In the event that the C<-n> flag is passed to this program, no emails
 179 are sent. Instead, messages are sent on standard output from this
 180 program. They may be redirected to a file if desired.
 181
 182 =head2 Templates
 183
 184 Templates can contain variables enclosed in double angle brackets like
 185 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 186 specific to the overdue items or relevant patron. Available variables
 187 are:
 188
 189 =over
 190
 191 =item E<lt>E<lt>bibE<gt>E<gt>
 192
 193 the name of the library
 194
 195 =item E<lt>E<lt>items.contentE<gt>E<gt>
 196
 197 one line for each item, each line containing a tab separated list of
 198 title, author, barcode, issuedate
 199
 200 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 201
 202 any field from the borrowers table
 203
 204 =item E<lt>E<lt>branches.*E<gt>E<gt>
 205
 206 any field from the branches table
 207
 208 =back
 209
 210 =head2 CSV output
 211
 212 The C<-csv> command line option lets you specify a file to which
 213 overdues data should be output in CSV format.
 214
 215 With the C<-n> flag set, data about all overdues is written to the
 216 file. Without that flag, only information about overdues that were
 217 unable to be sent directly to the patrons will be written. In other
 218 words, this CSV file replaces the data that is typically sent to the
 219 administrator email address.
 220
 221 =head1 USAGE EXAMPLES
 222
 223 C<overdue_notices.pl> - In this most basic usage, with no command line
 224 arguments, all libraries are procesed individually, and notices are
 225 prepared for all patrons with overdue items for whom we have email
 226 addresses. Messages for those patrons for whom we have no email
 227 address are sent in a single attachment to the library administrator's
 228 email address, or to the address in the KohaAdminEmailAddress system
 229 preference.
 230
 231 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 232 populates F</tmp/overdues.csv> with information about all overdue
 233 items.
 234
 235 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 236 overdues in the last 2 weeks for the MAIN library.
 237
 238 =head1 SEE ALSO
 239
 240 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 241 messages to patrons in advance of thier items becoming due, or to
 242 alert them of items that have just become due.
 243
 244 =cut
 245
 246 # These variables are set by command line options.
 247 # They are initially set to default values.
 248 my $dbh = C4::Context->dbh();
 249 my $help    = 0;
 250 my $man     = 0;
 251 my $verbose = 0;
 252 my $nomail  = 0;
 253 my $MAX     = 90;
 254 my @branchcodes; # Branch(es) passed as parameter
 255 my $csvfilename;
 256 my $htmlfilename;
 257 my $triggered = 0;
 258 my $listall = 0;
 259 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 260 my @myborcat;
 261 my @myborcatout;
 262
 263 GetOptions(
 264     'help|?'         => \$help,
 265     'man'            => \$man,
 266     'v'              => \$verbose,
 267     'n'              => \$nomail,
 268     'max=s'          => \$MAX,
 269     'library=s'      => \@branchcodes,
 270     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 271     'html:s'          => \$htmlfilename,    # this optional argument gets '' if not supplied.
 272     'itemscontent=s' => \$itemscontent,
 273     'list-all'      => \$listall,
 274     't|triggered'             => \$triggered,
 275     'borcat=s'      => \@myborcat,
 276     'borcatout=s'   => \@myborcatout,
 277 ) or pod2usage(2);
 278 pod2usage(1) if $help;
 279 pod2usage( -verbose => 2 ) if $man;
 280
 281 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 282     warn qq(using "$csvfilename" as filename, that seems odd);
 283 }
 284
 285 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 286 my @branches;                                                                   # Branches passed as parameter with overdue rules
 287 my $branchcount = scalar(@overduebranches);
 288
 289 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 290 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 291
 292 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 293
 294 if ($branchcount) {
 295     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 296 } else {
 297     die 'No branches with active overduerules';
 298 }
 299
 300 if (@branchcodes) {
 301     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 302
 303     # Getting libraries which have overdue rules
 304     my %seen = map { $_ => 1 } @branchcodes;
 305     @branches = grep { $seen{$_} } @overduebranches;
 306
 307
 308     if (@overduebranches) {
 309
 310         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 311         $verbose and warn "$branch_word @branches have overdue rules\n";
 312
 313     } else {
 314
 315         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 316         ( scalar grep { '' eq $_ } @branches )
 317           or die "No active overduerules for DEFAULT either!";
 318         $verbose and warn "Falling back on default rules for @branchcodes\n";
 319         @branches = ('');
 320     }
 321 }
 322
 323 # these are the fields that will be substituted into <<item.content>>
 324 my @item_content_fields = split( /,/, $itemscontent );
 325
 326 binmode( STDOUT, ":utf8" );
 327
 328
 329 our $csv;       # the Text::CSV_XS object
 330 our $csv_fh;    # the filehandle to the CSV file.
 331 if ( defined $csvfilename ) {
 332     my $sep_char = C4::Context->preference('delimiter') || ',';
 333     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 334     if ( $csvfilename eq '' ) {
 335         $csv_fh = *STDOUT;
 336     } else {
 337         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 338     }
 339     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 340         print $csv_fh $csv->string, "\n";
 341     } else {
 342         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 343     }
 344 }
 345
 346 @branches = @overduebranches unless @branches;
 347 our $html_fh;
 348 if ( defined $htmlfilename ) {
 349   if ( $htmlfilename eq '' ) {
 350     $html_fh = *STDOUT;
 351   } else {
 352     my $today = C4::Dates->new();
 353     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->output('iso').".html");
 354   }
 355
 356   print $html_fh "<html>\n";
 357   print $html_fh "<head>\n";
 358   print $html_fh "<style type='text/css'>\n";
 359   print $html_fh "pre {page-break-after: always;}\n";
 360   print $html_fh "pre {white-space: pre-wrap;}\n";
 361   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 362   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 363   print $html_fh "pre {word-wrap: break-work;}\n";
 364   print $html_fh "</style>\n";
 365   print $html_fh "</head>\n";
 366   print $html_fh "<body>\n";
 367 }
 368
 369 foreach my $branchcode (@branches) {
 370
 371     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 372     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 373     my @output_chunks;    # may be sent to mail or stdout or csv file.
 374
 375     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 376
 377     my $sth2 = $dbh->prepare( <<'END_SQL' );
 378 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS(NOW())-TO_DAYS(date_due) AS days_overdue
 379   FROM issues,items,biblio, biblioitems
 380   WHERE items.itemnumber=issues.itemnumber
 381     AND biblio.biblionumber   = items.biblionumber
 382     AND biblio.biblionumber   = biblioitems.biblionumber
 383     AND issues.borrowernumber = ?
 384     AND TO_DAYS(NOW())-TO_DAYS(date_due) BETWEEN ? and ?
 385 END_SQL
 386
 387     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 388     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 389     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 390
 391     my $rqoverduerules =  $dbh->prepare($query);
 392     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 393
 394     # We get default rules is there is no rule for this branch
 395     if($rqoverduerules->rows == 0){
 396         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 397         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 398         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 399
 400         $rqoverduerules = $dbh->prepare($query);
 401         $rqoverduerules->execute(@myborcat, @myborcatout);
 402     }
 403
 404     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 405     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 406       PERIOD: foreach my $i ( 1 .. 3 ) {
 407
 408             $verbose and warn "branch '$branchcode', pass $i\n";
 409             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 410             my $maxdays = (
 411                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 412                 ? $overdue_rules->{ "delay" . ( $i + 1 ) }
 413                 : ($MAX)
 414             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 415
 416             if ( !$overdue_rules->{"letter$i"} ) {
 417                 $verbose and warn "No letter$i code for branch '$branchcode'";
 418                 next PERIOD;
 419             }
 420
 421             # $letter->{'content'} is the text of the mail that is sent.
 422             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 423             # The following fields are available :
 424             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 425             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode>
 426
 427             my $borrower_sql = <<'END_SQL';
 428 SELECT COUNT(*), issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, MIN(date_due) as longest_issue
 429 FROM   issues,borrowers,categories
 430 WHERE  issues.borrowernumber=borrowers.borrowernumber
 431 AND    borrowers.categorycode=categories.categorycode
 432 END_SQL
 433             my @borrower_parameters;
 434             if ($branchcode) {
 435                 $borrower_sql .= ' AND issues.branchcode=? ';
 436                 push @borrower_parameters, $branchcode;
 437             }
 438             if ( $overdue_rules->{categorycode} ) {
 439                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 440                 push @borrower_parameters, $overdue_rules->{categorycode};
 441             }
 442             $borrower_sql .= '  AND categories.overduenoticerequired=1
 443                                 GROUP BY issues.borrowernumber ';
 444             if($triggered) {
 445                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) = ?';
 446                 push @borrower_parameters, $mindays;
 447             } else {
 448                 $borrower_sql .= ' HAVING TO_DAYS(NOW())-TO_DAYS(longest_issue) BETWEEN ? and ? ' ;
 449                 push @borrower_parameters, $mindays, $maxdays;
 450             }
 451
 452             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 453                 my $sth = $dbh->prepare($borrower_sql);
 454             $sth->execute(@borrower_parameters);
 455             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 456
 457             while ( my ($itemcount, $borrowernumber, $firstname, $lastname,
 458                     $address1, $address2, $city, $postcode, $country, $email,
 459                     $longest_issue ) = $sth->fetchrow )
 460             {
 461                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has $itemcount items triggering level $i.";
 462
 463                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"} );
 464
 465                 unless ($letter) {
 466                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 467
 468                     # might as well skip while PERIOD, no other borrowers are going to work.
 469                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 470                     next PERIOD;
 471                 }
 472
 473                 if ( $overdue_rules->{"debarred$i"} ) {
 474
 475                     #action taken is debarring
 476                     C4::Members::DebarMember($borrowernumber);
 477                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 478                 }
 479                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 480                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 481                 $sth2->execute(@params);
 482                 my $itemcount = 0;
 483                 my $titles = "";
 484                 my @items = ();
 485
 486                 my $i = 0;
 487                 my $exceededPrintNoticesMaxLines = 0;
 488                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 489                     if ( ( !$email || $nomail ) && $PrintNoticesMaxLines && $i >= $PrintNoticesMaxLines ) {
 490                       $exceededPrintNoticesMaxLines = 1;
 491                       last;
 492                     }
 493                     $i++;
 494                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 495                     $titles .= join("\t", @item_info) . "\n";
 496                     $itemcount++;
 497                     push @items, { itemnumber => $item_info->{'itemnumber'}, biblionumber => $item_info->{'biblionumber'} };
 498                 }
 499                 $sth2->finish;
 500                 $letter = parse_letter(
 501                     {   letter          => $letter,
 502                         borrowernumber  => $borrowernumber,
 503                         branchcode      => $branchcode,
 504                         items           => \@items,
 505                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 506                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 507                                             'items.content' => $titles
 508                                            }
 509                     }
 510                 );
 511
 512                 if ( $exceededPrintNoticesMaxLines ) {
 513                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 514                 }
 515
 516                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 517                 if (@misses) {
 518                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 519                 }
 520                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 521                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 522
 523                 if ($nomail) {
 524
 525                     push @output_chunks,
 526                       prepare_letter_for_printing(
 527                         {   letter         => $letter,
 528                             borrowernumber => $borrowernumber,
 529                             firstname      => $firstname,
 530                             lastname       => $lastname,
 531                             address1       => $address1,
 532                             address2       => $address2,
 533                             city           => $city,
 534                             postcode       => $postcode,
 535                             email          => $email,
 536                             itemcount      => $itemcount,
 537                             titles         => $titles,
 538                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 539                         }
 540                       );
 541                 } else {
 542                     if ($email) {
 543                         C4::Letters::EnqueueLetter(
 544                             {   letter                 => $letter,
 545                                 borrowernumber         => $borrowernumber,
 546                                 message_transport_type => 'email',
 547                                 from_address           => $admin_email_address,
 548                             }
 549                         );
 550                     } else {
 551
 552                         # If we don't have an email address for this patron, send it to the admin to deal with.
 553                         push @output_chunks,
 554                           prepare_letter_for_printing(
 555                             {   letter         => $letter,
 556                                 borrowernumber => $borrowernumber,
 557                                 firstname      => $firstname,
 558                                 lastname       => $lastname,
 559                                 address1       => $address1,
 560                                 address2       => $address2,
 561                                 city           => $city,
 562                                 postcode       => $postcode,
 563                                 email          => $email,
 564                                 itemcount      => $itemcount,
 565                                 titles         => $titles,
 566                                 outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 567                             }
 568                           );
 569                     }
 570                 }
 571             }
 572             $sth->finish;
 573         }
 574     }
 575
 576     if (@output_chunks) {
 577         if ( defined $csvfilename ) {
 578             print $csv_fh @output_chunks;
 579         }
 580         elsif ( defined $htmlfilename ) {
 581             print $html_fh @output_chunks;
 582         }
 583         elsif ($nomail){
 584                 local $, = "\f";    # pagebreak
 585                 print @output_chunks;
 586         }
 587         my $attachment = {
 588             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 589             type => 'text/plain',
 590             content => join( "\n", @output_chunks )
 591         };
 592
 593         my $letter = {
 594             title   => 'Overdue Notices',
 595             content => 'These messages were not sent directly to the patrons.',
 596         };
 597         C4::Letters::EnqueueLetter(
 598             {   letter                 => $letter,
 599                 borrowernumber         => undef,
 600                 message_transport_type => 'email',
 601                 attachments            => [$attachment],
 602                 to_address             => $admin_email_address,
 603             }
 604         );
 605     }
 606
 607 }
 608 if ($csvfilename) {
 609     # note that we're not testing on $csv_fh to prevent closing
 610     # STDOUT.
 611     close $csv_fh;
 612 }
 613
 614 if ( defined $htmlfilename ) {
 615   print $html_fh "</body>\n";
 616   print $html_fh "</html>\n";
 617   close $html_fh;
 618 }
 619
 620 =head1 INTERNAL METHODS
 621
 622 These methods are internal to the operation of overdue_notices.pl.
 623
 624 =head2 parse_letter
 625
 626 parses the letter template, replacing the placeholders with data
 627 specific to this patron, biblio, or item
 628
 629 named parameters:
 630   letter - required hashref
 631   borrowernumber - required integer
 632   substitute - optional hashref of other key/value pairs that should
 633     be substituted in the letter content
 634
 635 returns the C<letter> hashref, with the content updated to reflect the
 636 substituted keys and values.
 637
 638
 639 =cut
 640
 641 sub parse_letter { # FIXME: this code should probably be moved to C4::Letters:parseletter
 642     my $params = shift;
 643     foreach my $required (qw( letter borrowernumber )) {
 644         return unless exists $params->{$required};
 645     }
 646
 647
 648     if ( $params->{'substitute'} ) {
 649         while ( my ( $key, $replacedby ) = each %{ $params->{'substitute'} } ) {
 650             my $replacefield = "<<$key>>";
 651             $params->{'letter'}->{title}   =~ s/$replacefield/$replacedby/g;
 652             $params->{'letter'}->{content} =~ s/$replacefield/$replacedby/g;
 653         }
 654     }
 655
 656     $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'borrowers', $params->{'borrowernumber'} );
 657
 658     if ( $params->{'branchcode'} ) {
 659         $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'branches', $params->{'branchcode'} );
 660     }
 661
 662     if ( $params->{'items'} ) {
 663         my $item_format = '';
 664         PROCESS_ITEMS:
 665         while (scalar(@{$params->{'items'}}) > 0) {
 666             my $item = shift @{$params->{'items'}};
 667             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 668             if (!$item_format) {
 669                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 670                 $item_format = $1;
 671             }
 672             if ($params->{'letter'}->{'content'} =~ m/<fine>(.*)<\/fine>/) { # process any fine tags...
 673                 my $formatted_fine = currency_format("$1", "$fine", FMT_SYMBOL);
 674                 $params->{'letter'}->{'content'} =~ s/<fine>.*<\/fine>/$formatted_fine/;
 675             }
 676             $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'biblio',      $item->{'biblionumber'} );
 677             $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'biblioitems', $item->{'biblionumber'} );
 678             $params->{'letter'} = C4::Letters::parseletter( $params->{'letter'}, 'items', $item->{'itemnumber'} );
 679             $params->{'letter'}->{'content'} =~ s/(<item>.*<\/item>)/$1\n$item_format/ if scalar(@{$params->{'items'}} > 0);
 680
 681         }
 682     }
 683     $params->{'letter'}->{'content'} =~ s/<\/{0,1}?item>//g; # strip all remaining item tags...
 684     return $params->{'letter'};
 685 }
 686
 687 =head2 prepare_letter_for_printing
 688
 689 returns a string of text appropriate for printing in the event that an
 690 overdue notice will not be sent to the patron's email
 691 address. Depending on the desired output format, this may be a CSV
 692 string, or a human-readable representation of the notice.
 693
 694 required parameters:
 695   letter
 696   borrowernumber
 697
 698 optional parameters:
 699   outputformat
 700
 701 =cut
 702
 703 sub prepare_letter_for_printing {
 704     my $params = shift;
 705
 706     return unless ref $params eq 'HASH';
 707
 708     foreach my $required_parameter (qw( letter borrowernumber )) {
 709         return unless defined $params->{$required_parameter};
 710     }
 711
 712     my $return;
 713     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 714         if ($csv->combine(
 715                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 716                 $params->{'city'},      $params->{'email'},    $params->{'itemcount'}, $params->{'titles'}
 717             )
 718           ) {
 719             return $csv->string, "\n";
 720         } else {
 721             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 722         }
 723     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 724       $return = "<pre>\n";
 725       $return .= "$params->{'letter'}->{'content'}\n";
 726       $return .= "\n</pre>\n";
 727     } else {
 728         $return .= "$params->{'letter'}->{'content'}\n";
 729
 730         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 731     }
 732     return $return;
 733 }
 734