misc/export_records.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use MARC::File::XML;
  21 use List::MoreUtils qw(uniq);
  22 use Getopt::Long;
  23 use Pod::Usage;
  24
  25 use C4::Auth;
  26 use C4::Context;
  27 use C4::Csv;
  28 use C4::Record;
  29
  30 use Koha::Biblioitems;
  31 use Koha::Database;
  32 use Koha::Exporter::Record;
  33 use Koha::DateUtils qw( dt_from_string output_pref );
  34
  35 my ( $output_format, $timestamp, $dont_export_items, $csv_profile_id, $deleted_barcodes, $clean, $filename, $record_type, $id_list_file, $starting_authid, $ending_authid, $authtype, $starting_biblionumber, $ending_biblionumber, $itemtype, $starting_callnumber, $ending_callnumber, $start_accession, $end_accession, $help );
  36 GetOptions(
  37     'format=s'                => \$output_format,
  38     'date=s'                  => \$timestamp,
  39     'dont_export_items'       => \$dont_export_items,
  40     'csv_profile_id=s'        => \$csv_profile_id,
  41     'deleted_barcodes'        => \$deleted_barcodes,
  42     'clean'                   => \$clean,
  43     'filename=s'              => \$filename,
  44     'record-type=s'           => \$record_type,
  45     'id_list_file=s'          => \$id_list_file,
  46     'starting_authid=s'       => \$starting_authid,
  47     'ending_authid=s'         => \$ending_authid,
  48     'authtype=s'              => \$authtype,
  49     'starting_biblionumber=s' => \$starting_biblionumber,
  50     'ending_biblionumber=s'   => \$ending_biblionumber,
  51     'itemtype=s'              => \$itemtype,
  52     'starting_callnumber=s'   => \$starting_callnumber,
  53     'ending_callnumber=s'     => \$ending_callnumber,
  54     'start_accession=s'       => \$start_accession,
  55     'end_accession=s'         => \$end_accession,
  56     'h|help|?'                => \$help
  57 ) || pod2usage(1);
  58
  59 if ($help) {
  60     pod2usage(1);
  61 }
  62
  63 $filename ||= 'koha.mrc';
  64 $output_format ||= 'iso2709';
  65 $record_type ||= 'bibs';
  66
  67 # Retrocompatibility for the format parameter
  68 $output_format = 'iso2709' if $output_format eq 'marc';
  69
  70 if ( $output_format eq 'csv' and $record_type eq 'auths' ) {
  71     pod2usage(q|CSV output is only available for biblio records|);
  72 }
  73
  74
  75 if ( $timestamp and $record_type ne 'bibs' ) {
  76     pod2usage(q|--timestamp can only be used with biblios|);
  77 }
  78
  79 if ( $record_type ne 'bibs' and $record_type ne 'auths' ) {
  80     pod2usage(q|--record_type is not valid|);
  81 }
  82
  83 if ( $deleted_barcodes and $record_type ne 'bibs' ) {
  84     pod2usage(q|--deleted_barcodes can only be used with biblios|);
  85 }
  86
  87 $start_accession = dt_from_string( $start_accession ) if $start_accession;
  88 $end_accession   = dt_from_string( $end_accession )   if $end_accession;
  89
  90 my $dbh = C4::Context->dbh;
  91
  92 # Redirect stdout
  93 open STDOUT, '>', $filename if $filename;
  94
  95
  96 my @record_ids;
  97
  98 $timestamp = ($timestamp) ? output_pref({ dt => dt_from_string($timestamp), dateformat => 'iso', dateonly => 1, }): '';
  99
 100 if ( $record_type eq 'bibs' ) {
 101     if ( $timestamp ) {
 102         push @record_ids, $_->{biblionumber} for @{
 103             $dbh->selectall_arrayref(q| (
 104                 SELECT biblionumber
 105                 FROM biblioitems
 106                   LEFT JOIN items USING(biblionumber)
 107                 WHERE biblioitems.timestamp >= ?
 108                   OR items.timestamp >= ?
 109             ) UNION (
 110                 SELECT biblionumber
 111                 FROM biblioitems
 112                   LEFT JOIN deleteditems USING(biblionumber)
 113                 WHERE biblioitems.timestamp >= ?
 114                   OR deleteditems.timestamp >= ?
 115             ) |, { Slice => {} }, ( $timestamp ) x 4 );
 116         };
 117     } else {
 118         my $conditions = {
 119             ( $starting_biblionumber or $ending_biblionumber )
 120                 ? (
 121                     "me.biblionumber" => {
 122                         ( $starting_biblionumber ? ( '>=' => $starting_biblionumber ) : () ),
 123                         ( $ending_biblionumber   ? ( '<=' => $ending_biblionumber   ) : () ),
 124                     }
 125                 )
 126                 : (),
 127             ( $starting_callnumber or $ending_callnumber )
 128                 ? (
 129                     callnumber => {
 130                         ( $starting_callnumber ? ( '>=' => $starting_callnumber ) : () ),
 131                         ( $ending_callnumber   ? ( '<=' => $ending_callnumber   ) : () ),
 132                     }
 133                 )
 134                 : (),
 135             ( $start_accession or $end_accession )
 136                 ? (
 137                     dateaccessioned => {
 138                         ( $start_accession ? ( '>=' => $start_accession ) : () ),
 139                         ( $end_accession   ? ( '<=' => $end_accession   ) : () ),
 140                     }
 141                 )
 142                 : (),
 143             ( $itemtype
 144                 ?
 145                   C4::Context->preference('item-level_itypes')
 146                     ? ( 'items.itype' => $itemtype )
 147                     : ( 'biblioitems.itemtype' => $itemtype )
 148                 : ()
 149             ),
 150
 151         };
 152         my $biblioitems = Koha::Biblioitems->search( $conditions, { join => 'items' } );
 153         while ( my $biblioitem = $biblioitems->next ) {
 154             push @record_ids, $biblioitem->biblionumber;
 155         }
 156     }
 157 }
 158 elsif ( $record_type eq 'auths' ) {
 159     my $conditions = {
 160         ( $starting_authid or $ending_authid )
 161             ? (
 162                 authid => {
 163                     ( $starting_authid ? ( '>=' => $starting_authid ) : () ),
 164                     ( $ending_authid   ? ( '<=' => $ending_authid   ) : () ),
 165                 }
 166             )
 167             : (),
 168         ( $authtype ? ( authtypecode => $authtype ) : () ),
 169     };
 170     # Koha::MetadataRecord::Authority is not a Koha::Object...
 171     my $authorities = Koha::Database->new->schema->resultset('AuthHeader')->search( $conditions );
 172     @record_ids = map { $_->authid } $authorities->all;
 173 }
 174
 175 @record_ids = uniq @record_ids;
 176 if ( @record_ids and $id_list_file ) {
 177     open my $fh, '<', $id_list_file or die "Cannot open file $id_list_file ($!)";
 178     my @filter_record_ids = <$fh>;
 179     @filter_record_ids = map { my $id = $_; $id =~ s/[\r\n]*$//; $id } @filter_record_ids;
 180     # intersection
 181     my %record_ids = map { $_ => 1 } @record_ids;
 182     @record_ids = grep $record_ids{$_}, @filter_record_ids;
 183 }
 184
 185 if ($deleted_barcodes) {
 186     for my $record_id ( @record_ids ) {
 187         my $q = q|
 188         |;
 189         my $barcode = $dbh->selectall_arrayref(q| (
 190             SELECT DISTINCT barcode
 191             FROM deleteditems
 192             WHERE deleteditems.biblionumber = ?
 193         |, { Slice => {} }, $record_id );
 194         say $_->{barcode} for @$barcode
 195     }
 196 }
 197 else {
 198     Koha::Exporter::Record::export(
 199         {   record_type        => $record_type,
 200             record_ids         => \@record_ids,
 201             format             => $output_format,
 202             csv_profile_id     => ( $csv_profile_id || GetCsvProfileId( C4::Context->preference('ExportWithCsvProfile') ) || undef ),
 203             export_items       => (not $dont_export_items),
 204             clean              => $clean || 0,
 205         }
 206     );
 207 }
 208 exit;
 209
 210
 211 =head1 NAME
 212
 213 export records - This script exports record (biblios or authorities)
 214
 215 =head1 SYNOPSIS
 216
 217 export_records.pl [-h|--help] [--format=format] [--date=date] [--record-type=TYPE] [--dont_export_items] [--deleted_barcodes] [--clean] [--id_list_file=PATH] --filename=outputfile
 218
 219 =head1 OPTIONS
 220
 221 =over
 222
 223 =item B<-h|--help>
 224
 225 Print a brief help message.
 226
 227 =item B<--format>
 228
 229  --format=FORMAT        FORMAT is either 'xml', 'csv' (biblio records only) or 'marc' (default).
 230
 231 =item B<--date>
 232
 233  --date=DATE            DATE should be entered as the 'dateformat' syspref is
 234                         set (dd/mm/yyyy for metric, yyyy-mm-dd for iso,
 235                         mm/dd/yyyy for us) records exported are the ones that
 236                         have been modified since DATE.
 237
 238 =item B<--record-type>
 239
 240  --record-type=TYPE     TYPE is 'bibs' or 'auths'.
 241
 242 =item B<--dont_export_items>
 243
 244  --dont_export_items    If enabled, the item infos won't be exported.
 245
 246 =item B<--csv_profile_id>
 247
 248  --csv_profile_id=ID    Generate a CSV file with the given CSV profile id (see tools/csv-profiles.pl)
 249                         Unless provided, the one defined in the system preference 'ExportWithCsvProfile' will be used.
 250                         This can only be used to export biblio records.
 251
 252 =item B<--deleted_barcodes>
 253
 254  --deleted_barcodes     If used, a list of barcodes of items deleted since DATE
 255                         is produced (or from all deleted items if no date is
 256                         specified). Used only if TYPE is 'bibs'.
 257
 258 =item B<--clean>
 259
 260  --clean                removes NSE/NSB.
 261
 262 =item B<--id_list_file>
 263
 264  --id_list_file=PATH    PATH is a path to a file containing a list of
 265                         IDs (biblionumber or authid) with one ID per line.
 266                         This list works as a filter; it is compatible with
 267                         other parameters for selecting records.
 268
 269 =item B<--filename>
 270
 271  --filename=FILENAME   FILENAME used to export the data.
 272
 273 =item B<--starting_authid>
 274
 275  --starting_authid=ID  Export authorities with authid >= ID
 276
 277 =item B<--ending_authid>
 278
 279  --ending_authid=ID    Export authorities with authid <= ID
 280
 281 =item B<--authtype>
 282
 283  --authtype=AUTHTYPE   Export authorities from the given AUTHTYPE
 284
 285 =item B<--starting_biblionumber>
 286
 287  --starting_biblionumber=ID  Export biblio with biblionumber >= ID
 288
 289 =item B<--ending_biblionumber>
 290
 291  --ending_biblionumber=ID    Export biblio with biblionumber <= ID
 292
 293 =item B<--itemtype>
 294
 295  --itemtype=ITEMTYPE         Export biblio from the given ITEMTYPE
 296
 297 =item B<--starting_callnumber>
 298
 299  --starting_callnumber=CALLNUMBER Export biblio with callnumber >=CALLNUMBER
 300
 301 =item B<--ending_callnumber>
 302
 303  --ending_callnumber=CALLNUMBER Export biblio with callnumber <=CALLNUMBER
 304
 305 =item B<--start_accession>
 306
 307  --starting_accession=DATE      Export biblio with an item accessionned after DATE
 308
 309 =item B<--end_accession>
 310
 311  --end_accession=DATE           Export biblio with an item accessionned after DATE
 312
 313 =back
 314
 315 =head1 AUTHOR
 316
 317 Koha Development Team
 318
 319 =head1 COPYRIGHT
 320
 321 Copyright Koha Team
 322
 323 =head1 LICENSE
 324
 325 This file is part of Koha.
 326
 327 Koha is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software
 328 Foundation; either version 3 of the License, or (at your option) any later version.
 329
 330 You should have received a copy of the GNU General Public License along
 331 with Koha; if not, write to the Free Software Foundation, Inc.,
 332 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
 333
 334 =cut