misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43
  44 =head1 NAME
  45
  46 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  47
  48 =head1 SYNOPSIS
  49
  50 overdue_notices.pl [ -n ] [ -library <branchcode> ] [ -library <branchcode>...] [ -max <number of days> ] [ -csv [ <filename> ] ] [ -itemscontent <field list> ]
  51
  52  Options:
  53    -help                          brief help message
  54    -man                           full documentation
  55    -n                             No email will be sent
  56    -max          <days>           maximum days overdue to deal with
  57    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  58    -csv          <filename>       populate CSV file
  59    -html         <filename>       Output html to file
  60    -itemscontent <list of fields> item information in templates
  61    -borcat       <categorycode>   category code that must be included
  62    -borcatout    <categorycode>   category code that must be excluded
  63
  64 =head1 OPTIONS
  65
  66 =over 8
  67
  68 =item B<-help>
  69
  70 Print a brief help message and exits.
  71
  72 =item B<-man>
  73
  74 Prints the manual page and exits.
  75
  76 =item B<-v>
  77
  78 Verbose. Without this flag set, only fatal errors are reported.
  79
  80 =item B<-n>
  81
  82 Do not send any email. Overdue notices that would have been sent to
  83 the patrons or to the admin are printed to standard out. CSV data (if
  84 the -csv flag is set) is written to standard out or to any csv
  85 filename given.
  86
  87 =item B<-max>
  88
  89 Items older than max days are assumed to be handled somewhere else,
  90 probably the F<longoverdues.pl> script. They are therefore ignored by
  91 this program. No notices are sent for them, and they are not added to
  92 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  93
  94 =item B<-library>
  95
  96 select overdues for one specific library. Use the value in the
  97 branches.branchcode table. This option can be repeated in order
  98 to select overdues for a group of libraries.
  99
 100 =item B<-csv>
 101
 102 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 103 sent to standard out or to a filename if provided. Otherwise, only
 104 overdues that could not be emailed are sent in CSV format to the admin.
 105
 106 =item B<-html>
 107
 108 Produces html data. if patron does not have a mail address or
 109 -n (no mail) flag is set, an html file is generated in the specified
 110 directory. This can be downloaded or futher processed by library staff.
 111
 112 =item B<-itemscontent>
 113
 114 comma separated list of fields that get substituted into templates in
 115 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 116 defaults to due date,title,barcode,author
 117
 118 Other possible values come from fields in the biblios, items and
 119 issues tables.
 120
 121 =item B<-borcat>
 122
 123 Repetable field, that permit to select only few of patrons categories.
 124
 125 =item B<-borcatout>
 126
 127 Repetable field, permis to exclude some patrons categories.
 128
 129 =item B<-t> | B<--triggered>
 130
 131 This option causes a notice to be generated if and only if
 132 an item is overdue by the number of days defined in a notice trigger.
 133
 134 By default, a notice is sent each time the script runs, which is suitable for
 135 less frequent run cron script, but requires syncing notice triggers with
 136 the  cron schedule to ensure proper behavior.
 137 Add the --triggered option for daily cron, at the risk of no notice
 138 being generated if the cron fails to run on time.
 139
 140 =item B<-list-all>
 141
 142 Default items.content lists only those items that fall in the
 143 range of the currently processing notice.
 144 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 145
 146 =item B<-date>
 147
 148 use it in order to send overdues on a specific date and not Now.
 149
 150 =back
 151
 152 =head1 DESCRIPTION
 153
 154 This script is designed to alert patrons and administrators of overdue
 155 items.
 156
 157 =head2 Configuration
 158
 159 This script pays attention to the overdue notice configuration
 160 performed in the "Overdue notice/status triggers" section of the
 161 "Tools" area of the staff interface to Koha. There, you can choose
 162 which letter templates are sent out after a configurable number of
 163 days to patrons of each library. More information about the use of this
 164 section of Koha is available in the Koha manual.
 165
 166 The templates used to craft the emails are defined in the "Tools:
 167 Notices" section of the staff interface to Koha.
 168
 169 =head2 Outgoing emails
 170
 171 Typically, messages are prepared for each patron with overdue
 172 items. Messages for whom there is no email address on file are
 173 collected and sent as attachments in a single email to each library
 174 administrator, or if that is not set, then to the email address in the
 175 C<KohaAdminEmailAddress> system preference.
 176
 177 These emails are staged in the outgoing message queue, as are messages
 178 produced by other features of Koha. This message queue must be
 179 processed regularly by the
 180 F<misc/cronjobs/process_message_queue.pl> program.
 181
 182 In the event that the C<-n> flag is passed to this program, no emails
 183 are sent. Instead, messages are sent on standard output from this
 184 program. They may be redirected to a file if desired.
 185
 186 =head2 Templates
 187
 188 Templates can contain variables enclosed in double angle brackets like
 189 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 190 specific to the overdue items or relevant patron. Available variables
 191 are:
 192
 193 =over
 194
 195 =item E<lt>E<lt>bibE<gt>E<gt>
 196
 197 the name of the library
 198
 199 =item E<lt>E<lt>items.contentE<gt>E<gt>
 200
 201 one line for each item, each line containing a tab separated list of
 202 title, author, barcode, issuedate
 203
 204 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 205
 206 any field from the borrowers table
 207
 208 =item E<lt>E<lt>branches.*E<gt>E<gt>
 209
 210 any field from the branches table
 211
 212 =back
 213
 214 =head2 CSV output
 215
 216 The C<-csv> command line option lets you specify a file to which
 217 overdues data should be output in CSV format.
 218
 219 With the C<-n> flag set, data about all overdues is written to the
 220 file. Without that flag, only information about overdues that were
 221 unable to be sent directly to the patrons will be written. In other
 222 words, this CSV file replaces the data that is typically sent to the
 223 administrator email address.
 224
 225 =head1 USAGE EXAMPLES
 226
 227 C<overdue_notices.pl> - In this most basic usage, with no command line
 228 arguments, all libraries are procesed individually, and notices are
 229 prepared for all patrons with overdue items for whom we have email
 230 addresses. Messages for those patrons for whom we have no email
 231 address are sent in a single attachment to the library administrator's
 232 email address, or to the address in the KohaAdminEmailAddress system
 233 preference.
 234
 235 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 236 populates F</tmp/overdues.csv> with information about all overdue
 237 items.
 238
 239 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 240 overdues in the last 2 weeks for the MAIN library.
 241
 242 =head1 SEE ALSO
 243
 244 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 245 messages to patrons in advance of thier items becoming due, or to
 246 alert them of items that have just become due.
 247
 248 =cut
 249
 250 # These variables are set by command line options.
 251 # They are initially set to default values.
 252 my $dbh = C4::Context->dbh();
 253 my $help    = 0;
 254 my $man     = 0;
 255 my $verbose = 0;
 256 my $nomail  = 0;
 257 my $MAX     = 90;
 258 my @branchcodes; # Branch(es) passed as parameter
 259 my $csvfilename;
 260 my $htmlfilename;
 261 my $triggered = 0;
 262 my $listall = 0;
 263 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 264 my @myborcat;
 265 my @myborcatout;
 266 my $date;
 267
 268 GetOptions(
 269     'help|?'         => \$help,
 270     'man'            => \$man,
 271     'v'              => \$verbose,
 272     'n'              => \$nomail,
 273     'max=s'          => \$MAX,
 274     'library=s'      => \@branchcodes,
 275     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 276     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 277     'itemscontent=s' => \$itemscontent,
 278     'list-all'       => \$listall,
 279     't|triggered'    => \$triggered,
 280     'date'           => \$date,
 281     'borcat=s'       => \@myborcat,
 282     'borcatout=s'    => \@myborcatout,
 283 ) or pod2usage(2);
 284 pod2usage(1) if $help;
 285 pod2usage( -verbose => 2 ) if $man;
 286
 287 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 288     warn qq(using "$csvfilename" as filename, that seems odd);
 289 }
 290
 291 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 292 my @branches;                                                                   # Branches passed as parameter with overdue rules
 293 my $branchcount = scalar(@overduebranches);
 294
 295 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 296 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 297
 298 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 299
 300 if ($branchcount) {
 301     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 302 } else {
 303     die 'No branches with active overduerules';
 304 }
 305
 306 if (@branchcodes) {
 307     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 308
 309     # Getting libraries which have overdue rules
 310     my %seen = map { $_ => 1 } @branchcodes;
 311     @branches = grep { $seen{$_} } @overduebranches;
 312
 313
 314     if (@branches) {
 315
 316         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 317         $verbose and warn "$branch_word @branches have overdue rules\n";
 318
 319     } else {
 320
 321         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 322         ( scalar grep { '' eq $_ } @branches )
 323           or die "No active overduerules for DEFAULT either!";
 324         $verbose and warn "Falling back on default rules for @branchcodes\n";
 325         @branches = ('');
 326     }
 327 }
 328
 329 if ($date){
 330     $date=$dbh->quote($date);
 331 }
 332 else {
 333     $date="NOW()";
 334 }
 335
 336 # these are the fields that will be substituted into <<item.content>>
 337 my @item_content_fields = split( /,/, $itemscontent );
 338
 339 binmode( STDOUT, ':encoding(UTF-8)' );
 340
 341
 342 our $csv;       # the Text::CSV_XS object
 343 our $csv_fh;    # the filehandle to the CSV file.
 344 if ( defined $csvfilename ) {
 345     my $sep_char = C4::Context->preference('delimiter') || ',';
 346     $sep_char = "\t" if ($sep_char eq 'tabulation');
 347     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 348     if ( $csvfilename eq '' ) {
 349         $csv_fh = *STDOUT;
 350     } else {
 351         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 352     }
 353     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 354         print $csv_fh $csv->string, "\n";
 355     } else {
 356         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 357     }
 358 }
 359
 360 @branches = @overduebranches unless @branches;
 361 our $html_fh;
 362 if ( defined $htmlfilename ) {
 363   if ( $htmlfilename eq '' ) {
 364     $html_fh = *STDOUT;
 365   } else {
 366     my $today = DateTime->now(time_zone => C4::Context->tz );
 367     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 368   }
 369
 370   print $html_fh "<html>\n";
 371   print $html_fh "<head>\n";
 372   print $html_fh "<style type='text/css'>\n";
 373   print $html_fh "pre {page-break-after: always;}\n";
 374   print $html_fh "pre {white-space: pre-wrap;}\n";
 375   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 376   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 377   print $html_fh "pre {word-wrap: break-work;}\n";
 378   print $html_fh "</style>\n";
 379   print $html_fh "</head>\n";
 380   print $html_fh "<body>\n";
 381 }
 382
 383 foreach my $branchcode (@branches) {
 384
 385     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 386     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 387     my @output_chunks;    # may be sent to mail or stdout or csv file.
 388
 389     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 390
 391     my $sth2 = $dbh->prepare( <<"END_SQL" );
 392 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 393   FROM issues,items,biblio, biblioitems
 394   WHERE items.itemnumber=issues.itemnumber
 395     AND biblio.biblionumber   = items.biblionumber
 396     AND biblio.biblionumber   = biblioitems.biblionumber
 397     AND issues.borrowernumber = ?
 398     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 399 END_SQL
 400
 401     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 402     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 403     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 404
 405     my $rqoverduerules =  $dbh->prepare($query);
 406     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 407
 408     # We get default rules is there is no rule for this branch
 409     if($rqoverduerules->rows == 0){
 410         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 411         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 412         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 413
 414         $rqoverduerules = $dbh->prepare($query);
 415         $rqoverduerules->execute(@myborcat, @myborcatout);
 416     }
 417
 418     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 419     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 420       PERIOD: foreach my $i ( 1 .. 3 ) {
 421
 422             $verbose and warn "branch '$branchcode', pass $i\n";
 423             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 424             my $maxdays = (
 425                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 426                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 427                 : ($MAX)
 428             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 429
 430             if ( !$overdue_rules->{"letter$i"} ) {
 431                 $verbose and warn "No letter$i code for branch '$branchcode'";
 432                 next PERIOD;
 433             }
 434
 435             # $letter->{'content'} is the text of the mail that is sent.
 436             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 437             # The following fields are available :
 438             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 439             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 440
 441             my $borrower_sql = <<'END_SQL';
 442 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email
 443 FROM   issues,borrowers,categories
 444 WHERE  issues.borrowernumber=borrowers.borrowernumber
 445 AND    borrowers.categorycode=categories.categorycode
 446 END_SQL
 447             my @borrower_parameters;
 448             if ($branchcode) {
 449                 $borrower_sql .= ' AND issues.branchcode=? ';
 450                 push @borrower_parameters, $branchcode;
 451             }
 452             if ( $overdue_rules->{categorycode} ) {
 453                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 454                 push @borrower_parameters, $overdue_rules->{categorycode};
 455             }
 456             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 457             if($triggered) {
 458                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 459                 push @borrower_parameters, $mindays;
 460             } else {
 461                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 462                 push @borrower_parameters, $mindays, $maxdays;
 463             }
 464
 465             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 466                 my $sth = $dbh->prepare($borrower_sql);
 467             $sth->execute(@borrower_parameters);
 468             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 469
 470             while ( my ( $borrowernumber, $firstname, $lastname,
 471                     $address1, $address2, $city, $postcode, $country, $email
 472                     ) = $sth->fetchrow )
 473             {
 474                 $verbose and warn "borrower $firstname, $lastname ($borrowernumber) has items triggering level $i.";
 475
 476                 if ( $overdue_rules->{"debarred$i"} ) {
 477
 478                     #action taken is debarring
 479                     C4::Members::DebarMember($borrowernumber, '9999-12-31');
 480                     $verbose and warn "debarring $borrowernumber $firstname $lastname\n";
 481                 }
 482                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 483                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 484                 $sth2->execute(@params);
 485                 my $itemcount = 0;
 486                 my $titles = "";
 487                 my @items = ();
 488
 489                 my $j = 0;
 490                 my $exceededPrintNoticesMaxLines = 0;
 491                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 492                     if ( ( !$email || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 493                       $exceededPrintNoticesMaxLines = 1;
 494                       last;
 495                     }
 496                     $j++;
 497                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 498                     $titles .= join("\t", @item_info) . "\n";
 499                     $itemcount++;
 500                     push @items, $item_info;
 501                 }
 502                 $sth2->finish;
 503
 504                 my $letter = parse_letter(
 505                     {   letter_code     => $overdue_rules->{"letter$i"},
 506                         borrowernumber  => $borrowernumber,
 507                         branchcode      => $branchcode,
 508                         items           => \@items,
 509                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 510                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 511                                             'items.content' => $titles,
 512                                             'count'         => $itemcount,
 513                                            }
 514                     }
 515                 );
 516                 unless ($letter) {
 517                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 518
 519                     # might as well skip while PERIOD, no other borrowers are going to work.
 520                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 521                     next PERIOD;
 522                 }
 523
 524                 if ( $exceededPrintNoticesMaxLines ) {
 525                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 526                 }
 527
 528                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 529                 if (@misses) {
 530                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 531                 }
 532                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 533                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 534
 535                 if ($nomail) {
 536
 537                     push @output_chunks,
 538                       prepare_letter_for_printing(
 539                         {   letter         => $letter,
 540                             borrowernumber => $borrowernumber,
 541                             firstname      => $firstname,
 542                             lastname       => $lastname,
 543                             address1       => $address1,
 544                             address2       => $address2,
 545                             city           => $city,
 546                             postcode       => $postcode,
 547                             country        => $country,
 548                             email          => $email,
 549                             itemcount      => $itemcount,
 550                             titles         => $titles,
 551                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 552                         }
 553                       );
 554                 } else {
 555                     if ($email) {
 556                         C4::Letters::EnqueueLetter(
 557                             {   letter                 => $letter,
 558                                 borrowernumber         => $borrowernumber,
 559                                 message_transport_type => 'email',
 560                                 from_address           => $admin_email_address,
 561                             }
 562                         );
 563                     } else {
 564
 565                         # If we don't have an email address for this patron, send it to the admin to deal with.
 566                         push @output_chunks,
 567                           prepare_letter_for_printing(
 568                             {   letter         => $letter,
 569                                 borrowernumber => $borrowernumber,
 570                                 firstname      => $firstname,
 571                                 lastname       => $lastname,
 572                                 address1       => $address1,
 573                                 address2       => $address2,
 574                                 city           => $city,
 575                                 postcode       => $postcode,
 576                                 country        => $country,
 577                                 email          => $email,
 578                                 itemcount      => $itemcount,
 579                                 titles         => $titles,
 580                                 outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 581                             }
 582                           );
 583                     }
 584                 }
 585             }
 586             $sth->finish;
 587         }
 588     }
 589
 590     if (@output_chunks) {
 591         if ( defined $csvfilename ) {
 592             print $csv_fh @output_chunks;
 593         }
 594         elsif ( defined $htmlfilename ) {
 595             print $html_fh @output_chunks;
 596         }
 597         elsif ($nomail){
 598                 local $, = "\f";    # pagebreak
 599                 print @output_chunks;
 600         }
 601         # Generate the content of the csv with headers
 602         my $content = join(";", qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 603         $content .= join( "\n", @output_chunks );
 604
 605         my $attachment = {
 606             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 607             type => 'text/plain',
 608             content => $content,
 609         };
 610
 611         my $letter = {
 612             title   => 'Overdue Notices',
 613             content => 'These messages were not sent directly to the patrons.',
 614         };
 615         C4::Letters::EnqueueLetter(
 616             {   letter                 => $letter,
 617                 borrowernumber         => undef,
 618                 message_transport_type => 'email',
 619                 attachments            => [$attachment],
 620                 to_address             => $admin_email_address,
 621             }
 622         );
 623     }
 624
 625 }
 626 if ($csvfilename) {
 627     # note that we're not testing on $csv_fh to prevent closing
 628     # STDOUT.
 629     close $csv_fh;
 630 }
 631
 632 if ( defined $htmlfilename ) {
 633   print $html_fh "</body>\n";
 634   print $html_fh "</html>\n";
 635   close $html_fh;
 636 }
 637
 638 =head1 INTERNAL METHODS
 639
 640 These methods are internal to the operation of overdue_notices.pl.
 641
 642 =head2 parse_letter
 643
 644 parses the letter template, replacing the placeholders with data
 645 specific to this patron, biblio, or item
 646
 647 named parameters:
 648   letter - required hashref
 649   borrowernumber - required integer
 650   substitute - optional hashref of other key/value pairs that should
 651     be substituted in the letter content
 652
 653 returns the C<letter> hashref, with the content updated to reflect the
 654 substituted keys and values.
 655
 656
 657 =cut
 658
 659 sub parse_letter {
 660     my $params = shift;
 661     foreach my $required (qw( letter_code borrowernumber )) {
 662         return unless ( exists $params->{$required} && $params->{$required} );
 663     }
 664
 665     my $substitute = $params->{'substitute'} || {};
 666     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 667
 668     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 669     if ( my $p = $params->{'branchcode'} ) {
 670         $tables{'branches'} = $p;
 671     }
 672
 673     my $currency_format;
 674     if ( defined $params->{'letter'}->{'content'}
 675         and $params->{'letter'}->{'content'} =~ m/<fine>(.*)<\/fine>/o )
 676     {    # process any fine tags...
 677         $currency_format = $1;
 678         $params->{'letter'}->{'content'} =~ s/<fine>.*<\/fine>/<<item.fine>>/o;
 679     }
 680
 681     my @item_tables;
 682     if ( my $i = $params->{'items'} ) {
 683         my $item_format = '';
 684         foreach my $item (@$i) {
 685             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 686             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 687                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 688                 $item_format = $1;
 689             }
 690
 691             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL)
 692               if $currency_format;
 693
 694             push @item_tables, {
 695                 'biblio' => $item->{'biblionumber'},
 696                 'biblioitems' => $item->{'biblionumber'},
 697                 'items' => $item,
 698                 'issues' => $item->{'itemnumber'},
 699             };
 700         }
 701     }
 702
 703     return C4::Letters::GetPreparedLetter (
 704         module => 'circulation',
 705         letter_code => $params->{'letter_code'},
 706         branchcode => $params->{'branchcode'},
 707         tables => \%tables,
 708         substitute => $substitute,
 709         repeat => { item => \@item_tables },
 710     );
 711 }
 712
 713 =head2 prepare_letter_for_printing
 714
 715 returns a string of text appropriate for printing in the event that an
 716 overdue notice will not be sent to the patron's email
 717 address. Depending on the desired output format, this may be a CSV
 718 string, or a human-readable representation of the notice.
 719
 720 required parameters:
 721   letter
 722   borrowernumber
 723
 724 optional parameters:
 725   outputformat
 726
 727 =cut
 728
 729 sub prepare_letter_for_printing {
 730     my $params = shift;
 731
 732     return unless ref $params eq 'HASH';
 733
 734     foreach my $required_parameter (qw( letter borrowernumber )) {
 735         return unless defined $params->{$required_parameter};
 736     }
 737
 738     my $return;
 739     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 740         if ($csv->combine(
 741                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 742                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'itemcount'}, $params->{'titles'}
 743             )
 744           ) {
 745             return $csv->string, "\n";
 746         } else {
 747             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 748         }
 749     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 750       $return = "<pre>\n";
 751       $return .= "$params->{'letter'}->{'content'}\n";
 752       $return .= "\n</pre>\n";
 753     } else {
 754         $return .= "$params->{'letter'}->{'content'}\n";
 755
 756         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 757     }
 758     return $return;
 759 }
 760