virtualshelves/downloadshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw(encode);
  24
  25 use C4::Auth;
  26 use C4::Biblio;
  27 use C4::Items;
  28 use C4::Output;
  29 use C4::Record;
  30 use C4::Ris;
  31
  32 use Koha::CsvProfiles;
  33 use Koha::Virtualshelves;
  34
  35 use utf8;
  36 my $query = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user (
  39     {
  40         template_name   => "virtualshelves/downloadshelf.tt",
  41         query           => $query,
  42         type            => "intranet",
  43         authnotrequired => 0,
  44         flagsrequired   => { catalogue => 1 },
  45     }
  46 );
  47
  48 my $shelfid = $query->param('shelfid');
  49 my $format  = $query->param('format');
  50 my $dbh     = C4::Context->dbh;
  51 my @messages;
  52
  53 if ($shelfid && $format) {
  54
  55     my $marcflavour         = C4::Context->preference('marcflavour');
  56     my $output='';
  57
  58     my $shelf = Koha::Virtualshelves->find($shelfid);
  59     if ( $shelf ) {
  60         if ( $shelf->can_be_viewed( $loggedinuser ) ) {
  61
  62             my $contents = $shelf->get_contents;
  63             # CSV
  64             if ($format =~ /^\d+$/) {
  65                 my @biblios;
  66                 while ( my $content = $contents->next ) {
  67                     push @biblios, $content->biblionumber;
  68                 }
  69                 $output = marc2csv(\@biblios, $format);
  70             }
  71             else { #Other formats
  72                 while ( my $content = $contents->next ) {
  73                     my $biblionumber = $content->biblionumber;
  74                     my $record = GetMarcBiblio({
  75                         biblionumber => $biblionumber,
  76                         embed_items  => 1 });
  77                     if ($format eq 'iso2709') {
  78                         $output .= $record->as_usmarc();
  79                     }
  80                     elsif ($format eq 'ris') {
  81                         $output .= marc2ris($record);
  82                     }
  83                     elsif ($format eq 'bibtex') {
  84                         $output .= marc2bibtex($record, $biblionumber);
  85                     }
  86                 }
  87             }
  88
  89             # If it was a CSV export we change the format after the export so the file extension is fine
  90             $format = "csv" if ($format =~ m/^\d+$/);
  91
  92             print $query->header(
  93             -type => 'application/octet-stream',
  94             -'Content-Transfer-Encoding' => 'binary',
  95             -attachment=>"shelf.$format");
  96             print $output;
  97             exit;
  98         } else {
  99             push @messages, { type => 'error', code => 'unauthorized' };
 100         }
 101     } else {
 102         push @messages, { type => 'error', code => 'does_not_exist' };
 103     }
 104 }
 105 else {
 106     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc', used_for => 'export_records' }) ]);
 107     $template->param(shelfid => $shelfid);
 108 }
 109 $template->param( messages => \@messages );
 110 output_html_with_http_headers $query, $cookie, $template->output;