misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine GetOverdueMessageTransportTypes);
  43 use C4::Budgets qw(GetCurrency);
  44
  45 use Koha::Borrower::Debarments qw(AddUniqueDebarment);
  46 use Koha::DateUtils;
  47 use Koha::Calendar;
  48
  49 =head1 NAME
  50
  51 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  52
  53 =head1 SYNOPSIS
  54
  55 overdue_notices.pl
  56   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  57   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  58   [ -email <email_type> ... ]
  59
  60  Options:
  61    -help                          brief help message
  62    -man                           full documentation
  63    -n                             No email will be sent
  64    -max          <days>           maximum days overdue to deal with
  65    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  66    -csv          <filename>       populate CSV file
  67    -html         <directory>      Output html to a file in the given directory
  68    -text         <directory>      Output plain text to a file in the given directory
  69    -itemscontent <list of fields> item information in templates
  70    -borcat       <categorycode>   category code that must be included
  71    -borcatout    <categorycode>   category code that must be excluded
  72    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  73
  74 =head1 OPTIONS
  75
  76 =over 8
  77
  78 =item B<-help>
  79
  80 Print a brief help message and exits.
  81
  82 =item B<-man>
  83
  84 Prints the manual page and exits.
  85
  86 =item B<-v>
  87
  88 Verbose. Without this flag set, only fatal errors are reported.
  89
  90 =item B<-n>
  91
  92 Do not send any email. Overdue notices that would have been sent to
  93 the patrons or to the admin are printed to standard out. CSV data (if
  94 the -csv flag is set) is written to standard out or to any csv
  95 filename given.
  96
  97 =item B<-max>
  98
  99 Items older than max days are assumed to be handled somewhere else,
 100 probably the F<longoverdues.pl> script. They are therefore ignored by
 101 this program. No notices are sent for them, and they are not added to
 102 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
 103
 104 =item B<-library>
 105
 106 select overdues for one specific library. Use the value in the
 107 branches.branchcode table. This option can be repeated in order
 108 to select overdues for a group of libraries.
 109
 110 =item B<-csv>
 111
 112 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 113 sent to standard out or to a filename if provided. Otherwise, only
 114 overdues that could not be emailed are sent in CSV format to the admin.
 115
 116 =item B<-html>
 117
 118 Produces html data. If patron does not have an email address or
 119 -n (no mail) flag is set, an HTML file is generated in the specified
 120 directory. This can be downloaded or futher processed by library staff.
 121 The file will be called notices-YYYY-MM-DD.html and placed in the directory
 122 specified.
 123
 124 =item B<-text>
 125
 126 Produces plain text data. If patron does not have an email address or
 127 -n (no mail) flag is set, a text file is generated in the specified
 128 directory. This can be downloaded or futher processed by library staff.
 129 The file will be called notices-YYYY-MM-DD.txt and placed in the directory
 130 specified.
 131
 132 =item B<-itemscontent>
 133
 134 comma separated list of fields that get substituted into templates in
 135 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 136 defaults to due date,title,barcode,author
 137
 138 Other possible values come from fields in the biblios, items and
 139 issues tables.
 140
 141 =item B<-borcat>
 142
 143 Repetable field, that permit to select only few of patrons categories.
 144
 145 =item B<-borcatout>
 146
 147 Repetable field, permis to exclude some patrons categories.
 148
 149 =item B<-t> | B<--triggered>
 150
 151 This option causes a notice to be generated if and only if
 152 an item is overdue by the number of days defined in a notice trigger.
 153
 154 By default, a notice is sent each time the script runs, which is suitable for
 155 less frequent run cron script, but requires syncing notice triggers with
 156 the  cron schedule to ensure proper behavior.
 157 Add the --triggered option for daily cron, at the risk of no notice
 158 being generated if the cron fails to run on time.
 159
 160 =item B<-list-all>
 161
 162 Default items.content lists only those items that fall in the
 163 range of the currently processing notice.
 164 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 165
 166 =item B<-date>
 167
 168 use it in order to send overdues on a specific date and not Now.
 169
 170 =item B<-email>
 171
 172 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 173
 174 =back
 175
 176 =head1 DESCRIPTION
 177
 178 This script is designed to alert patrons and administrators of overdue
 179 items.
 180
 181 =head2 Configuration
 182
 183 This script pays attention to the overdue notice configuration
 184 performed in the "Overdue notice/status triggers" section of the
 185 "Tools" area of the staff interface to Koha. There, you can choose
 186 which letter templates are sent out after a configurable number of
 187 days to patrons of each library. More information about the use of this
 188 section of Koha is available in the Koha manual.
 189
 190 The templates used to craft the emails are defined in the "Tools:
 191 Notices" section of the staff interface to Koha.
 192
 193 =head2 Outgoing emails
 194
 195 Typically, messages are prepared for each patron with overdue
 196 items. Messages for whom there is no email address on file are
 197 collected and sent as attachments in a single email to each library
 198 administrator, or if that is not set, then to the email address in the
 199 C<KohaAdminEmailAddress> system preference.
 200
 201 These emails are staged in the outgoing message queue, as are messages
 202 produced by other features of Koha. This message queue must be
 203 processed regularly by the
 204 F<misc/cronjobs/process_message_queue.pl> program.
 205
 206 In the event that the C<-n> flag is passed to this program, no emails
 207 are sent. Instead, messages are sent on standard output from this
 208 program. They may be redirected to a file if desired.
 209
 210 =head2 Templates
 211
 212 Templates can contain variables enclosed in double angle brackets like
 213 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 214 specific to the overdue items or relevant patron. Available variables
 215 are:
 216
 217 =over
 218
 219 =item E<lt>E<lt>bibE<gt>E<gt>
 220
 221 the name of the library
 222
 223 =item E<lt>E<lt>items.contentE<gt>E<gt>
 224
 225 one line for each item, each line containing a tab separated list of
 226 title, author, barcode, issuedate
 227
 228 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 229
 230 any field from the borrowers table
 231
 232 =item E<lt>E<lt>branches.*E<gt>E<gt>
 233
 234 any field from the branches table
 235
 236 =back
 237
 238 =head2 CSV output
 239
 240 The C<-csv> command line option lets you specify a file to which
 241 overdues data should be output in CSV format.
 242
 243 With the C<-n> flag set, data about all overdues is written to the
 244 file. Without that flag, only information about overdues that were
 245 unable to be sent directly to the patrons will be written. In other
 246 words, this CSV file replaces the data that is typically sent to the
 247 administrator email address.
 248
 249 =head1 USAGE EXAMPLES
 250
 251 C<overdue_notices.pl> - In this most basic usage, with no command line
 252 arguments, all libraries are procesed individually, and notices are
 253 prepared for all patrons with overdue items for whom we have email
 254 addresses. Messages for those patrons for whom we have no email
 255 address are sent in a single attachment to the library administrator's
 256 email address, or to the address in the KohaAdminEmailAddress system
 257 preference.
 258
 259 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 260 populates F</tmp/overdues.csv> with information about all overdue
 261 items.
 262
 263 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 264 overdues in the last 2 weeks for the MAIN library.
 265
 266 =head1 SEE ALSO
 267
 268 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 269 messages to patrons in advance of thier items becoming due, or to
 270 alert them of items that have just become due.
 271
 272 =cut
 273
 274 # These variables are set by command line options.
 275 # They are initially set to default values.
 276 my $dbh = C4::Context->dbh();
 277 my $help    = 0;
 278 my $man     = 0;
 279 my $verbose = 0;
 280 my $nomail  = 0;
 281 my $MAX     = 90;
 282 my @branchcodes; # Branch(es) passed as parameter
 283 my @emails_to_use;    # Emails to use for messaging
 284 my @emails;           # Emails given in command-line parameters
 285 my $csvfilename;
 286 my $htmlfilename;
 287 my $text_filename;
 288 my $triggered = 0;
 289 my $listall = 0;
 290 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 291 my @myborcat;
 292 my @myborcatout;
 293 my $date;
 294
 295 GetOptions(
 296     'help|?'         => \$help,
 297     'man'            => \$man,
 298     'v'              => \$verbose,
 299     'n'              => \$nomail,
 300     'max=s'          => \$MAX,
 301     'library=s'      => \@branchcodes,
 302     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 303     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 304     'text:s'         => \$text_filename,    # this optional argument gets '' if not supplied.
 305     'itemscontent=s' => \$itemscontent,
 306     'list-all'       => \$listall,
 307     't|triggered'    => \$triggered,
 308     'date'           => \$date,
 309     'borcat=s'       => \@myborcat,
 310     'borcatout=s'    => \@myborcatout,
 311     'email=s'        => \@emails,
 312 ) or pod2usage(2);
 313 pod2usage(1) if $help;
 314 pod2usage( -verbose => 2 ) if $man;
 315
 316 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 317     warn qq(using "$csvfilename" as filename, that seems odd);
 318 }
 319
 320 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 321 my @branches;                                                                   # Branches passed as parameter with overdue rules
 322 my $branchcount = scalar(@overduebranches);
 323
 324 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 325 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 326
 327 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 328
 329 if ($branchcount) {
 330     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 331 } else {
 332     die 'No branches with active overduerules';
 333 }
 334
 335 if (@branchcodes) {
 336     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 337
 338     # Getting libraries which have overdue rules
 339     my %seen = map { $_ => 1 } @branchcodes;
 340     @branches = grep { $seen{$_} } @overduebranches;
 341
 342
 343     if (@branches) {
 344
 345         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 346         $verbose and warn "$branch_word @branches have overdue rules\n";
 347
 348     } else {
 349
 350         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 351         ( scalar grep { '' eq $_ } @branches )
 352           or die "No active overduerules for DEFAULT either!";
 353         $verbose and warn "Falling back on default rules for @branchcodes\n";
 354         @branches = ('');
 355     }
 356 }
 357 my $date_to_run;
 358 if ($date){
 359     $date=$dbh->quote($date);
 360     $date_to_run = dt_from_string($date);
 361 }
 362 else {
 363     $date="NOW()";
 364     $date_to_run = DateTime->now( time_zone => C4::Context->tz() );
 365 }
 366
 367 # these are the fields that will be substituted into <<item.content>>
 368 my @item_content_fields = split( /,/, $itemscontent );
 369
 370 binmode( STDOUT, ':encoding(UTF-8)' );
 371
 372
 373 our $csv;       # the Text::CSV_XS object
 374 our $csv_fh;    # the filehandle to the CSV file.
 375 if ( defined $csvfilename ) {
 376     my $sep_char = C4::Context->preference('delimiter') || ';';
 377     $sep_char = "\t" if ($sep_char eq 'tabulation');
 378     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 379     if ( $csvfilename eq '' ) {
 380         $csv_fh = *STDOUT;
 381     } else {
 382         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 383     }
 384     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email phone cardnumber itemcount itemsinfo branchname letternumber)) ) {
 385         print $csv_fh $csv->string, "\n";
 386     } else {
 387         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 388     }
 389 }
 390
 391 @branches = @overduebranches unless @branches;
 392 our $fh;
 393 if ( defined $htmlfilename ) {
 394   if ( $htmlfilename eq '' ) {
 395     $fh = *STDOUT;
 396   } else {
 397     my $today = DateTime->now(time_zone => C4::Context->tz );
 398     open $fh, ">:encoding(UTF-8)",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 399   }
 400
 401   print $fh "<html>\n";
 402   print $fh "<head>\n";
 403   print $fh "<meta http-equiv=\"Content-Type\" content=\"text/html; charset=utf-8\" />\n";
 404   print $fh "<style type='text/css'>\n";
 405   print $fh "pre {page-break-after: always;}\n";
 406   print $fh "pre {white-space: pre-wrap;}\n";
 407   print $fh "pre {white-space: -moz-pre-wrap;}\n";
 408   print $fh "pre {white-space: -o-pre-wrap;}\n";
 409   print $fh "pre {word-wrap: break-work;}\n";
 410   print $fh "</style>\n";
 411   print $fh "</head>\n";
 412   print $fh "<body>\n";
 413 }
 414 elsif ( defined $text_filename ) {
 415   if ( $text_filename eq '' ) {
 416     $fh = *STDOUT;
 417   } else {
 418     my $today = DateTime->now(time_zone => C4::Context->tz );
 419     open $fh, ">",File::Spec->catdir ($text_filename,"notices-".$today->ymd().".txt");
 420   }
 421 }
 422
 423 foreach my $branchcode (@branches) {
 424     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 425         my $calendar = Koha::Calendar->new( branchcode => $branchcode );
 426         if ( $calendar->is_holiday($date_to_run) ) {
 427             next;
 428         }
 429     }
 430
 431     my $branch_details      = C4::Branch::GetBranchDetail($branchcode);
 432     my $admin_email_address = $branch_details->{'branchemail'}
 433       || C4::Context->preference('KohaAdminEmailAddress');
 434     my @output_chunks;    # may be sent to mail or stdout or csv file.
 435
 436     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 437
 438     my $sth2 = $dbh->prepare( <<"END_SQL" );
 439 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue, branchname
 440   FROM issues,items,biblio, biblioitems, branches b
 441   WHERE items.itemnumber=issues.itemnumber
 442     AND biblio.biblionumber   = items.biblionumber
 443     AND b.branchcode = items.homebranch
 444     AND biblio.biblionumber   = biblioitems.biblionumber
 445     AND issues.borrowernumber = ?
 446 END_SQL
 447
 448     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 449     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 450     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 451
 452     my $rqoverduerules =  $dbh->prepare($query);
 453     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 454
 455     # We get default rules is there is no rule for this branch
 456     if($rqoverduerules->rows == 0){
 457         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 458         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 459         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 460
 461         $rqoverduerules = $dbh->prepare($query);
 462         $rqoverduerules->execute(@myborcat, @myborcatout);
 463     }
 464
 465     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 466     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 467       PERIOD: foreach my $i ( 1 .. 3 ) {
 468
 469             $verbose and warn "branch '$branchcode', pass $i\n";
 470             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 471             my $maxdays = (
 472                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 473                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 474                 : ($MAX)
 475             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 476
 477             if ( !$overdue_rules->{"letter$i"} ) {
 478                 $verbose and warn "No letter$i code for branch '$branchcode'";
 479                 next PERIOD;
 480             }
 481
 482             # $letter->{'content'} is the text of the mail that is sent.
 483             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 484             # The following fields are available :
 485             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 486             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 487
 488             my $borrower_sql = <<'END_SQL';
 489 SELECT issues.borrowernumber, firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email, smsalertnumber, phone, cardnumber,
 490 TO_DAYS(?)-TO_DAYS(date_due) as difference, date_due
 491 FROM   issues,borrowers,categories
 492 WHERE  issues.borrowernumber=borrowers.borrowernumber
 493 AND    borrowers.categorycode=categories.categorycode
 494 END_SQL
 495             my @borrower_parameters;
 496             push @borrower_parameters, $date_to_run->datetime();
 497             if ($branchcode) {
 498                 $borrower_sql .= ' AND issues.branchcode=? ';
 499                 push @borrower_parameters, $branchcode;
 500             }
 501             if ( $overdue_rules->{categorycode} ) {
 502                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 503                 push @borrower_parameters, $overdue_rules->{categorycode};
 504             }
 505             $borrower_sql .= '  AND categories.overduenoticerequired=1 ORDER BY issues.borrowernumber';
 506
 507             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 508                 my $sth = $dbh->prepare($borrower_sql);
 509             $sth->execute(@borrower_parameters);
 510
 511             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays, ".  $date_to_run->datetime() .")\nreturns " . $sth->rows . " rows";
 512             my $borrowernumber;
 513             while ( my $data = $sth->fetchrow_hashref ) {
 514
 515                 next unless ( DateTime->compare( $date_to_run,  dt_from_string($data->{date_due})) ) == 1;
 516
 517                 # check the borrower has at least one item that matches
 518                 my $days_between;
 519                 if ( C4::Context->preference('OverdueNoticeCalendar') )
 520                 {
 521                     my $calendar =
 522                       Koha::Calendar->new( branchcode => $branchcode );
 523                     $days_between =
 524                       $calendar->days_between(  dt_from_string($data->{date_due}),
 525                         $date_to_run );
 526                 }
 527                 else {
 528                     $days_between =
 529                       $date_to_run->delta_days(  dt_from_string($data->{date_due}) );
 530                 }
 531                 $days_between = $days_between->in_units('days');
 532                 if ($triggered) {
 533                     if ( $mindays != $days_between ) {
 534                         next;
 535                     }
 536                 }
 537                 else {
 538                     unless (   $days_between >= $mindays
 539                         && $days_between <= $maxdays )
 540                     {
 541                         next;
 542                     }
 543                 }
 544                 if ($borrowernumber eq $data->{'borrowernumber'}){
 545 # we have already dealt with this borrower
 546                     $verbose and warn "already dealt with this borrower $borrowernumber";
 547                     next;
 548                 }
 549                 $borrowernumber = $data->{'borrowernumber'};
 550                 my $borr =
 551                     $data->{'firstname'} . ', '
 552                   . $data->{'surname'} . ' ('
 553                   . $borrowernumber . ')';
 554                 $verbose
 555                   and warn "borrower $borr has items triggering level $i.";
 556
 557                 @emails_to_use = ();
 558                 my $notice_email =
 559                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 560                 unless ($nomail) {
 561                     if (@emails) {
 562                         foreach (@emails) {
 563                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 564                         }
 565                     }
 566                     else {
 567                         push @emails_to_use, $notice_email if ($notice_email);
 568                     }
 569                 }
 570
 571                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 572
 573                 unless ($letter) {
 574                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 575
 576                     # might as well skip while PERIOD, no other borrowers are going to work.
 577                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 578                     next PERIOD;
 579                 }
 580
 581                 if ( $overdue_rules->{"debarred$i"} ) {
 582
 583                     #action taken is debarring
 584                     AddUniqueDebarment(
 585                         {
 586                             borrowernumber => $borrowernumber,
 587                             type           => 'OVERDUES',
 588                             comment => "Restriction added by overdues process "
 589                               . output_pref( dt_from_string() ),
 590                         }
 591                     );
 592                     $verbose and warn "debarring $borr\n";
 593                 }
 594 #                my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 595                 my @params = ($borrowernumber);
 596                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber";
 597                 $sth2->execute(@params);
 598                 my $itemcount = 0;
 599                 my $titles = "";
 600                 my @items = ();
 601
 602                 my $j = 0;
 603                 my $exceededPrintNoticesMaxLines = 0;
 604                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 605                     if ( C4::Context->preference('OverdueNoticeCalendar') ) {
 606                         my $calendar =
 607                           Koha::Calendar->new( branchcode => $branchcode );
 608                         $days_between =
 609                           $calendar->days_between(
 610                             dt_from_string( $item_info->{date_due} ), $date_to_run );
 611                     }
 612                     else {
 613                         $days_between =
 614                           $date_to_run->delta_days(
 615                             dt_from_string( $item_info->{date_due} ) );
 616                     }
 617                     $days_between = $days_between->in_units('days');
 618                     if ($listall){
 619                         unless ($days_between >= 1 and $days_between <= $MAX){
 620                             next;
 621                         }
 622                     }
 623                     else {
 624                         unless ($days_between >=$mindays && $days_between <= $maxdays){
 625                             next;
 626                         }
 627                     }
 628
 629                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 630                       $exceededPrintNoticesMaxLines = 1;
 631                       last;
 632                     }
 633                     $j++;
 634                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 635                     $titles .= join("\t", @item_info) . "\n";
 636                     $itemcount++;
 637                     push @items, $item_info;
 638                 }
 639                 $sth2->finish;
 640
 641                 my @message_transport_types = @{ GetOverdueMessageTransportTypes( $branchcode, $overdue_rules->{categorycode}, $i) };
 642                 @message_transport_types = @{ GetOverdueMessageTransportTypes( q{}, $overdue_rules->{categorycode}, $i) }
 643                     unless @message_transport_types;
 644
 645
 646                 my $print_sent = 0; # A print notice is not yet sent for this patron
 647                 for my $mtt ( @message_transport_types ) {
 648
 649                     my $letter = parse_letter(
 650                         {   letter_code     => $overdue_rules->{"letter$i"},
 651                             borrowernumber  => $borrowernumber,
 652                             branchcode      => $branchcode,
 653                             items           => \@items,
 654                             substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 655                                                 bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 656                                                 'items.content' => $titles,
 657                                                 'count'         => $itemcount,
 658                                                },
 659                             message_transport_type => $mtt,
 660                         }
 661                     );
 662                     unless ($letter) {
 663                         $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 664                         # this transport doesn't have a configured notice, so try another
 665                         next;
 666                     }
 667
 668                     if ( $exceededPrintNoticesMaxLines ) {
 669                       $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 670                     }
 671
 672                     my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 673                     if (@misses) {
 674                         $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 675                     }
 676
 677                     if ($nomail) {
 678                         push @output_chunks,
 679                           prepare_letter_for_printing(
 680                           {   letter         => $letter,
 681                               borrowernumber => $borrowernumber,
 682                               firstname      => $data->{'firstname'},
 683                               lastname       => $data->{'surname'},
 684                               address1       => $data->{'address'},
 685                               address2       => $data->{'address2'},
 686                               city           => $data->{'city'},
 687                               phone          => $data->{'phone'},
 688                               cardnumber     => $data->{'cardnumber'},
 689                               branchname     => $branch_details->{'branchname'},
 690                               letternumber   => $i,
 691                               postcode       => $data->{'zipcode'},
 692                               country        => $data->{'country'},
 693                               email          => $notice_email,
 694                               itemcount      => $itemcount,
 695                               titles         => $titles,
 696                               outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 697                             }
 698                           );
 699                     } else {
 700                         if ( ($mtt eq 'email' and not scalar @emails_to_use) or ($mtt eq 'sms' and not $data->{smsalertnumber}) ) {
 701                             # email or sms is requested but not exist, do a print.
 702                             $mtt = 'print';
 703                             push @output_chunks,
 704                               prepare_letter_for_printing(
 705                               {   letter         => $letter,
 706                                   borrowernumber => $borrowernumber,
 707                                   firstname      => $data->{'firstname'},
 708                                   lastname       => $data->{'surname'},
 709                                   address1       => $data->{'address'},
 710                                   address2       => $data->{'address2'},
 711                                   city           => $data->{'city'},
 712                                   postcode       => $data->{'zipcode'},
 713                                   country        => $data->{'country'},
 714                                   email          => $notice_email,
 715                                   itemcount      => $itemcount,
 716                                   titles         => $titles,
 717                                   outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : defined $text_filename ? 'text' : '',
 718                                 }
 719                               );
 720                         }
 721                         unless ( $mtt eq 'print' and $print_sent == 1 ) {
 722                             # Just sent a print if not already done.
 723                             C4::Letters::EnqueueLetter(
 724                                 {   letter                 => $letter,
 725                                     borrowernumber         => $borrowernumber,
 726                                     message_transport_type => $mtt,
 727                                     from_address           => $admin_email_address,
 728                                     to_address             => join(',', @emails_to_use),
 729                                 }
 730                             );
 731                             # A print notice should be sent only once per overdue level.
 732                             # Without this check, a print could be sent twice or more if the library checks sms and email and print and the patron has no email or sms number.
 733                             $print_sent = 1 if $mtt eq 'print';
 734                         }
 735                     }
 736                 }
 737             }
 738             $sth->finish;
 739         }
 740     }
 741
 742     if (@output_chunks) {
 743         if ( defined $csvfilename ) {
 744             print $csv_fh @output_chunks;
 745         }
 746         elsif ( defined $htmlfilename ) {
 747             print $fh @output_chunks;
 748         }
 749         elsif ( defined $text_filename ) {
 750             print $fh @output_chunks;
 751         }
 752         elsif ($nomail){
 753                 local $, = "\f";    # pagebreak
 754                 print @output_chunks;
 755         }
 756         # Generate the content of the csv with headers
 757         my $content;
 758         if ( defined $csvfilename ) {
 759             my $delimiter = C4::Context->preference('delimiter') || ';';
 760             $content = join($delimiter, qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 761         }
 762         else {
 763             $content = "";
 764         }
 765         $content .= join( "\n", @output_chunks );
 766
 767         my $attachment = {
 768             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 769             type => 'text/plain',
 770             content => $content,
 771         };
 772
 773         my $letter = {
 774             title   => 'Overdue Notices',
 775             content => 'These messages were not sent directly to the patrons.',
 776         };
 777         C4::Letters::EnqueueLetter(
 778             {   letter                 => $letter,
 779                 borrowernumber         => undef,
 780                 message_transport_type => 'email',
 781                 attachments            => [$attachment],
 782                 to_address             => $admin_email_address,
 783             }
 784         );
 785     }
 786
 787 }
 788 if ($csvfilename) {
 789     # note that we're not testing on $csv_fh to prevent closing
 790     # STDOUT.
 791     close $csv_fh;
 792 }
 793
 794 if ( defined $htmlfilename ) {
 795   print $fh "</body>\n";
 796   print $fh "</html>\n";
 797   close $fh;
 798 } elsif ( defined $text_filename ) {
 799   close $fh;
 800 }
 801
 802 =head1 INTERNAL METHODS
 803
 804 These methods are internal to the operation of overdue_notices.pl.
 805
 806 =head2 parse_letter
 807
 808 parses the letter template, replacing the placeholders with data
 809 specific to this patron, biblio, or item
 810
 811 named parameters:
 812   letter - required hashref
 813   borrowernumber - required integer
 814   substitute - optional hashref of other key/value pairs that should
 815     be substituted in the letter content
 816
 817 returns the C<letter> hashref, with the content updated to reflect the
 818 substituted keys and values.
 819
 820
 821 =cut
 822
 823 sub parse_letter {
 824     my $params = shift;
 825     foreach my $required (qw( letter_code borrowernumber )) {
 826         return unless ( exists $params->{$required} && $params->{$required} );
 827     }
 828
 829     my $substitute = $params->{'substitute'} || {};
 830     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 831
 832     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 833     if ( my $p = $params->{'branchcode'} ) {
 834         $tables{'branches'} = $p;
 835     }
 836
 837     my $currencies = GetCurrency();
 838     my $currency_format;
 839     $currency_format = $currencies->{currency} if defined($currencies);
 840
 841     my @item_tables;
 842     if ( my $i = $params->{'items'} ) {
 843         my $item_format = '';
 844         foreach my $item (@$i) {
 845             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 846             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 847                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 848                 $item_format = $1;
 849             }
 850
 851             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL);
 852             # if active currency isn't correct ISO code fallback to sprintf
 853             $item->{'fine'} = sprintf('%.2f', $fine) unless $item->{'fine'};
 854
 855             push @item_tables, {
 856                 'biblio' => $item->{'biblionumber'},
 857                 'biblioitems' => $item->{'biblionumber'},
 858                 'items' => $item,
 859                 'issues' => $item->{'itemnumber'},
 860             };
 861         }
 862     }
 863
 864     return C4::Letters::GetPreparedLetter (
 865         module => 'circulation',
 866         letter_code => $params->{'letter_code'},
 867         branchcode => $params->{'branchcode'},
 868         tables => \%tables,
 869         substitute => $substitute,
 870         repeat => { item => \@item_tables },
 871         message_transport_type => $params->{message_transport_type},
 872     );
 873 }
 874
 875 =head2 prepare_letter_for_printing
 876
 877 returns a string of text appropriate for printing in the event that an
 878 overdue notice will not be sent to the patron's email
 879 address. Depending on the desired output format, this may be a CSV
 880 string, or a human-readable representation of the notice.
 881
 882 required parameters:
 883   letter
 884   borrowernumber
 885
 886 optional parameters:
 887   outputformat
 888
 889 =cut
 890
 891 sub prepare_letter_for_printing {
 892     my $params = shift;
 893
 894     return unless ref $params eq 'HASH';
 895
 896     foreach my $required_parameter (qw( letter borrowernumber )) {
 897         return unless defined $params->{$required_parameter};
 898     }
 899
 900     my $return;
 901     chomp $params->{titles};
 902     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 903         if ($csv->combine(
 904                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 905                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'phone'}, $params->{'cardnumber'},
 906                 $params->{'itemcount'}, $params->{'titles'}, $params->{'branchname'}, $params->{'letternumber'}
 907             )
 908           ) {
 909             return $csv->string, "\n";
 910         } else {
 911             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 912         }
 913     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 914       $return = "<pre>\n";
 915       $return .= "$params->{'letter'}->{'content'}\n";
 916       $return .= "\n</pre>\n";
 917     } else {
 918         $return .= "$params->{'letter'}->{'content'}\n";
 919
 920         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 921     }
 922     return $return;
 923 }
 924