opac/opac-search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # $Header$
   6 #
   7 # Copyright 2006 LibLime
   8 #
   9 # This file is part of Koha
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along with
  21 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  22 # Suite 330, Boston, MA  02111-1307 USA
  23
  24 =head1 NAME
  25
  26 search - a search script for finding records in a Koha system (Version 3.0)
  27
  28 =head1 OVERVIEW
  29
  30 This script contains a new search API for Koha 3.0. It is designed to be
  31 simple to use and configure, yet capable of performing feats like stemming,
  32 field weighting, relevance ranking, support for multiple  query language
  33 formats (CCL, CQL, PQF), full or nearly full support for the
  34 bib1 attribute set, extended attribute sets defined in Zebra profiles, access
  35 to the full range of Z39.50 query options, federated searches on Z39.50
  36 targets, etc.
  37
  38 I believe the API as represented in this script is mostly sound, even if the
  39 individual functions in Search.pm and Koha.pm need to be cleaned up. Of course,
  40 you are free to disagree :-)
  41
  42 I will attempt to describe what is happening at each part of this script.
  43 -- JF
  44
  45 =head2 INTRO
  46
  47 This script performs two functions:
  48
  49 =over
  50
  51 =item 1. interacts with Koha to retrieve and display the results of a search
  52
  53 =item 2. loads the advanced search page
  54
  55 =back
  56
  57 These two functions share many of the same variables and modules, so the first
  58 task is to load what they have in common and determine which template to use.
  59 Once determined, proceed to only load the variables and procedures necessary
  60 for that function.
  61
  62 =head2 THE ADVANCED SEARCH PAGE
  63
  64 If we're loading the advanced search page this script will call a number of
  65 display* routines which populate objects that are sent to the template for
  66 display of things like search indexes, languages, search limits, branches,
  67 etc. These are not stored in the template for two reasons:
  68
  69 =over
  70
  71 =item 1. Efficiency - we have more control over objects inside the script,
  72 and it's possible to not duplicate things like indexes (if the search indexes
  73 were stored in the template they would need to be repeated)
  74
  75 =item 2. Customization - if these elements were moved to the sql database it
  76 would allow a simple librarian to determine which fields to display on the page
  77 without editing any html (also how the fields should behave when being searched).
  78
  79 =back
  80
  81 However, they create one problem : the strings aren't translated. I have an idea
  82 for how to do this that I will purusue soon.
  83
  84 =head2 PERFORMING A SEARCH
  85
  86 If we're performing a search, this script  performs three primary
  87 operations:
  88
  89 =over
  90
  91 =item 1. builds query strings (yes, plural)
  92
  93 =item 2. perform the search and return the results array
  94
  95 =item 3. build the HTML for output to the template
  96
  97 =back
  98
  99 There are several additional secondary functions performed that I will
 100 not cover in detail.
 101
 102 =head3 1. Building Query Strings
 103
 104 There are several types of queries needed in the process of search and retrieve:
 105
 106 =over
 107
 108 =item 1 Koha query - the query that is passed to Zebra
 109
 110 This is the most complex query that needs to be built. The original design goal
 111 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
 112 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
 113 weighting, koha-specific relevance ranking, and stemming. When I have a chance
 114 I'll try to flesh out this section to better explain.
 115
 116 This query incorporates query profiles that aren't compatible with non-Zebra
 117 Z39.50 targets to acomplish the field weighting and relevance ranking.
 118
 119 =item 2 Federated query - the query that is passed to other Z39.50 targets
 120
 121 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 122 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 123
 124 =item 3 Search description - passed to the template / saved for future refinements of
 125 the query (by user)
 126
 127 This is a simple string that completely expresses the query in a way that can be parsed
 128 by Koha for future refinements of the query or as a part of a history feature. It differs
 129 from the human search description:
 130
 131 1. it does not contain commas or = signs
 132
 133 =item 4 Human search description - what the user sees in the search_desc area
 134
 135 This is a simple string nearly identical to the Search description, but more human
 136 readable. It will contain = signs or commas, etc.
 137
 138 =back
 139
 140 =head3 2. Perform the Search
 141
 142 This section takes the query strings and performs searches on the named servers, including
 143 the Koha Zebra server, stores the results in a deeply nested object, builds 'faceted results',
 144 and returns these objects.
 145
 146 =head3 3. Build HTML
 147
 148 The final major section of this script takes the objects collected thusfar and builds the
 149 HTML for output to the template and user.
 150
 151 =head3 Additional Notes
 152
 153 Not yet completed...
 154
 155 =cut
 156
 157 use strict;            # always use
 158
 159 ## STEP 1. Load things that are used in both search page and
 160 # results page and decide which template to load, operations
 161 # to perform, etc.
 162 ## load Koha modules
 163 use C4::Context;
 164 use C4::Output;
 165 use C4::Auth;
 166 use C4::Search;
 167 use C4::Languages; # getAllLanguages
 168 use C4::Koha;
 169 use POSIX qw(ceil floor);
 170 use C4::Branch; # GetBranches
 171 # create a new CGI object
 172 # not sure undef_params option is working, need to test
 173 use CGI qw('-no_undef_params');
 174 my $cgi = new CGI;
 175
 176 my ($template,$borrowernumber,$cookie);
 177
 178 # decide which template to use
 179 my $template_name;
 180 my $template_type;
 181 my @params = $cgi->param("limit");
 182 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 183     $template_name = 'opac-results.tmpl';
 184 }
 185 else {
 186     $template_name = 'opac-advsearch.tmpl';
 187         $template_type = 'advsearch';
 188 }
 189 # load the template
 190 ($template, $borrowernumber, $cookie) = get_template_and_user({
 191     template_name => $template_name,
 192     query => $cgi,
 193     type => "opac",
 194     authnotrequired => 1,
 195     }
 196 );
 197 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 198         $template->param('UNIMARC' => 1);
 199 }
 200
 201 =head1 BUGS and FIXMEs
 202
 203 There are many, most are documented in the code. The one that
 204 isn't fully documented, but referred to is the need for a full
 205 query parser.
 206
 207 =cut
 208
 209 ## URI Re-Writing
 210 # Deprecated, but preserved because it's interesting :-)
 211 #my $rewrite_flag;
 212 #my $uri = $cgi->url(-base => 1);
 213 #my $relative_url = $cgi->url(-relative=>1);
 214 #$uri.="/".$relative_url."?";
 215 #warn "URI:$uri";
 216 #my @cgi_params_list = $cgi->param();
 217 #my $url_params = $cgi->Vars;
 218 #
 219 #for my $each_param_set (@cgi_params_list) {
 220 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 221 #}
 222 #warn "New URI:$uri";
 223 # Only re-write a URI if there are params or if it already hasn't been re-written
 224 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 225 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 226 #                            -cookie => $cookie);
 227 #    exit;
 228 #}
 229
 230 # load the branches
 231 my $branches = GetBranches();
 232 my @branch_loop;
 233 #push @branch_loop, {value => "", branchname => "All Branches", };
 234 for my $branch_hash (sort keys %$branches) {
 235     push @branch_loop, {value => "$branch_hash" , branchname => $branches->{$branch_hash}->{'branchname'}, };
 236 }
 237
 238 my $categories = GetBranchCategories(undef,'searchdomain');
 239
 240 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 241
 242 # load the itemtypes
 243 my $itemtypes = GetItemTypes;
 244 my @itemtypesloop;
 245 my $selected=1;
 246 my $cnt;
 247 my $imgdir = getitemtypeimagesrc();
 248 foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 249     my %row =(  number=>$cnt++,
 250                 imageurl=> $itemtypes->{$thisitemtype}->{'imageurl'}?($imgdir."/".$itemtypes->{$thisitemtype}->{'imageurl'}):"",
 251                 code => $thisitemtype,
 252                 selected => $selected,
 253                 description => $itemtypes->{$thisitemtype}->{'description'},
 254                 count5 => $cnt % 4,
 255             );
 256     $selected = 0 if ($selected) ;
 257     push @itemtypesloop, \%row;
 258 }
 259 $template->param(itemtypeloop => \@itemtypesloop);
 260
 261 # # load the itypes (Called item types in the template -- just authorized values for searching)
 262 # my ($itypecount,@itype_loop) = GetCcodes();
 263 # $template->param(itypeloop=>\@itype_loop,);
 264
 265 # load the languages ( for switching from one template to another )
 266 $template->param(languages_loop => getTranslatedLanguages('intranet','prog'));
 267
 268 # The following should only be loaded if we're bringing up the advanced search template
 269 if ( $template_type eq 'advsearch' ) {
 270     # load the servers (used for searching -- to do federated searching, etc.)
 271     my $primary_servers_loop;# = displayPrimaryServers();
 272     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 273
 274     my $secondary_servers_loop;# = displaySecondaryServers();
 275     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 276
 277     # determine what to display next to the search boxes (ie, boolean option
 278     # shouldn't appear on the first one, scan indexes should, adding a new
 279     # box should only appear on the last, etc.
 280     my @search_boxes_array;
 281     my $search_boxes_count = C4::Context->preference("OPACAdvSearchInputCount") | 3; # FIXME: should be a syspref
 282     for (my $i=1;$i<=$search_boxes_count;$i++) {
 283                 # if it's the first one, don't display boolean option, but show scan indexes
 284         if ($i==1) {
 285             push @search_boxes_array,
 286                 {
 287                 scan_index => 1,
 288                 };
 289
 290         }
 291                 # if it's the last one, show the 'add field' box
 292         elsif ($i==$search_boxes_count) {
 293             push @search_boxes_array,
 294                 {
 295                                 boolean => 1,
 296                 add_field => 1,
 297                                 };
 298         }
 299                 else {
 300                         push @search_boxes_array,
 301                                 {
 302                                 boolean => 1,
 303                                 };
 304                 }
 305
 306     }
 307     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 308                       search_boxes_loop => \@search_boxes_array);
 309
 310     # load the language limits (for search)
 311     my $languages_limit_loop = getAllLanguages();
 312     $template->param(search_languages_loop => $languages_limit_loop,);
 313
 314         # use the global setting by default
 315         if ( C4::Context->preference("expandedSearchOption") == 1) {
 316                 $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 317         }
 318         # but let the user override it
 319         if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 320         $template->param( expanded_options => $cgi->param('expanded_options'));
 321         }
 322
 323     output_html_with_http_headers $cgi, $cookie, $template->output;
 324     exit;
 325 }
 326
 327 ### OK, if we're this far, we're performing an actual search
 328
 329 # Fetch the paramater list as a hash in scalar context:
 330 #  * returns paramater list as tied hash ref
 331 #  * we can edit the values by changing the key
 332 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 333 my $params = $cgi->Vars;
 334
 335 # Params that can have more than one value
 336 # sort by is used to sort the query
 337 # in theory can have more than one but generally there's just one
 338 my @sort_by;
 339 @sort_by = split("\0",$params->{'sort_by'}) if $params->{'sort_by'};
 340 foreach my $sort (@sort_by) {
 341         $template->param($sort => 1);
 342 }
 343 $template->param('sort_by' => $sort_by[0]);
 344
 345 # Use the servers defined, or just search our local catalog(default)
 346 my @servers;
 347 @servers = split("\0",$params->{'server'}) if $params->{'server'};
 348 unless (@servers) {
 349     #FIXME: this should be handled using Context.pm
 350     @servers = ("biblioserver");
 351     # @servers = C4::Context->config("biblioserver");
 352 }
 353
 354 # operators include boolean and proximity operators and are used
 355 # to evaluate multiple operands
 356 my @operators;
 357 @operators = split("\0",$params->{'op'}) if $params->{'op'};
 358
 359 # indexes are query qualifiers, like 'title', 'author', etc. They
 360 # can be single or multiple parameters separated by comma: kw,right-Truncation
 361 my @indexes;
 362 @indexes = split("\0",$params->{'idx'});
 363
 364 # if a simple index (only one)  display the index used in the top search box
 365 if (@indexes[0] && !@indexes[1]) {
 366         $template->param(@indexes[0] => 1);
 367 }
 368 # an operand can be a single term, a phrase, or a complete ccl query
 369 my @operands;
 370 @operands = split("\0",$params->{'q'}) if $params->{'q'};
 371
 372 # if a simple search, display the value in the search box
 373 if (@operands[0] && !@operands[1]) {
 374     $template->param(ms_value => @operands[0]);
 375 }
 376
 377 # limits are use to limit to results to a pre-defined category such as branch or language
 378 my @limits;
 379 @limits = split("\0",$params->{'limit'}) if $params->{'limit'};
 380
 381 if($params->{'multibranchlimit'}) {
 382 push @limits, join(" or ", map { "branch: $_ "}  @{GetBranchesInCategory($params->{'multibranchlimit'})}) ;
 383 }
 384
 385 my $available;
 386 foreach my $limit(@limits) {
 387     if ($limit =~/available/) {
 388         $available = 1;
 389     }
 390 }
 391 $template->param(available => $available);
 392
 393 # append year limits if they exist
 394 push @limits, map "yr:".$_, split("\0",$params->{'limit-yr'}) if $params->{'limit-yr'};
 395
 396 # Params that can only have one value
 397 my $scan = $params->{'scan'};
 398 my $results_per_page = $params->{'count'} || 20;
 399 my $offset = $params->{'offset'} || 0;
 400 my $page = $cgi->param('page') || 1;
 401 #my $offset = ($page-1)*$results_per_page;
 402 my $hits;
 403 my $expanded_facet = $params->{'expand'};
 404
 405 # Define some global variables
 406 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 407
 408 my @results;
 409
 410 ## I. BUILD THE QUERY
 411 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by);
 412
 413 ## parse the query_cgi string and put it into a form suitable for <input>s
 414 my @query_inputs;
 415 for my $this_cgi ( split('&',$query_cgi) ) {
 416         next unless $this_cgi;
 417         $this_cgi =~ m/(.*=)(.*)/;
 418         my $input_name = $1;
 419         my $input_value = $2;
 420         $input_name =~ s/=$//;
 421         push @query_inputs, { input_name => $input_name, input_value => $input_value };
 422 }
 423 $template->param ( QUERY_INPUTS => \@query_inputs );
 424
 425 ## parse the limit_cgi string and put it into a form suitable for <input>s
 426 my @limit_inputs;
 427 for my $this_cgi ( split('&',$limit_cgi) ) {
 428         next unless $this_cgi;
 429     $this_cgi =~ m/(.*=)(.*)/;
 430     my $input_name = $1;
 431     my $input_value = $2;
 432     $input_name =~ s/=$//;
 433     push @limit_inputs, { input_name => $input_name, input_value => $input_value };
 434 }
 435 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 436
 437 ## II. DO THE SEARCH AND GET THE RESULTS
 438 my $total; # the total results for the whole set
 439 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 440 my @results_array;
 441 my $results_hashref;
 442
 443 if (C4::Context->preference('NoZebra')) {
 444     eval {
 445         ($error, $results_hashref, $facets) = NZgetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 446     };
 447 } else {
 448     eval {
 449         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 450     };
 451 }
 452 if ($@ || $error) {
 453     $template->param(query_error => $error.$@);
 454
 455     output_html_with_http_headers $cgi, $cookie, $template->output;
 456     exit;
 457 }
 458
 459 # FIXME: This belongs in tools/ not in the primary search results page
 460 my $op=$cgi->param("operation");
 461 if ($op eq "bulkedit"){
 462         my ($countchanged,$listunchanged)=
 463         ModBiblios($results_hashref->{'biblioserver'}->{"RECORDS"},
 464                       $params->{"tagsubfield"},
 465                       $params->{"inputvalue"},
 466                       $params->{"targetvalue"},
 467                       $params->{"test"}
 468                       );
 469         $template->param(bulkeditresults=>1,
 470                       tagsubfield=>$params->{"tagsubfield"},
 471                       inputvalue=>$params->{"inputvalue"},
 472                       targetvalue=>$params->{"targetvalue"},
 473                       countchanged=>$countchanged,
 474                       countunchanged=>scalar(@$listunchanged),
 475                       listunchanged=>$listunchanged);
 476
 477         if (C4::Context->userenv->{'flags'}==1 ||(C4::Context->userenv->{'flags'} & ( 2**9 ) )){
 478         #Edit Catalogue Permissions
 479                 $template->param(bulkedit => 1);
 480                 $template->param(tagsubfields=>GetManagedTagSubfields());
 481         }
 482 }
 483 # At this point, each server has given us a result set
 484 # now we build that set for template display
 485 my @sup_results_array;
 486 for (my $i=0;$i<=@servers;$i++) {
 487     my $server = $servers[$i];
 488     if ($server =~/biblioserver/) { # this is the local bibliographic server
 489         $hits = $results_hashref->{$server}->{"hits"};
 490         my $page = $cgi->param('page') || 0;
 491         my @newresults = searchResults( $query_desc,$hits,$results_per_page,$offset,@{$results_hashref->{$server}->{"RECORDS"}});
 492         $total = $total + $results_hashref->{$server}->{"hits"};
 493         if ($hits) {
 494             $template->param(total => $hits);
 495                         my $limit_cgi_not_availablity = $limit_cgi;
 496                         $limit_cgi_not_availablity =~ s/&limit=available//g;
 497                         $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 498                         $template->param(limit_cgi => $limit_cgi);
 499                         $template->param(query_cgi => $query_cgi);
 500                         $template->param(query_desc => $query_desc);
 501                         $template->param(limit_desc => $limit_desc);
 502                         if ($query_desc || $limit_desc) {
 503                 $template->param(searchdesc => 1);
 504                         }
 505                         $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 506             $template->param(results_per_page =>  $results_per_page);
 507             $template->param(SEARCH_RESULTS => \@newresults);
 508                         ## Build the page numbers on the bottom of the page
 509                         my @page_numbers;
 510                         # total number of pages there will be
 511                         my $pages = ceil($hits / $results_per_page);
 512                         # default page number
 513                         my $current_page_number = 1;
 514                         $current_page_number = ($offset / $results_per_page + 1) if $offset;
 515                         my $previous_page_offset = $offset - $results_per_page unless ($offset - $results_per_page <0);
 516                         my $next_page_offset = $offset + $results_per_page;
 517                         # If we're within the first 10 pages, keep it simple
 518                         #warn "current page:".$current_page_number;
 519                         if ($current_page_number < 10) {
 520                                 # just show the first 10 pages
 521                                 # Loop through the pages
 522                                 my $pages_to_show = 10;
 523                                 $pages_to_show = $pages if $pages<10;
 524                                 for ($i=1; $i<=$pages_to_show;$i++) {
 525                                         # the offset for this page
 526                                         my $this_offset = (($i*$results_per_page)-$results_per_page);
 527                                         # the page number for this page
 528                                         my $this_page_number = $i;
 529                                         # it should only be highlighted if it's the current page
 530                                         my $highlight = 1 if ($this_page_number == $current_page_number);
 531                                         # put it in the array
 532                                         push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 533
 534                                 }
 535
 536                         }
 537                         # now, show twenty pages, with the current one smack in the middle
 538                         else {
 539                                 for ($i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 540                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 541                     my $this_page_number = $i-9;
 542                     my $highlight = 1 if ($this_page_number == $current_page_number);
 543                                         if ($this_page_number <= $pages) {
 544                         push @page_numbers, { offset => $this_offset, pg => $this_page_number, highlight => $highlight, sort_by => join " ",@sort_by };
 545                                         }
 546                 }
 547
 548                         }
 549                         $template->param(       PAGE_NUMBERS => \@page_numbers,
 550                                                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 551                         $template->param(next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 552          }
 553     } # end of the if local
 554     else {
 555         # check if it's a z3950 or opensearch source
 556         my $zed3950 = 0;  # FIXME :: Hardcoded value.
 557         if ($zed3950) {
 558             my @inner_sup_results_array;
 559             for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 560                 my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 561                 my $control_number = $marc_record_object->field('010')->subfield('a') if $marc_record_object->field('010');
 562                 $control_number =~ s/^ //g;
 563                 my $link = "http://catalog.loc.gov/cgi-bin/Pwebrecon.cgi?SAB1=".$control_number."&BOOL1=all+of+these&FLD1=LC+Control+Number+LCCN+%28K010%29+%28K010%29&GRP1=AND+with+next+set&SAB2=&BOOL2=all+of+these&FLD2=Keyword+Anywhere+%28GKEY%29+%28GKEY%29&PID=6211&SEQ=20060816121838&CNT=25&HIST=1";
 564                 my $title = $marc_record_object->title();
 565                 push @inner_sup_results_array, {
 566                     'title' => $title,
 567                     'link' => $link,
 568                 };
 569             }
 570             my $servername = $server;
 571             push @sup_results_array, { servername => $servername, inner_sup_results_loop => \@inner_sup_results_array};
 572             $template->param(outer_sup_results_loop => \@sup_results_array);
 573         }
 574     }
 575
 576 } #/end of the for loop
 577 #$template->param(FEDERATED_RESULTS => \@results_array);
 578
 579
 580 $template->param(
 581             #classlist => $classlist,
 582             total => $total,
 583             opacfacets => 1,
 584             facets_loop => $facets,
 585             scan => $scan,
 586             search_error => $error,
 587 );
 588
 589 if ($query_desc || $limit_desc) {
 590         $template->param(searchdesc => 1);
 591 }
 592
 593 ## Now let's find out if we have any supplemental data to show the user
 594 #  and in the meantime, save the current query for statistical purposes, etc.
 595 my $koha_spsuggest; # a flag to tell if we've got suggestions coming from Koha
 596 my @koha_spsuggest; # place we store the suggestions to be returned to the template as LOOP
 597 my $phrases = $query_desc;
 598 my $ipaddress;
 599
 600 if ( C4::Context->preference("kohaspsuggest") ) {
 601                 my ($suggest_host, $suggest_dbname, $suggest_user, $suggest_pwd) = split(':', C4::Context->preference("kohaspsuggest"));
 602         eval {
 603             my $koha_spsuggest_dbh;
 604             # FIXME: this needs to be moved to Context.pm
 605             eval {
 606                 $koha_spsuggest_dbh=DBI->connect("DBI:mysql:$suggest_dbname:$suggest_host","$suggest_user","$suggest_pwd");
 607             };
 608             if ($@) {
 609                 warn "can't connect to spsuggest db";
 610             }
 611             else {
 612                 my $koha_spsuggest_insert = "INSERT INTO phrase_log(phr_phrase,phr_resultcount,phr_ip) VALUES(?,?,?)";
 613                 my $koha_spsuggest_query = "SELECT display FROM distincts WHERE strcmp(soundex(suggestion), soundex(?)) = 0 order by soundex(suggestion) limit 0,5";
 614                 my $koha_spsuggest_sth = $koha_spsuggest_dbh->prepare($koha_spsuggest_query);
 615                 $koha_spsuggest_sth->execute($phrases);
 616                 while (my $spsuggestion = $koha_spsuggest_sth->fetchrow_array) {
 617                     $spsuggestion =~ s/(:|\/)//g;
 618                     my %line;
 619                     $line{spsuggestion} = $spsuggestion;
 620                     push @koha_spsuggest,\%line;
 621                     $koha_spsuggest = 1;
 622                 }
 623
 624                 # Now save the current query
 625                 $koha_spsuggest_sth=$koha_spsuggest_dbh->prepare($koha_spsuggest_insert);
 626                 #$koha_spsuggest_sth->execute($phrases,$results_per_page,$ipaddress);
 627                 $koha_spsuggest_sth->finish;
 628
 629                 $template->param( koha_spsuggest => $koha_spsuggest ) unless $hits;
 630                 $template->param( SPELL_SUGGEST => \@koha_spsuggest,
 631                 );
 632             }
 633     };
 634     if ($@) {
 635             warn "Kohaspsuggest failure:".$@;
 636     }
 637 }
 638
 639 # VI. BUILD THE TEMPLATE
 640 output_html_with_http_headers $cgi, $cookie, $template->output;