opac/opac-sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI;
  24 use Encode qw(encode);
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use C4::VirtualShelves;
  35 use C4::Members;
  36
  37 my $query = new CGI;
  38
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  40     {
  41         template_name   => "opac-sendshelfform.tmpl",
  42         query           => $query,
  43         type            => "opac",
  44         authnotrequired => 1,
  45         flagsrequired   => { borrow => 1 },
  46     }
  47 );
  48
  49 my $shelfid = $query->param('shelfid');
  50 my $email   = $query->param('email');
  51
  52 my $dbh          = C4::Context->dbh;
  53
  54 if ( $email ) {
  55     my $email_from = C4::Context->preference('KohaAdminEmailAddress');
  56     my $comment    = $query->param('comment');
  57
  58     my %mail = (
  59         To   => $email,
  60         From => $email_from
  61     );
  62
  63     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  64         {
  65             template_name   => "opac-sendshelf.tmpl",
  66             query           => $query,
  67             type            => "opac",
  68             authnotrequired => 1,
  69             flagsrequired   => { borrow => 1 },
  70         }
  71     );
  72
  73     my @shelf               = GetShelf($shelfid);
  74     my ($items, $totitems)  = GetShelfContents($shelfid);
  75     my $marcflavour         = C4::Context->preference('marcflavour');
  76     my $iso2709;
  77     my @results;
  78
  79     # retrieve biblios from shelf
  80     foreach my $biblio (@$items) {
  81         my $biblionumber = $biblio->{biblionumber};
  82
  83         my $dat              = GetBiblioData($biblionumber);
  84         my $record           = GetMarcBiblio($biblionumber);
  85         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  86         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  87         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  88
  89         my @items = &GetItemsInfo( $biblionumber, 'opac' );
  90
  91         $dat->{MARCNOTES}      = $marcnotesarray;
  92         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  93         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  94         $dat->{'biblionumber'} = $biblionumber;
  95         $dat->{ITEM_RESULTS}   = \@items;
  96
  97         $iso2709 .= $record->as_usmarc();
  98
  99         push( @results, $dat );
 100     }
 101
 102     my $user = GetMember(borrowernumber => $borrowernumber);
 103
 104     $template2->param(
 105         BIBLIO_RESULTS => \@results,
 106         email_sender   => $email_from,
 107         comment        => $comment,
 108         shelfname      => $shelf[1],
 109         firstname      => $user->{firstname},
 110         surname        => $user->{surname},
 111     );
 112
 113     # Getting template result
 114     my $template_res = $template2->output();
 115     my $body;
 116
 117     # Analysing information and getting mail properties
 118     if ( $template_res =~ /<SUBJECT>\n(.*)\n<END_SUBJECT>/s ) {
 119         $mail{'subject'} = $1;
 120     }
 121     else { $mail{'subject'} = "no subject"; }
 122
 123     my $email_header = "";
 124     if ( $template_res =~ /<HEADER>\n(.*)\n<END_HEADER>/s ) {
 125         $email_header = $1;
 126     }
 127
 128     my $email_file = "basket.txt";
 129     if ( $template_res =~ /<FILENAME>\n(.*)\n<END_FILENAME>/s ) {
 130         $email_file = $1;
 131     }
 132
 133     if ( $template_res =~ /<MESSAGE>\n(.*)\n<END_MESSAGE>/s ) { $body = encode_qp($1); }
 134
 135     my $boundary = "====" . time() . "====";
 136
 137     # We set and put the multipart content
 138     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 139
 140     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 141     $boundary = '--' . $boundary;
 142
 143     $mail{body} = <<END_OF_BODY;
 144 $boundary
 145 Content-Type: text/plain; charset="utf-8"
 146 Content-Transfer-Encoding: quoted-printable
 147
 148 $email_header
 149 $body
 150 $boundary
 151 Content-Type: application/octet-stream; name="shelf.iso2709"
 152 Content-Transfer-Encoding: base64
 153 Content-Disposition: attachment; filename="shelf.iso2709"
 154
 155 $isofile
 156 $boundary--
 157 END_OF_BODY
 158
 159     # Sending mail
 160     if ( sendmail %mail ) {
 161         # do something if it works....
 162         $template->param( SENT      => "1" );
 163     }
 164     else {
 165         # do something if it doesnt work....
 166         carp "Error sending mail: $Mail::Sendmail::error \n";
 167         $template->param( error => 1 );
 168     }
 169
 170     $template->param( email => $email );
 171     output_html_with_http_headers $query, $cookie, $template->output;
 172
 173
 174 }else{
 175     $template->param( shelfid => $shelfid,
 176                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 177                     );
 178     output_html_with_http_headers $query, $cookie, $template->output;
 179 }