t/db_dependent/VirtualShelves.t

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is a test script for C4::VirtualShelves.pm
   5 # Author : Antoine Farnault, antoine@koha-fr.org
   6 #
   7
   8 use strict;
   9 use warnings;
  10 use C4::Context;
  11
  12 use Test::More tests => 92;
  13
  14 # Getting some borrowers from database.
  15 my $dbh = C4::Context->dbh;
  16 my $query = qq/
  17     SELECT borrowernumber
  18     FROM   borrowers
  19     LIMIT  10
  20 /;
  21 my $sth = $dbh->prepare($query);
  22 $sth->execute;
  23 my @borrowers;
  24 while(my $borrower = $sth->fetchrow){
  25     push @borrowers, $borrower;
  26 }
  27
  28 # Getting some biblionumbers from database
  29 $query = qq/
  30     SELECT biblionumber
  31     FROM   biblio
  32     LIMIT  10
  33 /;
  34 $sth = $dbh->prepare($query);
  35 $sth->execute;
  36 my @biblionumbers;
  37 while(my $biblionumber = $sth->fetchrow){
  38     push @biblionumbers, $biblionumber;
  39 }
  40
  41 # ---
  42 my $delete_virtualshelf = qq/
  43     DELETE FROM  virtualshelves WHERE 1
  44 /;
  45 my $delete_virtualshelfcontent =qq/
  46     DELETE  FROM  virtualshelfcontents WHERE 1
  47 /;
  48
  49 $sth = $dbh->prepare($delete_virtualshelf);
  50 $sth->execute;
  51 $sth = $dbh->prepare($delete_virtualshelfcontent);
  52 $sth->execute;
  53 # ---
  54
  55 #----------------------------------------------------------------------#
  56 #
  57 #           TESTS START HERE
  58 #
  59 #----------------------------------------------------------------------#
  60
  61 use_ok('C4::VirtualShelves');
  62
  63 #-----------------------TEST AddShelf function------------------------#
  64 # usage : $shelfnumber = &AddShelf( $shelfname, $owner, $category);
  65
  66 # creating 10 good shelves.
  67 my @shelves;
  68 for(my $i=0; $i<10;$i++){
  69      my $ShelfNumber = AddShelf("Shelf_".$i,$borrowers[$i] || '',int(rand(3))+1);
  70      die "test Not ok, remove some shelves before" if ($ShelfNumber == -1);
  71      ok($ShelfNumber > -1, "created shelf");   # Shelf creation successful;
  72      push @shelves, $ShelfNumber if $ShelfNumber > -1;
  73 }
  74
  75 ok(10 == scalar @shelves, 'created 10 lists'); # 10 shelves in @shelves;
  76
  77 # try to create some shelf which already exists.
  78 for(my $i=0;$i<10;$i++){
  79     my $badNumShelf = AddShelf("Shelf_".$i,$borrowers[$i] || '','');
  80     ok(-1 == $badNumShelf, 'do not create lists with duplicate names');   # AddShelf returns -1 if name already exist.
  81 }
  82
  83 #-----------TEST AddToShelf & GetShelfContents &  DelFromShelf functions--------------#
  84 # usage : &AddToShelf($biblionumber, $shelfnumber);
  85 # usage : $biblist = &GetShelfContents($shelfnumber);
  86 # usage : $biblist = GetShelfContents($shelfnumber);
  87
  88 my %used = ();
  89 for(my $i=0; $i<10;$i++){
  90     my $bib = $biblionumbers[int(rand(9))];
  91     my $shelfnumber = $shelves[int(rand(9))];
  92
  93     my $key = "$bib\t$shelfnumber";
  94     my $should_fail if exists $used{$key};
  95
  96     my ($biblistBefore,$countbefore) = GetShelfContents($shelfnumber);
  97     my $status = AddToShelf($bib,$shelfnumber);
  98     my ($biblistAfter,$countafter) = GetShelfContents($shelfnumber);
  99
 100     if ($should_fail) {
 101         ok(!defined($status), 'failed to add to list when we should');
 102     } else {
 103         ok(defined($status), 'added to list when we should');
 104     }
 105
 106     if (defined $status) {
 107         ok($countbefore == $countafter - 1, 'added bib to list');  # the bib has been successfuly added.
 108     } else {
 109         ok($countbefore == $countafter,     'did not add duplicate bib to list');  # the bib has been successfuly added.
 110     }
 111
 112     $used{$key}++;
 113
 114 }
 115
 116 #-----------------------TEST ModShelf & GetShelf functions------------------------#
 117 # usage : ModShelf($shelfnumber, $shelfname, $owner, $category )
 118 # usage : (shelfnumber,shelfname,owner,category) = GetShelf($shelfnumber);
 119
 120 for(my $i=0; $i<10;$i++){
 121     my $rand = int(rand(9));
 122     my $numA = $shelves[$rand];
 123     my $shelf = { shelfname => "NewName_".$rand,
 124         owner => $borrowers[$rand],
 125         category =>  int(rand(3))+1 };
 126
 127     ModShelf($numA,$shelf);
 128     my ($numB,$nameB,$ownerB,$categoryB) = GetShelf($numA);
 129
 130     ok($numA == $numB, 'modified shelf');
 131     ok($shelf->{shelfname} eq $nameB,     '... and name change took');
 132     ok($shelf->{owner}     eq $ownerB,    '... and owner change took');
 133     ok($shelf->{category}  eq $categoryB, '... and category change took');
 134 }
 135
 136 #-----------------------TEST DelShelf & DelFromShelf functions------------------------#
 137 # usage : ($status) = &DelShelf($shelfnumber);
 138
 139 for(my $i=0; $i<10;$i++){
 140     my $shelfnumber = $shelves[$i];
 141     my $status = DelShelf($shelfnumber);
 142     ok(1 == $status, "deleted shelf $shelfnumber and its contents");
 143 }