misc/cronjobs/overdue_notices.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Liblime
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23
  24 BEGIN {
  25
  26     # find Koha's Perl modules
  27     # test carefully before changing this
  28     use FindBin;
  29     eval { require "$FindBin::Bin/../kohalib.pl" };
  30 }
  31
  32 use Getopt::Long;
  33 use Pod::Usage;
  34 use Text::CSV_XS;
  35 use Locale::Currency::Format 1.28;
  36 use Encode;
  37
  38 use C4::Context;
  39 use C4::Dates qw/format_date/;
  40 use C4::Debug;
  41 use C4::Letters;
  42 use C4::Overdues qw(GetFine);
  43 use C4::Budgets qw(GetCurrency);
  44
  45 =head1 NAME
  46
  47 overdue_notices.pl - prepare messages to be sent to patrons for overdue items
  48
  49 =head1 SYNOPSIS
  50
  51 overdue_notices.pl
  52   [ -n ][ -library <branchcode> ][ -library <branchcode> ... ]
  53   [ -max <number of days> ][ -csv [<filename>] ][ -itemscontent <field list> ]
  54   [ -email <email_type> ... ]
  55
  56  Options:
  57    -help                          brief help message
  58    -man                           full documentation
  59    -n                             No email will be sent
  60    -max          <days>           maximum days overdue to deal with
  61    -library      <branchname>     only deal with overdues from this library (repeatable : several libraries can be given)
  62    -csv          <filename>       populate CSV file
  63    -html         <filename>       Output html to file
  64    -itemscontent <list of fields> item information in templates
  65    -borcat       <categorycode>   category code that must be included
  66    -borcatout    <categorycode>   category code that must be excluded
  67    -email        <email_type>     type of email that will be used. Can be 'email', 'emailpro' or 'B_email'. Repeatable.
  68
  69 =head1 OPTIONS
  70
  71 =over 8
  72
  73 =item B<-help>
  74
  75 Print a brief help message and exits.
  76
  77 =item B<-man>
  78
  79 Prints the manual page and exits.
  80
  81 =item B<-v>
  82
  83 Verbose. Without this flag set, only fatal errors are reported.
  84
  85 =item B<-n>
  86
  87 Do not send any email. Overdue notices that would have been sent to
  88 the patrons or to the admin are printed to standard out. CSV data (if
  89 the -csv flag is set) is written to standard out or to any csv
  90 filename given.
  91
  92 =item B<-max>
  93
  94 Items older than max days are assumed to be handled somewhere else,
  95 probably the F<longoverdues.pl> script. They are therefore ignored by
  96 this program. No notices are sent for them, and they are not added to
  97 any CSV files. Defaults to 90 to match F<longoverdues.pl>.
  98
  99 =item B<-library>
 100
 101 select overdues for one specific library. Use the value in the
 102 branches.branchcode table. This option can be repeated in order
 103 to select overdues for a group of libraries.
 104
 105 =item B<-csv>
 106
 107 Produces CSV data. if -n (no mail) flag is set, then this CSV data is
 108 sent to standard out or to a filename if provided. Otherwise, only
 109 overdues that could not be emailed are sent in CSV format to the admin.
 110
 111 =item B<-html>
 112
 113 Produces html data. if patron does not have a mail address or
 114 -n (no mail) flag is set, an html file is generated in the specified
 115 directory. This can be downloaded or futher processed by library staff.
 116
 117 =item B<-itemscontent>
 118
 119 comma separated list of fields that get substituted into templates in
 120 places of the E<lt>E<lt>items.contentE<gt>E<gt> placeholder. This
 121 defaults to due date,title,barcode,author
 122
 123 Other possible values come from fields in the biblios, items and
 124 issues tables.
 125
 126 =item B<-borcat>
 127
 128 Repetable field, that permit to select only few of patrons categories.
 129
 130 =item B<-borcatout>
 131
 132 Repetable field, permis to exclude some patrons categories.
 133
 134 =item B<-t> | B<--triggered>
 135
 136 This option causes a notice to be generated if and only if
 137 an item is overdue by the number of days defined in a notice trigger.
 138
 139 By default, a notice is sent each time the script runs, which is suitable for
 140 less frequent run cron script, but requires syncing notice triggers with
 141 the  cron schedule to ensure proper behavior.
 142 Add the --triggered option for daily cron, at the risk of no notice
 143 being generated if the cron fails to run on time.
 144
 145 =item B<-list-all>
 146
 147 Default items.content lists only those items that fall in the
 148 range of the currently processing notice.
 149 Choose list-all to include all overdue items in the list (limited by B<-max> setting).
 150
 151 =item B<-date>
 152
 153 use it in order to send overdues on a specific date and not Now.
 154
 155 =item B<-email>
 156
 157 Allows to specify which type of email will be used. Can be email, emailpro or B_email. Repeatable.
 158
 159 =back
 160
 161 =head1 DESCRIPTION
 162
 163 This script is designed to alert patrons and administrators of overdue
 164 items.
 165
 166 =head2 Configuration
 167
 168 This script pays attention to the overdue notice configuration
 169 performed in the "Overdue notice/status triggers" section of the
 170 "Tools" area of the staff interface to Koha. There, you can choose
 171 which letter templates are sent out after a configurable number of
 172 days to patrons of each library. More information about the use of this
 173 section of Koha is available in the Koha manual.
 174
 175 The templates used to craft the emails are defined in the "Tools:
 176 Notices" section of the staff interface to Koha.
 177
 178 =head2 Outgoing emails
 179
 180 Typically, messages are prepared for each patron with overdue
 181 items. Messages for whom there is no email address on file are
 182 collected and sent as attachments in a single email to each library
 183 administrator, or if that is not set, then to the email address in the
 184 C<KohaAdminEmailAddress> system preference.
 185
 186 These emails are staged in the outgoing message queue, as are messages
 187 produced by other features of Koha. This message queue must be
 188 processed regularly by the
 189 F<misc/cronjobs/process_message_queue.pl> program.
 190
 191 In the event that the C<-n> flag is passed to this program, no emails
 192 are sent. Instead, messages are sent on standard output from this
 193 program. They may be redirected to a file if desired.
 194
 195 =head2 Templates
 196
 197 Templates can contain variables enclosed in double angle brackets like
 198 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 199 specific to the overdue items or relevant patron. Available variables
 200 are:
 201
 202 =over
 203
 204 =item E<lt>E<lt>bibE<gt>E<gt>
 205
 206 the name of the library
 207
 208 =item E<lt>E<lt>items.contentE<gt>E<gt>
 209
 210 one line for each item, each line containing a tab separated list of
 211 title, author, barcode, issuedate
 212
 213 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 214
 215 any field from the borrowers table
 216
 217 =item E<lt>E<lt>branches.*E<gt>E<gt>
 218
 219 any field from the branches table
 220
 221 =back
 222
 223 =head2 CSV output
 224
 225 The C<-csv> command line option lets you specify a file to which
 226 overdues data should be output in CSV format.
 227
 228 With the C<-n> flag set, data about all overdues is written to the
 229 file. Without that flag, only information about overdues that were
 230 unable to be sent directly to the patrons will be written. In other
 231 words, this CSV file replaces the data that is typically sent to the
 232 administrator email address.
 233
 234 =head1 USAGE EXAMPLES
 235
 236 C<overdue_notices.pl> - In this most basic usage, with no command line
 237 arguments, all libraries are procesed individually, and notices are
 238 prepared for all patrons with overdue items for whom we have email
 239 addresses. Messages for those patrons for whom we have no email
 240 address are sent in a single attachment to the library administrator's
 241 email address, or to the address in the KohaAdminEmailAddress system
 242 preference.
 243
 244 C<overdue_notices.pl -n -csv /tmp/overdues.csv> - sends no email and
 245 populates F</tmp/overdues.csv> with information about all overdue
 246 items.
 247
 248 C<overdue_notices.pl -library MAIN max 14> - prepare notices of
 249 overdues in the last 2 weeks for the MAIN library.
 250
 251 =head1 SEE ALSO
 252
 253 The F<misc/cronjobs/advance_notices.pl> program allows you to send
 254 messages to patrons in advance of thier items becoming due, or to
 255 alert them of items that have just become due.
 256
 257 =cut
 258
 259 # These variables are set by command line options.
 260 # They are initially set to default values.
 261 my $dbh = C4::Context->dbh();
 262 my $help    = 0;
 263 my $man     = 0;
 264 my $verbose = 0;
 265 my $nomail  = 0;
 266 my $MAX     = 90;
 267 my @branchcodes; # Branch(es) passed as parameter
 268 my @emails_to_use;    # Emails to use for messaging
 269 my @emails;           # Emails given in command-line parameters
 270 my $csvfilename;
 271 my $htmlfilename;
 272 my $triggered = 0;
 273 my $listall = 0;
 274 my $itemscontent = join( ',', qw( date_due title barcode author itemnumber ) );
 275 my @myborcat;
 276 my @myborcatout;
 277 my $date;
 278
 279 GetOptions(
 280     'help|?'         => \$help,
 281     'man'            => \$man,
 282     'v'              => \$verbose,
 283     'n'              => \$nomail,
 284     'max=s'          => \$MAX,
 285     'library=s'      => \@branchcodes,
 286     'csv:s'          => \$csvfilename,    # this optional argument gets '' if not supplied.
 287     'html:s'         => \$htmlfilename,    # this optional argument gets '' if not supplied.
 288     'itemscontent=s' => \$itemscontent,
 289     'list-all'       => \$listall,
 290     't|triggered'    => \$triggered,
 291     'date'           => \$date,
 292     'borcat=s'       => \@myborcat,
 293     'borcatout=s'    => \@myborcatout,
 294     'email=s'        => \@emails,
 295 ) or pod2usage(2);
 296 pod2usage(1) if $help;
 297 pod2usage( -verbose => 2 ) if $man;
 298
 299 if ( defined $csvfilename && $csvfilename =~ /^-/ ) {
 300     warn qq(using "$csvfilename" as filename, that seems odd);
 301 }
 302
 303 my @overduebranches    = C4::Overdues::GetBranchcodesWithOverdueRules();        # Branches with overdue rules
 304 my @branches;                                                                   # Branches passed as parameter with overdue rules
 305 my $branchcount = scalar(@overduebranches);
 306
 307 my $overduebranch_word = scalar @overduebranches > 1 ? 'branches' : 'branch';
 308 my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 309
 310 my $PrintNoticesMaxLines = C4::Context->preference('PrintNoticesMaxLines');
 311
 312 if ($branchcount) {
 313     $verbose and warn "Found $branchcount $overduebranch_word with first message enabled: " . join( ', ', map { "'$_'" } @overduebranches ), "\n";
 314 } else {
 315     die 'No branches with active overduerules';
 316 }
 317
 318 if (@branchcodes) {
 319     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 320
 321     # Getting libraries which have overdue rules
 322     my %seen = map { $_ => 1 } @branchcodes;
 323     @branches = grep { $seen{$_} } @overduebranches;
 324
 325
 326     if (@branches) {
 327
 328         my $branch_word = scalar @branches > 1 ? 'branches' : 'branch';
 329         $verbose and warn "$branch_word @branches have overdue rules\n";
 330
 331     } else {
 332
 333         $verbose and warn "No active overduerules for $branchcodes_word  '@branchcodes'\n";
 334         ( scalar grep { '' eq $_ } @branches )
 335           or die "No active overduerules for DEFAULT either!";
 336         $verbose and warn "Falling back on default rules for @branchcodes\n";
 337         @branches = ('');
 338     }
 339 }
 340
 341 if ($date){
 342     $date=$dbh->quote($date);
 343 }
 344 else {
 345     $date="NOW()";
 346 }
 347
 348 # these are the fields that will be substituted into <<item.content>>
 349 my @item_content_fields = split( /,/, $itemscontent );
 350
 351 binmode( STDOUT, ':encoding(UTF-8)' );
 352
 353
 354 our $csv;       # the Text::CSV_XS object
 355 our $csv_fh;    # the filehandle to the CSV file.
 356 if ( defined $csvfilename ) {
 357     my $sep_char = C4::Context->preference('delimiter') || ',';
 358     $sep_char = "\t" if ($sep_char eq 'tabulation');
 359     $csv = Text::CSV_XS->new( { binary => 1 , sep_char => $sep_char } );
 360     if ( $csvfilename eq '' ) {
 361         $csv_fh = *STDOUT;
 362     } else {
 363         open $csv_fh, ">", $csvfilename or die "unable to open $csvfilename: $!";
 364     }
 365     if ( $csv->combine(qw(name surname address1 address2 zipcode city country email itemcount itemsinfo)) ) {
 366         print $csv_fh $csv->string, "\n";
 367     } else {
 368         $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 369     }
 370 }
 371
 372 @branches = @overduebranches unless @branches;
 373 our $html_fh;
 374 if ( defined $htmlfilename ) {
 375   if ( $htmlfilename eq '' ) {
 376     $html_fh = *STDOUT;
 377   } else {
 378     my $today = DateTime->now(time_zone => C4::Context->tz );
 379     open $html_fh, ">",File::Spec->catdir ($htmlfilename,"notices-".$today->ymd().".html");
 380   }
 381
 382   print $html_fh "<html>\n";
 383   print $html_fh "<head>\n";
 384   print $html_fh "<style type='text/css'>\n";
 385   print $html_fh "pre {page-break-after: always;}\n";
 386   print $html_fh "pre {white-space: pre-wrap;}\n";
 387   print $html_fh "pre {white-space: -moz-pre-wrap;}\n";
 388   print $html_fh "pre {white-space: -o-pre-wrap;}\n";
 389   print $html_fh "pre {word-wrap: break-work;}\n";
 390   print $html_fh "</style>\n";
 391   print $html_fh "</head>\n";
 392   print $html_fh "<body>\n";
 393 }
 394
 395 foreach my $branchcode (@branches) {
 396
 397     my $branch_details = C4::Branch::GetBranchDetail($branchcode);
 398     my $admin_email_address = $branch_details->{'branchemail'} || C4::Context->preference('KohaAdminEmailAddress');
 399     my @output_chunks;    # may be sent to mail or stdout or csv file.
 400
 401     $verbose and warn sprintf "branchcode : '%s' using %s\n", $branchcode, $admin_email_address;
 402
 403     my $sth2 = $dbh->prepare( <<"END_SQL" );
 404 SELECT biblio.*, items.*, issues.*, biblioitems.itemtype, TO_DAYS($date)-TO_DAYS(date_due) AS days_overdue
 405   FROM issues,items,biblio, biblioitems
 406   WHERE items.itemnumber=issues.itemnumber
 407     AND biblio.biblionumber   = items.biblionumber
 408     AND biblio.biblionumber   = biblioitems.biblionumber
 409     AND issues.borrowernumber = ?
 410     AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ?
 411 END_SQL
 412
 413     my $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = ? ";
 414     $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 415     $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 416
 417     my $rqoverduerules =  $dbh->prepare($query);
 418     $rqoverduerules->execute($branchcode, @myborcat, @myborcatout);
 419
 420     # We get default rules is there is no rule for this branch
 421     if($rqoverduerules->rows == 0){
 422         $query = "SELECT * FROM overduerules WHERE delay1 IS NOT NULL AND branchcode = '' ";
 423         $query .= " AND categorycode IN (".join( ',' , ('?') x @myborcat ).") " if (@myborcat);
 424         $query .= " AND categorycode NOT IN (".join( ',' , ('?') x @myborcatout ).") " if (@myborcatout);
 425
 426         $rqoverduerules = $dbh->prepare($query);
 427         $rqoverduerules->execute(@myborcat, @myborcatout);
 428     }
 429
 430     # my $outfile = 'overdues_' . ( $mybranch || $branchcode || 'default' );
 431     while ( my $overdue_rules = $rqoverduerules->fetchrow_hashref ) {
 432       PERIOD: foreach my $i ( 1 .. 3 ) {
 433
 434             $verbose and warn "branch '$branchcode', pass $i\n";
 435             my $mindays = $overdue_rules->{"delay$i"};    # the notice will be sent after mindays days (grace period)
 436             my $maxdays = (
 437                   $overdue_rules->{ "delay" . ( $i + 1 ) }
 438                 ? $overdue_rules->{ "delay" . ( $i + 1 ) } - 1
 439                 : ($MAX)
 440             );                                            # issues being more than maxdays late are managed somewhere else. (borrower probably suspended)
 441
 442             if ( !$overdue_rules->{"letter$i"} ) {
 443                 $verbose and warn "No letter$i code for branch '$branchcode'";
 444                 next PERIOD;
 445             }
 446
 447             # $letter->{'content'} is the text of the mail that is sent.
 448             # this text contains fields that are replaced by their value. Those fields must be written between brackets
 449             # The following fields are available :
 450             # itemcount is interpreted here as the number of items in the overdue range defined by the current notice or all overdues < max if(-list-all).
 451             # <date> <itemcount> <firstname> <lastname> <address1> <address2> <address3> <city> <postcode> <country>
 452
 453             my $borrower_sql = <<'END_SQL';
 454 SELECT distinct(issues.borrowernumber), firstname, surname, address, address2, city, zipcode, country, email, emailpro, B_email
 455 FROM   issues,borrowers,categories
 456 WHERE  issues.borrowernumber=borrowers.borrowernumber
 457 AND    borrowers.categorycode=categories.categorycode
 458 END_SQL
 459             my @borrower_parameters;
 460             if ($branchcode) {
 461                 $borrower_sql .= ' AND issues.branchcode=? ';
 462                 push @borrower_parameters, $branchcode;
 463             }
 464             if ( $overdue_rules->{categorycode} ) {
 465                 $borrower_sql .= ' AND borrowers.categorycode=? ';
 466                 push @borrower_parameters, $overdue_rules->{categorycode};
 467             }
 468             $borrower_sql .= '  AND categories.overduenoticerequired=1 ';
 469             if($triggered) {
 470                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) = ?";
 471                 push @borrower_parameters, $mindays;
 472             } else {
 473                 $borrower_sql .= " AND TO_DAYS($date)-TO_DAYS(date_due) BETWEEN ? and ? " ;
 474                 push @borrower_parameters, $mindays, $maxdays;
 475             }
 476
 477             # $sth gets borrower info iff at least one overdue item has triggered the overdue action.
 478                 my $sth = $dbh->prepare($borrower_sql);
 479             $sth->execute(@borrower_parameters);
 480             $verbose and warn $borrower_sql . "\n $branchcode | " . $overdue_rules->{'categorycode'} . "\n ($mindays, $maxdays)\nreturns " . $sth->rows . " rows";
 481
 482             while ( my $data = $sth->fetchrow_hashref ) {
 483                 my $borrowernumber = $data->{'borrowernumber'};
 484                 my $borr =
 485                     $data->{'firstname'} . ', '
 486                   . $data->{'surname'} . ' ('
 487                   . $borrowernumber . ')';
 488                 $verbose
 489                   and warn "borrower $borr has items triggering level $i.";
 490
 491                 @emails_to_use = ();
 492                 my $notice_email =
 493                     C4::Members::GetNoticeEmailAddress($borrowernumber);
 494                 unless ($nomail) {
 495                     if (@emails) {
 496                         foreach (@emails) {
 497                             push @emails_to_use, $data->{$_} if ( $data->{$_} );
 498                         }
 499                     }
 500                     else {
 501                         push @emails_to_use, $notice_email if ($notice_email);
 502                     }
 503                 }
 504
 505                 my $letter = C4::Letters::getletter( 'circulation', $overdue_rules->{"letter$i"}, $branchcode );
 506
 507                 unless ($letter) {
 508                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 509
 510                     # might as well skip while PERIOD, no other borrowers are going to work.
 511                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 512                     next PERIOD;
 513                 }
 514
 515                 if ( $overdue_rules->{"debarred$i"} ) {
 516
 517                     #action taken is debarring
 518                     C4::Members::DebarMember($borrowernumber, '9999-12-31');
 519                     $verbose and warn "debarring $borr\n";
 520                 }
 521                 my @params = ($listall ? ( $borrowernumber , 1 , $MAX ) : ( $borrowernumber, $mindays, $maxdays ));
 522                 $verbose and warn "STH2 PARAMS: borrowernumber = $borrowernumber, mindays = $mindays, maxdays = $maxdays";
 523                 $sth2->execute(@params);
 524                 my $itemcount = 0;
 525                 my $titles = "";
 526                 my @items = ();
 527
 528                 my $j = 0;
 529                 my $exceededPrintNoticesMaxLines = 0;
 530                 while ( my $item_info = $sth2->fetchrow_hashref() ) {
 531                     if ( ( scalar(@emails_to_use) == 0 || $nomail ) && $PrintNoticesMaxLines && $j >= $PrintNoticesMaxLines ) {
 532                       $exceededPrintNoticesMaxLines = 1;
 533                       last;
 534                     }
 535                     $j++;
 536                     my @item_info = map { $_ =~ /^date|date$/ ? format_date( $item_info->{$_} ) : $item_info->{$_} || '' } @item_content_fields;
 537                     $titles .= join("\t", @item_info) . "\n";
 538                     $itemcount++;
 539                     push @items, $item_info;
 540                 }
 541                 $sth2->finish;
 542
 543                 $letter = parse_letter(
 544                     {   letter_code     => $overdue_rules->{"letter$i"},
 545                         borrowernumber  => $borrowernumber,
 546                         branchcode      => $branchcode,
 547                         items           => \@items,
 548                         substitute      => {    # this appears to be a hack to overcome incomplete features in this code.
 549                                             bib             => $branch_details->{'branchname'}, # maybe 'bib' is a typo for 'lib<rary>'?
 550                                             'items.content' => $titles,
 551                                             'count'         => $itemcount,
 552                                            }
 553                     }
 554                 );
 555                 unless ($letter) {
 556                     $verbose and warn "Message '$overdue_rules->{letter$i}' content not found";
 557
 558                     # might as well skip while PERIOD, no other borrowers are going to work.
 559                     # FIXME : Does this mean a letter must be defined in order to trigger a debar ?
 560                     next PERIOD;
 561                 }
 562
 563                 if ( $exceededPrintNoticesMaxLines ) {
 564                   $letter->{'content'} .= "List too long for form; please check your account online for a complete list of your overdue items.";
 565                 }
 566
 567                 my @misses = grep { /./ } map { /^([^>]*)[>]+/; ( $1 || '' ); } split /\</, $letter->{'content'};
 568                 if (@misses) {
 569                     $verbose and warn "The following terms were not matched and replaced: \n\t" . join "\n\t", @misses;
 570                 }
 571                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # Now that we've warned about them, remove them.
 572                 $letter->{'content'} =~ s/\<[^<>]*?\>//g;    # 2nd pass for the double nesting.
 573
 574                 if ( !$nomail && scalar @emails_to_use ) {
 575                     C4::Letters::EnqueueLetter(
 576                         {   letter                 => $letter,
 577                             borrowernumber         => $borrowernumber,
 578                             message_transport_type => 'email',
 579                             from_address           => $admin_email_address,
 580                             to_address             => join(',', @emails_to_use),
 581                         }
 582                     );
 583                 } else {
 584                     # if not sent by email then print
 585                     push @output_chunks,
 586                       prepare_letter_for_printing(
 587                         {   letter         => $letter,
 588                             borrowernumber => $borrowernumber,
 589                             firstname      => $data->{'firstname'},
 590                             lastname       => $data->{'surname'},
 591                             address1       => $data->{'address'},
 592                             address2       => $data->{'address2'},
 593                             city           => $data->{'city'},
 594                             postcode       => $data->{'zipcode'},
 595                             country        => $data->{'country'},
 596                             email          => $notice_email,
 597                             itemcount      => $itemcount,
 598                             titles         => $titles,
 599                             outputformat   => defined $csvfilename ? 'csv' : defined $htmlfilename ? 'html' : '',
 600                         }
 601                       );
 602                 }
 603             }
 604             $sth->finish;
 605         }
 606     }
 607
 608     if (@output_chunks) {
 609         if ( defined $csvfilename ) {
 610             print $csv_fh @output_chunks;
 611         }
 612         elsif ( defined $htmlfilename ) {
 613             print $html_fh @output_chunks;
 614         }
 615         elsif ($nomail){
 616                 local $, = "\f";    # pagebreak
 617                 print @output_chunks;
 618         }
 619         # Generate the content of the csv with headers
 620         my $content = join(";", qw(title name surname address1 address2 zipcode city country email itemcount itemsinfo due_date issue_date)) . "\n";
 621         $content .= join( "\n", @output_chunks );
 622
 623         my $attachment = {
 624             filename => defined $csvfilename ? 'attachment.csv' : 'attachment.txt',
 625             type => 'text/plain',
 626             content => $content,
 627         };
 628
 629         my $letter = {
 630             title   => 'Overdue Notices',
 631             content => 'These messages were not sent directly to the patrons.',
 632         };
 633         C4::Letters::EnqueueLetter(
 634             {   letter                 => $letter,
 635                 borrowernumber         => undef,
 636                 message_transport_type => 'email',
 637                 attachments            => [$attachment],
 638                 to_address             => $admin_email_address,
 639             }
 640         );
 641     }
 642
 643 }
 644 if ($csvfilename) {
 645     # note that we're not testing on $csv_fh to prevent closing
 646     # STDOUT.
 647     close $csv_fh;
 648 }
 649
 650 if ( defined $htmlfilename ) {
 651   print $html_fh "</body>\n";
 652   print $html_fh "</html>\n";
 653   close $html_fh;
 654 }
 655
 656 =head1 INTERNAL METHODS
 657
 658 These methods are internal to the operation of overdue_notices.pl.
 659
 660 =head2 parse_letter
 661
 662 parses the letter template, replacing the placeholders with data
 663 specific to this patron, biblio, or item
 664
 665 named parameters:
 666   letter - required hashref
 667   borrowernumber - required integer
 668   substitute - optional hashref of other key/value pairs that should
 669     be substituted in the letter content
 670
 671 returns the C<letter> hashref, with the content updated to reflect the
 672 substituted keys and values.
 673
 674
 675 =cut
 676
 677 sub parse_letter {
 678     my $params = shift;
 679     foreach my $required (qw( letter_code borrowernumber )) {
 680         return unless ( exists $params->{$required} && $params->{$required} );
 681     }
 682
 683     my $substitute = $params->{'substitute'} || {};
 684     $substitute->{today} ||= C4::Dates->new()->output("syspref");
 685
 686     my %tables = ( 'borrowers' => $params->{'borrowernumber'} );
 687     if ( my $p = $params->{'branchcode'} ) {
 688         $tables{'branches'} = $p;
 689     }
 690
 691     my $currency_format = GetCurrency()->{currency};
 692
 693     my @item_tables;
 694     if ( my $i = $params->{'items'} ) {
 695         my $item_format = '';
 696         foreach my $item (@$i) {
 697             my $fine = GetFine($item->{'itemnumber'}, $params->{'borrowernumber'});
 698             if ( !$item_format and defined $params->{'letter'}->{'content'} ) {
 699                 $params->{'letter'}->{'content'} =~ m/(<item>.*<\/item>)/;
 700                 $item_format = $1;
 701             }
 702
 703             $item->{'fine'} = currency_format($currency_format, "$fine", FMT_SYMBOL);
 704             # if active currency isn't correct ISO code fallback to sprintf
 705             $item->{'fine'} = sprintf('%.2f', $fine) unless $item->{'fine'};
 706
 707             push @item_tables, {
 708                 'biblio' => $item->{'biblionumber'},
 709                 'biblioitems' => $item->{'biblionumber'},
 710                 'items' => $item,
 711                 'issues' => $item->{'itemnumber'},
 712             };
 713         }
 714     }
 715
 716     return C4::Letters::GetPreparedLetter (
 717         module => 'circulation',
 718         letter_code => $params->{'letter_code'},
 719         branchcode => $params->{'branchcode'},
 720         tables => \%tables,
 721         substitute => $substitute,
 722         repeat => { item => \@item_tables },
 723     );
 724 }
 725
 726 =head2 prepare_letter_for_printing
 727
 728 returns a string of text appropriate for printing in the event that an
 729 overdue notice will not be sent to the patron's email
 730 address. Depending on the desired output format, this may be a CSV
 731 string, or a human-readable representation of the notice.
 732
 733 required parameters:
 734   letter
 735   borrowernumber
 736
 737 optional parameters:
 738   outputformat
 739
 740 =cut
 741
 742 sub prepare_letter_for_printing {
 743     my $params = shift;
 744
 745     return unless ref $params eq 'HASH';
 746
 747     foreach my $required_parameter (qw( letter borrowernumber )) {
 748         return unless defined $params->{$required_parameter};
 749     }
 750
 751     my $return;
 752     if ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'csv' ) {
 753         if ($csv->combine(
 754                 $params->{'firstname'}, $params->{'lastname'}, $params->{'address1'},  $params->{'address2'}, $params->{'postcode'},
 755                 $params->{'city'}, $params->{'country'}, $params->{'email'}, $params->{'itemcount'}, $params->{'titles'}
 756             )
 757           ) {
 758             return $csv->string, "\n";
 759         } else {
 760             $verbose and warn 'combine failed on argument: ' . $csv->error_input;
 761         }
 762     } elsif ( exists $params->{'outputformat'} && $params->{'outputformat'} eq 'html' ) {
 763       $return = "<pre>\n";
 764       $return .= "$params->{'letter'}->{'content'}\n";
 765       $return .= "\n</pre>\n";
 766     } else {
 767         $return .= "$params->{'letter'}->{'content'}\n";
 768
 769         # $return .= Data::Dumper->Dump( [ $params->{'borrowernumber'}, $params->{'letter'} ], [qw( borrowernumber letter )] );
 770     }
 771     return $return;
 772 }
 773