opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 use Modern::Perl;
  19
  20 use CGI;
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use String::Random qw( random_string );
  23
  24 use C4::Auth;
  25 use C4::Output;
  26 use C4::Members;
  27 use Koha::Borrower::Modifications;
  28 use C4::Branch qw(GetBranchesLoop);
  29
  30 my $cgi = new CGI;
  31 my $dbh = C4::Context->dbh;
  32
  33 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  34     {
  35         template_name   => "opac-memberentry.tmpl",
  36         type            => "opac",
  37         query           => $cgi,
  38         authnotrequired => 1,
  39     }
  40 );
  41
  42 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  43 {
  44     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  45     exit;
  46 }
  47
  48 my $action = $cgi->param('action') || q{};
  49 if ( $action eq q{} ) {
  50     if ($borrowernumber) {
  51         $action = 'edit';
  52     }
  53     else {
  54         $action = 'new';
  55     }
  56 }
  57
  58 $template->param(
  59     action            => $action,
  60     hidden            => GetHiddenFields(),
  61     mandatory         => GetMandatoryFields($action),
  62     member_titles     => GetTitles(),
  63     branches          => GetBranchesLoop(),
  64     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  65 );
  66
  67 if ( $action eq 'create' ) {
  68
  69     my %borrower = ParseCgiForBorrower($cgi);
  70
  71     %borrower = DelEmptyFields(%borrower);
  72
  73     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
  74
  75     if (@empty_mandatory_fields) {
  76         $template->param(
  77             empty_mandatory_fields => \@empty_mandatory_fields,
  78             borrower               => \%borrower
  79         );
  80     }
  81     elsif (
  82         md5_base64( $cgi->param('captcha') ) ne $cgi->param('captcha_digest') )
  83     {
  84         $template->param(
  85             failed_captcha => 1,
  86             borrower       => \%borrower
  87         );
  88     }
  89     else {
  90         if (
  91             C4::Context->boolean_preference(
  92                 'PatronSelfRegistrationVerifyByEmail')
  93           )
  94         {
  95             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  96                 {
  97                     template_name   => "opac-registration-email-sent.tmpl",
  98                     type            => "opac",
  99                     query           => $cgi,
 100                     authnotrequired => 1,
 101                 }
 102             );
 103             $template->param( 'email' => $borrower{'email'} );
 104
 105             my $verification_token = md5_hex( \%borrower );
 106             $borrower{'password'} = random_string("..........");
 107
 108             Koha::Borrower::Modifications->new(
 109                 verification_token => $verification_token )
 110               ->AddModifications(\%borrower);
 111
 112             #Send verification email
 113             my $letter = C4::Letters::GetPreparedLetter(
 114                 module      => 'members',
 115                 letter_code => 'OPAC_REG_VERIFY',
 116                 tables      => {
 117                     borrower_modifications =>
 118                       [ $verification_token, $verification_token ],
 119                 },
 120             );
 121
 122             C4::Letters::EnqueueLetter(
 123                 {
 124                     letter                 => $letter,
 125                     message_transport_type => 'email',
 126                     to_address             => $borrower{'email'},
 127                     from_address =>
 128                       C4::Context->preference('KohaAdminEmailAddress'),
 129                 }
 130             );
 131         }
 132         else {
 133             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 134                 {
 135                     template_name   => "opac-registration-confirmation.tmpl",
 136                     type            => "opac",
 137                     query           => $cgi,
 138                     authnotrequired => 1,
 139                 }
 140             );
 141
 142             $template->param( OpacPasswordChange =>
 143                   C4::Context->preference('OpacPasswordChange') );
 144
 145             my ( $borrowernumber, $password ) = AddMember_Opac(%borrower);
 146
 147             $template->param( password_cleartext => $password );
 148             $template->param(
 149                 borrower => GetMember( borrowernumber => $borrowernumber ) );
 150             $template->param(
 151                 PatronSelfRegistrationAdditionalInstructions =>
 152                   C4::Context->preference(
 153                     'PatronSelfRegistrationAdditionalInstructions')
 154             );
 155         }
 156     }
 157 }
 158 elsif ( $action eq 'update' ) {
 159
 160     my %borrower = ParseCgiForBorrower($cgi);
 161
 162     my %borrower_changes = DelEmptyFields(%borrower);
 163     my @empty_mandatory_fields =
 164       CheckMandatoryFields( \%borrower_changes, $action );
 165
 166     if (@empty_mandatory_fields) {
 167         $template->param(
 168             empty_mandatory_fields => \@empty_mandatory_fields,
 169             borrower               => \%borrower
 170         );
 171
 172         $template->param( action => 'edit' );
 173     }
 174     else {
 175         ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 176             {
 177                 template_name   => "opac-memberentry-update-submitted.tmpl",
 178                 type            => "opac",
 179                 query           => $cgi,
 180                 authnotrequired => 1,
 181             }
 182         );
 183
 184         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 185
 186         my $m =
 187           Koha::Borrower::Modifications->new(
 188             borrowernumber => $borrowernumber );
 189
 190         $m->DelModifications;
 191         $m->AddModifications(\%borrower_changes);
 192         $template->param(
 193             borrower => GetMember( borrowernumber => $borrowernumber ),
 194         );
 195     }
 196 }
 197 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 198     $template->param(
 199         borrower => GetMember( borrowernumber => $borrowernumber ), );
 200 }
 201
 202 my $captcha = random_string("CCCCC");
 203
 204 $template->param(
 205     captcha        => $captcha,
 206     captcha_digest => md5_base64($captcha)
 207 );
 208
 209 output_html_with_http_headers $cgi, $cookie, $template->output;
 210
 211 sub GetHiddenFields {
 212     my %hidden_fields;
 213
 214     my $BorrowerUnwantedField =
 215       C4::Context->preference("PatronSelfRegistrationBorrowerUnwantedField");
 216
 217     my @fields = split( /\|/, $BorrowerUnwantedField );
 218     foreach (@fields) {
 219         next unless m/\w/o;
 220         $hidden_fields{$_} = 1;
 221     }
 222
 223     return \%hidden_fields;
 224 }
 225
 226 sub GetMandatoryFields {
 227     my ($action) = @_;
 228
 229     my %mandatory_fields;
 230
 231     my $BorrowerMandatoryField =
 232       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 233
 234     my @fields = split( /\|/, $BorrowerMandatoryField );
 235
 236     foreach (@fields) {
 237         $mandatory_fields{$_} = 1;
 238     }
 239
 240     if ( $action eq 'create' || $action eq 'new' ) {
 241         $mandatory_fields{'email'} = 1
 242           if C4::Context->boolean_preference(
 243             'PatronSelfRegistrationVerifyByEmail');
 244     }
 245
 246     return \%mandatory_fields;
 247 }
 248
 249 sub CheckMandatoryFields {
 250     my ( $borrower, $action ) = @_;
 251
 252     my @empty_mandatory_fields;
 253
 254     my $mandatory_fields = GetMandatoryFields($action);
 255     delete $mandatory_fields->{'cardnumber'};
 256
 257     foreach my $key ( keys %$mandatory_fields ) {
 258         push( @empty_mandatory_fields, $key )
 259           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 260     }
 261
 262     return @empty_mandatory_fields;
 263 }
 264
 265 sub ParseCgiForBorrower {
 266     my ($cgi) = @_;
 267
 268     my %borrower;
 269
 270     foreach ( $cgi->param ) {
 271         if ( $_ =~ '^borrower_' ) {
 272             my ($key) = substr( $_, 9 );
 273             $borrower{$key} = $cgi->param($_);
 274         }
 275     }
 276
 277     $borrower{'dateofbirth'} =
 278       C4::Dates->new( $borrower{'dateofbirth'} )->output("iso")
 279       if ( defined( $borrower{'dateofbirth'} ) );
 280
 281     return %borrower;
 282 }
 283
 284 sub DelUnchangedFields {
 285     my ( $borrowernumber, %new_data ) = @_;
 286
 287     my $current_data = GetMember( borrowernumber => $borrowernumber );
 288
 289     foreach my $key ( keys %new_data ) {
 290         if ( $current_data->{$key} eq $new_data{$key} ) {
 291             delete $new_data{$key};
 292         }
 293     }
 294
 295     return %new_data;
 296 }
 297
 298 sub DelEmptyFields {
 299     my (%borrower) = @_;
 300
 301     foreach my $key ( keys %borrower ) {
 302         delete $borrower{$key} unless $borrower{$key};
 303     }
 304
 305     return %borrower;
 306 }