tools/viewlog.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2010 BibLibre
   4 # Copyright 2011 MJ Ray and software.coop
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use C4::Auth;
  24 use CGI qw ( -utf8 );
  25 use Text::CSV::Encoded;
  26 use C4::Context;
  27 use C4::Koha;
  28 use C4::Output;
  29 use C4::Log;
  30 use C4::Items;
  31 use C4::Branch;
  32 use C4::Debug;
  33 use C4::Search;    # enabled_staff_search_views
  34
  35 use vars qw($debug $cgi_debug);
  36
  37 =head1 viewlog.pl
  38
  39 plugin that shows stats
  40
  41 =cut
  42
  43 my $input = new CGI;
  44
  45 $debug or $debug = $cgi_debug;
  46 my $do_it    = $input->param('do_it');
  47 my @modules  = $input->param("modules");
  48 my $user     = $input->param("user") // '';
  49 my @actions  = $input->param("actions");
  50 my $object   = $input->param("object");
  51 my $info     = $input->param("info");
  52 my $datefrom = $input->param("from");
  53 my $dateto   = $input->param("to");
  54 my $basename = $input->param("basename");
  55 my $output   = $input->param("output") || "screen";
  56 my $src      = $input->param("src") || ""; # this param allows us to be told where we were called from -fbcit
  57
  58 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  59     {
  60         template_name   => "tools/viewlog.tt",
  61         query           => $input,
  62         type            => "intranet",
  63         authnotrequired => 0,
  64         flagsrequired   => { tools => 'view_system_logs' },
  65         debug           => 1,
  66     }
  67 );
  68
  69 if ( $src eq 'circ' ) {
  70
  71     # if we were called from circulation, use the circulation menu and get data to populate it -fbcit
  72     use C4::Members;
  73     use C4::Members::Attributes qw(GetBorrowerAttributes);
  74     my $borrowernumber = $object;
  75     my $data = GetMember( 'borrowernumber' => $borrowernumber );
  76     my ( $picture, $dberror ) = GetPatronImage( $data->{'borrowernumber'} );
  77     $template->param( picture => 1 ) if $picture;
  78
  79     if ( C4::Context->preference('ExtendedPatronAttributes') ) {
  80         my $attributes = GetBorrowerAttributes( $data->{'borrowernumber'} );
  81         $template->param(
  82             ExtendedPatronAttributes => 1,
  83             extendedattributes       => $attributes
  84         );
  85     }
  86
  87     my $roadtype = C4::Koha::GetAuthorisedValueByCode( 'ROADTYPE', $data->{streettype} );
  88     $template->param(%$data);
  89
  90     $template->param(
  91         menu           => 1,
  92         borrowernumber => $borrowernumber,
  93         categoryname   => $data->{'description'},
  94         roadtype       => $roadtype,
  95         branchname     => GetBranchName( $data->{'branchcode'} ),
  96         RoutingSerials => C4::Context->preference('RoutingSerials'),
  97     );
  98 }
  99
 100 $template->param(
 101     debug => $debug,
 102     C4::Search::enabled_staff_search_views,
 103     object => $object,
 104 );
 105
 106 if ($do_it) {
 107
 108     my @data;
 109     my ( $results, $modules, $actions );
 110     if ( defined $actions[0] && $actions[0] ne '' ) { $actions  = \@actions; }     # match All means no limit
 111     if ( $modules[0] ne '' ) { $modules = \@modules; }    # match All means no limit
 112     $results = GetLogs( $datefrom, $dateto, $user, $modules, $actions, $object, $info );
 113     @data = @$results;
 114     foreach my $result (@data) {
 115
 116         # Init additional columns for CSV export
 117         $result->{'biblionumber'}      = q{};
 118         $result->{'biblioitemnumber'}  = q{};
 119         $result->{'barcode'}           = q{};
 120         $result->{'userfirstname'}     = q{};
 121         $result->{'usersurname'}       = q{};
 122         $result->{'borrowerfirstname'} = q{};
 123         $result->{'borrowersurname'}   = q{};
 124
 125         if ( substr( $result->{'info'}, 0, 4 ) eq 'item' || $result->{module} eq "CIRCULATION" ) {
 126
 127             # get item information so we can create a working link
 128             my $itemnumber = $result->{'object'};
 129             $itemnumber = $result->{'info'} if ( $result->{module} eq "CIRCULATION" );
 130             my $item = GetItem($itemnumber);
 131             if ($item) {
 132                 $result->{'biblionumber'}     = $item->{'biblionumber'};
 133                 $result->{'biblioitemnumber'} = $item->{'biblionumber'};
 134                 $result->{'barcode'}          = $item->{'barcode'};
 135             }
 136         }
 137
 138         #always add firstname and surname for librarian/user
 139         if ( $result->{'user'} ) {
 140             my $userdetails = C4::Members::GetMemberDetails( $result->{'user'} );
 141             if ($userdetails) {
 142                 $result->{'userfirstname'} = $userdetails->{'firstname'};
 143                 $result->{'usersurname'}   = $userdetails->{'surname'};
 144             }
 145         }
 146
 147         #add firstname and surname for borrower, when using the CIRCULATION, MEMBERS, FINES
 148         if ( $result->{module} eq "CIRCULATION" || $result->{module} eq "MEMBERS" || $result->{module} eq "FINES" ) {
 149             if ( $result->{'object'} ) {
 150                 my $borrowerdetails = C4::Members::GetMemberDetails( $result->{'object'} );
 151                 if ($borrowerdetails) {
 152                     $result->{'borrowerfirstname'} = $borrowerdetails->{'firstname'};
 153                     $result->{'borrowersurname'}   = $borrowerdetails->{'surname'};
 154                 }
 155             }
 156         }
 157     }
 158
 159     if ( $output eq "screen" ) {
 160
 161         # Printing results to screen
 162         $template->param(
 163             logview  => 1,
 164             total    => scalar @data,
 165             looprow  => \@data,
 166             do_it    => 1,
 167             datefrom => $datefrom,
 168             dateto   => $dateto,
 169             user     => $user,
 170             info     => $info,
 171             src      => $src,
 172             modules  => \@modules,
 173             actions  => \@actions,
 174         );
 175
 176         # Used modules
 177         foreach my $module (@modules) {
 178             $template->param( $module => 1 );
 179         }
 180
 181         output_html_with_http_headers $input, $cookie, $template->output;
 182     }
 183     else {
 184
 185         # Printing to a csv file
 186         my $content = q{};
 187         my $delimiter = C4::Context->preference('delimiter') || ',';
 188         if (@data) {
 189             my $csv = Text::CSV::Encoded->new( { encoding_out => 'utf8', sep_char => $delimiter } );
 190             $csv or die "Text::CSV::Encoded->new FAILED: " . Text::CSV::Encoded->error_diag();
 191
 192             # First line with heading
 193             # Exporting bd id seems useless
 194             my @headings = grep { $_ ne 'action_id' } sort keys %{$data[0]};
 195             if ( $csv->combine(@headings) ) {
 196                 $content .= $csv->string() . "\n";
 197             }
 198
 199             # Lines of logs
 200             foreach my $line (@data) {
 201                 my @cells = map { $line->{$_} } @headings;
 202                 if ( $csv->combine(@cells) ) {
 203                     $content .= $csv->string() . "\n";
 204                 }
 205             }
 206         }
 207
 208         # Output
 209         print $input->header(
 210             -type       => 'text/csv',
 211             -attachment => $basename . '.csv',
 212         );
 213         print $content;
 214     }
 215     exit;
 216 }
 217 else {
 218     output_html_with_http_headers $input, $cookie, $template->output;
 219 }