opac/opac-sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI;
  24 use Encode qw(decode encode);
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use C4::VirtualShelves;
  35 use C4::Members;
  36 use Koha::Email;
  37
  38 my $query = new CGI;
  39
  40 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  41     {
  42         template_name   => "opac-sendshelfform.tt",
  43         query           => $query,
  44         type            => "opac",
  45         authnotrequired => 0,
  46         flagsrequired   => { borrow => 1 },
  47     }
  48 );
  49
  50 my $shelfid = $query->param('shelfid');
  51 my $email   = $query->param('email');
  52
  53 my $dbh          = C4::Context->dbh;
  54
  55 if ( ShelfPossibleAction( (defined($borrowernumber) ? $borrowernumber : -1), $shelfid, 'view' ) ) {
  56
  57 if ( $email ) {
  58     my $message = Koha::Email->new();
  59     my $comment    = $query->param('comment');
  60
  61     my %mail = $message->create_message_headers(
  62         {
  63             to => $email,
  64         }
  65     );
  66
  67     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  68         {
  69             template_name   => "opac-sendshelf.tt",
  70             query           => $query,
  71             type            => "opac",
  72             authnotrequired => 1,
  73             flagsrequired   => { borrow => 1 },
  74         }
  75     );
  76
  77     my @shelf               = GetShelf($shelfid);
  78     my ($items, $totitems)  = GetShelfContents($shelfid);
  79     my $marcflavour         = C4::Context->preference('marcflavour');
  80     my $iso2709;
  81     my @results;
  82
  83     # retrieve biblios from shelf
  84     foreach my $biblio (@$items) {
  85         my $biblionumber = $biblio->{biblionumber};
  86         my $fw               = GetFrameworkCode($biblionumber);
  87         my $dat              = GetBiblioData($biblionumber);
  88         my $record           = GetMarcBiblio($biblionumber);
  89         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  90         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  91         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  92         my $subtitle         = GetRecordValue('subtitle', $record, $fw);
  93
  94         my @items = GetItemsInfo( $biblionumber );
  95
  96         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  97         $dat->{MARCNOTES}      = $marcnotesarray;
  98         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  99         $dat->{MARCAUTHORS}    = $marcauthorsarray;
 100         $dat->{'biblionumber'} = $biblionumber;
 101         $dat->{ITEM_RESULTS}   = \@items;
 102         $dat->{subtitle}       = $subtitle;
 103         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
 104
 105         $iso2709 .= $record->as_usmarc();
 106
 107         push( @results, $dat );
 108     }
 109
 110     my $user = GetMember(borrowernumber => $borrowernumber);
 111
 112     $template2->param(
 113         BIBLIO_RESULTS => \@results,
 114         email_sender   => $mail{'from'},
 115         comment        => $comment,
 116         shelfname      => $shelf[1],
 117         firstname      => $user->{firstname},
 118         surname        => $user->{surname},
 119     );
 120
 121     # Getting template result
 122     my $template_res = $template2->output();
 123     my $body;
 124
 125     # Analysing information and getting mail properties
 126     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 127         $mail{subject} = $1;
 128         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 129     }
 130     else { $mail{'subject'} = "no subject"; }
 131
 132     my $email_header = "";
 133     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 134         $email_header = $1;
 135         $email_header =~ s|\n?(.*)\n?|$1|;
 136         $email_header = encode_qp($email_header);
 137     }
 138
 139     my $email_file = "list.txt";
 140     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 141         $email_file = $1;
 142         $email_file =~ s|\n?(.*)\n?|$1|;
 143     }
 144
 145     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 146         $body = $1;
 147         $body =~ s|\n?(.*)\n?|$1|;
 148         $body = encode_qp($body);
 149     }
 150
 151     my $boundary = "====" . time() . "====";
 152
 153     # We set and put the multipart content
 154     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 155
 156     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 157     $boundary = '--' . $boundary;
 158
 159     $mail{body} = <<END_OF_BODY;
 160 $boundary
 161 MIME-Version: 1.0
 162 Content-Type: text/plain; charset="utf-8"
 163 Content-Transfer-Encoding: quoted-printable
 164
 165 $email_header
 166 $body
 167 $boundary
 168 Content-Type: application/octet-stream; name="list.iso2709"
 169 Content-Transfer-Encoding: base64
 170 Content-Disposition: attachment; filename="list.iso2709"
 171
 172 $isofile
 173 $boundary--
 174 END_OF_BODY
 175
 176     # Sending mail
 177     if ( sendmail %mail ) {
 178         # do something if it works....
 179         $template->param( SENT      => "1" );
 180     }
 181     else {
 182         # do something if it doesnt work....
 183         carp "Error sending mail: $Mail::Sendmail::error \n";
 184         $template->param( error => 1 );
 185     }
 186
 187     $template->param( email => $email );
 188     output_html_with_http_headers $query, $cookie, $template->output;
 189
 190
 191 }else{
 192     $template->param( shelfid => $shelfid,
 193                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 194                     );
 195     output_html_with_http_headers $query, $cookie, $template->output;
 196 }
 197
 198 } else {
 199     $template->param( invalidlist => 1,
 200                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 201     );
 202     output_html_with_http_headers $query, $cookie, $template->output;
 203 }