t/db_dependent/Circulation/GetIssues.t

   1 #!/usr/bin/perl
   2
   3 use Modern::Perl;
   4
   5 use Test::More tests => 10;
   6 use Test::MockModule;
   7 use C4::Biblio;
   8 use C4::Items;
   9 use C4::Members;
  10 use C4::Branch;
  11 use C4::Category;
  12 use C4::Circulation;
  13 use MARC::Record;
  14
  15 my $dbh = C4::Context->dbh;
  16 $dbh->{AutoCommit} = 0;
  17 $dbh->{RaiseError} = 1;
  18
  19 $dbh->do(q|DELETE FROM issues|);
  20
  21 my $branchcode;
  22 my $branch_created;
  23 my @branches = keys %{ GetBranches() };
  24 if (@branches) {
  25     $branchcode = $branches[0];
  26 } else {
  27     $branchcode = 'B';
  28     ModBranch({ add => 1, branchcode => $branchcode, branchname => 'Branch' });
  29     $branch_created = 1;
  30 }
  31
  32 my %item_branch_infos = (
  33     homebranch => $branchcode,
  34     holdingbranch => $branchcode,
  35 );
  36
  37 my ($biblionumber1) = AddBiblio(MARC::Record->new, '');
  38 my $itemnumber1 = AddItem({ barcode => '0101', %item_branch_infos }, $biblionumber1);
  39 my $itemnumber2 = AddItem({ barcode => '0102', %item_branch_infos }, $biblionumber1);
  40
  41 my ($biblionumber2) = AddBiblio(MARC::Record->new, '');
  42 my $itemnumber3 = AddItem({ barcode => '0203', %item_branch_infos }, $biblionumber2);
  43
  44 my $categorycode;
  45 my $category_created;
  46 my @categories = C4::Category->all;
  47 if (@categories) {
  48     $categorycode = $categories[0]->{categorycode}
  49 } else {
  50     $categorycode = 'C';
  51     C4::Context->dbh->do(
  52         "INSERT INTO categories(categorycode) VALUES(?)", undef, $categorycode);
  53     $category_created = 1;
  54 }
  55
  56 my $borrowernumber = AddMember(categorycode => $categorycode, branchcode => $branchcode);
  57 my $borrower = GetMember(borrowernumber => $borrowernumber);
  58
  59 # Need to mock userenv for AddIssue
  60 my $module = new Test::MockModule('C4::Context');
  61 $module->mock('userenv', sub { { branch => $branchcode } });
  62 AddIssue($borrower, '0101');
  63 AddIssue($borrower, '0203');
  64
  65 # Begin tests...
  66 my $issues;
  67 $issues = C4::Circulation::GetIssues({biblionumber => $biblionumber1});
  68 is(scalar @$issues, 1, "Biblio $biblionumber1 has 1 item issued");
  69 is($issues->[0]->{itemnumber}, $itemnumber1, "First item of biblio $biblionumber1 is issued");
  70
  71 $issues = C4::Circulation::GetIssues({biblionumber => $biblionumber2});
  72 is(scalar @$issues, 1, "Biblio $biblionumber2 has 1 item issued");
  73 is($issues->[0]->{itemnumber}, $itemnumber3, "First item of biblio $biblionumber2 is issued");
  74
  75 $issues = C4::Circulation::GetIssues({borrowernumber => $borrowernumber});
  76 is(scalar @$issues, 2, "Borrower $borrowernumber checked out 2 items");
  77
  78 $issues = C4::Circulation::GetIssues({borrowernumber => $borrowernumber, biblionumber => $biblionumber1});
  79 is(scalar @$issues, 1, "One of those is an item from biblio $biblionumber1");
  80
  81 $issues = C4::Circulation::GetIssues({borrowernumber => $borrowernumber, biblionumber => $biblionumber2});
  82 is(scalar @$issues, 1, "The other is an item from biblio $biblionumber2");
  83
  84 $issues = C4::Circulation::GetIssues({itemnumber => $itemnumber2});
  85 is(scalar @$issues, 0, "No one has issued the second item of biblio $biblionumber2");
  86
  87 my $onsite_checkouts = GetPendingOnSiteCheckouts;
  88 is( scalar @$onsite_checkouts, 0, "No pending on-site checkouts" );
  89
  90 my $itemnumber4 = AddItem({ barcode => '0104', %item_branch_infos }, $biblionumber1);
  91 AddIssue( $borrower, '0104', undef, undef, undef, undef, { onsite_checkout => 1 } );
  92 $onsite_checkouts = GetPendingOnSiteCheckouts;
  93 is( scalar @$onsite_checkouts, 1, "There is 1 pending on-site checkout" );