Bug 24857: No words
[koha.git] / patron_lists / list.pl
1 #!/usr/bin/perl
2
3 # Copyright 2013 ByWater Solutions
4 #
5 # This file is part of Koha.
6 #
7 # Koha is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # Koha is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
19
20 use Modern::Perl;
21
22 use CGI qw ( -utf8 );
23
24 use C4::Auth qw( get_template_and_user );
25 use C4::Output qw( output_html_with_http_headers );
26 use Koha::List::Patron qw(
27     AddPatronsToList
28     DelPatronsFromList
29     GetPatronLists
30 );
31 use List::MoreUtils qw( uniq );
32
33 my $cgi = CGI->new;
34
35 my ( $template, $logged_in_user, $cookie ) = get_template_and_user(
36     {
37         template_name   => "patron_lists/list.tt",
38         query           => $cgi,
39         type            => "intranet",
40         flagsrequired => { tools => 'manage_patron_lists' },
41     }
42 );
43
44 my ($list) =
45   GetPatronLists( { patron_list_id => scalar $cgi->param('patron_list_id') } );
46
47 my @existing = $list->patron_list_patrons;
48
49 my $patrons_by_id = $cgi->param('patrons_by_id');
50 my $id_column = $cgi->param('id_column');
51
52 if ( $patrons_by_id ){
53     push my @patrons_list, uniq( split(/\s\n/, $patrons_by_id) );
54     my %add_params;
55     $add_params{list} = $list;
56     $add_params{ $id_column } = \@patrons_list;
57     my @results = AddPatronsToList(\%add_params);
58     my $id = $id_column eq 'borrowernumbers' ? 'borrowernumber' : 'cardnumber';
59     my %found = map { $_->borrowernumber->$id => 1 } @results;
60     my %exist = map { $_->borrowernumber->$id => 1 } @existing;
61     my (@not_found, @existed);
62     foreach my $patron ( @patrons_list ){
63         push (@not_found, $patron) unless defined $found{$patron};
64         push (@existed, $patron) if defined $exist{$patron};
65     }
66     $template->param(
67         not_found => \@not_found,
68         existed   => \@existed,
69         id_column => $id_column,
70     );
71 }
72
73 my @patrons_to_add = $cgi->multi_param('patrons_to_add');
74 if (@patrons_to_add) {
75     AddPatronsToList( { list => $list, cardnumbers => \@patrons_to_add } );
76 }
77
78 my @patrons_to_remove = $cgi->multi_param('patrons_to_remove');
79 if (@patrons_to_remove) {
80     DelPatronsFromList( { list => $list, patron_list_patrons => \@patrons_to_remove } );
81 }
82
83 $template->param( list => $list );
84
85 output_html_with_http_headers( $cgi, $cookie, $template->output );