opac/opac-search.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2008 Garry Collum and the Koha Koha Development team
   4 # Copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 # Script to perform searching
  22 # Mostly copied from search.pl, see POD there
  23 use strict;            # always use
  24 use warnings;
  25
  26 ## STEP 1. Load things that are used in both search page and
  27 # results page and decide which template to load, operations
  28 # to perform, etc.
  29 ## load Koha modules
  30 use C4::Context;
  31 use C4::Output;
  32 use C4::Auth qw(:DEFAULT get_session);
  33 use C4::Languages qw(getAllLanguages);
  34 use C4::Search;
  35 use C4::Biblio;  # GetBiblioData
  36 use C4::Koha;
  37 use C4::Tags qw(get_tags);
  38 use C4::Branch; # GetBranches
  39 use C4::SocialData;
  40 use POSIX qw(ceil floor strftime);
  41 use URI::Escape;
  42 use Storable qw(thaw freeze);
  43 use Business::ISBN;
  44
  45
  46 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
  47 # create a new CGI object
  48 # FIXME: no_undef_params needs to be tested
  49 use CGI qw('-no_undef_params');
  50 my $cgi = new CGI;
  51
  52 BEGIN {
  53     if (C4::Context->preference('BakerTaylorEnabled')) {
  54         require C4::External::BakerTaylor;
  55         import C4::External::BakerTaylor qw(&image_url &link_url);
  56     }
  57 }
  58
  59 my ($template,$borrowernumber,$cookie);
  60
  61 # decide which template to use
  62 my $template_name;
  63 my $template_type = 'basic';
  64 my @params = $cgi->param("limit");
  65
  66 my $format = $cgi->param("format") || '';
  67 my $build_grouped_results = C4::Context->preference('OPACGroupResults');
  68 if ($format =~ /(rss|atom|opensearchdescription)/) {
  69     $template_name = 'opac-opensearch.tmpl';
  70 }
  71 elsif (@params && $build_grouped_results) {
  72     $template_name = 'opac-results-grouped.tmpl';
  73 }
  74 elsif ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
  75     $template_name = 'opac-results.tmpl';
  76 }
  77 else {
  78     $template_name = 'opac-advsearch.tmpl';
  79     $template_type = 'advsearch';
  80 }
  81 # load the template
  82 ($template, $borrowernumber, $cookie) = get_template_and_user({
  83     template_name => $template_name,
  84     query => $cgi,
  85     type => "opac",
  86     authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  87     }
  88 );
  89 if ($template_name eq 'opac-results.tmpl') {
  90    $template->param('COinSinOPACResults' => C4::Context->preference('COinSinOPACResults'));
  91 }
  92
  93 # get biblionumbers stored in the cart
  94 my @cart_list;
  95
  96 if($cgi->cookie("bib_list")){
  97     my $cart_list = $cgi->cookie("bib_list");
  98     @cart_list = split(/\//, $cart_list);
  99 }
 100
 101 if ($format eq 'rss2' or $format eq 'opensearchdescription' or $format eq 'atom') {
 102     $template->param($format => 1);
 103     $template->param(timestamp => strftime("%Y-%m-%dT%H:%M:%S-00:00", gmtime)) if ($format eq 'atom');
 104     # FIXME - the timestamp is a hack - the biblio update timestamp should be used for each
 105     # entry, but not sure if that's worth an extra database query for each bib
 106 }
 107 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 108     $template->param('UNIMARC' => 1);
 109 }
 110 elsif (C4::Context->preference("marcflavour") eq "MARC21" ) {
 111     $template->param('usmarc' => 1);
 112 }
 113 $template->param( 'AllowOnShelfHolds' => C4::Context->preference('AllowOnShelfHolds') );
 114 $template->param( 'OPACNoResultsFound' => C4::Context->preference('OPACNoResultsFound') );
 115
 116 if (C4::Context->preference('BakerTaylorEnabled')) {
 117     $template->param(
 118         BakerTaylorEnabled  => 1,
 119         BakerTaylorImageURL => &image_url(),
 120         BakerTaylorLinkURL  => &link_url(),
 121         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 122     );
 123 }
 124 if (C4::Context->preference('TagsEnabled')) {
 125     $template->param(TagsEnabled => 1);
 126     foreach (qw(TagsShowOnList TagsInputOnList)) {
 127         C4::Context->preference($_) and $template->param($_ => 1);
 128     }
 129 }
 130
 131 ## URI Re-Writing
 132 # Deprecated, but preserved because it's interesting :-)
 133 # The same thing can be accomplished with mod_rewrite in
 134 # a more elegant way
 135 #
 136 #my $rewrite_flag;
 137 #my $uri = $cgi->url(-base => 1);
 138 #my $relative_url = $cgi->url(-relative=>1);
 139 #$uri.="/".$relative_url."?";
 140 #warn "URI:$uri";
 141 #my @cgi_params_list = $cgi->param();
 142 #my $url_params = $cgi->Vars;
 143 #
 144 #for my $each_param_set (@cgi_params_list) {
 145 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 146 #}
 147 #warn "New URI:$uri";
 148 # Only re-write a URI if there are params or if it already hasn't been re-written
 149 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 150 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 151 #                            -cookie => $cookie);
 152 #    exit;
 153 #}
 154
 155 # load the branches
 156
 157 my $branches = GetBranches();   # used later in *getRecords, probably should be internalized by those functions after caching in C4::Branch is established
 158 $template->param(
 159     searchdomainloop => GetBranchCategories(undef,'searchdomain'),
 160 );
 161
 162 # load the language limits (for search)
 163 my $languages_limit_loop = getAllLanguages();
 164 $template->param(search_languages_loop => $languages_limit_loop,);
 165
 166 # load the Type stuff
 167 my $itemtypes = GetItemTypes;
 168 # the index parameter is different for item-level itemtypes
 169 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 170 my @advancedsearchesloop;
 171 my $cnt;
 172 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 173 my @advanced_search_types = split(/\|/, $advanced_search_types);
 174
 175 foreach my $advanced_srch_type (@advanced_search_types) {
 176    if ($advanced_srch_type eq 'itemtypes') {
 177    # itemtype is a special case, since it's not defined in authorized values
 178         my @itypesloop;
 179         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{'description'} cmp $itemtypes->{$b}->{'description'} } keys %$itemtypes ) {
 180             my %row =(  number=>$cnt++,
 181                 ccl => "$itype_or_itemtype,phr",
 182                 code => $thisitemtype,
 183                 description => $itemtypes->{$thisitemtype}->{'description'},
 184                 imageurl=> getitemtypeimagelocation( 'opac', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 185             );
 186             push @itypesloop, \%row;
 187         }
 188         my %search_code = (  advanced_search_type => $advanced_srch_type,
 189                              code_loop => \@itypesloop );
 190         push @advancedsearchesloop, \%search_code;
 191     } else {
 192     # covers all the other cases: non-itemtype authorized values
 193        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type, '', 'opac');
 194         my @authvalueloop;
 195         for my $thisitemtype (@$advsearchtypes) {
 196                 my %row =(
 197                                 number=>$cnt++,
 198                                 ccl => $advanced_srch_type,
 199                 code => $thisitemtype->{authorised_value},
 200                 description => $thisitemtype->{'lib_opac'} || $thisitemtype->{'lib'},
 201                 imageurl => getitemtypeimagelocation( 'opac', $thisitemtype->{'imageurl'} ),
 202                 );
 203                 push @authvalueloop, \%row;
 204         }
 205         my %search_code = (  advanced_search_type => $advanced_srch_type,
 206                              code_loop => \@authvalueloop );
 207         push @advancedsearchesloop, \%search_code;
 208     }
 209 }
 210 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 211
 212 # # load the itypes (Called item types in the template -- just authorized values for searching)
 213 # my ($itypecount,@itype_loop) = GetCcodes();
 214 # $template->param(itypeloop=>\@itype_loop,);
 215
 216 # The following should only be loaded if we're bringing up the advanced search template
 217 if ( $template_type && $template_type eq 'advsearch' ) {
 218     # load the servers (used for searching -- to do federated searching, etc.)
 219     my $primary_servers_loop;# = displayPrimaryServers();
 220     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 221
 222     my $secondary_servers_loop;
 223     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 224
 225     # set the default sorting
 226     if (   C4::Context->preference('OPACdefaultSortField')
 227         && C4::Context->preference('OPACdefaultSortOrder') ) {
 228         my $default_sort_by =
 229             C4::Context->preference('OPACdefaultSortField') . '_'
 230           . C4::Context->preference('OPACdefaultSortOrder');
 231         $template->param( sort_by => $default_sort_by );
 232     }
 233
 234     # determine what to display next to the search boxes (ie, boolean option
 235     # shouldn't appear on the first one, scan indexes should, adding a new
 236     # box should only appear on the last, etc.
 237     my @search_boxes_array;
 238     my $search_boxes_count = 3; # begin whith 3 boxes
 239     for (my $i=1;$i<=$search_boxes_count;$i++) {
 240         # if it's the first one, don't display boolean option, but show scan indexes
 241         if ($i==1) {
 242             push @search_boxes_array,
 243                 {
 244                 scan_index => 1,
 245                 };
 246
 247         }
 248         # if it's the last one, show the 'add field' box
 249         elsif ($i==$search_boxes_count) {
 250             push @search_boxes_array,
 251                 {
 252                 boolean => 1,
 253                 add_field => 1,
 254                 };
 255         }
 256         else {
 257             push @search_boxes_array,
 258                 {
 259                 boolean => 1,
 260                 };
 261         }
 262
 263     }
 264     $template->param(uc(    C4::Context->preference("marcflavour")) => 1,   # we already did this for UNIMARC
 265                             advsearch => 1,
 266                             search_boxes_loop => \@search_boxes_array);
 267
 268     # use the global setting by default
 269     if ( C4::Context->preference("expandedSearchOption") == 1 ) {
 270         $template->param( expanded_options => C4::Context->preference("expandedSearchOption") );
 271     }
 272     # but let the user override it
 273     if (defined $cgi->param('expanded_options')) {
 274         if ( ($cgi->param('expanded_options') == 0) || ($cgi->param('expanded_options') == 1 ) ) {
 275             $template->param( expanded_options => $cgi->param('expanded_options'));
 276         }
 277     }
 278     output_html_with_http_headers $cgi, $cookie, $template->output;
 279     exit;
 280 }
 281
 282 ### OK, if we're this far, we're performing an actual search
 283
 284 # Fetch the paramater list as a hash in scalar context:
 285 #  * returns paramater list as tied hash ref
 286 #  * we can edit the values by changing the key
 287 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 288 my $params = $cgi->Vars;
 289 my $tag;
 290 $tag = $params->{tag} if $params->{tag};
 291
 292
 293 # String with params with the search criteria for the paging in opac-detail
 294 my $pasarParams = '';
 295 my $j = 0;
 296 for (keys %$params) {
 297     my @pasarParam = split("\0", $params->{$_});
 298     for my $paramValue(@pasarParam) {
 299         $pasarParams .= '&amp;' if ($j > 0);
 300         $pasarParams .= $_ . '=' . $paramValue;
 301         $j++;
 302     }
 303 }
 304
 305 # Params that can have more than one value
 306 # sort by is used to sort the query
 307 # in theory can have more than one but generally there's just one
 308 my @sort_by;
 309 my $default_sort_by;
 310 if (   C4::Context->preference('OPACdefaultSortField')
 311     && C4::Context->preference('OPACdefaultSortOrder') ) {
 312     $default_sort_by =
 313         C4::Context->preference('OPACdefaultSortField') . '_'
 314       . C4::Context->preference('OPACdefaultSortOrder');
 315 }
 316
 317 my @allowed_sortby = qw /acqdate_asc acqdate_dsc author_az author_za call_number_asc call_number_dsc popularity_asc popularity_dsc pubdate_asc pubdate_dsc relevance title_az title_za/;
 318 @sort_by = split("\0",$params->{'sort_by'}) if $params->{'sort_by'};
 319 $sort_by[0] = $default_sort_by if !$sort_by[0] && defined($default_sort_by);
 320 foreach my $sort (@sort_by) {
 321     if ( $sort ~~ @allowed_sortby ) {
 322         $template->param($sort => 1);
 323     }
 324 }
 325 $template->param('sort_by' => $sort_by[0]);
 326
 327 # Use the servers defined, or just search our local catalog(default)
 328 my @servers;
 329 @servers = split("\0",$params->{'server'}) if $params->{'server'};
 330 unless (@servers) {
 331     #FIXME: this should be handled using Context.pm
 332     @servers = ("biblioserver");
 333     # @servers = C4::Context->config("biblioserver");
 334 }
 335
 336 # operators include boolean and proximity operators and are used
 337 # to evaluate multiple operands
 338 my @operators;
 339 @operators = split("\0",$params->{'op'}) if $params->{'op'};
 340
 341 # indexes are query qualifiers, like 'title', 'author', etc. They
 342 # can be single or multiple parameters separated by comma: kw,right-Truncation
 343 my @indexes;
 344 @indexes = split("\0",$params->{'idx'}) if $params->{'idx'};
 345
 346 # if a simple index (only one)  display the index used in the top search box
 347 if ($indexes[0] && !$indexes[1]) {
 348     $template->param("ms_".$indexes[0] => 1);
 349 }
 350 # an operand can be a single term, a phrase, or a complete ccl query
 351 my @operands;
 352 @operands = split("\0",$params->{'q'}) if $params->{'q'};
 353
 354 # if a simple search, display the value in the search box
 355 if ($operands[0] && !$operands[1]) {
 356     $template->param(ms_value => $operands[0]);
 357 }
 358
 359 # limits are use to limit to results to a pre-defined category such as branch or language
 360 my @limits;
 361 @limits = split("\0",$params->{'limit'}) if $params->{'limit'};
 362
 363 if($params->{'multibranchlimit'}) {
 364     push @limits, '('.join( " or ", map { "branch: $_ " } @{ GetBranchesInCategory( $params->{'multibranchlimit'} ) } ).')';
 365 }
 366
 367 my $available;
 368 foreach my $limit(@limits) {
 369     if ($limit =~/available/) {
 370         $available = 1;
 371     }
 372 }
 373 $template->param(available => $available);
 374
 375 # append year limits if they exist
 376 if ($params->{'limit-yr'}) {
 377     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 378         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 379         push @limits, "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 380     }
 381     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 382         push @limits, "yr,st-numeric=$params->{'limit-yr'}";
 383     }
 384     else {
 385         #FIXME: Should return a error to the user, incorect date format specified
 386     }
 387 }
 388
 389 # Params that can only have one value
 390 my $scan = $params->{'scan'};
 391 my $count = C4::Context->preference('OPACnumSearchResults') || 20;
 392 my $countRSS         = C4::Context->preference('numSearchRSSResults') || 50;
 393 my $results_per_page = $params->{'count'} || $count;
 394 my $offset = $params->{'offset'} || 0;
 395 my $page = $cgi->param('page') || 1;
 396 $offset = ($page-1)*$results_per_page if $page>1;
 397 my $hits;
 398 my $expanded_facet = $params->{'expand'};
 399
 400 # Define some global variables
 401 my ($error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 402
 403 my @results;
 404
 405 ## I. BUILD THE QUERY
 406 my $lang = C4::Templates::getlanguage($cgi, 'opac');
 407 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by, 0, $lang);
 408
 409 sub _input_cgi_parse ($) {
 410     my @elements;
 411     for my $this_cgi ( split('&',shift) ) {
 412         next unless $this_cgi;
 413         $this_cgi =~ /(.*?)=(.*)/;
 414         push @elements, { input_name => $1, input_value => $2 };
 415     }
 416     return @elements;
 417 }
 418
 419 ## parse the query_cgi string and put it into a form suitable for <input>s
 420 my @query_inputs = _input_cgi_parse($query_cgi);
 421 $template->param ( QUERY_INPUTS => \@query_inputs );
 422
 423 ## parse the limit_cgi string and put it into a form suitable for <input>s
 424 my @limit_inputs = $limit_cgi ? _input_cgi_parse($limit_cgi) : ();
 425
 426 # add OPAC 'hidelostitems'
 427 #if (C4::Context->preference('hidelostitems') == 1) {
 428 #    # either lost ge 0 or no value in the lost register
 429 #    $query ="($query) and ( (lost,st-numeric <= 0) or ( allrecords,AlwaysMatches='' not lost,AlwaysMatches='') )";
 430 #}
 431 #
 432 # add OPAC suppression - requires at least one item indexed with Suppress
 433 if (C4::Context->preference('OpacSuppression')) {
 434     $query = "($query) not Suppress=1";
 435 }
 436
 437 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 438 $template->param ( OPACResultsSidebar => C4::Context->preference('OPACResultsSidebar'));
 439
 440 ## II. DO THE SEARCH AND GET THE RESULTS
 441 my $total = 0; # the total results for the whole set
 442 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 443 my @results_array;
 444 my $results_hashref;
 445 my @coins;
 446
 447 if ($tag) {
 448     $query_cgi = "tag=" .$tag . "&" . $query_cgi;
 449     my $taglist = get_tags({term=>$tag, approved=>1});
 450     $results_hashref->{biblioserver}->{hits} = scalar (@$taglist);
 451     my @biblist  = (map {GetBiblioData($_->{biblionumber})} @$taglist);
 452     my @marclist = (map {$_->{marc}} @biblist );
 453     $DEBUG and printf STDERR "taglist (%s biblionumber)\nmarclist (%s records)\n", scalar(@$taglist), scalar(@marclist);
 454     $results_hashref->{biblioserver}->{RECORDS} = \@marclist;
 455     # FIXME: tag search and standard search should work together, not exclusively
 456     # FIXME: No facets for tags search.
 457 }
 458 elsif (C4::Context->preference('NoZebra')) {
 459     eval {
 460         ($error, $results_hashref, $facets) = NZgetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 461     };
 462 } elsif ($build_grouped_results) {
 463     eval {
 464         ($error, $results_hashref, $facets) = C4::Search::pazGetRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 465     };
 466 } else {
 467     $pasarParams .= '&amp;query=' . $query;
 468     $pasarParams .= '&amp;count=' . $results_per_page;
 469     $pasarParams .= '&amp;simple_query=' . $simple_query;
 470     $pasarParams .= '&amp;query_type=' . $query_type if ($query_type);
 471     eval {
 472         ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$query_type,$scan);
 473     };
 474 }
 475 # This sorts the facets into alphabetical order
 476 if ($facets) {
 477     foreach my $f (@$facets) {
 478         $f->{facets} = [ sort { uc($a->{facet_title_value}) cmp uc($b->{facet_title_value}) } @{ $f->{facets} } ];
 479     }
 480     @$facets = sort {$a->{expand} cmp $b->{expand}} @$facets;
 481 }
 482
 483 # use Data::Dumper; print STDERR "-" x 25, "\n", Dumper($results_hashref);
 484 if ($@ || $error) {
 485     $template->param(query_error => $error.$@);
 486     output_html_with_http_headers $cgi, $cookie, $template->output;
 487     exit;
 488 }
 489
 490 # At this point, each server has given us a result set
 491 # now we build that set for template display
 492 my @sup_results_array;
 493 for (my $i=0;$i<@servers;$i++) {
 494     my $server = $servers[$i];
 495     if ($server && $server =~/biblioserver/) { # this is the local bibliographic server
 496         $hits = $results_hashref->{$server}->{"hits"};
 497         my $page = $cgi->param('page') || 0;
 498         my @newresults;
 499         if ($build_grouped_results) {
 500             foreach my $group (@{ $results_hashref->{$server}->{"GROUPS"} }) {
 501                 # because pazGetRecords handles retieving only the records
 502                 # we want as specified by $offset and $results_per_page,
 503                 # we need to set the offset parameter of searchResults to 0
 504                 my @group_results = searchResults( 'opac', $query_desc, $group->{'group_count'},$results_per_page, 0, $scan,
 505                                                    $group->{"RECORDS"});
 506                 push @newresults, { group_label => $group->{'group_label'}, GROUP_RESULTS => \@group_results };
 507             }
 508         } else {
 509             @newresults = searchResults('opac', $query_desc, $hits, $results_per_page, $offset, $scan,
 510                                         $results_hashref->{$server}->{"RECORDS"});
 511         }
 512
 513         # must define a value for size if not present in DB
 514         # in order to avoid problems generated by the default size value in TT
 515         foreach my $line (@newresults) {
 516             if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 517             # while we're checking each line, see if item is in the cart
 518             if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 519                 $line->{'incart'} = 1;
 520             }
 521         }
 522
 523         my $tag_quantity;
 524         if (C4::Context->preference('TagsEnabled') and
 525             $tag_quantity = C4::Context->preference('TagsShowOnList')) {
 526             foreach (@newresults) {
 527                 my $bibnum = $_->{biblionumber} or next;
 528                 $_->{itemsissued} = CountItemsIssued( $bibnum );
 529                 $_ ->{'TagLoop'} = get_tags({biblionumber=>$bibnum, approved=>1, 'sort'=>'-weight',
 530                                         limit=>$tag_quantity });
 531             }
 532         }
 533         if (C4::Context->preference('COinSinOPACResults')) {
 534             foreach (@newresults) {
 535                 my $record = GetMarcBiblio($_->{'biblionumber'});
 536                 $_->{coins} = GetCOinSBiblio($record);
 537                 if ( C4::Context->preference( "Babeltheque" ) and $_->{normalized_isbn} ) {
 538                     my $isbn = Business::ISBN->new( $_->{normalized_isbn} );
 539                     next if not $isbn;
 540                     $isbn = $isbn->as_isbn13->as_string;
 541                     $isbn =~ s/-//g;
 542                     my $social_datas = C4::SocialData::get_data( $isbn );
 543                     next if not $social_datas;
 544                     for my $key ( keys %$social_datas ) {
 545                         $_->{$key} = $$social_datas{$key};
 546                         if ( $key eq 'score_avg' ){
 547                             $_->{score_int} = sprintf("%.0f", $$social_datas{score_avg} );
 548                         }
 549                     }
 550                 }
 551             }
 552         }
 553
 554         if ($results_hashref->{$server}->{"hits"}){
 555             $total = $total + $results_hashref->{$server}->{"hits"};
 556         }
 557
 558         # Opac search history
 559         my $newsearchcookie;
 560         if (C4::Context->preference('EnableOpacSearchHistory')) {
 561             my @recentSearches;
 562
 563             # Getting the (maybe) already sent cookie
 564             my $searchcookie = $cgi->cookie('KohaOpacRecentSearches');
 565             if ($searchcookie){
 566                 $searchcookie = uri_unescape($searchcookie);
 567                 if (thaw($searchcookie)) {
 568                     @recentSearches = @{thaw($searchcookie)};
 569                 }
 570             }
 571
 572             # Adding the new search if needed
 573             if (!$borrowernumber || $borrowernumber eq '') {
 574                 # To a cookie (the user is not logged in)
 575                 if (($params->{'offset'}||'') eq '') {
 576                     push @recentSearches, {
 577                                 "query_desc" => $query_desc || "unknown",
 578                                 "query_cgi"  => $query_cgi  || "unknown",
 579                                 "time"       => time(),
 580                                 "total"      => $total
 581                               };
 582                     $template->param(ShowOpacRecentSearchLink => 1);
 583                 }
 584
 585                 shift @recentSearches if (@recentSearches > 15);
 586                 # Pushing the cookie back
 587                 $newsearchcookie = $cgi->cookie(
 588                             -name => 'KohaOpacRecentSearches',
 589                             # We uri_escape the whole freezed structure so we're sure we won't have any encoding problems
 590                             -value => uri_escape(freeze(\@recentSearches)),
 591                             -expires => ''
 592                 );
 593                 $cookie = [$cookie, $newsearchcookie];
 594             }
 595             else {
 596                 # To the session (the user is logged in)
 597                 if (($params->{'offset'}||'') eq '') {
 598                     AddSearchHistory($borrowernumber, $cgi->cookie("CGISESSID"), $query_desc, $query_cgi, $total);
 599                     $template->param(ShowOpacRecentSearchLink => 1);
 600                 }
 601             }
 602         }
 603         ## If there's just one result, redirect to the detail page
 604         if ($total == 1 && $format ne 'rss2'
 605         && $format ne 'opensearchdescription' && $format ne 'atom') {
 606             my $biblionumber=$newresults[0]->{biblionumber};
 607             if (C4::Context->preference('BiblioDefaultView') eq 'isbd') {
 608                 print $cgi->redirect("/cgi-bin/koha/opac-ISBDdetail.pl?biblionumber=$biblionumber");
 609             } elsif  (C4::Context->preference('BiblioDefaultView') eq 'marc') {
 610                 print $cgi->redirect("/cgi-bin/koha/opac-MARCdetail.pl?biblionumber=$biblionumber");
 611             } else {
 612                 print $cgi->redirect("/cgi-bin/koha/opac-detail.pl?biblionumber=$biblionumber");
 613             }
 614             exit;
 615         }
 616         if ($hits) {
 617             if (!C4::Context->preference('NoZebra') && !$build_grouped_results) {
 618                 # We build the encrypted list of first OPACnumSearchResults biblios to pass with the search criteria for paging on opac-detail
 619                 $pasarParams .= '&amp;listBiblios=';
 620                 my $j = 0;
 621                 foreach (@newresults) {
 622                     my $bibnum = ($_->{biblionumber})?$_->{biblionumber}:0;
 623                     $pasarParams .= $bibnum . ',';
 624                     $j++;
 625                     last if ($j == $results_per_page);
 626                 }
 627                 chop $pasarParams if ($pasarParams =~ /,$/);
 628                 $pasarParams .= '&amp;total=' . int($total) if ($pasarParams !~ /total=(?:[0-9]+)?/);
 629                 if ($pasarParams) {
 630                     my $session = get_session($cgi->cookie("CGISESSID"));
 631                     $session->param('busc' => $pasarParams);
 632                 }
 633                 #
 634             }
 635             $template->param(total => $hits);
 636             my $limit_cgi_not_availablity = $limit_cgi;
 637             $limit_cgi_not_availablity =~ s/&limit=available//g if defined $limit_cgi_not_availablity;
 638             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 639             $template->param(limit_cgi => $limit_cgi);
 640             $template->param(countrss  => $countRSS );
 641             $template->param(query_cgi => $query_cgi);
 642             $template->param(query_desc => $query_desc);
 643             $template->param(limit_desc => $limit_desc);
 644             $template->param(offset     => $offset);
 645             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 646             if ($query_desc || $limit_desc) {
 647                 $template->param(searchdesc => 1);
 648             }
 649             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 650             $template->param(results_per_page =>  $results_per_page);
 651             my $hide = C4::Context->preference('OpacHiddenItems');
 652             $hide = ($hide =~ m/\S/) if $hide; # Just in case it has some spaces/new lines
 653             $template->param(
 654                 SEARCH_RESULTS => \@newresults,
 655                 OPACItemsResultsDisplay => (C4::Context->preference("OPACItemsResultsDisplay") eq "itemdetails"?1:0),
 656                 suppress_result_number => $hide,
 657                             );
 658             if (C4::Context->preference("OPACLocalCoverImages")){
 659                 $template->param(OPACLocalCoverImages => 1);
 660                 $template->param(OPACLocalCoverImagesPriority => C4::Context->preference("OPACLocalCoverImagesPriority"));
 661             }
 662             ## Build the page numbers on the bottom of the page
 663             my @page_numbers;
 664             # total number of pages there will be
 665             my $pages = ceil($hits / $results_per_page);
 666             # default page number
 667             my $current_page_number = 1;
 668             if ($offset) {
 669                 $current_page_number = ( $offset / $results_per_page + 1 );
 670             }
 671             my $previous_page_offset;
 672             if ( $offset >= $results_per_page ) {
 673                 $previous_page_offset = $offset - $results_per_page;
 674             }
 675             my $next_page_offset = $offset + $results_per_page;
 676             # If we're within the first 10 pages, keep it simple
 677             #warn "current page:".$current_page_number;
 678             if ($current_page_number < 10) {
 679                 # just show the first 10 pages
 680                 # Loop through the pages
 681                 my $pages_to_show = 10;
 682                 $pages_to_show = $pages if $pages<10;
 683                 for ($i=1; $i<=$pages_to_show;$i++) {
 684                     # the offset for this page
 685                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 686                     # the page number for this page
 687                     my $this_page_number = $i;
 688                     # put it in the array
 689                     push @page_numbers,
 690                       { offset    => $this_offset,
 691                         pg        => $this_page_number,
 692                         highlight => $this_page_number == $current_page_number,
 693                         sort_by   => join ' ', @sort_by
 694                       };
 695
 696                 }
 697
 698             }
 699             # now, show twenty pages, with the current one smack in the middle
 700             else {
 701                 for ($i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 702                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 703                     my $this_page_number = $i-9;
 704                     if ( $this_page_number <= $pages ) {
 705                         push @page_numbers,
 706                           { offset    => $this_offset,
 707                             pg        => $this_page_number,
 708                             highlight => $this_page_number == $current_page_number,
 709                             sort_by => join ' ', @sort_by
 710                           };
 711                     }
 712                 }
 713
 714             }
 715             $template->param(   PAGE_NUMBERS => \@page_numbers,
 716                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 717             $template->param(next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 718         }
 719         # no hits
 720         else {
 721             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 722         }
 723     } # end of the if local
 724     # asynchronously search the authority server
 725     elsif ($server && $server =~/authorityserver/) { # this is the local authority server
 726         my @inner_sup_results_array;
 727         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 728             my $marc_record_object = MARC::Record->new_from_usmarc($sup_record);
 729             my $title_field = $marc_record_object->field(100);
 730             push @inner_sup_results_array, {
 731                 'title' => $title_field->subfield('a'),
 732                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 733             };
 734         }
 735         my $servername = $server;
 736         push @sup_results_array, {  servername => $servername,
 737                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 738     }
 739     # FIXME: can add support for other targets as needed here
 740     $template->param(           outer_sup_results_loop => \@sup_results_array);
 741 } #/end of the for loop
 742 #$template->param(FEDERATED_RESULTS => \@results_array);
 743
 744 $template->param(
 745             #classlist => $classlist,
 746             total => $total,
 747             opacfacets => 1,
 748             facets_loop => $facets,
 749             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 750             scan => $scan,
 751             search_error => $error,
 752 );
 753
 754 if ($query_desc || $limit_desc) {
 755     $template->param(searchdesc => 1);
 756 }
 757
 758 # VI. BUILD THE TEMPLATE
 759 # Build drop-down list for 'Add To:' menu...
 760 my ($totalref, $pubshelves, $barshelves)=
 761         C4::VirtualShelves::GetSomeShelfNames($borrowernumber,'COMBO',1);
 762 $template->param(
 763         addbarshelves     => $totalref->{bartotal},
 764         addbarshelvesloop => $barshelves,
 765         addpubshelves     => $totalref->{pubtotal},
 766         addpubshelvesloop => $pubshelves,
 767         );
 768
 769 my $content_type = ($format eq 'rss' or $format eq 'atom') ? $format : 'html';
 770
 771 # If GoogleIndicTransliteration system preference is On Set paramter to load Google's javascript in OPAC search screens
 772 if (C4::Context->preference('GoogleIndicTransliteration')) {
 773         $template->param('GoogleIndicTransliteration' => 1);
 774 }
 775
 776 output_with_http_headers $cgi, $cookie, $template->output, $content_type;