opac/opac-authoritiesdetail.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 =head1 NAME
  21
  22 opac-authoritiesdetail.pl : script to show an authority in MARC format
  23
  24 =head1 SYNOPSIS
  25
  26 =cut
  27
  28 =head1 DESCRIPTION
  29
  30 This script needs an authid
  31
  32 It shows the authority in a (nice) MARC format depending on authority MARC
  33 parameters tables.
  34
  35 =head1 FUNCTIONS
  36
  37 =cut
  38
  39 use strict;
  40 use warnings;
  41
  42 use C4::AuthoritiesMarc;
  43 use C4::Auth;
  44 use C4::Context;
  45 use C4::Output;
  46 use CGI;
  47 use MARC::Record;
  48 use C4::Koha;
  49
  50
  51 my $query = new CGI;
  52
  53 my $dbh = C4::Context->dbh;
  54
  55 my $display_hierarchy = C4::Context->preference("AuthDisplayHierarchy");
  56 my $show_marc = $query->param('marc');
  57
  58 # open template
  59 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  60     {
  61         template_name   => $show_marc ? "opac-auth-MARCdetail.tt" : "opac-auth-detail.tt",
  62         query           => $query,
  63         type            => "opac",
  64         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  65         debug           => 1,
  66     }
  67 );
  68
  69 my $authid = $query->param('authid');
  70 $authid = int($authid);
  71 my $record = GetAuthority( $authid );
  72 if ( ! $record ) {
  73     print $query->redirect("/cgi-bin/koha/errors/404.pl"); # escape early
  74     exit;
  75 }
  76
  77 my $authtypecode = &GetAuthTypeCode( $authid );
  78
  79 if ($display_hierarchy){
  80     $template->{VARS}->{'displayhierarchy'} = $display_hierarchy;
  81     $template->{VARS}->{'loophierarchies'} = GenerateHierarchy($authid);
  82 }
  83
  84 my $count = CountUsage($authid);
  85
  86
  87 my $authtypes     = getauthtypes();
  88 my @authtypesloop = ();
  89 foreach my $thisauthtype ( keys %{$authtypes} ) {
  90     push @authtypesloop,
  91          { value        => $thisauthtype,
  92            selected     => $thisauthtype eq $authtypecode,
  93            authtypetext => $authtypes->{$thisauthtype}{'authtypetext'},
  94          };
  95 }
  96 $template->{VARS}->{'authtypesloop'} = \@authtypesloop;
  97 $template->{VARS}->{'authtypetext'}  = $authtypes->{$authtypecode}{'authtypetext'};
  98 $template->{VARS}->{'authid'}        = $authid;
  99 $template->{VARS}->{'count'}         = $count;
 100
 101 # find the marc field/subfield used in biblio by this authority
 102 if ($show_marc) {
 103     my $tagslib = &GetTagsLabels( 0, $authtypecode );
 104     my $sth =
 105         $dbh->prepare(
 106                 "select distinct tagfield from marc_subfield_structure where authtypecode=?"
 107                 );
 108     $sth->execute($authtypecode);
 109     my $biblio_fields;
 110     while ( my ($tagfield) = $sth->fetchrow ) {
 111         $biblio_fields .= $tagfield . "9,";
 112     }
 113     chop $biblio_fields;
 114
 115 # fill arrays
 116     my @loop_data = ();
 117     my $tag;
 118
 119 # loop through each tag
 120     my @fields    = $record->fields();
 121     foreach my $field (@fields) {
 122         my @subfields_data;
 123
 124 # skip UNIMARC fields <200, they are useless for a patron
 125         next if C4::Context->preference('marcflavour') eq 'UNIMARC' && $field->tag() <200;
 126
 127 # if tag <10, there's no subfield, use the "@" trick
 128         if ( $field->tag() < 10 ) {
 129             next if ( $tagslib->{ $field->tag() }->{'@'}->{hidden} );
 130             my %subfield_data;
 131             $subfield_data{marc_lib}   = $tagslib->{ $field->tag() }->{'@'}->{lib};
 132             $subfield_data{marc_value} = $field->data();
 133             $subfield_data{marc_subfield} = '@';
 134             $subfield_data{marc_tag}      = $field->tag();
 135             push( @subfields_data, \%subfield_data );
 136         }
 137         elsif ( C4::Context->preference('marcflavour') eq 'MARC21' && $field->tag() eq 667 ) {
 138             # tagfield 667 is a nonpublic general note in MARC21, which shouldn't be shown in the OPAC
 139         }
 140         else {
 141             my @subf = $field->subfields;
 142
 143 # loop through each subfield
 144             for my $i ( 0 .. $#subf ) {
 145                 $subf[$i][0] = "@" unless defined $subf[$i][0];
 146                 next if ( $tagslib->{ $field->tag() }->{ $subf[$i][0] }->{hidden} );
 147 # skip useless subfields (for patrons)
 148                 next if $subf[$i][0] =~ /7|8|9/;
 149                 my %subfield_data;
 150                 $subfield_data{marc_lib} =
 151                     $tagslib->{ $field->tag() }->{ $subf[$i][0] }->{lib};
 152                 $subfield_data{marc_subfield} = $subf[$i][0];
 153                 $subfield_data{marc_tag}      = $field->tag();
 154                 $subfield_data{isurl} =  $tagslib->{ $field->tag() }->{ $subf[$i][0] }->{isurl};
 155                 $subfield_data{marc_value} = $subf[$i][1];
 156                 push( @subfields_data, \%subfield_data );
 157             }
 158         }
 159         if ( $#subfields_data >= 0 ) {
 160             my %tag_data;
 161             $tag_data{tag} =
 162                 $field->tag()
 163                 . ' '
 164                 . C4::Koha::display_marc_indicators($field)
 165                 . ' - ' . $tagslib->{ $field->tag() }->{lib};
 166             $tag_data{subfield} = \@subfields_data;
 167             push( @loop_data, \%tag_data );
 168         }
 169     }
 170     $template->param( "Tab0XX" => \@loop_data );
 171 } else {
 172     my $summary = BuildSummary($record, $authid, $authtypecode);
 173     $template->{VARS}->{'summary'} = $summary;
 174 }
 175
 176 output_html_with_http_headers $query, $cookie, $template->output;